Amiga MA Magazine 1998 #3/amigamamagazinepolishissue1998.iso/bazy/muivideo/muivideo.install

Text File | 1996-11-25 | 6KB | 253 lines

; *****************************
; *                           *
; *   MUIVideo-Install 0.97   *
; *          25.11.96         *
; *       © 1996 by mice      *
; *    und Christoph Kirsch   *
; *        - AMCLUST -        *
; *                           *
; *****************************


(complete 0)

; Text-Strings

(set #falsekick
(cat "\nMUIVideo und MUITapes benoetigen zwingend OS3.0 oder höher."
))

(set #info
(cat "\n\nDieses Script installiert MUIVideo und alle "
     "dazugehörigen Dateien auf Ihre Festplatte. "
     "Bei der Installation wird ein Verzeichnis mit Namen "
     "\"MUIVideo\" angelegt in das alle wichtigen "
     "Programmteile kopiert werden."
))

(set #info2
(cat "\n\nIm folgenden wird ihnen eine Textdatei angezeigt, "
     "die Sie ueber die gravierendsten Aenderungen und "
     "Neuerungen dieser Version von \"MUIVideo\" informiert. "
     "Bitte lesen Sie den Text aufmerksam durch ! "
     "Weitere Informationen entnehmen Sie bitte dem Guidefile."
))

(set #changes
(cat "\nCHANGES MUIVideo 2.00\n\n"
))

(set #oldmv
(cat "\nEs wurde eine MUIVideo-Installation gefunden !\n\n"
))

(set #oldmvbak
(cat "\n\nVon der alten Installation wird nun eine Sicherheitskopie"
     "mit Namen \"MUIVideo_old\" angelegt"
))


(set #muivhelp
(cat "\nMUIVideo ist eine Datenbank zur Filmverwaltung, deren "
     "Oberfläche mit Hilfe von @{"MUI" LINK MUI} erzeugt wurde."
))

(set #datamess
(cat "\nIm folgenden werden alle von MUIVideo benoetigten "
     "Datenfiles kopiert."
))

(set #prefsmess
(cat "\nNun werden die Default-Prefs zu MUIVideo installiert."
))

(set #arexxmess
(cat "\nEs werden alle bisher verfügbaren ARexx-Scripte für "
     "MUIVideo installiert."
))

(set #readme
(cat "\nAenderungen zur Version 1.5"
))

(set #mtmess
(cat "\nSoll das Zusatzprogramm MUITapes installiert werden ?"
     "\n\nMUITapes  ist  ein  Zusatzmodul  zu  dem  Programm   MUIVideo. "
     "MUITapes ergänzt MUIVideo nun um  eine  Cassettenverwaltung.  Der "
     "Datenaustausch  erfolgt  dabei  über  die  ARexx-Ports der beiden "
     "Programme."
))

; Test-Kick

(if (< (/ (getversion) 65536) 39)
    (abort #falsekick)
)

; Infotexte anzeigen

(message #info)
(message #info2)
(run "run >NIL: SYS:Utilities/MultiView LIES_MICH!" (prompt #readme))

; Zielverzeichnis fuer MUIVideo wählen

(set mvdest
          (askdir (prompt "Bitte das Ziel für das MUIVideo wählen. Ein Verzeichnis \"MUIVideo\" wird angelegt.")
                  (help #imhelp @askdir-help)
                  (default "Work:")
          )
)

(set mvdest (tackon mvdest "MUIVideo"))
(set @default-dest mvdest)

; Auf bereits installiertes MUIVideo checken

(if (exists mvdest)
(
    (set oldmv (cat mvdest "_old"))
    (
        (message #oldmv "'" @default-dest "'." #oldmvbak)
        (rename mvdest oldmv)
        (rename (cat mvdest ".info") (cat oldmv ".info"))
    )
))

; Verzeichnisse anlegen

(makedir mvdest (infos) (prompt "Verzeichnisse werden angelegt..."))
(makedir (tackon mvdest "ARexx"))
(makedir (tackon mvdest "Data"))
(makedir (tackon mvdest "Prefs"))
(copyfiles
        (prompt ("Kopiere Piktogramme nach %s " mvdest))
        (source "ARexx.info")
        (dest mvdest)
)
(copyfiles
        (prompt ("Kopiere Piktogramme nach %s " mvdest))
        (source "Data.info")
        (dest mvdest)
)
(copyfiles
        (prompt ("Kopiere Piktogramme nach %s " mvdest))
        (source "Prefs.info")
        (dest mvdest)
)

(complete 10)

; Hauptprogramm und Zusatzdateien kopieren

(copyfiles
        (prompt ("Kopiere MUIVideo nach %s " mvdest))
        (source "MUIVideo")
        (dest mvdest)
        (infos)
)

(copyfiles
        (source "LIES_MICH!")
        (dest mvdest)
        (infos)
)

(complete 30)

; Guidefile kopieren

(set vote
        (askbool
                (prompt "\nSoll das Guide zu MUIVideo installiert werden ?")
                (choices "Ja" "Nein")
                (help #guidehelp)
        )
)
(if (= 1 vote)
        (copyfiles
                (prompt ("Kopiere MUIVideo.guide nach %s ." mvdest))
                (source "MUIVideo.guide")
                (dest mvdest)
                (infos)
                (help @copyfiles-help)
        )
)

(complete 40)

; Datenfiles installieren

(message #datamess)

(set mddest (tackon mvdest "Data"))

(copyfiles
        (prompt ("Kopiere MUIVideo-Daten nach %s " mvdest))
        (source "Data")
        (all)
        (dest mddest)
        (help @copyfiles-help)
)

(complete 60)

(message #prefsmess)

(set mpdest (tackon mvdest "Prefs"))

(copyfiles
        (prompt ("Kopiere MUIVideo-Prefs nach %s " mvdest))
        (source "Prefs")
        (all)
        (dest mpdest)
        (help @copyfiles-help)
)

(complete 70)

(message #arexxmess)

(set madest (tackon mvdest "ARexx"))

(copyfiles
        (prompt ("Kopiere MUIVideo-Arexx nach %s " mvdest))
        (source "ARexx")
        (all)
        (dest madest)
        (help @copyfiles-help)
)

(complete 80)

; MUITapes installieren ?

(set vote
        (askbool
                (prompt #mtmess)
                (choices "Ja" "Nein")
                (help #guidehelp)
        )
)

(if (= 1 vote)
    (
         (set mtdest (tackon mvdest "MUITapes"))
         (copyfiles
               (source "MUITapes.info")
               (dest mvdest)
               (help @copyfiles-help)
         )
         (copyfiles
               (prompt ("Kopiere MUITapes nach %s " mvdest))
               (source "MUITapes")
               (all)
               (dest mtdest)
               (help @copyfiles-help)
        )
    )
)

(complete 100)