home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_kl.asm < prev    next >
Assembly Source File  |  1998-06-08  |  7KB  |  308 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_kl.asm $
  13. ; $Revision: 1.3 $
  14. ; $Author: mike $
  15. ; $Date: 1994/11/30 00:56:50 $
  16. ;
  17. ; Linear, lighted texture mapper inner loop with a constant lighting value.
  18. ;
  19. ; $Log: tmap_kl.asm $
  20. ; Revision 1.3  1994/11/30  00:56:50  mike
  21. ; optimization.
  22. ; 
  23. ; Revision 1.2  1994/11/12  16:39:38  mike
  24. ; jae to ja.
  25. ; 
  26. ; Revision 1.1  1994/05/10  09:37:52  mike
  27. ; Initial revision
  28. ; 
  29. ; Revision 1.1  1993/09/08  17:29:52  mike
  30. ; Initial revision
  31. ; 
  32. ;
  33. ;
  34.  
  35.     .386
  36.  
  37.     public    asm_tmap_scanline_lin_lighted_k_
  38.  
  39.     include    tmap_inc.asm
  40.  
  41. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  42.  
  43.     extrn    _fx_l:dword
  44. ;**    extrn    _fx_dl_dx:dword
  45.     extrn    _dither_intensity_lighting:dword
  46.  
  47.     extrn    _fx_u:dword
  48.     extrn    _fx_v:dword
  49.     extrn    _fx_du_dx:dword
  50.     extrn    _fx_dv_dx:dword
  51.     extrn    _fx_y:dword
  52.     extrn    _fx_xleft:dword
  53.     extrn    _fx_xright:dword
  54.  
  55.     extrn    _pixptr:dword
  56.  
  57.     extrn    _x:dword
  58.     extrn    _loop_count:dword
  59.  
  60.     extern    _pixel_data_selector:word, _gr_fade_table_selector:word
  61.  
  62. _DATA    ENDS
  63.  
  64. DGROUP    GROUP    _DATA
  65.  
  66. _TEXT   SEGMENT PARA PUBLIC USE32 'CODE'
  67.  
  68.     ASSUME    DS:_DATA
  69.     ASSUME    CS:_TEXT
  70.  
  71. ; --------------------------------------------------------------------------------------------------
  72. ; Enter:
  73. ;    _xleft    fixed point left x coordinate
  74. ;    _xright    fixed point right x coordinate
  75. ;    _y    fixed point y coordinate
  76. ;    _pixptr    address of source pixel map
  77. ;    _u    fixed point initial u coordinate
  78. ;    _v    fixed point initial v coordinate
  79. ;    _du_dx    fixed point du/dx
  80. ;    _dv_dx    fixed point dv/dx
  81.  
  82. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  83. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  84. ;      _setpixel(x,y);
  85. ;
  86. ;      u += du_dx;
  87. ;      v += dv_dx;
  88. ;      z += dz_dx;
  89. ;   }
  90.  
  91.     align    4
  92. asm_tmap_scanline_lin_lighted_k_:
  93.     push    es
  94.     push    fs
  95.     pusha
  96.  
  97.     mov    es,_pixel_data_selector    ; selector[0*2]
  98.     mov    fs,_gr_fade_table_selector    ; selector[1*2]    ; fs = bmd_fade_table
  99.  
  100. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  101. ;   esi    source pixel pointer = pixptr
  102. ;   edi    initial row pointer = y*320+x
  103.  
  104. ; set esi = pointer to start of texture map data
  105.     mov    esi,_pixptr
  106.  
  107. ; set edi = address of first pixel to modify
  108.     mov    edi,_fx_y    ; this is actually an int
  109.     cmp    edi,_window_bottom
  110.     ja    _none_to_do
  111.  
  112.     imul    edi,_bytes_per_row
  113.     mov    ebx,_fx_xleft
  114.     sar    ebx,16
  115.     jns    ebx_ok
  116.     sub    ebx,ebx
  117. ebx_ok:
  118.     add    edi,ebx
  119.     add    edi,write_buffer
  120.  
  121. ; set _loop_count = # of iterations
  122.     mov    eax,_fx_xright
  123.     sar    eax,16
  124.     cmp    eax,_window_right
  125.     jl    eax_ok1
  126.     mov    eax,_window_right
  127. eax_ok1:    cmp    eax,_window_left
  128.     jg    eax_ok2
  129.     mov    eax,_window_left
  130. eax_ok2:
  131.  
  132.     sub    eax,ebx
  133.     js    _none_to_do
  134.     cmp    eax,_window_width
  135.     jbe    _ok_to_do
  136.     mov    eax,_window_width
  137. _ok_to_do:
  138.     mov    _loop_count,eax
  139.  
  140. ;    edi    destination pixel pointer
  141.  
  142.  
  143.     mov    ecx,offset _lighting_tables
  144.     mov    eax,_fx_u    ; get 32 bit u coordinate
  145.     shr    eax,6    ; get 6:10 int:frac u coordinate into low word
  146.     mov    ebp,_fx_v    ; get 32 bit v coordinate
  147.     shl    ebp,10    ; put 6:10 int:frac into high word
  148.     mov    bp,ax    ; put u coordinate in low word
  149.  
  150.     mov    eax,_fx_du_dx    ; get 32 bit delta u
  151.     shr    eax,6    ; get 6:10 int:frac delta u into low word
  152.     mov    edx,_fx_dv_dx    ; get 32 bit delta v
  153.     shl    edx,10    ; put 6:10 int:frac into high word
  154.     mov    dx,ax    ; put delta u in low word
  155.  
  156. ;; esi, ecx should be free
  157. loop_test = 1    ; set to 1 to run as loop for better profiling
  158.  if loop_test
  159.     mov    ebx,_fx_l
  160.     shr    ebx,8
  161.  
  162.     mov    ecx,_loop_count
  163.     inc    ecx
  164.     shr    ecx,1
  165.     je    one_more_pix
  166.     pushf
  167.  
  168.     align    4
  169. loop1:
  170.     mov    eax,ebp    ; get u, v
  171.     shr    eax,26    ; shift out all but int(v)
  172.     shld    ax,bp,6    ; shift in u, shifting up v
  173.  
  174.     mov    bl,es:[eax]    ; get pixel from source bitmap
  175.  
  176.     mov    al,fs:[ebx]    ; xlat pixel through lighting tables
  177.  
  178.     add    ebp,edx    ; u += du, v += dv
  179.     mov    [edi],al    ; write pixel...
  180.     inc    edi    ; ...and advance
  181.  
  182. ; --- ---
  183.  
  184.     mov    eax,ebp    ; get u, v
  185.     shr    eax,26    ; shift out all but int(v)
  186.     shld    ax,bp,6    ; shift in u, shifting up v
  187.  
  188.     mov    bl,es:[eax]    ; get pixel from source bitmap
  189.  
  190.     add    ebp,edx    ; u += du, v += dv
  191.  
  192.     mov    al,fs:[ebx]    ; xlat pixel through lighting tables
  193.     mov    [edi],al    ; write pixel...
  194.     inc    edi    ; ...and advance
  195.  
  196.     dec    ecx    ; _loop_count
  197.     jne    loop1
  198.  
  199.     popf
  200.     jnc    all_done
  201.  
  202. one_more_pix:    mov    eax,ebp    ; get u, v
  203.     shr    eax,26    ; shift out all but int(v)
  204.     shld    ax,bp,6    ; shift in u, shifting up v
  205.  
  206.     mov    bl,es:[eax]    ; get pixel from source bitmap
  207.     mov    al,fs:[ebx]    ; xlat pixel through lighting tables
  208.     mov    [edi],al    ; write pixel...
  209.  
  210. all_done:    popa
  211.     pop    fs
  212.     pop    es
  213.     ret
  214.  
  215.  
  216.  endif
  217.  
  218. ; usage:
  219. ;    eax    work
  220. ;    ebx    lighting value
  221. ;    ecx    _lighting_tables
  222. ;    edx    du, dv 6:10:6:10
  223. ;    ebp    u, v coordinates 6:10:6:10
  224. ;    esi    pointer to source bitmap
  225. ;    edi    write address
  226.  
  227. _size = (_end1 - _start1)/num_iters
  228.     mov    ebx,_fx_l
  229.     shr    ebx,8
  230.     mov    eax,num_iters
  231.     sub    eax,_loop_count
  232.     imul    eax,eax,dword ptr _size
  233.     add    eax,offset _start1
  234.     jmp    eax
  235.  
  236.     align    4
  237. _start1:
  238.  
  239. ; usage:
  240. ;    eax    work
  241. ;    ebx    lighting value
  242. ;    ecx    _lighting_tables
  243. ;    edx    du, dv 6:10:6:10
  244. ;    ebp    u, v coordinates 6:10:6:10
  245. ;    esi    pointer to source bitmap
  246. ;    edi    write address
  247.  
  248. ; do all but the last pixel in the unwound loop, last pixel done separately because less work is needed
  249.   rept num_iters
  250.  if 1
  251.  
  252.     mov    eax,ebp    ; get u, v
  253.     shr    eax,26    ; shift out all but int(v)
  254.     shld    ax,bp,6    ; shift in u, shifting up v
  255.  
  256.     add    ebp,edx    ; u += du, v += dv
  257.  
  258.     mov    bl,[esi+eax]    ; get pixel from source bitmap
  259.     mov    al,[ecx+ebx]    ; xlat pixel through lighting tables
  260.     mov    [edi],al    ; write pixel...
  261.     inc    edi    ; ...and advance
  262.  
  263.  
  264.   else
  265.  
  266. ; version which assumes segment overrides are in place (which they are obviously not)
  267.     mov    eax,ebp    ; get u, v
  268.     shr    eax,26    ; shift out all but int(v)
  269.     shld    ax,bp,6    ; shift in u, shifting up v
  270.  
  271.     add    ebp,edx    ; u += du, v += dv
  272.  
  273.     mov    bl,[eax]    ; get pixel from source bitmap
  274.     mov    al,[ebx]    ; xlat pixel through lighting tables
  275.     mov    [edi],al    ; write pixel...
  276.     inc    edi    ; ...and advance
  277.  endif
  278.   endm
  279.  
  280. _end1:
  281.  
  282. ; now do the leftover pixel
  283.     mov    eax,ebp
  284.     shr    eax,26    ; shift in v coordinate
  285.     shld    ax,bp,6    ; shift in u coordinate while shifting up v coordinate
  286.     mov    bl,[esi+eax]    ; get pixel from source bitmap
  287.     mov    al,_lighting_tables[ebx]    ; xlat pixel through lighting tables
  288.     mov    [edi],al    ; write pixel...
  289.  
  290. _none_to_do:    popa
  291.     pop    fs
  292.     pop    es
  293.     ret
  294.  
  295. ; -- Code to get rgb 5 bits integer, 5 bits fraction value into 5 bits integer (for each gun)
  296. ; suitable for inverse color lookup
  297. ;**__test:
  298. ;** int 3
  299. ;**;                  rrrrrfffffrrrrrfffffxxbbbbbfffff
  300. ;**    mov    eax,11111001001010101110101101110111b
  301. ;**    and    eax,11111000001111100000001111100000b
  302. ;**    shld    ebx,eax,15
  303. ;**    or    bx,ax
  304.  
  305. _TEXT    ends
  306.  
  307.     end
  308.