home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga MA Magazine 1998 #3
/
amigamamagazinepolishissue1998.iso
/
bazy
/
adm
/
arexx
/
adm-arexxmakros.lha
/
ImExport
/
PageStream3_SerienbrExport.adm
< prev
next >
Wrap
Text File
|
1996-03-04
|
3KB
|
118 lines
/* $VER: PageStream3_SerienbrExport.adm 1.0 (1.3.96)
Exportiert Daten für PageStream3 zum Serienbriefdruck.
- Dieses Makro vom ADM-Menü aus aufrufen und den Dateiname
auswählen. Das Makro erstellt dann diese Datei, die die
Adressdaten enthaelt.
- Dann das MailMerge-Makro im PageStream3-Dokument ausführen (mit
"Makros/ARexx-Skript ausführen...") und im dann erscheinenden
Dateiauswahlfenster die hier erstellte Datei "Adressen.csv"
im Laufwerk "RAM:" auswählen.
PageStream3 legt nun im Dokument Variablen an, die dann in den
Dokumententext eingefügt werden können und im "Serienbrief" dann
ersetzt werden.
- Danach können mit dem Menüpunkt
"Variable einfügen » benutzerdefinierter Text..."
in PageStream3 die folgenden Variablen in den Text eingefügt
werden:
«Firma»
«Anrede»
«Briefanrede» (*)
«Vorname»
«Nachname»
«Adresse1»
«Adresse2»
«PLZ»
«Ort»
«Telefon»
«Fax»
«EMail»
zu (*): "Sehr geehrt«Briefanrede» «Anrede» «Nachname»"
ergibt korrekte Anrede/Begrüßung.
- Ein erneuter Aufruf des MailMerge-Makros startet den Seriendruck.
von Jan Geißler.
*/
OPTIONS RESULTS
ACTIVATEFIRST
ADDRINMEM
anzahl = RESULT
/* RexxReqTools-Library öffnen */
reqname = "rexxreqtools.library"
if ~show("L", reqname) then
if ~addlib(reqname, 0, -30, 0) then do
say reqname "not found!"
EXIT
end
/* Filename-Filerequester */
NL = "0a"x
rqdir = "ram:"
rqtitle = "PageStream3-Serienbriefdatei abspeichern"
rqfile = "Adressen.csv"
rqok = "Speichern"
rqflags = "rtfi_flags=freqf_save"
filename = rtfilerequest(rqdir,rqfile,rqtitle,rqok,rqflags,)
if filename = "" then do
call rtezrequest("Keine Datei ausgewählt", "Abbruch")
EXIT
end
IF ~OPEN(file,filename,"W") THEN DO /* Ausgabedatei öffnen */
SAY "Kann Ausgabedatei nicht öffnen!"
EXIT
END
dd = "09"x
text = "Firma" || dd || "Anrede" || dd || "Briefanrede" || dd || "Vorname" || dd || "Nachname" || dd || "Adresse1" || dd || "Adresse2" || dd || "PLZ" || dd || "Ort" || dd || "Telefon" || dd || "Fax" || dd || "EMail"
ok = WRITELN(file,text)
DO FOR anzahl
GETADDRESS ADM
IF ADM.salutation = "Herrn" THEN DO
salute = "er";
ADM.salutation = "Herr"
END
ELSE IF ADM.salutation = "Frau" THEN salute = "e"
ELSE salute = ""
text = ADM.company || dd || ADM.salutation || dd || salute || dd || ADM.firstname || dd || STRIP( ADM.title ADM.lastname) || dd || ADM.address1 || dd || ADM.address2 || dd || ADM.postcode || dd || ADM.city || dd || ADM.telephone || dd || ADM.fax || dd || ADM.email1
ok = WRITELN(file,text)
ACTIVATENEXT
END
ok = Close(file)
/* ----- Inforequester */
text = "Die Daten wurden nun in der Datei" filename" abgelegt." NL||,
"Starten Sie nun PageStream3 und starten das PageStream3-" NL||,
"Makro 'MailMerge'. Wählen Sie dann die o.g. Datei wieder aus," NL||,
"MailMerge erstellt nun Dokument-Variablen, die mit der Funktion" NL||,
"'Variable einfügen » benutzerdefinierter Text...' ins Dokument" NL||,
"eingefügt werden können." NL||,
"Ein erneuter Aufruf von 'MailMerge' druckt den Serienbrief."
CALL RTEZREQUEST(text,"_OK","PageStream3-Serienbrief",,"rtez_defaultresponse=1")