home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_per.asm < prev    next >
Assembly Source File  |  1998-06-08  |  33KB  |  1,340 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_per.asm $
  13. ; $Revision: 1.26 $
  14. ; $Author: john $
  15. ; $Date: 1995/02/20 18:22:55 $
  16. ;
  17. ; Perspective texture mapper inner loop.
  18. ;
  19. ; $Log: tmap_per.asm $
  20. ; Revision 1.26  1995/02/20  18:22:55  john
  21. ; Put all the externs in the assembly modules into tmap_inc.asm.
  22. ; Also, moved all the C versions of the inner loops into a new module, 
  23. ; scanline.c.
  24. ; 
  25. ; Revision 1.25  1995/02/20  17:09:08  john
  26. ; Added code so that you can build the tmapper with no assembly!
  27. ; 
  28. ; Revision 1.24  1995/01/10  09:32:07  mike
  29. ; mostly fix garbage at end of scanline, but slow down by 1-4%.
  30. ; 
  31. ; Revision 1.23  1994/12/02  23:29:57  mike
  32. ; optimizations.
  33. ; 
  34. ; Revision 1.22  1994/11/30  00:57:00  mike
  35. ; optimization.
  36. ; 
  37. ; Revision 1.21  1994/11/21  13:57:42  mike
  38. ; fix right side shear bug
  39. ; 
  40. ; Revision 1.20  1994/11/12  16:41:09  mike
  41. ; jae -> ja.
  42. ; 
  43. ; Revision 1.19  1994/10/27  19:40:00  john
  44. ; Made lighting table lookup be _gr_fade_table[eax] instead
  45. ; of fs:[eax], which gets rig of a segment override that 
  46. ; supposedly costs 1 clock on a 486.  Mainly, I wanted to verify
  47. ; that the only reason we need selectors is for the source texture
  48. ; data .
  49. ; 
  50. ; Revision 1.18  1994/05/03  11:08:32  mike
  51. ; Trap divide overflows.
  52. ; 
  53. ; Revision 1.17  1994/04/21  15:03:41  mike
  54. ; make faster.
  55. ; 
  56. ; Revision 1.16  1994/04/08  16:46:57  john
  57. ; Made 32 fade levels. Hacked.
  58. ; 
  59. ; Revision 1.15  1994/03/31  08:35:18  mike
  60. ; Fix quantized-by-4 bug in inner loop.
  61. ; 
  62. ; Revision 1.14  1994/03/14  17:41:14  mike
  63. ; Fix bug in unlighted version.
  64. ; 
  65. ; Revision 1.13  1994/03/14  15:45:14  mike
  66. ; streamline code.
  67. ; 
  68. ; Revision 1.12  1994/01/14  14:01:58  mike
  69. ; *** empty log message ***
  70. ; 
  71. ; Revision 1.11  1993/12/18  14:43:44  john
  72. ; Messed around with doing 1/z, the u*(1/z) and v*(1/z)
  73. ; (Went from 23 fps to 21 fps... not good! )
  74. ;
  75. ; Revision 1.10  1993/12/17  16:14:17  john
  76. ; Split lighted/nonlighted, so there is no cmp lighting
  77. ; in the inner loop. 
  78. ; 
  79. ; Revision 1.9  1993/12/17  12:34:29  john
  80. ; Made leftover bytes use linear approx instead of correct...
  81. ; should save about 8 divides per scanline on average.
  82. ; Also, took out anti-aliasing code and rearranged to
  83. ; order of some instructions to help on 486 pipelining.
  84. ; (The anti-aliasing code did *not* look good, so I
  85. ; figure there was no reason to keep it in. )
  86. ; 
  87. ; Revision 1.8  1993/12/16  18:37:52  mike
  88. ; Align some stuff on 4 byte boundaries.
  89. ; 
  90. ; Revision 1.7  1993/11/30  08:44:18  john
  91. ; Made selector set check for < 64*64 bitmaps.
  92. ; 
  93. ; Revision 1.6  1993/11/23  17:25:26  john
  94. ; Added safety "and eax, 0fffh" in lighting lookup.
  95. ; 
  96. ; Revision 1.5  1993/11/23  15:08:52  mike
  97. ; Fixed lighting bug. 
  98. ; 
  99. ; Revision 1.4  1993/11/23  14:38:50  john
  100. ; optimized NORMAL code by switching EBX and ESI, so BH can be used in
  101. ; the lighting process.
  102. ; 
  103. ; Revision 1.3  1993/11/23  14:30:53  john
  104. ; Made the perspective tmapper do 1/8 divides; added lighting.
  105. ; 
  106. ; Revision 1.2  1993/11/22  10:24:59  mike
  107. ; *** empty log message ***
  108. ; 
  109. ; Revision 1.1  1993/09/08  17:29:53  mike
  110. ; Initial revision
  111. ; 
  112. ;
  113. ;
  114.  
  115.     .386
  116.  
  117.     public    asm_tmap_scanline_per_
  118.  
  119.     include    tmap_inc.asm
  120.  
  121.     public _max_ecx,_min_ecx
  122.  
  123.  
  124. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  125.     align    4
  126. mem_edx dd ?
  127. ;**_v_window_left    dd    _window_left
  128. ;**_v_window_right    dd    _window_right
  129. ;**_v_window_top    dd    _window_top
  130. ;**_v_window_bottom    dd    _window_bottom
  131.  
  132. ; ---------- These are passed in by the C caller ----------
  133. ; ----------^^ These are passed in by the C caller ^^----------
  134.  
  135.     public    _x,_loop_count, new_end
  136.     align    4
  137. _x    dd    ?
  138. _loop_count    dd    ?
  139.  
  140. _max_ecx    dd    0
  141. _min_ecx    dd    55555555h
  142.  
  143. extern _per2_flag:dword
  144. new_end    dd    1    ; if set, use new, but slower, way of finishing off extra pixels on scanline, 01/10/95 --MK
  145.  
  146.  
  147.     public    _scan_doubling_flag, _linear_if_far_flag
  148.  
  149. _scan_doubling_flag    dd 0
  150. _linear_if_far_flag    dd 0
  151.  
  152. ;---------- local variables
  153.     align    4
  154. req_base    dd    ?
  155. req_size    dd    ?
  156. U0    dd    ?
  157. U1    dd    ?
  158. V0    dd    ?
  159. V1    dd    ?
  160. num_left_over    dd    ?
  161. DU1    dd    ?
  162. DV1    dd    ?
  163. DZ1    dd    ?
  164. ;**_fx_dl_dx1    dd    ?
  165. ;**_fx_dl_dx2    dd    ?
  166.  
  167. _DATA    ENDS
  168.  
  169. DGROUP    GROUP    _DATA
  170.  
  171.  
  172. _TEXT   SEGMENT PARA PUBLIC USE32 'CODE'
  173.     ASSUME    DS:_DATA
  174.     ASSUME    CS:_TEXT
  175.  
  176. ; --------------------------------------------------------------------------------------------------
  177. ; Enter:
  178. ;    _xleft    fixed point left x coordinate
  179. ;    _xright    fixed point right x coordinate
  180. ;    _y    fixed point y coordinate
  181. ;    _pixptr    address of source pixel map
  182. ;    _u    fixed point initial u coordinate
  183. ;    _v    fixed point initial v coordinate
  184. ;    _z    fixed point initial z coordinate
  185. ;    _du_dx    fixed point du/dx
  186. ;    _dv_dx    fixed point dv/dx
  187. ;    _dz_dx    fixed point dz/dx
  188.  
  189. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  190. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  191. ;      _setpixel(x,y);
  192. ;
  193. ;      u += du_dx;
  194. ;      v += dv_dx;
  195. ;      z += dz_dx;
  196. ;   }
  197.  
  198.  
  199. ;;goto_none_to_do:
  200. ;; int 3    ; thinking this can't get hit, if so, kill compare against _window_bottom
  201. ;; jmp _none_to_do
  202.     align    16
  203. asm_tmap_scanline_per_:
  204.     push    es
  205.     pusha
  206.     
  207. ;---------------------------- setup for loop ---------------------------------
  208. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  209. ;    esi    source pixel pointer = pixptr
  210. ;    edi    initial row pointer = y*320+x
  211. ; NOTE: fx_xright and fx_xleft changed from fix to int by mk on 12/01/94.
  212.  
  213. ; set esi = pointer to start of texture map data
  214.  
  215. ; set edi = address of first pixel to modify
  216.     mov    edi,_fx_y
  217.     mov    es,_pixel_data_selector    ; selector[0*2]
  218. ;;    cmp    edi,_window_bottom
  219. ;;    ja    goto_none_to_do
  220.  
  221.     mov    edi,_y_pointers[edi*4]
  222.  
  223.     mov    ebx,_fx_xleft
  224.     test    ebx, ebx
  225.     jns    ebx_ok
  226.     xor    ebx, ebx
  227. ebx_ok:    add    edi,write_buffer
  228.     add    edi,ebx
  229.  
  230. ; set _loop_count = # of iterations
  231.     mov    eax,_fx_xright
  232. ;;    cmp    eax,_window_right
  233. ;;    jl    eax_ok1
  234. ;;    mov    eax,_window_right
  235. ;;eax_ok1:
  236. ;;    cmp    eax,_window_left
  237. ;;    jg    eax_ok2
  238. ;;    mov    eax,_window_left
  239. ;;eax_ok2:
  240.     sub    eax,ebx
  241.     js    _none_to_do
  242. ;;    cmp    eax,_window_width
  243. ;;    jbe    _ok_to_do
  244. ;;    mov    eax,_window_width
  245. ;;_ok_to_do:
  246.     mov    _loop_count,eax
  247.  
  248. ; lighting values are passed in fixed point, but need to be in 8 bit integer, 8 bit fraction so we can easily
  249. ; get the integer by reading %bh
  250.     sar    _fx_l, 8
  251.     sar    _fx_dl_dx,8
  252.     jns    dl_dx_ok
  253.     inc    _fx_dl_dx    ; round towards 0 for negative deltas
  254. dl_dx_ok:
  255.  
  256. ; set initial values
  257.     mov    ebx,_fx_u
  258.     mov    ebp,_fx_v
  259.     mov    ecx,_fx_z
  260.  
  261.     test    _per2_flag,-1
  262.     je    tmap_loop
  263.  
  264.     test    _Lighting_on, -1
  265.     je    tmap_loop_fast_nolight
  266.     jmp    tmap_loop_fast
  267.  
  268. ;================ PERSPECTIVE TEXTURE MAP INNER LOOPS ========================
  269. ;
  270. ; Usage in loop:    eax    division, pixel value
  271. ;    ebx    u
  272. ;    ecx    z
  273. ;    edx    division
  274. ;    ebp    v
  275. ;    esi    source pixel pointer
  276. ;    edi    destination pixel pointer
  277.  
  278. ;-------------------- NORMAL PERSPECTIVE TEXTURE MAP LOOP -----------------
  279. tmap_loop:
  280.     mov    esi, ebx    ; esi becomes u coordinate
  281.  
  282.     align    4
  283. tmap_loop0:
  284.  
  285. ; compute v coordinate
  286.     mov    eax, ebp    ; get v
  287.     mov    edx, eax
  288.     sar    edx, 31
  289.     idiv    ecx    ; eax = (v/z)
  290.  
  291.     and    eax,3fh    ; mask with height-1
  292.     mov    ebx,eax
  293.  
  294. ; compute u coordinate
  295.     mov    eax, esi    ; get u
  296.     mov    edx, eax
  297.     sar    edx, 31
  298.     idiv    ecx    ; eax = (u/z)
  299.  
  300.     shl     eax,26
  301.     shld     ebx,eax,6    ; esi = v*64+u
  302.  
  303. ; read 1 pixel
  304.     xor    eax, eax
  305.     test    _Lighting_on, -1
  306.     mov    al, es:[ebx]    ; get pixel from source bitmap
  307.     je    NoLight1
  308.  
  309. ; LIGHTING CODE
  310.     mov    ebx, _fx_l    ; get temp copy of lighting value
  311.     mov    ah, bh    ; get lighting level
  312.     add    ebx, _fx_dl_dx    ; update lighting value
  313.     mov    al, _gr_fade_table[eax]    ; xlat pixel thru lighting tables
  314.     mov    _fx_l, ebx    ; save temp copy of lighting value
  315.  
  316. ; transparency check
  317. NoLight1:    cmp    al,255
  318.     je    skip1
  319.  
  320.     mov    [edi],al
  321. skip1:    inc    edi
  322.     
  323. ; update deltas
  324.     add    ebp,_fx_dv_dx
  325.     add    esi,_fx_du_dx
  326.     add    ecx,_fx_dz_dx
  327.     je    _div_0_abort    ; would be dividing by 0, so abort
  328.  
  329.     dec    _loop_count
  330.     jns    tmap_loop0
  331.  
  332. _none_to_do:    
  333.     popa
  334.     pop    es
  335.     ret
  336.  
  337. ; We detected a z=0 condition, which seems pretty bogus, don't you think?
  338. ; So, we abort, but maybe we want to know about it.
  339. _div_0_abort:
  340. ;**    int    3
  341.     jmp    _none_to_do
  342.  
  343. ;-------------------------- PER/4 TMAPPER ----------------
  344. ; 
  345. ;    x = x1
  346. ;    U0 = u/w; V0 = v/w;
  347. ;    while ( 1 )
  348. ;        u += du_dx*4; v+= dv_dx*4
  349. ;        U1 = u/w; V1 = v/w;
  350. ;        DUDX = (U1-U0)/4; DVDX = (V1-V0)/4;
  351. ;
  352. ;    ; Pixel 0
  353. ;        pixels = texmap[V0*64+U0];
  354. ;        U0 += DUDX; V0 += DVDX
  355. ;    ; Pixel 1
  356. ;        pixels = (pixels<<8)+texmap[V0*64+U0];
  357. ;        U0 += DUDX; V0 += DVDX
  358. ;    ; Pixel 2
  359. ;        pixels = (pixels<<8)+texmap[V0*64+U0];
  360. ;        U0 += DUDX; V0 += DVDX
  361. ;    ; Pixel 3
  362. ;        pixels = (pixels<<8)+texmap[V0*64+U0];
  363. ;
  364. ;        screen[x] = pixel
  365. ;        x += 4;
  366. ;        U0 = U1; V0 = V1 
  367.  
  368. NBITS = 4    ; 2^NBITS pixels plotted per divide
  369. ZSHIFT = 4    ; precision used in PDIV macro
  370.  
  371.  
  372. PDIV MACRO
  373. ; Returns EAX/ECX in 16.16 format in EAX. Trashes EDX
  374. ;          sig bits   6.3
  375.     mov    edx,eax
  376.     shl    eax,ZSHIFT
  377.     sar    edx,32-ZSHIFT
  378.     idiv    ecx    ; eax = (v/z)
  379.     shl    eax, 16-ZSHIFT
  380.  
  381. ENDM
  382.  
  383. wr_onepix    macro    num
  384.     local    skip
  385.     cmp    cl,255
  386.     je    skip
  387.     mov    num[edi],cl
  388. skip:    ror    ecx,8
  389.  
  390.     endm
  391.  
  392. public tmap_loop_fast
  393.  
  394. ; -------------------------------------- Start of Getting Dword Aligned ----------------------------------------------
  395. ;    ebx    fx_u
  396.  
  397. tmap_loop_fast:
  398.     mov    esi,ebx
  399.  
  400.     align    4
  401. NotDwordAligned1:
  402.     test    edi, 11b
  403.     jz    DwordAligned1
  404.  
  405. ; compute v coordinate
  406.     mov    eax, ebp    ; get v
  407.     mov    edx, eax
  408.     sar    edx, 31
  409.     idiv    ecx    ; eax = (v/z)
  410.  
  411.     and    eax,3fh    ; mask with height-1
  412.     mov    ebx,eax
  413.  
  414. ; compute u coordinate
  415.     mov    eax, esi    ; get u
  416.     mov    edx, eax
  417.     sar    edx, 31
  418.     idiv    ecx    ; eax = (u/z)
  419.  
  420.     shl     eax,26
  421.     shld     ebx,eax,6    ; esi = v*64+u
  422.  
  423. ; read 1  pixel
  424.     xor    eax, eax
  425.     mov    al, es:[ebx]    ; get pixel from source bitmap
  426.  
  427. ; lighting code
  428.     mov    ebx, _fx_l    ; get temp copy of lighting value
  429.     mov    ah, bh    ; get lighting level
  430.     add    ebx, _fx_dl_dx    ; update lighting value
  431.     mov    _fx_l, ebx    ; save temp copy of lighting value
  432.  
  433. ; transparency check
  434.     cmp    al,255
  435.     je    skip2    ; this pixel is transparent, so don't write it (or light it)
  436.  
  437.     mov    al, _gr_fade_table[eax]    ; xlat pixel thru lighting tables
  438.                     
  439. ; write 1 pixel
  440.     mov    [edi],al
  441. skip2:    inc    edi
  442.     
  443. ; update deltas
  444.     add    ebp,_fx_dv_dx
  445.     add    esi,_fx_du_dx
  446.     add    ecx,_fx_dz_dx
  447.     je    _div_0_abort    ; would be dividing by 0, so abort
  448.  
  449.     dec    _loop_count
  450.     jns    NotDwordAligned1
  451.  
  452.     jmp    _none_to_do
  453.  
  454. ; -------------------------------------- End of Getting Dword Aligned ----------------------------------------------
  455.  
  456. DwordAligned1:
  457.  
  458. ;--;    mov    ebx,esi    ; get fx_u
  459. ;--;
  460. ;--;    mov    eax, _loop_count
  461. ;--;    inc    eax
  462. ;--;    mov    num_left_over, eax
  463. ;--;    shr    eax, NBITS
  464. ;--;
  465. ;--;    test    eax, -1
  466. ;--;    je    tmap_loop    ; there are no 2^NBITS chunks, do divide/pixel for whole scanline
  467. ;--;    
  468. ;--;    mov     _loop_count, eax    ; _loop_count = pixels / NPIXS
  469. ;--;    shl    eax, NBITS
  470. ;--;    sub    num_left_over, eax    ; num_left_over = obvious
  471.  
  472.     mov    eax, _loop_count
  473.     mov    ebx, esi    ; get fx_u [pentium pipelining]
  474.     inc    eax
  475.     mov    esi, eax
  476.     and    esi, (1 shl NBITS) - 1
  477.     sar    eax, NBITS
  478.     mov    num_left_over, esi
  479.     je    tmap_loop    ; there are no 2^NBITS chunks, do divide/pixel for whole scanline
  480.     mov     _loop_count, eax    ; _loop_count = pixels / NPIXS
  481.         
  482. ; compute initial v coordinate
  483.     mov    eax,ebp    ; get v
  484.     mov    edx,ebp
  485.     shl    eax,ZSHIFT
  486.     sar    edx,32-ZSHIFT
  487.     idiv    ecx    ; eax = (v/z)
  488.     shl    eax, 16-ZSHIFT
  489.     mov    V0, eax
  490.  
  491. ; compute initial u coordinate
  492.     mov    eax,ebx    ; get u
  493.     mov    edx,ebx
  494.     shl    eax,ZSHIFT
  495.     sar    edx,32-ZSHIFT
  496.     idiv    ecx    ; eax = (v/z)
  497.     shl    eax, 16-ZSHIFT
  498.     mov    U0, eax
  499.  
  500. ; Set deltas to NPIXS pixel increments
  501.     mov    eax, _fx_du_dx
  502.     shl    eax, NBITS
  503.     mov    DU1, eax
  504.     mov    eax, _fx_dv_dx
  505.     shl    eax, NBITS
  506.     mov    DV1, eax
  507.     mov    eax, _fx_dz_dx
  508.     shl    eax, NBITS
  509.     mov    DZ1, eax
  510.  
  511.     align    4
  512. TopOfLoop4:
  513.     add    ebx, DU1
  514.     add    ebp, DV1
  515.     add    ecx, DZ1
  516.     je    _div_0_abort    ; would be dividing by 0, so abort
  517.  
  518. ; Done with ebx, ebp, ecx until next iteration
  519.     push    ebx
  520.     push    ecx
  521.     push    ebp
  522.     push    edi
  523.     
  524. ; Find fixed U1        
  525.     mov    eax, ebx
  526.     mov    edx,ebx
  527.     shl    eax,ZSHIFT
  528.     sar    edx,32-ZSHIFT
  529.     idiv    ecx    ; eax = (v/z)
  530.     shl    eax, 16-ZSHIFT
  531.     mov    ebx, eax    ; ebx = U1 until pop's
  532.  
  533. ; Find fixed V1        
  534.     mov    eax, ebp
  535.     mov    edx, ebp
  536.     shl    eax,ZSHIFT
  537.     sar    edx,32-ZSHIFT
  538.     idiv    ecx    ; eax = (v/z)
  539.  
  540.     mov    ecx, U0    ; ecx = U0 until pop's
  541.     mov    edi, V0    ; edi = V0 until pop's
  542.  
  543.     shl    eax, 16-ZSHIFT
  544.     mov    ebp, eax    ; ebp = V1 until pop's
  545.  
  546. ; Make ESI =  V0:U0 in 6:10,6:10 format
  547.     mov    eax, ecx
  548.     shr    eax, 6
  549.     mov    esi, edi
  550.     shl    esi, 10
  551.     mov    si, ax
  552.         
  553. ; Make EDX = DV:DU in 6:10,6:10 format
  554.     mov    eax, ebx
  555.     sub    eax, ecx
  556.     sar    eax, NBITS+6
  557.     mov    edx, ebp
  558.     sub    edx, edi
  559.     shl    edx, 10-NBITS    ; EDX = V1-V0/ 4 in 6:10 int:frac
  560.     mov    dx, ax    ; put delta u in low word
  561.  
  562. ; Save the U1 and V1 so we don't have to divide on the next iteration
  563.     mov    U0, ebx
  564.     mov    V0, ebp
  565.  
  566.     pop    edi    ; Restore EDI before using it
  567.         
  568. ; LIGHTING CODE
  569.     mov    ebx, _fx_l
  570.     mov    ebp, _fx_dl_dx
  571.  
  572.     test    _transparency_on,-1
  573.     je    no_trans1
  574.  
  575.     REPT (1 SHL (NBITS-2))
  576.     local    skip3,no_trans1
  577.         REPT 2
  578.     local    skipa1,skipa2
  579.  
  580.     mov    eax, esi    ; get u,v
  581.     shr    eax, 26    ; shift out all but int(v)
  582.     shld    ax,si,6    ; shift in u, shifting up v
  583.     add    esi, edx    ; inc u,v
  584.     mov     al, es:[eax]    ; get pixel from source bitmap
  585.     cmp    al,255
  586.     je    skipa1
  587.     mov    ah, bh    ; form lighting table lookup value
  588.     add    ebx, ebp    ; update lighting value
  589.     mov    al, _gr_fade_table[eax]    ; xlat thru lighting table into dest buffer
  590.     mov    [edi],al
  591. skipa1:
  592.     inc    edi
  593.  
  594. ; Do odd pixel
  595.     mov    eax, esi    ; get u,v
  596.     shr    eax, 26    ; shift out all but int(v)
  597.     shld    ax,si,6    ; shift in u, shifting up v
  598.     add    esi, edx    ; inc u,v
  599.     mov     al, es:[eax]    ; get pixel from source bitmap
  600.     cmp    al,255
  601.     je    skipa2
  602.     mov    ah, bh    ; form lighting table lookup value
  603.     add    ebx, ebp    ; update lighting value
  604.     mov    al, _gr_fade_table[eax]    ; xlat thru lighting table into dest buffer
  605.     mov    [edi],al
  606. skipa2:
  607.     inc    edi
  608.  
  609.         ENDM
  610.  
  611.     ENDM
  612.     jmp    cont1
  613.  
  614. ; -------------------------------------------------------
  615. no_trans1:
  616. ;----------; push edx
  617. ;----------; mov mem_edx, edx
  618. ;----------; sub edx, edx
  619.   REPT (1 SHL (NBITS-2))
  620.     REPT 2
  621.  
  622.     mov    eax, esi    ; get u,v
  623.     shr    eax, 26    ; shift out all but int(v)
  624.     shld    ax,si,6    ; shift in u, shifting up v
  625.     add    esi, edx    ; inc u,v
  626.     mov     al, es:[eax]    ; get pixel from source bitmap
  627.     mov    ah, bh    ; form lighting table lookup value
  628.     add    ebx, ebp    ; update lighting value
  629.     mov    cl, _gr_fade_table[eax]    ; xlat thru lighting table into dest buffer
  630.  
  631. ; Do odd pixel
  632.     mov    eax, esi    ; get u,v
  633.     shr    eax, 26    ; shift out all but int(v)
  634.     shld    ax,si,6    ; shift in u, shifting up v
  635.     add    esi, edx    ; inc u,v
  636.     mov     al, es:[eax]    ; get pixel from source bitmap
  637.     mov    ah, bh    ; form lighting table lookup value
  638.     add    ebx, ebp    ; update lighting value
  639.     mov    ch, _gr_fade_table[eax]    ; xlat thru lighting table into dest buffer
  640.  
  641. ; ----- This is about 1% faster than the above, and could probably be optimized more.
  642. ; ----- Problem is, it gets the u,v coordinates backwards.  What you would need to do
  643. ; ----- is switch the packing of the u,v coordinates above (about 95 lines up).
  644. ;----------;    mov    eax, esi
  645. ;----------;    shr    ax, 10
  646. ;----------;    rol    eax, 6
  647. ;----------;    mov    dx, ax
  648. ;----------;    add    esi, mem_edx
  649. ;----------;    mov    dl, es:[edx]
  650. ;----------;    mov    dh, bh
  651. ;----------;    add    ebx, ebp
  652. ;----------;    mov    cl, _gr_fade_table[edx]
  653. ;----------;
  654. ;----------;    mov    eax, esi
  655. ;----------;    shr    ax, 10
  656. ;----------;    rol    eax, 6
  657. ;----------;    mov    dx, ax
  658. ;----------;    add    esi, mem_edx
  659. ;----------;    mov    dl, es:[edx]
  660. ;----------;    mov    dh, bh
  661. ;----------;    add    ebx, ebp
  662. ;----------;    mov    ch, _gr_fade_table[edx]
  663.  
  664.     ror    ecx, 16    ; move to next double dest pixel position
  665.  
  666.     ENDM
  667.     mov     [edi],ecx    ; Draw 4 pixels to display
  668.     add     edi,4
  669.   ENDM
  670. ;; pop edx
  671. cont1:
  672.  
  673. ; -------------------------------------------------------
  674.  
  675. ; LIGHTING CODE
  676.     mov    _fx_l, ebx
  677.     pop    ebp
  678.     pop    ecx
  679.     pop    ebx
  680.     dec    _loop_count
  681.     jnz    TopOfLoop4
  682.  
  683. EndOfLoop4:
  684.     test    num_left_over, -1
  685.     je    _none_to_do
  686.  
  687. ; ----------------------------------------- Start of LeftOver Pixels ------------------------------------------
  688. DoEndPixels:
  689.     push    ecx
  690.  
  691.     mov    eax, ecx
  692.     lea    eax, [eax*2+eax]
  693.  
  694.     add    ecx, DZ1
  695.     js    notokhere
  696.     shl    ecx,2
  697.     cmp    eax, ecx
  698.     pop    ecx
  699.     jl    okhere
  700.     jmp    bah_bah
  701. notokhere:
  702.     pop    ecx
  703. bah_bah:
  704.     test    new_end,-1
  705.     jne    NewDoEndPixels
  706. okhere:
  707.  
  708.     add    ebx, DU1
  709.     add    ebp, DV1
  710.     add    ecx, DZ1
  711.     je    _div_0_abort
  712.     jns    dep_cont
  713.  
  714. ; z went negative.
  715. ; this can happen because we added DZ1 to the current z, but dz1 represents dz for perhaps 16 pixels
  716. ; though we might only plot one more pixel.
  717.     mov    cl, 1
  718.  
  719. dep_loop:    mov    eax, DU1
  720.     sar    eax, cl
  721.     sub    ebx, eax
  722.  
  723.     mov    eax, DV1
  724.     sar    eax, cl
  725.     sub    ebp, eax
  726.  
  727.     mov    eax, DZ1
  728.     sar    eax, cl
  729.     sub    ecx, eax
  730.     je    _div_0_abort
  731.     jns    dep_cont
  732.  
  733.     inc    cl
  734.     cmp    cl, NBITS
  735.     jne    dep_loop
  736.  
  737. dep_cont:
  738.     push    edi    ; use edi as a temporary variable
  739.  
  740.     cmp    ecx,1 shl (ZSHIFT+1)
  741.     jg    ecx_ok
  742.     mov    ecx, 1 shl (ZSHIFT+1)
  743. ecx_ok:
  744.  
  745. ; Find fixed U1        
  746.     mov    eax, ebx
  747.     PDIV
  748.     mov    ebx, eax    ; ebx = U1 until pop's
  749.  
  750. ; Find fixed V1        
  751.     mov    eax, ebp
  752.     PDIV
  753.     mov    ebp, eax    ; ebp = V1 until pop's
  754.  
  755.     mov    ecx, U0    ; ecx = U0 until pop's
  756.     mov    edi, V0    ; edi = V0 until pop's
  757.  
  758. ; Make ESI =  V0:U0 in 6:10,6:10 format
  759.     mov    eax, ecx
  760.     shr    eax, 6
  761.     mov    esi, edi
  762.     shl    esi, 10
  763.     mov    si, ax
  764.         
  765. ; Make EDX = DV:DU in 6:10,6:10 format
  766.     mov    eax, ebx
  767.     sub    eax, ecx
  768.     sar    eax, NBITS+6
  769.     mov    edx, ebp
  770.     sub    edx, edi
  771.     shl    edx, 10-NBITS    ; EDX = V1-V0/ 4 in 6:10 int:frac
  772.     mov    dx, ax    ; put delta u in low word
  773.  
  774.     pop    edi    ; Restore EDI before using it
  775.         
  776.     mov    ecx, num_left_over
  777.  
  778. ; LIGHTING CODE
  779.     mov    ebx, _fx_l
  780.     mov    ebp, _fx_dl_dx
  781.  
  782.     ITERATION = 0
  783.     REPT (1 SHL (NBITS-1))
  784.     local    skip4, skip5
  785. ; Do even pixel
  786.     mov    eax, esi    ; get u,v
  787.     shr    eax, 26    ; shift out all but int(v)
  788.     shld    ax,si,6    ; shift in u, shifting up v
  789.     mov     al, es:[eax]    ; get pixel from source bitmap
  790.     add    esi, edx    ; inc u,v
  791.     mov    ah, bh    ; form lighting table lookup value
  792.     add    ebx, ebp    ; update lighting value
  793.     cmp    al,255
  794.     je    skip4
  795.     mov    al, _gr_fade_table[eax]    ; xlat thru lighting table into dest buffer
  796.     mov    [edi+ITERATION], al    ; write pixel
  797. skip4:    dec    ecx
  798.     jz    _none_to_do
  799.     ITERATION = ITERATION + 1
  800.  
  801. ; Do odd pixel
  802.     mov    eax, esi    ; get u,v
  803.     shr    eax, 26    ; shift out all but int(v)
  804.     shld    ax,si,6    ; shift in u, shifting up v
  805.     mov     al, es:[eax]    ; get pixel from source bitmap
  806.     add    esi, edx    ; inc u,v
  807.     mov    ah, bh    ; form lighting table lookup value
  808.     add    ebx, _fx_dl_dx    ; update lighting value
  809.     cmp    al,255
  810.     je    skip5
  811.     mov    al, _gr_fade_table[eax]    ; xlat thru lighting table into dest buffer
  812.     mov    [edi+ITERATION], al    ; write pixel
  813. skip5:    dec    ecx
  814.     jz    _none_to_do
  815.     ITERATION = ITERATION + 1
  816.     ENDM
  817.  
  818. ; Should never get here!!!!
  819.     int    3
  820.     jmp    _none_to_do
  821.  
  822. ; ----------------------------------------- End of LeftOver Pixels ------------------------------------------
  823.  
  824. ; --BUGGY NEW--NewDoEndPixels:
  825. ; --BUGGY NEW--    mov    eax, num_left_over
  826. ; --BUGGY NEW--    and    num_left_over, 3
  827. ; --BUGGY NEW--    shr    eax, 2
  828. ; --BUGGY NEW--    je    NDEP_1
  829. ; --BUGGY NEW--    mov    _loop_count, eax
  830. ; --BUGGY NEW--
  831. ; --BUGGY NEW--; do 4 pixels per hunk, not 16, so div deltas by 4 (16/4=4)
  832. ; --BUGGY NEW-- shr DU1,2
  833. ; --BUGGY NEW-- shr DV1,2
  834. ; --BUGGY NEW-- shr DZ1,2
  835. ; --BUGGY NEW--
  836. ; --BUGGY NEW--NDEP_TopOfLoop4:
  837. ; --BUGGY NEW--    add    ebx, DU1
  838. ; --BUGGY NEW--    add    ebp, DV1
  839. ; --BUGGY NEW--    add    ecx, DZ1
  840. ; --BUGGY NEW--    je    _div_0_abort    ; would be dividing by 0, so abort
  841. ; --BUGGY NEW--
  842. ; --BUGGY NEW--; Done with ebx, ebp, ecx until next iteration
  843. ; --BUGGY NEW--    push    ebx
  844. ; --BUGGY NEW--    push    ecx
  845. ; --BUGGY NEW--    push    ebp
  846. ; --BUGGY NEW--    push    edi
  847. ; --BUGGY NEW--    
  848. ; --BUGGY NEW--; Find fixed U1        
  849. ; --BUGGY NEW--    mov    eax, ebx
  850. ; --BUGGY NEW--    mov    edx,ebx
  851. ; --BUGGY NEW--    shl    eax,(ZSHIFT-2)
  852. ; --BUGGY NEW--    sar    edx,32-(ZSHIFT-2)
  853. ; --BUGGY NEW--    idiv    ecx    ; eax = (v/z)
  854. ; --BUGGY NEW--    shl    eax, 16-(ZSHIFT-2)
  855. ; --BUGGY NEW--    mov    ebx, eax    ; ebx = U1 until pop's
  856. ; --BUGGY NEW--
  857. ; --BUGGY NEW--; Find fixed V1        
  858. ; --BUGGY NEW--    mov    eax, ebp
  859. ; --BUGGY NEW--    mov    edx, ebp
  860. ; --BUGGY NEW--    shl    eax,(ZSHIFT-2)
  861. ; --BUGGY NEW--    sar    edx,32-(ZSHIFT-2)
  862. ; --BUGGY NEW--    idiv    ecx    ; eax = (v/z)
  863. ; --BUGGY NEW--
  864. ; --BUGGY NEW--    mov    ecx, U0    ; ecx = U0 until pop's
  865. ; --BUGGY NEW--    mov    edi, V0    ; edi = V0 until pop's
  866. ; --BUGGY NEW--
  867. ; --BUGGY NEW--    shl    eax, 16-(ZSHIFT-2)
  868. ; --BUGGY NEW--    mov    ebp, eax    ; ebp = V1 until pop's
  869. ; --BUGGY NEW--
  870. ; --BUGGY NEW--; Make ESI =  V0:U0 in 6:10,6:10 format
  871. ; --BUGGY NEW--    mov    eax, ecx
  872. ; --BUGGY NEW--    shr    eax, 6
  873. ; --BUGGY NEW--    mov    esi, edi
  874. ; --BUGGY NEW--    shl    esi, 10
  875. ; --BUGGY NEW--    mov    si, ax
  876. ; --BUGGY NEW--
  877. ; --BUGGY NEW--; Make EDX = DV:DU in 6:10,6:10 format
  878. ; --BUGGY NEW--    mov    eax, ebx
  879. ; --BUGGY NEW--    sub    eax, ecx
  880. ; --BUGGY NEW--    sar    eax, (NBITS-2)+6
  881. ; --BUGGY NEW--    mov    edx, ebp
  882. ; --BUGGY NEW--    sub    edx, edi
  883. ; --BUGGY NEW--    shl    edx, 10-(NBITS-2)    ; EDX = V1-V0/ 4 in 6:10 int:frac
  884. ; --BUGGY NEW--    mov    dx, ax    ; put delta u in low word
  885. ; --BUGGY NEW--
  886. ; --BUGGY NEW--; Save the U1 and V1 so we don't have to divide on the next iteration
  887. ; --BUGGY NEW--    mov    U0, ebx
  888. ; --BUGGY NEW--    mov    V0, ebp
  889. ; --BUGGY NEW--
  890. ; --BUGGY NEW--    pop    edi    ; Restore EDI before using it
  891. ; --BUGGY NEW--        
  892. ; --BUGGY NEW--; LIGHTING CODE
  893. ; --BUGGY NEW--    mov    ebx, _fx_l
  894. ; --BUGGY NEW--    mov    ebp, _fx_dl_dx
  895. ; --BUGGY NEW--
  896. ; --BUGGY NEW--;**    test    _transparency_on,-1
  897. ; --BUGGY NEW--;**    je    NDEP_no_trans1
  898. ; --BUGGY NEW--
  899. ; --BUGGY NEW--        REPT 2
  900. ; --BUGGY NEW--    local    NDEP_skipa1, NDEP_skipa2
  901. ; --BUGGY NEW--
  902. ; --BUGGY NEW--    mov    eax, esi    ; get u,v
  903. ; --BUGGY NEW--    shr    eax, 26    ; shift out all but int(v)
  904. ; --BUGGY NEW--    shld    ax,si,6    ; shift in u, shifting up v
  905. ; --BUGGY NEW--    add    esi, edx    ; inc u,v
  906. ; --BUGGY NEW--    mov     al, es:[eax]    ; get pixel from source bitmap
  907. ; --BUGGY NEW--    cmp    al,255
  908. ; --BUGGY NEW--    je    NDEP_skipa1
  909. ; --BUGGY NEW--    mov    ah, bh    ; form lighting table lookup value
  910. ; --BUGGY NEW--    add    ebx, ebp    ; update lighting value
  911. ; --BUGGY NEW--    mov    al, _gr_fade_table[eax]    ; xlat thru lighting table into dest buffer
  912. ; --BUGGY NEW--    mov    [edi],al
  913. ; --BUGGY NEW--NDEP_skipa1:
  914. ; --BUGGY NEW--    inc    edi
  915. ; --BUGGY NEW--
  916. ; --BUGGY NEW--; Do odd pixel
  917. ; --BUGGY NEW--    mov    eax, esi    ; get u,v
  918. ; --BUGGY NEW--    shr    eax, 26    ; shift out all but int(v)
  919. ; --BUGGY NEW--    shld    ax,si,6    ; shift in u, shifting up v
  920. ; --BUGGY NEW--    add    esi, edx    ; inc u,v
  921. ; --BUGGY NEW--    mov     al, es:[eax]    ; get pixel from source bitmap
  922. ; --BUGGY NEW--    cmp    al,255
  923. ; --BUGGY NEW--    je    NDEP_skipa2
  924. ; --BUGGY NEW--    mov    ah, bh    ; form lighting table lookup value
  925. ; --BUGGY NEW--    add    ebx, ebp    ; update lighting value
  926. ; --BUGGY NEW--    mov    al, _gr_fade_table[eax]    ; xlat thru lighting table into dest buffer
  927. ; --BUGGY NEW--    mov    [edi],al
  928. ; --BUGGY NEW--NDEP_skipa2:
  929. ; --BUGGY NEW--    inc    edi
  930. ; --BUGGY NEW--
  931. ; --BUGGY NEW--        ENDM
  932. ; --BUGGY NEW--
  933. ; --BUGGY NEW--    mov    _fx_l, ebx
  934. ; --BUGGY NEW--    pop    ebp
  935. ; --BUGGY NEW--    pop    ecx
  936. ; --BUGGY NEW--    pop    ebx
  937. ; --BUGGY NEW--    dec    _loop_count
  938. ; --BUGGY NEW--    jnz    NDEP_TopOfLoop4
  939. ; --BUGGY NEW--
  940. ; --BUGGY NEW--    test    num_left_over, -1
  941. ; --BUGGY NEW--    je    _none_to_do
  942. ; --BUGGY NEW--
  943. ; --BUGGY NEW--NDEP_1:
  944. ; --BUGGY NEW--    mov    esi,ebx
  945. ; --BUGGY NEW--
  946. ; --BUGGY NEW--    align    4
  947. ; --BUGGY NEW--NDEP_loop:
  948. ; --BUGGY NEW--
  949. ; --BUGGY NEW--; compute v coordinate
  950. ; --BUGGY NEW--    mov    eax, ebp    ; get v
  951. ; --BUGGY NEW--    mov    edx, eax
  952. ; --BUGGY NEW--    sar    edx, 31
  953. ; --BUGGY NEW--    idiv    ecx    ; eax = (v/z)
  954. ; --BUGGY NEW--
  955. ; --BUGGY NEW--    and    eax,3fh    ; mask with height-1
  956. ; --BUGGY NEW--    mov    ebx,eax
  957. ; --BUGGY NEW--
  958. ; --BUGGY NEW--; compute u coordinate
  959. ; --BUGGY NEW--    mov    eax,     esi    ; get u
  960. ; --BUGGY NEW--    mov    edx, eax
  961. ; --BUGGY NEW--    sar    edx, 31
  962. ; --BUGGY NEW--    idiv    ecx    ; eax = (u/z)
  963. ; --BUGGY NEW--
  964. ; --BUGGY NEW--    shl     eax,26
  965. ; --BUGGY NEW--    shld     ebx,eax,6    ; esi = v*64+u
  966. ; --BUGGY NEW--
  967. ; --BUGGY NEW--; read 1  pixel
  968. ; --BUGGY NEW--    xor    eax, eax
  969. ; --BUGGY NEW--    mov    al, es:[ebx]    ; get pixel from source bitmap
  970. ; --BUGGY NEW--
  971. ; --BUGGY NEW--; lighting code
  972. ; --BUGGY NEW--    mov    ebx, _fx_l    ; get temp copy of lighting value
  973. ; --BUGGY NEW--    mov    ah, bh    ; get lighting level
  974. ; --BUGGY NEW--    add    ebx, _fx_dl_dx    ; update lighting value
  975. ; --BUGGY NEW--    mov    _fx_l, ebx    ; save temp copy of lighting value
  976. ; --BUGGY NEW--
  977. ; --BUGGY NEW--; transparency check
  978. ; --BUGGY NEW--    cmp    al,255
  979. ; --BUGGY NEW--    je    NDEP_skip2    ; this pixel is transparent, so don't write it (or light it)
  980. ; --BUGGY NEW--
  981. ; --BUGGY NEW--    mov    al, _gr_fade_table[eax]    ; xlat pixel thru lighting tables
  982. ; --BUGGY NEW--                    
  983. ; --BUGGY NEW--; write 1 pixel
  984. ; --BUGGY NEW--    mov    [edi],al
  985. ; --BUGGY NEW--NDEP_skip2:    inc    edi
  986. ; --BUGGY NEW--    
  987. ; --BUGGY NEW--; update deltas
  988. ; --BUGGY NEW--    add    ebp,_fx_dv_dx
  989. ; --BUGGY NEW--    add    esi,_fx_du_dx
  990. ; --BUGGY NEW--    add    ecx,_fx_dz_dx
  991. ; --BUGGY NEW--    je    _div_0_abort    ; would be dividing by 0, so abort
  992. ; --BUGGY NEW--
  993. ; --BUGGY NEW--    dec    num_left_over
  994. ; --BUGGY NEW--    jne    NDEP_loop
  995. ; --BUGGY NEW--
  996. ; --BUGGY NEW--    jmp    _none_to_do
  997.  
  998. NewDoEndPixels:
  999.     mov    esi,ebx
  1000.  
  1001.     align    4
  1002. NDEP_loop:
  1003.  
  1004. ; compute v coordinate
  1005.     mov    eax, ebp    ; get v
  1006.     mov    edx, eax
  1007.     sar    edx, 31
  1008.     idiv    ecx    ; eax = (v/z)
  1009.  
  1010.     and    eax,3fh    ; mask with height-1
  1011.     mov    ebx,eax
  1012.  
  1013. ; compute u coordinate
  1014.     mov    eax,     esi    ; get u
  1015.     mov    edx, eax
  1016.     sar    edx, 31
  1017.     idiv    ecx    ; eax = (u/z)
  1018.  
  1019.     shl     eax,26
  1020.     shld     ebx,eax,6    ; esi = v*64+u
  1021.  
  1022. ; read 1  pixel
  1023.     xor    eax, eax
  1024.     mov    al, es:[ebx]    ; get pixel from source bitmap
  1025.  
  1026. ; lighting code
  1027.     mov    ebx, _fx_l    ; get temp copy of lighting value
  1028.     mov    ah, bh    ; get lighting level
  1029.     add    ebx, _fx_dl_dx    ; update lighting value
  1030.     mov    _fx_l, ebx    ; save temp copy of lighting value
  1031.  
  1032. ; transparency check
  1033.     cmp    al,255
  1034.     je    NDEP_skip2    ; this pixel is transparent, so don't write it (or light it)
  1035.  
  1036.     mov    al, _gr_fade_table[eax]    ; xlat pixel thru lighting tables
  1037.                     
  1038. ; write 1 pixel
  1039.     mov    [edi],al
  1040. NDEP_skip2:    inc    edi
  1041.     
  1042. ; update deltas
  1043.     add    ebp,_fx_dv_dx
  1044.     add    esi,_fx_du_dx
  1045.     add    ecx,_fx_dz_dx
  1046.     je    _div_0_abort    ; would be dividing by 0, so abort
  1047.  
  1048.     dec    num_left_over
  1049.     jne    NDEP_loop
  1050.  
  1051.     jmp    _none_to_do
  1052.  
  1053. ; ==================================================== No Lighting Code ======================================================
  1054. public tmap_loop_fast_nolight
  1055. tmap_loop_fast_nolight:
  1056.     mov    esi,ebx
  1057.  
  1058.     align    4
  1059. NotDwordAligned1_nolight:
  1060.     test    edi, 11b
  1061.     jz    DwordAligned1_nolight
  1062.  
  1063. ; compute v coordinate
  1064.     mov    eax,ebp    ; get v
  1065.     mov    edx, eax
  1066.     sar    edx, 31
  1067.     idiv    ecx    ; eax = (v/z)
  1068.  
  1069.     and    eax,3fh    ; mask with height-1
  1070.     mov    ebx,eax
  1071.  
  1072. ; compute u coordinate
  1073.     mov    eax, esi    ; get u
  1074.     mov    edx, eax
  1075.     sar    edx, 31
  1076.     idiv    ecx    ; eax = (u/z)
  1077.  
  1078.     shl     eax,26
  1079.     shld     ebx,eax,6    ; esi = v*64+u
  1080.  
  1081. ; read 1  pixel
  1082.     mov    al,es:[ebx]    ; get pixel from source bitmap
  1083.  
  1084. ; write 1 pixel
  1085.     cmp    al,255
  1086.     je    skip6
  1087.     mov    [edi],al
  1088. skip6:    inc    edi
  1089.     
  1090. ; update deltas
  1091.     add    ebp,_fx_dv_dx
  1092.     add    esi,_fx_du_dx
  1093.     add    ecx,_fx_dz_dx
  1094.     je    _div_0_abort    ; would be dividing by 0, so abort
  1095.  
  1096.     dec    _loop_count
  1097.     jns    NotDwordAligned1_nolight
  1098.     jmp    _none_to_do
  1099.  
  1100. DwordAligned1_nolight:
  1101.     mov    ebx,esi
  1102.  
  1103.     mov    eax, _loop_count
  1104.     inc    eax
  1105.     mov    num_left_over, eax
  1106.     shr    eax, NBITS
  1107.  
  1108.     test    eax, -1
  1109.     je    tmap_loop    ; no 2^NBITS chunks, do divide/pixel for whole scanline
  1110.     
  1111.     mov     _loop_count, eax    ; _loop_count = pixels / NPIXS
  1112.     shl    eax, NBITS
  1113.     sub    num_left_over, eax    ; num_left_over = obvious
  1114.         
  1115. ; compute initial v coordinate
  1116.     mov    eax,ebp    ; get v
  1117.     PDIV
  1118.     mov    V0, eax
  1119.  
  1120. ; compute initial u coordinate
  1121.     mov    eax,ebx    ; get u
  1122.     PDIV    
  1123.     mov    U0, eax
  1124.  
  1125. ; Set deltas to NPIXS pixel increments
  1126.     mov    eax, _fx_du_dx
  1127.     shl    eax, NBITS
  1128.     mov    DU1, eax
  1129.     mov    eax, _fx_dv_dx
  1130.     shl    eax, NBITS
  1131.     mov    DV1, eax
  1132.     mov    eax, _fx_dz_dx
  1133.     shl    eax, NBITS
  1134.     mov    DZ1, eax
  1135.  
  1136.     align    4
  1137. TopOfLoop4_nolight:
  1138.     add    ebx, DU1
  1139.     add    ebp, DV1
  1140.     add    ecx, DZ1
  1141.     je    _div_0_abort
  1142.  
  1143. ; Done with ebx, ebp, ecx until next iteration
  1144.     push    ebx
  1145.     push    ecx
  1146.     push    ebp
  1147.     push    edi
  1148.     
  1149. ; Find fixed U1        
  1150.     mov    eax, ebx
  1151.     PDIV
  1152.     mov    ebx, eax    ; ebx = U1 until pop's
  1153.  
  1154. ; Find fixed V1        
  1155.     mov    eax, ebp
  1156.     PDIV
  1157.     mov    ebp, eax    ; ebp = V1 until pop's
  1158.  
  1159.     mov    ecx, U0    ; ecx = U0 until pop's
  1160.     mov    edi, V0    ; edi = V0 until pop's
  1161.  
  1162. ; Make ESI =  V0:U0 in 6:10,6:10 format
  1163.     mov    eax, ecx
  1164.     shr    eax, 6
  1165.     mov    esi, edi
  1166.     shl    esi, 10
  1167.     mov    si, ax
  1168.         
  1169. ; Make EDX = DV:DU in 6:10,6:10 format
  1170.     mov    eax, ebx
  1171.     sub    eax, ecx
  1172.     sar    eax, NBITS+6
  1173.     mov    edx, ebp
  1174.     sub    edx, edi
  1175.     shl    edx, 10-NBITS    ; EDX = V1-V0/ 4 in 6:10 int:frac
  1176.     mov    dx, ax    ; put delta u in low word
  1177.  
  1178. ; Save the U1 and V1 so we don't have to divide on the next iteration
  1179.     mov    U0, ebx
  1180.     mov    V0, ebp
  1181.  
  1182.     pop    edi    ; Restore EDI before using it
  1183.         
  1184.     REPT (1 SHL (NBITS-2))
  1185.     local    skip7, no_trans2, skip1q, skip2q, skip3q, skip4q
  1186.  
  1187. ; Do 1 pixel 
  1188.     mov    eax, esi    ; get u,v
  1189.     shr    eax, 26    ; shift out all but int(v)
  1190.     shld    ax,si,6    ; shift in u, shifting up v
  1191.     add    esi, edx    ; inc u,v
  1192.     mov    cl, es:[eax]    ; load into buffer register
  1193. ;;;    ror    ecx, 8    ; move to next dest pixel
  1194.  
  1195.     mov    eax, esi    ; get u,v
  1196.     shr    eax, 26    ; shift out all but int(v)
  1197.     shld    ax,si,6    ; shift in u, shifting up v
  1198.     mov    ch, es:[eax]    ; load into buffer register
  1199.     add    esi, edx    ; inc u,v
  1200.     ror    ecx, 16    ; move to next dest pixel
  1201.  
  1202.     mov    eax, esi    ; get u,v
  1203.     shr    eax, 26    ; shift out all but int(v)
  1204.     shld    ax,si,6    ; shift in u, shifting up v
  1205.     mov    cl, es:[eax]    ; load into buffer register
  1206.     add    esi, edx    ; inc u,v
  1207. ;;;    ror    ecx, 8    ; move to next dest pixel
  1208.  
  1209.     mov    eax, esi    ; get u,v
  1210.     shr    eax, 26    ; shift out all but int(v)
  1211.     shld    ax,si,6    ; shift in u, shifting up v
  1212.     mov    ch, es:[eax]    ; load into buffer register
  1213.     add    esi, edx    ; inc u,v
  1214.     ror    ecx, 16 ;-- can get rid of this, just write in different order below --     ; move to next dest pixel
  1215.  
  1216.     test    _transparency_on,-1
  1217.     je    no_trans2
  1218.     cmp    ecx,-1
  1219.     je    skip7
  1220.  
  1221.     cmp    cl,255
  1222.     je    skip1q
  1223.     mov    [edi],cl
  1224. skip1q:
  1225.  
  1226.     cmp    ch,255
  1227.     je    skip2q
  1228.     mov    1[edi],ch
  1229. skip2q:
  1230.     ror    ecx,16
  1231.  
  1232.     cmp    cl,255
  1233.     je    skip3q
  1234.     mov    2[edi],cl
  1235. skip3q:
  1236.  
  1237.  
  1238.     cmp    ch,255
  1239.     je    skip4q
  1240.     mov    3[edi],ch
  1241. skip4q:
  1242.  
  1243. ;;    wr_onepix    0
  1244. ;;    wr_onepix    1
  1245. ;;    wr_onepix    2
  1246. ;;    wr_onepix    3
  1247.     jmp    skip7
  1248. no_trans2:
  1249.     mov     [edi],ecx    ; Draw 4 pixels to display
  1250. skip7:    add     edi,4
  1251.  
  1252.     ENDM
  1253.  
  1254.     pop    ebp
  1255.     pop    ecx
  1256.     pop    ebx
  1257.     dec    _loop_count
  1258.     jnz    TopOfLoop4_nolight
  1259.  
  1260. EndOfLoop4_nolight:
  1261.  
  1262.     test    num_left_over, -1
  1263.     je    _none_to_do
  1264.  
  1265. DoEndPixels_nolight:
  1266.     add    ebx, DU1
  1267.     add    ebp, DV1
  1268.     add    ecx, DZ1
  1269.     je    _div_0_abort
  1270.     push    edi    ; use edi as a temporary variable
  1271.  
  1272. ; Find fixed U1        
  1273.     mov    eax, ebx
  1274.     mov    edx,eax
  1275.     shl    eax,ZSHIFT
  1276.     sar    edx,32-ZSHIFT
  1277.     idiv    ecx    ; eax = (v/z)
  1278.     shl    eax, 16-ZSHIFT
  1279.     mov    ebx, eax    ; ebx = U1 until pop's
  1280.  
  1281. ; Find fixed V1        
  1282.     mov    eax, ebp
  1283.     mov    edx,eax
  1284.     shl    eax,ZSHIFT
  1285.     sar    edx,32-ZSHIFT
  1286.     idiv    ecx    ; eax = (v/z)
  1287.     shl    eax, 16-ZSHIFT
  1288.     mov    ebp, eax    ; ebp = V1 until pop's
  1289.  
  1290.     mov    ecx, U0    ; ecx = U0 until pop's
  1291.     mov    edi, V0    ; edi = V0 until pop's
  1292.  
  1293. ; Make ESI =  V0:U0 in 6:10,6:10 format
  1294.     mov    eax, ecx
  1295.     shr    eax, 6
  1296.     mov    esi, edi
  1297.     shl    esi, 10
  1298.     mov    si, ax
  1299.         
  1300. ; Make EDX = DV:DU in 6:10,6:10 format
  1301.     mov    eax, ebx
  1302.     sub    eax, ecx
  1303.     sar    eax, NBITS+6
  1304.     mov    edx, ebp
  1305.     sub    edx, edi
  1306.     shl    edx, 10-NBITS    ; EDX = V1-V0/ 4 in 6:10 int:frac
  1307.     mov    dx, ax    ; put delta u in low word
  1308.  
  1309.     pop    edi    ; Restore EDI before using it
  1310.         
  1311.     mov    ecx, num_left_over
  1312.  
  1313.     ITERATION = 0
  1314.     REPT (1 SHL NBITS)
  1315.     local    skip8
  1316. ; Do 1 pixel 
  1317.     mov    eax, esi    ; get u,v
  1318.     shr    eax, 26    ; shift out all but int(v)
  1319.     shld    ax,si,6    ; shift in u, shifting up v
  1320.     mov    al, es:[eax]    ; load into buffer register
  1321.     add    esi, edx    ; inc u,v
  1322.     cmp    al,255
  1323.     je    skip8
  1324.     mov    [edi+ITERATION], al    ; write pixel
  1325. skip8:    dec    ecx
  1326.     jz    _none_to_do
  1327.     ITERATION = ITERATION + 1
  1328.     ENDM
  1329.  
  1330. ; Should never get here!!!!!
  1331.     int    3
  1332.     jmp    _none_to_do
  1333.  
  1334.     
  1335.  
  1336. _TEXT    ends
  1337.  
  1338.     end
  1339.  
  1340.