home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / bios / timer.asm < prev    next >
Assembly Source File  |  1998-06-08  |  19KB  |  649 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/bios/rcs/timer.asm $
  13. ; $Revision: 1.28 $
  14. ; $Author: matt $
  15. ; $Date: 1995/02/15 01:36:56 $
  16. ;
  17. ; Routines for setting and using system timers
  18. ;
  19. ; $Log: timer.asm $
  20. ; Revision 1.28  1995/02/15  01:36:56  matt
  21. ; Cleaned up code to avoid doing out 20,20 more than once
  22. ; 
  23. ; Revision 1.27  1995/02/14  11:39:37  john
  24. ; Fixed bug with joystick handler not having enough
  25. ; stack space under Windows.
  26. ; 
  27. ; Revision 1.26  1995/02/09  21:51:39  john
  28. ; Made so that DOS timer interrupt gets called before interrupts are
  29. ; enabled in timer interpt because not doing this cause conflicts with
  30. ; ps2 style mice and smartdrv with write caching enabled that hangs the
  31. ; program and trashes the FAT.
  32. ; 
  33. ; Revision 1.25  1995/02/04  15:39:33  john
  34. ; More time interrupt changes.
  35. ; 
  36. ; Revision 1.24  1995/02/03  23:25:21  john
  37. ; Made so that when interrupts are nested, the time interrupt still
  38. ; calls the DOS one.
  39. ; 
  40. ; Revision 1.23  1995/01/29  19:00:42  john
  41. ; Made latching timer value more readable.
  42. ; 
  43. ; Revision 1.22  1995/01/17  10:34:53  mike
  44. ; prevent divide overflows.
  45. ; 
  46. ; Revision 1.21  1994/12/15  11:10:54  john
  47. ; Added code that should make DOS 18.2 callbacks 
  48. ; a bit more accurate.
  49. ; 
  50. ; Revision 1.20  1994/12/10  12:47:34  john
  51. ; Made so that timer_get_fixed seconds and get_approx seconds are always equal.
  52. ; 
  53. ; Revision 1.19  1994/12/10  12:27:34  john
  54. ; Added timer_get_approx_seconds.
  55. ; 
  56. ; Revision 1.18  1994/12/10  12:07:14  john
  57. ; Added tick counter variable.
  58. ; 
  59. ; Revision 1.17  1994/12/04  11:55:16  john
  60. ; Made stick read at whatever rate the clock is at, not
  61. ; at 18.2 times/second.
  62. ; 
  63. ; Revision 1.16  1994/11/28  15:24:10  john
  64. ; Cleaned up timer interrupt a bit.
  65. ; 
  66. ; Revision 1.15  1994/11/22  17:00:43  john
  67. ; Made the timer handler fill in ES along with DS.
  68. ; The HMI drivers expect this.
  69. ; 
  70. ; Revision 1.14  1994/11/15  12:04:38  john
  71. ; Cleaned up timer code a bit... took out unused functions
  72. ; like timer_get_milliseconds, etc.
  73. ; 
  74. ; Revision 1.13  1994/10/05  16:17:40  john
  75. ; Made interrupts more stable.
  76. ; 
  77. ; Revision 1.12  1994/09/29  18:29:57  john
  78. ; Enabled interrupts whil calling the user_function.
  79. ; 
  80. ; Revision 1.11  1994/09/23  16:00:31  john
  81. ; MAde the timer interrupt switch to a 4K stack
  82. ; before calling the timer_function.
  83. ; 
  84. ; Revision 1.10  1994/09/22  16:09:21  john
  85. ; Fixed some virtual memory lockdown problems with timer and
  86. ; joystick.
  87. ; 
  88. ; Revision 1.9  1994/04/29  12:13:48  john
  89. ; Locked all memory used during interrupts so that program
  90. ; won't hang when using virtual memory.
  91. ; 
  92. ; Revision 1.8  1994/04/28  23:50:49  john
  93. ; Changed calling for init_timer.  Made the function that the
  94. ; timer calls be a far function. All of this was done to make
  95. ; our timer system compatible with the HMI sound stuff.
  96. ; 
  97. ; Revision 1.7  1994/02/17  15:57:15  john
  98. ; Changed key libary to C.
  99. ; 
  100. ; Revision 1.6  1994/01/18  20:19:17  john
  101. ; Fixed minor flaws with pending interrupts,
  102. ; interfaced with joystick code.
  103. ; 
  104. ; Revision 1.5  1994/01/18  13:54:18  john
  105. ; Fixed a few miner flaws.
  106. ; 
  107. ; Revision 1.4  1994/01/18  10:58:25  john
  108. ; Added timer_get_fixed_seconds
  109. ; 
  110. ; Revision 1.3  1993/12/20  15:40:59  john
  111. ; *** empty log message ***
  112. ; 
  113. ; Revision 1.2  1993/09/23  18:08:44  john
  114. ; added code so that timer_init can handle multiple calls.
  115. ; added code so that atexit is called.
  116. ; 
  117. ; Revision 1.1  1993/07/10  13:10:43  matt
  118. ; Initial revision
  119. ; 
  120. ;
  121. ;
  122.  
  123. ;***************************************************************************
  124. ;***************************************************************************
  125. ;*****                                                                 *****
  126. ;*****                     T I M E R . A S M                           *****
  127. ;*****                                                                 *****
  128. ;*****                                                                 *****
  129. ;***** PROCEDURES                                                      *****
  130. ;*****                                                                 *****
  131. ;*****                                                                 *****
  132. ;*****                                                                 *****
  133. ;***** VARIABLES                                                       *****
  134. ;*****                                                                 *****
  135. ;*****                                                                 *****
  136. ;***** CONSTANTS                                                       *****
  137. ;*****                                                                 *****
  138. ;*****                                                                 *****
  139. ;***************************************************************************
  140. ;***************************************************************************
  141.  
  142. .386
  143.  
  144. ;************************************************************************
  145. ;**************** FLAT MODEL DATA SEGMENT STUFF *************************
  146. ;************************************************************************
  147.  
  148. _DATA   SEGMENT BYTE PUBLIC USE32 'DATA'
  149.  
  150. rcsid    db    "$Id: timer.asm 1.28 1995/02/15 01:36:56 matt Exp $"
  151.  
  152. TDATA           EQU     40h
  153. TCOMMAND        EQU     43h
  154. PIC             EQU     020h
  155. STACK_SIZE    EQU    4096    ; A 4K stack
  156.  
  157. TIMER_DATA STRUCT   
  158.     in_timer    db  0
  159.  
  160.     nested_counter    dd    0
  161.  
  162.     _timer_cnt      dd  65536
  163.     dos_timer       dd  ?
  164.  
  165.     joystick_poller    dd  0
  166.  
  167.     user_function   df  0
  168.     
  169.     org_interrupt    df  0    
  170.  
  171.     saved_stack    df  0
  172.  
  173.     new_stack    df  0
  174.  
  175.     tick_count    dd  0
  176.  
  177.     Installed db     0
  178.  
  179.     TimerStack    db  STACK_SIZE dup (?)        
  180. TIMER_DATA ENDS
  181.  
  182.     TimerData    TIMER_DATA <>    
  183.  
  184. _DATA   ENDS
  185.  
  186. DGROUP  GROUP _DATA
  187.  
  188.  
  189. ;************************************************************************
  190. ;**************** FLAT MODEL CODE SEGMENT STUFF *************************
  191. ;************************************************************************
  192.  
  193. _TEXT   SEGMENT BYTE PUBLIC USE32 'CODE'
  194.  
  195.         ASSUME  ds:_DATA
  196.         ASSUME  cs:_TEXT
  197.  
  198. INCLUDE PSMACROS.INC
  199.  
  200. TIMER_LOCKED_CODE_START:
  201.  
  202.         extn atexit_
  203.  
  204. PUBLIC timer_get_stamp64
  205.  
  206. timer_get_stamp64:
  207.         ; Return a 64-bit stamp that is the number of 1.19Mhz pulses
  208.         ; since the time was initialized.  Returns in EDX:EAX.
  209.         ; Also, interrupts must be disabled.
  210.  
  211.         xor     eax, eax            ; Clear all of EAX
  212.         out     TCOMMAND, al        ; Tell timer to latch
  213.  
  214.         mov     al, 0ah             ; Find if interrupt pending
  215.         out     PIC, al
  216.         jmp    @f
  217. @@:        in      al, PIC
  218.         and     eax, 01b
  219.         jz      NoInterrupt
  220.  
  221.         in      al, TDATA           ; Read in lo byte
  222.         mov     dl, al
  223.             in      al, TDATA           ; Read in hi byte
  224.         mov    dh, al
  225.         and    edx, 0ffffh
  226.         mov    eax, TimerData._timer_cnt
  227.         shl    eax, 1        
  228.         sub    eax, edx
  229.             
  230.         push    ebx
  231.         mov    ebx, eax
  232.         mov    eax, TimerData.tick_count
  233.         imul    TimerData._timer_cnt    ; edx:eax = Number of 1.19 MHz ticks elapsed...
  234.         add    eax, ebx
  235.         adc    edx, 0                
  236.         pop    ebx
  237.  
  238.         ret
  239.  
  240. NoInterrupt:
  241.         in      al, TDATA           ; Read in lo byte
  242.         mov     ah, al
  243.         in      al, TDATA           ; Read in hi byte
  244.         xchg    ah, al              ; arrange em correctly
  245.         mov     edx, TimerData._timer_cnt
  246.         sub     dx, ax              ; BX = timer ticks
  247.         mov     ax, dx
  248.  
  249.         push    ebx
  250.         mov    ebx, eax
  251.         mov    eax, TimerData.tick_count
  252.         imul    TimerData._timer_cnt    ; edx:eax = Number of 1.19 MHz ticks elapsed...
  253.         add    eax, ebx
  254.         adc    edx, 0                
  255.         pop    ebx
  256.  
  257.         ret
  258.  
  259.  
  260. PUBLIC  timer_get_fixed_seconds_
  261.  
  262. timer_get_fixed_seconds_:
  263.         push    ebx
  264.         push    edx
  265.  
  266.         cli
  267.         call    timer_get_stamp64
  268.         sti
  269.  
  270.         ; Timing in fixed point (16.16) seconds.
  271.         ; Can be used for up to 1000 hours
  272.         shld    edx, eax, 16            ; Keep 32+11 bits
  273.         shl     eax, 16            
  274.         ; edx:eax = number of 1.19Mhz pulses elapsed.
  275.         mov     ebx, 1193180
  276.  
  277. ; Make sure we won't divide overflow.  Make time wrap at about 9 hours
  278. sub_again:        sub     edx, ebx    ; subtract until negative...
  279.         jns     sub_again    ; ...to prevent divide overflow...
  280.         add     edx, ebx    ; ...then add in to get correct value.
  281.         div     ebx
  282.         ; eax = fixed point seconds elapsed...
  283.  
  284.         pop     edx
  285.         pop     ebx
  286.  
  287.         ret
  288.  
  289. PUBLIC  timer_get_fixed_secondsX_
  290.  
  291. timer_get_fixed_secondsX_:
  292.         push    ebx
  293.         push    edx
  294.  
  295.         call    timer_get_stamp64
  296.  
  297.         ; Timing in fixed point (16.16) seconds.
  298.         ; Can be used for up to 1000 hours
  299.         shld    edx, eax, 16            ; Keep 32+11 bits
  300.         shl     eax, 16            
  301.         ; edx:eax = number of 1.19Mhz pulses elapsed.
  302.         mov     ebx, 1193180
  303.  
  304. xsub_again:        sub     edx, ebx    ; subtract until negative...
  305.         jns     xsub_again    ; ...to prevent divide overflow...
  306.         add     edx, ebx    ; ...then add in to get correct value.
  307.  
  308.         div     ebx
  309.         ; eax = fixed point seconds elapsed...
  310.  
  311.         pop     edx
  312.         pop     ebx
  313.  
  314.         ret
  315.  
  316. PUBLIC timer_get_approx_seconds_
  317. timer_get_approx_seconds_:
  318.     push    ebx
  319.     push    edx
  320.  
  321.     mov    eax, TimerData.tick_count
  322.     imul    TimerData._timer_cnt    ; edx:eax = Number of 1.19 MHz ticks elapsed...
  323.     shld    edx, eax, 16            ; Keep 32+16 bits, for conversion to fixed point
  324.     shl     eax, 16            
  325.     ; edx:eax = number of 1.19Mhz pulses elapsed.
  326.     mov     ebx, 1193180
  327.  
  328. approx_sub_again:    sub     edx, ebx    ; subtract until negative...
  329.     jns     approx_sub_again    ; ...to prevent divide overflow...
  330.     add     edx, ebx    ; ...then add in to get correct value.
  331.  
  332.     div     ebx
  333.     ; eax = fixed point seconds elapsed...
  334.  
  335.     pop    edx
  336.     pop    ebx
  337.     ret
  338.  
  339.  
  340.  
  341. ;extern void timer_set_rate(int count_val);
  342. ;extern void timer_set_function( void _far * function );
  343.  
  344. PUBLIC  timer_set_rate_
  345. timer_set_rate_:
  346.     ; eax = rate
  347.     pushad
  348.  
  349.     ; Make sure eax below or equal to 65535 and above 0
  350.     ; if its not, make it be 65536 which is normal dos
  351.     ; timing.
  352.     cmp    eax, 65535
  353.     jbe    @f
  354.     mov    eax, 65536
  355. @@:    cmp    eax, 0
  356.     jne    @f
  357.     mov    eax, 65536
  358. @@:    ; Set the timer rate to eax
  359.     cli
  360.     mov    TimerData.tick_count, 0
  361.     mov     TimerData._timer_cnt, eax        
  362.     mov     al, 34h        ; count in binary, mode 2, load low byte then hi byte, counter 0:  00 11 010 0
  363.     out     TCOMMAND, al    ; Reset PIT channel 0
  364.     mov     eax, TimerData._timer_cnt
  365.     out     TDATA, al
  366.     mov     al, ah
  367.     out     TDATA, al
  368.     sti
  369.     popad
  370.     ret
  371.  
  372. PUBLIC  timer_set_function_
  373. timer_set_function_:
  374.     ; dx:eax = far pointer to user function
  375.     pushad
  376.     cli
  377.     mov    dword ptr TimerData.user_function[0], eax    ; offset
  378.     mov     word ptr TimerData.user_function[4], dx        ; selector
  379.     sti
  380.     popad
  381.     ret
  382.  
  383. PUBLIC timer_set_joyhandler_
  384. timer_set_joyhandler_:
  385.     cli
  386.     mov    TimerData.joystick_poller, eax
  387.     sti
  388.     ret
  389.  
  390.  
  391. ;************************************************************************
  392. ;************************************************************************
  393. ;*****                                                              *****
  394. ;*****                T I M E R _ H A N D L E R                     *****
  395. ;*****                                                              *****
  396. ;************************************************************************
  397. ;************************************************************************
  398.  
  399. timer_handler:
  400.         push    ds
  401.         push    es
  402.         push    eax
  403.  
  404.         mov     ax, DGROUP       ; Interrupt, so point to our data segment
  405.         mov     ds, ax
  406.         mov     es, ax
  407.  
  408.         ; Increment time counter...
  409.         inc    TimerData.tick_count
  410.  
  411.         mov    eax, TimerData._timer_cnt
  412.         add     TimerData.dos_timer, eax        ; Increment DOS timer
  413.         cmp    TimerData.dos_timer, 65536
  414.         jb    NoChainToOld            ; See if we need to chain to DOS 18.2
  415.         and    TimerData.dos_timer, 0ffffh
  416.  
  417.         ;
  418.         ; Call the original DOS handler....
  419.         ;
  420.         pushfd
  421.         call    fword ptr [TimerData.org_interrupt]
  422.  
  423.         jmp    NoReset        ;old handler has reset, so we don't
  424.  
  425. NoChainToOld:
  426.         ; Reset controller
  427.         mov     al, 20h         ; Reset interrupt controller
  428.         out     20h, al
  429.  
  430. NoReset:
  431.         cmp    TimerData.in_timer, 0
  432.         jne    ExitInterrupt
  433.  
  434.         mov    TimerData.in_timer, 1        ; Mark that we're in a timer interrupt...
  435.  
  436.         ; Reenable interrupts
  437.         sti            ; Reenable interrupts
  438.  
  439.         cmp     word ptr TimerData.user_function[4], 0        ; Check the selector...
  440.         je      NoUserFunction
  441.  
  442.         ; Switch stacks while calling the user-definable function...
  443.         pushad
  444.         push    fs
  445.         push    gs
  446.         mov    dword ptr TimerData.saved_stack[0], esp
  447.         mov    word ptr TimerData.saved_stack[4], ss
  448.         lss    esp, TimerData.new_stack    ; Switch to new stack
  449.         call    fword ptr [TimerData.user_function]    ; Call new function
  450.         lss    esp,  TimerData.saved_stack    ; Switch back to original stack
  451.         pop    gs
  452.         pop    fs
  453.         popad
  454.  
  455. NoUserFunction:    
  456.         cmp    dword ptr TimerData.joystick_poller, 0
  457.         je    NoJoyPolling
  458.         mov    eax, TimerData._timer_cnt
  459.         mov    dword ptr TimerData.saved_stack[0], esp
  460.         mov    word ptr TimerData.saved_stack[4], ss
  461.         lss    esp, TimerData.new_stack    ; Switch to new stack
  462.         call    dword ptr TimerData.joystick_poller
  463.         lss    esp,  TimerData.saved_stack    ; Switch back to original stack
  464.  
  465. NoJoyPolling:
  466.         cli
  467.         mov    TimerData.in_timer, 0
  468.  
  469. ExitInterrupt:
  470.         ;;mov     al, 20h         ; Reset interrupt controller
  471.         ;;out     20h, al
  472.         pop    eax
  473.         pop    es
  474.         pop    ds
  475.         iretd                ; Return from timer interrupt
  476.  
  477.  
  478. TIMER_LOCKED_CODE_STOP:
  479.  
  480. ;************************************************************************
  481. ;************************************************************************
  482. ;*****                                                              *****
  483. ;*****                   T I M E R _ I N I T                        *****
  484. ;*****                                                              *****
  485. ;************************************************************************
  486. ;************************************************************************
  487.  
  488.  
  489. PUBLIC  timer_init_
  490.  
  491. timer_init_:
  492.         pushad
  493.         push    ds
  494.         push    es
  495.  
  496.         cmp     TimerData.Installed, 1
  497.         je      AlreadyInstalled
  498.  
  499.         mov     TimerData._timer_cnt, 65536    ; Set to BIOS's normal 18.2 Hz
  500.         mov     TimerData.dos_timer, 0        ; clear DOS Interrupt counter
  501.         mov     dword ptr TimerData.user_function[0], 0    ; offset of user function
  502.         mov     word ptr TimerData.user_function[4], 0    ; selector of user function
  503.  
  504.         lea    eax, ds:[TimerData.TimerStack]    ; Use EAX as temp stack pointer
  505.         add    eax, STACK_SIZE            ; Top of stack minus space for saving old ss:esp
  506.         mov    dword ptr TimerData.new_stack[0], eax
  507.         mov    word ptr TimerData.new_stack[4], ds
  508.  
  509.         ;--------------- lock data used in interrupt
  510.         mov    eax, SIZEOF TIMER_DATA
  511.         mov    esi, eax
  512.         shr    esi, 16            
  513.         mov    edi, eax
  514.         and    edi, 0ffffh    ; si:di = length of region to lock in bytes
  515.         lea    ebx, ds:TimerData
  516.         lea    ecx, ds:TimerData
  517.         shr    ebx, 16
  518.         and    ecx, 0ffffh    ; bx:cx = start of linear address to lock
  519.         mov    eax, 0600h    ; DPMI lock address function
  520.         int    31h        ; call dpmi
  521.         jnc    @f
  522.         int    3        ; LOCK FAILED!!
  523. @@:
  524.         ;--------------- lock code used in interrupt
  525.         lea    eax, cs:TIMER_LOCKED_CODE_STOP
  526.         lea    ecx, cs:TIMER_LOCKED_CODE_START
  527.         sub    eax, ecx
  528.         inc    eax        ; EAX = size of timer interrupt handler
  529.         mov    esi, eax
  530.         shr    esi, 16            
  531.         mov    edi, eax
  532.         and    edi, 0ffffh    ; si:di = length of region to lock in bytes
  533.         lea    ebx, cs:TIMER_LOCKED_CODE_START
  534.         lea    ecx, cs:TIMER_LOCKED_CODE_START
  535.         shr    ebx, 16
  536.         and    ecx, 0ffffh    ; bx:cx = start of linear address to lock
  537.         mov    eax, 0600h    ; DPMI lock address function
  538.         int    31h        ; call dpmi
  539.         jnc    @f
  540.         int    3        ; LOCK FAILED!!
  541. @@:
  542.  
  543.         ;**************************************************************
  544.         ;******************* SAVE OLD INT8 HANDLER ********************
  545.         ;**************************************************************
  546.         mov     eax, 03508h             ; DOS Get Vector 08h
  547.         int     21h                     ; Call DOS
  548.  
  549.         mov     dword ptr TimerData.org_interrupt[0], ebx    ; offset of user function
  550.         mov    word ptr TimerData.org_interrupt[4], es        ; selector of user function
  551.  
  552.         ;**************************************************************
  553.         ;***************** INSTALL NEW INT8 HANDLER *******************
  554.         ;**************************************************************
  555.  
  556.         cli
  557.  
  558.         mov     al, 34h        ; count in binary, mode 2, load low byte then hi byte, counter 0:  00 11 010 0
  559.         out     TCOMMAND, al    ; Reset PIT channel 0
  560.         mov     eax, TimerData._timer_cnt
  561.         out     TDATA, al
  562.         mov     al, ah
  563.         out     TDATA, al
  564.  
  565.         mov     TimerData.tick_count, 0
  566.         mov     TimerData.Installed,1
  567.  
  568.         mov     eax, 02508h             ; DOS Set Vector 08h
  569.         mov     edx, offset timer_handler  ; Point DS:EDX to new handler
  570.         mov     bx, cs
  571.         push    ds
  572.         mov     ds, bx
  573.         int     21h
  574.         pop     ds
  575.         sti
  576.         lea     eax, cs:timer_close_
  577.         call    atexit_
  578.  
  579. AlreadyInstalled:
  580.  
  581.         pop     es
  582.         pop     ds
  583.         popad
  584.  
  585.         ret
  586.  
  587.  
  588. ;************************************************************************
  589. ;************************************************************************
  590. ;*****                                                              *****
  591. ;*****                  T I M E R _ C L O S E _                     *****
  592. ;*****                                                              *****
  593. ;************************************************************************
  594. ;************************************************************************
  595.  
  596. PUBLIC  timer_close_
  597.  
  598. timer_close_:
  599.         push    eax
  600.         push    edx
  601.         push    ds
  602.  
  603.  
  604.         cmp     TimerData.Installed, 0
  605.         je      NotInstalled
  606.         mov     TimerData.Installed, 0
  607.  
  608.         ;**************************************************************
  609.         ;***************** RESTORE OLD INT9 HANDLER *******************
  610.         ;**************************************************************
  611.  
  612.         cli
  613.         mov     al, 36h        ; count in binary, mode 3, load low byte then hi byte, counter 0:  00 11 011 0
  614.         out     TCOMMAND, al    ; Reser PIT channel 0
  615.         mov     ax, 0h
  616.         out     TDATA, al
  617.         mov     al, ah
  618.         out     TDATA, al
  619.  
  620.         push    ds
  621.         mov     eax, 02508h         ; DOS Set Vector 08h
  622.         mov     edx, dword ptr TimerData.org_interrupt[0]
  623.         mov     ds, word ptr TimerData.org_interrupt[4]
  624.         int     21h
  625.         pop    ds
  626.  
  627.         sti
  628.         
  629.         cmp    TimerData.nested_counter, 0
  630.         je    NoNestedInterrupts
  631.         mov    eax, TimerData.nested_counter
  632.         ;int     3        ; Get John!!
  633.     
  634. NoNestedInterrupts:
  635.         
  636.  
  637. NotInstalled:
  638.         pop     ds
  639.         pop     edx
  640.         pop     eax
  641.  
  642.         ret
  643.  
  644.  
  645. _TEXT           ENDS
  646.  
  647.  
  648.         END
  649.