home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / includes / psmacros.inc < prev    next >
Text File  |  1998-06-08  |  9KB  |  382 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/includes/rcs/psmacros.inc $
  13. ; $Revision: 1.12 $
  14. ; $Author: matt $
  15. ; $Date: 1994/12/06 14:32:19 $
  16. ;
  17. ; Useful macros.  Everyone should use these.
  18. ;
  19. ; $Log: psmacros.inc $
  20. ; Revision 1.12  1994/12/06  14:32:19  matt
  21. ; Made mprintf turn off if NMONO set
  22. ; 
  23. ; Revision 1.11  1994/11/27  23:18:19  matt
  24. ; Made mprintf go away when debugging turned off
  25. ; 
  26. ; Revision 1.10  1994/03/25  18:00:34  matt
  27. ; Added imulc of 6
  28. ; 
  29. ; Revision 1.9  1994/02/10  18:00:58  matt
  30. ; Changed 'if DEBUG_ON' to 'ifndef NDEBUG'
  31. ; 
  32. ; Revision 1.8  1993/11/22  23:47:06  matt
  33. ; debug macros were trashing eax
  34. ; 
  35. ; Revision 1.7  1993/11/04  12:39:25  mike
  36. ; Modify imulc macro to support fast multiply by 36
  37. ; and multiply anything using imul, but give warning.
  38. ; 
  39. ; Revision 1.6  1993/10/19  21:17:31  matt
  40. ; Added abs_eax macro
  41. ; 
  42. ; Revision 1.5  1993/09/26  22:28:21  matt
  43. ; Removed extra register pushes in mprintf
  44. ; Make DEBUG_ON all uppercase since we seem to have case sensitivity on
  45. ; 
  46. ; Revision 1.4  1993/09/26  19:22:30  matt
  47. ; Added imulc macro, to multiply a register by a constant.  It does not
  48. ; at this time support arbitrary constants, only 0,1,3,5,9, and powers of 2
  49. ; 
  50. ; Revision 1.3  1993/09/13  11:50:57  matt
  51. ; Added 'b' & 'w', aliases for 'byte ptr' and 'word ptr'
  52. ; 
  53. ; Revision 1.2  1993/09/03  19:00:03  matt
  54. ; Added breakpoint macros
  55. ; 
  56. ; Revision 1.1  1993/08/24  12:51:52  matt
  57. ; Initial revision
  58. ; 
  59. ;
  60. ;
  61.  
  62. ;Shortcuts for casting
  63.  
  64. w equ word ptr
  65. b equ byte ptr
  66.  
  67.  
  68. ;The macros @ArgCount() & @ArgRev() are from the file MACROS.INC, provided 
  69. ;with MASM.  I have included them here because MACROS.INC has bugs, so I 
  70. ;couldn't just include it.
  71.  
  72. ; Utility Macros - Version 1.0 - for Microsoft Macro Assembler 6.0
  73. ; (C) Copyright Microsoft Corporation, 1987,1988,1989,1990
  74.  
  75. ;* @ArgCount - Macro function returns the number of arguments in a
  76. ;* VARARG list.
  77. ;*
  78. ;* Params:  arglist - arguments to be counted
  79.  
  80. @ArgCount MACRO arglist:VARARG
  81.     LOCAL count
  82.     count = 0
  83.     FOR arg, <arglist>
  84.         count = count + 1
  85.     ENDM
  86.     EXITM %count
  87. ENDM
  88.  
  89. ;* @ArgRev - Macro function returns a reversed order version of a
  90. ;* VARARG list.
  91. ;*
  92. ;* Shows:   Operators           - <>         !        %
  93. ;*          String directive    - SUBSTR
  94. ;*          Predefined function - @SizeStr
  95. ;*
  96. ;* Params:  arglist - arguments to be reversed
  97.  
  98. @ArgRev MACRO arglist:vararg
  99.     LOCAL txt, arg
  100.     txt TEXTEQU <>
  101. %   FOR arg, <arglist>
  102.         txt CATSTR <arg>, <!,>, txt
  103.     ENDM
  104.  
  105.     txt SUBSTR  txt, 1, @SizeStr( %txt ) - 1
  106.     txt CATSTR  <!<>, txt, <!>>
  107.     EXITM txt
  108. ENDM
  109.  
  110. ;These macros are used for decalaring external vars and functions
  111.  
  112. ;this macro is used to declare several symbols of the same type
  113. ;usage is:  extdef  type,sym0,sym1,...
  114. extdef    macro    type,syms:vararg
  115.     for    sym,<syms>
  116.      externdef sym:type
  117.     endm
  118.     endm
  119.  
  120. ;this macro is used to generate ext<type> macros 
  121. extgen    macro    type,id
  122. ext&id    macro    syms:vararg
  123.     extdef    type,syms
  124.     endm
  125.     endm
  126.  
  127. ;macros for common types, such as word (extw), byte (extb), & near (extn)
  128.  
  129.     extgen    word,w
  130.     extgen    byte,b
  131.     extgen    dword,d
  132.     extgen    near,n
  133.  
  134.  
  135. ;compute the absolute value of eax.  afterwards, edx=sign (0 or -1)
  136. abs_eax    macro
  137.     cdq
  138.     xor    eax,edx
  139.     sub    eax,edx
  140.     endm
  141.  
  142. ;PUSHM & POPM are used for multiple registers.  Note that POPM pops in the
  143. ;reverse order from PUSHM, so the list of regs shouls be the same for both.
  144. ;You can also define a constant which is a register list, and use it as the
  145. ;argument to both macros.
  146.  
  147. ;push multiple registers
  148. pushm    macro    args:vararg
  149.     local    arg
  150.     for    arg,<args>
  151.      push    arg
  152.     endm
  153.     endm
  154.  
  155. ;pop multiple registers
  156. popm    macro    args:vararg
  157.     local    arg
  158. %    for    arg,@ArgRev(args)
  159.      pop    arg
  160.     endm
  161.     endm
  162.  
  163. ;PUSHLONG pushes a long, zero extending the argument if necessary
  164. ;it trashes no registers
  165. pushlong    macro    arg
  166.     local    s
  167. s = TYPE arg
  168.     if    s EQ 0    ;constant, I think
  169.      push    arg
  170.     elseif    s LT 4
  171.      push    eax
  172.      movzx    eax,arg
  173.      xchg    eax,[esp]
  174.     else
  175.      push    arg
  176.     endif
  177.  
  178.     endm
  179.  
  180. ;PUSHML is pushm using pushlong
  181. pushml    macro    args:vararg
  182.     local    arg
  183.     for    arg,<args>
  184.      pushlong    arg
  185.     endm
  186.     endm
  187.  
  188.  
  189. ;DBSTR stores a string with occurances of \n converted to newlines
  190. ;this macro expects quotes around the string
  191. ;
  192. ;note the 'fudge' variable.  This fixes an odd problem with the way
  193. ;the string macros deal with backslashes - @InStr() treats them like
  194. ;any other character, but @SubStr() ignores them
  195. dbstr    macro    str
  196.     local    pos,oldpos,len,fudge
  197.  
  198.     oldpos = 2    ;skip initial quote
  199.     fudge = 0
  200.     len = @SizeStr(str)
  201.  
  202.     pos = @InStr(oldpos,str,<\n>)
  203.  
  204.     while    pos GE oldpos
  205.  
  206.      if    pos GT oldpos
  207.       %db    '&@SubStr(<&str>,&oldpos-&fudge,&pos-&oldpos)'
  208.      endif
  209.      db    10
  210.      oldpos = pos+2
  211.      fudge = fudge+1
  212.  
  213.      pos = @InStr(oldpos,<str>,<\n>)
  214.  
  215.     endm
  216.  
  217.     if    oldpos LT len
  218. ;;;     %db    '&@SubStr(&str,&oldpos-&fudge,&len-&oldpos-1)'
  219.      %db    '&@SubStr(&str,&oldpos-&fudge,&len-&oldpos)'
  220.     endif
  221.  
  222.     endm
  223.  
  224.  
  225. ;MPRINTF is a macro interface to the mprintf funcion.  It puts the format
  226. ;string in the code segment at the current location, pushes the args, and
  227. ;calls mprintf. If window is not specified, zero is assumed
  228. mprintf    macro    window:=<0>,format:req,args:vararg
  229.     local    string,skip
  230.     ifndef    NDEBUG
  231.     ifndef    NMONO
  232.     extn    _mprintf_
  233.     jmp    skip
  234. string    label    byte
  235.     dbstr    format
  236.     db    0
  237. skip:
  238.     ifnb    <args>
  239. %     pushml    @ArgRev(args)
  240.     endif
  241.     pushml    offset string,window
  242.     call    _mprintf_
  243.     add    esp,(@ArgCount(args)+2)*4    ;fix stack
  244.     endif
  245.     endif
  246.     endm
  247.  
  248.  
  249. ;MPRINTF_AT - version of mprintf with coordinates
  250. mprintf_at    macro    window:=<0>,row,col,format:req,args:vararg
  251.     local    string,skip
  252.     ifndef    NDEBUG
  253.     ifndef    NMONO
  254.     extn    _mprintf_at_
  255.     jmp    skip
  256. string    label    byte
  257.     dbstr    format
  258.     db    0
  259. skip:
  260.     ifnb    <args>
  261. %     pushml    @ArgRev(args)
  262.     endif
  263.     pushml    offset string,col,row,window
  264.     call    _mprintf_at_
  265.     add    esp,(@ArgCount(args)+4)*4    ;fix stack
  266.     endif
  267.     endif
  268.     endm
  269.  
  270.  
  271. ;DEBUG calls mprintf with window 0, preserving all registers and flags
  272. ;is is conditionall assembled based on the DEBUG_ON flags
  273. debug    macro    format:req,args:vararg
  274.     ifndef    NDEBUG
  275.      pushf        ;save flags
  276.      push    eax    ;mprintf trashes eax
  277.      mprintf    ,format,args
  278.      pop    eax
  279.      popf
  280.     endif
  281.     endm
  282.  
  283. ;DEBUG_AT - version of debug with coordinates
  284. debug_at    macro    row,col,format:req,args:vararg
  285.     ifndef    NDEBUG
  286.      pushf        ;save flags
  287.      push    eax    ;mprintf trashes eax
  288.      mprintf_at ,row,col,format,args
  289.      pop    eax
  290.      popf
  291.     endif
  292.     endm
  293.  
  294. ;Debugging breakpoint macros
  295.  
  296. ;print a message, and do an int3 to pop into the debugger  
  297. debug_brk    macro    str
  298.     ifndef    NDEBUG
  299.      debug    str
  300.      int    3
  301.     endif
  302.     endm
  303.  
  304. break_if    macro    cc,str
  305.     local    skip,yes_break
  306.     ifndef    NDEBUG
  307.      j&cc    yes_break
  308.      jmp    skip
  309. yes_break:     debug_brk str
  310. skip:
  311.     endif
  312.     endm
  313.  
  314. ;returns the bit number of the highest bit
  315. @HighBit    macro    n
  316.     local    t,c
  317.     if    n EQ 0
  318.      exitm    <-1>    ;error!
  319.     else
  320.      t = n
  321.      c = 0
  322.      while    t GT 1
  323.       t = t SHR 1
  324.       c = c+1
  325.      endm
  326.      exitm    <c>
  327.     endif
  328.     endm
  329.  
  330. ;returns the bit number of the lowest bit
  331. @LowBit    macro    n
  332.     ;local    t,c
  333.     local    c
  334.     if    n EQ 0
  335.      exitm    <-1>    ;error!
  336.     else
  337.      t = n
  338.      c = 0
  339.      while    (t and 1) EQ 0
  340.       t = t SHR 1
  341.       c = c+1
  342.      endm
  343.      exitm    <c>
  344.     endif
  345.     endm
  346.  
  347.  
  348. ;"multiply" the given register by a constant, using whatever method is
  349. ;best for the given constant
  350. imulc    macro    reg,c
  351.     local    low,high
  352.  
  353.     if    c EQ 0
  354.      xor    reg,reg
  355.     elseif    c EQ 1
  356.     elseif    c EQ 3
  357.      lea    reg,[reg*2+reg]
  358.     elseif    c EQ 5
  359.      lea    reg,[reg*4+reg]
  360.     elseif    c EQ 6
  361.      lea    reg,[reg*2+reg]    ;*3
  362.      shl    reg,1    ;*6
  363.     elseif    c EQ 9
  364.      lea    reg,[reg*8+reg]
  365.     elseif    c EQ 36
  366.      lea    reg,[reg*8+reg]
  367.      sal    reg,2
  368.     else
  369.      low = @LowBit(c)
  370.      high = @HighBit(c)
  371.      if    low EQ high
  372.       shl    reg,@LowBit(c)
  373.      else
  374.       imul    reg,c
  375.       echo    Warning: Using imul, to perform multiply by &c
  376.       ;; .err
  377.      endif
  378.     endif
  379.  
  380.     endm
  381.  
  382.