home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / bios / oldkey.asm < prev    next >
Assembly Source File  |  1998-06-08  |  31KB  |  1,080 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11.  
  12. ;
  13. ; $Source: f:/miner/source/bios/rcs/oldkey.asm $
  14. ; $Revision: 1.2 $
  15. ; $Author: john $
  16. ; $Date: 1994/02/17 15:55:59 $
  17. ; 
  18. ; Old assembly key stuff...
  19. ; 
  20. ; $Log: oldkey.asm $
  21. ; Revision 1.2  1994/02/17  15:55:59  john
  22. ; Initial version
  23. ; 
  24. ; Revision 1.1  1994/02/17  15:55:11  john
  25. ; Initial revision
  26. ; 
  27. ; 
  28.  
  29. ; $Log: oldkey.asm $
  30. ; Revision 1.2  1994/02/17  15:55:59  john
  31. ; Initial version
  32. ; 
  33. ; Revision 1.20  1994/01/18  10:58:55  john
  34. ; *** empty log message ***
  35. ; 
  36. ; Revision 1.19  1993/12/22  13:28:40  john
  37. ; Added back changes Matt made in r1.14
  38. ; 
  39. ; Revision 1.18  1993/12/22  13:18:32  john
  40. ; *** empty log message ***
  41. ; 
  42. ; Revision 1.17  1993/12/20  16:48:47  john
  43. ; Put cli/sti around clear keybuffer in key_close
  44. ; 
  45. ; Revision 1.16  1993/12/20  15:39:13  john
  46. ; Tried to neaten handler code... also, moved some cli's and sti's around
  47. ; trying to find bug.  Made the code call key_get_milliseconds instead
  48. ; of timer_get_milliseconds, because we don't want the cli and sti
  49. ; stuff in the interrupt handler.  
  50. ; 
  51. ; Revision 1.15  1993/12/02  10:54:48  john
  52. ; Made the Ctrl,Shift,Alt keys buffer like all the other keys.
  53. ; 
  54. ; Revision 1.14  1993/10/29  11:25:18  matt
  55. ; Made key_down_time() not accumulate time if shift,alt,ctrl down
  56. ; 
  57. ; Revision 1.13  1993/10/29  10:47:00  john
  58. ; *** empty log message ***
  59. ; 
  60. ; Revision 1.12  1993/10/16  19:24:16  matt
  61. ; Added new function key_clear_times() & key_clear_counts()
  62. ; 
  63. ; Revision 1.11  1993/10/15  10:16:49  john
  64. ; bunch of stuff, mainly with detecting debugger.
  65. ; 
  66. ; Revision 1.10  1993/10/04  13:25:57  john
  67. ; Changed the way extended keys are processed.
  68. ; 
  69. ; Revision 1.9  1993/09/28  11:35:32  john
  70. ; added key_peekkey
  71. ; 
  72. ; Revision 1.8  1993/09/23  18:09:23  john
  73. ; fixed bug checking for DBG
  74. ; 
  75. ; Revision 1.7  1993/09/23  17:28:01  john
  76. ; made debug check look for DBG> instead of CONTROL
  77. ; 
  78. ; Revision 1.6  1993/09/20  17:08:19  john
  79. ; Made so that keys pressed in debugger don't get passed through to
  80. ; the keyboard handler. I also discovered, but didn't fix a error
  81. ; (page fault) caused by jumping back and forth between the debugger
  82. ; and the program...
  83. ; 
  84. ; Revision 1.5  1993/09/17  09:58:12  john
  85. ; Added checks for already installed, not installed, etc.
  86. ; 
  87. ; Revision 1.4  1993/09/15  17:28:00  john
  88. ; Fixed bug in FlushBuffer that used CX before a REP instead of ECX.
  89. ; 
  90. ; Revision 1.3  1993/09/08  14:48:00  john
  91. ; made getch() return an int instead of a char that has shift states, etc.
  92. ; 
  93. ; Revision 1.2  1993/07/22  13:12:23  john
  94. ; fixed comment
  95. ; ,.
  96. ; 
  97. ; Revision 1.1  1993/07/10  13:10:42  matt
  98. ; Initial revision
  99. ; 
  100. ;
  101. ;
  102.  
  103. ;***************************************************************************
  104. ;***************************************************************************
  105. ;*****                                                                 *****
  106. ;*****                                                                 *****
  107. ;*****                        K E Y . A S M                            *****
  108. ;*****                                                                 *****
  109. ;***** Contains routines to get, buffer, and check key presses.        *****
  110. ;*****                                                                 *****
  111. ;*****                                                                 *****
  112. ;***** PROCEDURES                                                      *****
  113. ;*****                                                                 *****
  114. ;***** key_init()  - Activates the keyboard package.                   *****
  115. ;***** key_close() - Deactivates the keyboard package.                 *****
  116. ;***** key_check() - Returns 1 if a buffered key is waiting.           *****
  117. ;***** key_getch() - Waits for and returns a buffered keypress.        *****
  118. ;***** key_flush() - Clears buffers and state array.                   *****
  119. ;***** key_time() - Index by scan code. Contains the time key has been *****
  120. ;*****             held down. NOT DONE YET.                            *****
  121. ;*****                                                                 *****
  122. ;*****                                                                 *****
  123. ;***** VARIABLES                                                       *****
  124. ;*****                                                                 *****
  125. ;***** keyd_buffer_type -Set to 0 and key_getch() always returns 0.    *****
  126. ;*****                  Set to 1 to so that ASCII codes are returned   *****
  127. ;*****                  by key_getch().  Set to 2 and key_getch() returns*****
  128. ;*****                  the buffered keyboard scan codes.              *****
  129. ;***** keyd_repeat     - Set to 0 to not allow repeated keys in the    *****
  130. ;*****                  keyboard buffer.  Set to 1 to allow repeats.   *****
  131. ;***** keyd_pressed[] -Index by scan code. Contains 1 if key down else 0*****
  132. ;*****                                                                 *****
  133. ;*****                                                                 *****
  134. ;***** CONSTANTS                                                       *****
  135. ;*****                                                                 *****
  136. ;***** Setting the DEBUG to 1 at compile time passes SysReq through    *****
  137. ;***** to the debugger, and when the debugger is active, it will give  *****
  138. ;***** the debugger any keys that are pressed.  Note that this only    *****
  139. ;***** works with the Watcom VIDEO debugger at this time.  Setting     *****
  140. ;***** DEBUG to 0 takes out all the debugging stuff.                   *****
  141. ;*****                                                                 *****
  142. ;***************************************************************************
  143. ;***************************************************************************
  144.  
  145. DEBUG EQU 1
  146. .386
  147.  
  148. ;************************************************************************
  149. ;**************** FLAT MODEL DATA SEGMENT STUFF *************************
  150. ;************************************************************************
  151.  
  152. _DATA   SEGMENT BYTE PUBLIC USE32 'DATA'
  153.  
  154. rcsid    db    "$Id: oldkey.asm 1.2 1994/02/17 15:55:59 john Exp $"
  155.  
  156. PUBLIC  _keyd_pressed     ; Must start with a _ so C can see the variable.
  157.  
  158.         _keyd_pressed   db  256 dup (?)
  159.  
  160.         keybuffer       dw  256 dup (?)     ; Use 256 so an inc wraps around
  161.  
  162.         TimeKeyWentDown dd  256 dup(0)
  163.         TimeKeyHeldDown dd  256 dup(0)
  164.         NumDowns        dd  256 dup(0)
  165.         NumUps          dd  256 dup(0)
  166.  
  167.         MyCodeSegment   dw  ?
  168.  
  169. PUBLIC _keyd_editor_mode
  170.  
  171.         _keyd_editor_mode db 0
  172.  
  173. PUBLIC         _keyd_use_bios
  174.  
  175.         _keyd_use_bios    db 1
  176.  
  177. PUBLIC      _keyd_last_pressed
  178.         _keyd_last_pressed  db 0
  179. PUBLIC      _keyd_last_released
  180.         _keyd_last_released db 0
  181.  
  182. PUBLIC         _keyd_dump_key_array
  183.         _keyd_dump_key_array    db 0
  184.         org_int_sel dw  ?
  185.         org_int_off dd  ?
  186.  
  187.         interrupted_cs dw  ?
  188.         interrupted_eip dd  ?
  189.  
  190.         keyhead      db  ?
  191.         keytail      db  ?
  192. PUBLIC  _keyd_buffer_type
  193. PUBLIC  _keyd_repeat
  194.         _keyd_buffer_type db  ?   ; 0=No buffer, 1=buffer ASCII, 2=buffer scans
  195.         _keyd_repeat      db  ?
  196.  
  197.         E0Flag      db     0
  198.  
  199.         Installed   db  0
  200.  
  201. INCLUDE KEYS.INC
  202.  
  203.  
  204. _DATA   ENDS
  205.  
  206. DGROUP  GROUP _DATA
  207.  
  208.  
  209. ;************************************************************************
  210. ;**************** FLAT MODEL CODE SEGMENT STUFF *************************
  211. ;************************************************************************
  212.  
  213. _TEXT   SEGMENT BYTE PUBLIC USE32 'CODE'
  214.  
  215.         ASSUME  ds:_DATA
  216.         ASSUME  cs:_TEXT
  217.  
  218. key_get_milliseconds:
  219.         EXTERNDEF   timer_get_stamp64:NEAR
  220.  
  221.         push    ebx
  222.         push    edx
  223.  
  224.         call    timer_get_stamp64
  225.  
  226.         ; Timing in milliseconds
  227.         ; Can be used for up to 1000 hours
  228.         shld    edx, eax, 21            ; Keep 32+11 bits
  229.         shl     eax, 21
  230.         mov     ebx, 2502279823         ; 2^21*1193180/1000
  231.         div     ebx
  232.  
  233.         pop     edx
  234.         pop     ebx
  235.  
  236.         ret
  237.  
  238. ;************************************************************************
  239. ;************************************************************************
  240. ;*****                                                              *****
  241. ;*****                   K E Y _ T O _ A S C I I _                  *****
  242. ;*****                                                              *****
  243. ;************************************************************************
  244. ;************************************************************************
  245.  
  246. PUBLIC  key_to_ascii_
  247.  
  248. key_to_ascii_:
  249.  
  250.         ; EAX = scancode
  251.         push    ebx
  252.  
  253.         mov     bl, ah
  254.         and     bl, 011111110b
  255.         cmp     bl, 0
  256.         jne     CantDoKey
  257.  
  258.         cmp     al, 127
  259.         jae     CantDoKey
  260.  
  261.         and     ah, 01b        ; take away ctrl and alt codes
  262.         shl     al, 1
  263.         shr     eax, 1
  264.         and     eax, 0ffh
  265.         mov     al, byte ptr key1[eax]
  266.         pop     ebx
  267.         ret
  268.  
  269. CantDoKey:
  270.         pop     ebx
  271.         mov     eax, 255
  272.         ret
  273.  
  274.  
  275. public key_clear_times_,key_clear_counts_
  276.  
  277. ;clear the array of key down times.
  278. key_clear_times_:    
  279.     cli
  280.     push    eax
  281.     push    ecx
  282.     push    edi
  283.     xor    eax,eax
  284.     mov    ecx,256
  285.     lea    edi,TimeKeyHeldDown
  286.     rep    stosd    ;clear array
  287.     pop    edi
  288.     pop    ecx
  289.     pop    eax
  290.     sti
  291.     ret
  292.  
  293. ;clear the arrays of key down counts
  294. key_clear_counts_:    
  295.     cli
  296.     push    eax
  297.     push    ecx
  298.     push    edi
  299.     xor    eax,eax
  300.     mov    ecx,256
  301.     lea    edi,NumDowns
  302.     rep    stosd    ;clear array
  303.     mov    ecx,256
  304.     lea    edi,NumUps
  305.     rep    stosd    ;clear array
  306.     pop    edi
  307.     pop    ecx
  308.     pop    eax
  309.     sti
  310.     ret
  311.  
  312.  
  313. PUBLIC  key_down_time_
  314.  
  315. key_down_time_:
  316.         cli
  317.  
  318.         push    edx
  319.         push    ecx
  320.         push    ebx
  321.  
  322.  
  323.         mov     ebx, eax
  324.         xor     eax, eax
  325.  
  326.         cmp     _keyd_pressed[ebx], 0
  327.         je      NotPressed
  328.  
  329.         
  330.         cmp    _keyd_editor_mode, 0
  331.         je    read_time
  332.  
  333.         call    get_modifiers    ;shift,alt,ctrl?
  334.         or      ah,ah
  335.         jz      read_time
  336.         xor     eax,eax
  337.         jmp     NotPressed
  338.  
  339. read_time:    mov     ecx, TimeKeyWentDown[ebx*4]
  340.         call    key_get_milliseconds
  341.         mov     TimeKeyWentDown[ebx*4], eax
  342.         sub     eax, ecx        ; EAX = time held since last
  343.  
  344. NotPressed:
  345.         add     eax, TimeKeyHeldDown[ebx*4]
  346.         mov     TimeKeyHeldDown[ebx*4], 0
  347.  
  348.         pop     ebx
  349.         pop     ecx
  350.         pop     edx
  351.         sti
  352.         ret
  353.  
  354. PUBLIC  key_down_count_
  355. key_down_count_:
  356.         cli
  357.         push    ebx
  358.         mov     ebx, eax
  359.         mov     eax, NumDowns[ebx*4]
  360.         mov     NumDowns[ebx*4], 0
  361.         pop     ebx
  362.         sti
  363.         ret
  364.  
  365. PUBLIC  key_up_count_
  366. key_up_count_:
  367.         cli
  368.         push    ebx
  369.         mov     ebx, eax
  370.         mov     eax, NumUps[ebx*4]
  371.         mov     NumUps[ebx*4], 0
  372.         pop     ebx
  373.         sti
  374.         ret
  375.  
  376.  
  377.  
  378. ;************************************************************************
  379. ;************************************************************************
  380. ;*****                                                              *****
  381. ;*****                   K E Y _ F L U S H                          *****
  382. ;*****                                                              *****
  383. ;************************************************************************
  384. ;************************************************************************
  385.  
  386. PUBLIC  key_flush_
  387.  
  388. key_flush_:
  389.         cli
  390.  
  391.         push    eax
  392.         push    ecx
  393.         push    edi
  394.  
  395.         mov     keyhead,0
  396.         mov     keytail,255
  397.         mov     E0Flag, 0
  398.  
  399.         ; Clear the keyboard array
  400.         mov     edi, offset _keyd_pressed
  401.         mov     ecx, 32
  402.         mov     eax,0
  403.         rep     stosd
  404.  
  405.         pop     edi
  406.         pop     ecx
  407.         pop     eax
  408.         sti
  409.         ret
  410.  
  411. ;************************************************************************
  412. ;************************************************************************
  413. ;*****                                                              *****
  414. ;*****                   K E Y _ I N I T                            *****
  415. ;*****                                                              *****
  416. ;************************************************************************
  417. ;************************************************************************
  418.  
  419. PUBLIC  key_init_
  420.  
  421. key_init_:
  422.         push    eax
  423.         push    ebx
  424.         push    ds
  425.         push    es
  426.  
  427.         ;**************************************************************
  428.         ;******************* INITIALIZE key QUEUE **********************
  429.         ;**************************************************************
  430.  
  431.         mov     _keyd_buffer_type,1
  432.         mov     _keyd_repeat,1
  433.         mov     E0Flag, 0
  434.  
  435.         ; Clear the keyboard array
  436.         call    key_flush_
  437.  
  438.         cmp     Installed, 0
  439.         jne     AlreadyInstalled
  440.  
  441.         ;**************************************************************
  442.         ;******************* SAVE OLD INT9 HANDLER ********************
  443.         ;**************************************************************
  444.  
  445.         mov     Installed, 1
  446.  
  447.         mov     eax, 03509h             ; DOS Get Vector 09h
  448.         int     21h                     ; Call DOS
  449.         mov     org_int_sel, es         ; Save old interrupt selector
  450.         mov     org_int_off, ebx        ; Save old interrupt offset
  451.  
  452.  
  453.         ;**************************************************************
  454.         ;***************** INSTALL NEW INT9 HANDLER *******************
  455.         ;**************************************************************
  456.  
  457.         mov     eax, 02509h             ; DOS Set Vector 09h
  458.         mov     edx, offset key_handler  ; Point DS:EDX to new handler
  459.         mov     bx, cs
  460.         mov     MyCodeSegment, bx
  461.         mov     ds, bx
  462.         int     21h
  463.  
  464.  
  465. AlreadyInstalled:
  466.  
  467.         pop     es
  468.         pop     ds
  469.         pop     ebx
  470.         pop     eax
  471.  
  472.         ret
  473.  
  474.  
  475. ;************************************************************************
  476. ;************************************************************************
  477. ;*****                                                              *****
  478. ;*****                   K E Y _ C L O S E _                          *****
  479. ;*****                                                              *****
  480. ;************************************************************************
  481. ;************************************************************************
  482.  
  483. PUBLIC  key_close_
  484.  
  485. key_close_:
  486.         push    eax
  487.         push    ebx
  488.         push    edx
  489.         push    ds
  490.  
  491.  
  492.         cmp     Installed, 0
  493.         je      @f
  494.  
  495.         ;**************************************************************
  496.         ;***************** RESTORE OLD INT9 HANDLER *******************
  497.         ;**************************************************************
  498.  
  499.         mov     Installed, 0
  500.  
  501.         ; Clear the BIOS buffer
  502.         cli
  503.         mov     ebx, 041ch
  504.         mov     al, byte ptr [ebx]
  505.         mov     ebx, 041ah
  506.         mov     byte ptr [ebx], al
  507.         sti
  508.  
  509.         mov     eax, 02509h         ; DOS Set Vector 09h
  510.         mov     edx, org_int_off
  511.         mov     ds, org_int_sel
  512.         int     21h
  513.  
  514. @@:         pop     ds
  515.         pop     edx
  516.         pop     ebx
  517.         pop     eax
  518.  
  519.         ret
  520.  
  521. ;************************************************************************
  522. ;************************************************************************
  523. ;*****                                                              *****
  524. ;*****                   K E Y _ C H E C K _                          *****
  525. ;*****                                                              *****
  526. ;************************************************************************
  527. ;************************************************************************
  528.  
  529. PUBLIC  key_checkch_       ; Must end with a _ so C can see the function.
  530.  
  531. key_checkch_:
  532.         cli
  533.         push    ebx
  534.  
  535.         xor     eax, eax
  536.         cmp     Installed, 0
  537.         je      NoKey
  538.  
  539.         mov     bl, keytail
  540.         inc     bl
  541.         cmp     bl, keyhead
  542.         je      Nokey
  543.         mov     eax, 1
  544. Nokey:
  545.         pop     ebx
  546.         sti
  547.         ret
  548.  
  549. ;************************************************************************
  550. ;************************************************************************
  551. ;*****                                                              *****
  552. ;*****                 K E Y _ D E B U G                              *****
  553. ;*****                                                              *****
  554. ;************************************************************************
  555. ;************************************************************************
  556.  
  557. PUBLIC  key_debug_
  558. key_debug_:
  559.         int 3h
  560.         ret
  561.  
  562.  
  563. ;************************************************************************
  564. ;************************************************************************
  565. ;*****                                                              *****
  566. ;*****                   K E Y _ G E T C H _                        *****
  567. ;*****                                                              *****
  568. ;************************************************************************
  569. ;************************************************************************
  570.  
  571. PUBLIC  key_getch_       ; Must end with a _ so C can see the function.
  572.  
  573. key_getch_:
  574.         push    ebx
  575.  
  576.         xor     eax, eax
  577.         xor     ebx, ebx
  578.         cmp     Installed, 0
  579.         jne     StillNoKey
  580.         pop     ebx
  581.         ret
  582.  
  583. StillNoKey:
  584.         cli             ; Critical section
  585.         mov     bl, keytail
  586.         inc     bl
  587.         cmp     bl, keyhead
  588.         sti
  589.         je      StillNoKey
  590.  
  591.         cli             ; Critical section
  592.         xor     ebx, ebx
  593.         mov     bl, keyhead
  594.         mov     ax, word ptr keybuffer[ebx*2]
  595.         inc     BYTE PTR keyhead
  596.         sti
  597.  
  598.         pop     ebx
  599.         ret
  600.  
  601.  
  602. ;************************************************************************
  603. ;************************************************************************
  604. ;*****                                                              *****
  605. ;*****                   K E Y _ I N K E Y _                        *****
  606. ;*****                                                              *****
  607. ;************************************************************************
  608. ;************************************************************************
  609.  
  610. PUBLIC  key_inkey_       ; Must end with a _ so C can see the function.
  611.  
  612. key_inkey_:
  613.         push    ebx
  614.  
  615.         xor     eax, eax
  616.         xor     ebx, ebx
  617.  
  618.         cmp     Installed, 0
  619.         je      NoInkey
  620.  
  621.         cli             ; Critical section
  622.         mov     bl, keytail
  623.         inc     bl
  624.         cmp     bl, keyhead
  625.         sti
  626.         je      NoInkey
  627.  
  628.         cli             ; Critical section
  629.         mov     bl, keyhead
  630.         mov     ax, word ptr keybuffer[ebx*2]
  631.         inc     BYTE PTR keyhead
  632.         sti
  633. NoInkey:
  634.         pop     ebx
  635.         ret
  636.  
  637. PUBLIC  key_peekkey_       ; Must end with a _ so C can see the function.
  638.  
  639. key_peekkey_:
  640.         push    ebx
  641.  
  642.         xor     eax, eax
  643.         xor     ebx, ebx
  644.  
  645.         cli             ; Critical section
  646.  
  647.         cmp     Installed, 0
  648.         je      NoPeek
  649.         mov     bl, keytail
  650.         inc     bl
  651.         cmp     bl, keyhead
  652.         je      NoPeek
  653.         mov     bl, keyhead
  654.         mov     ax, word ptr keybuffer[ebx*2]
  655.         
  656. NoPeek:        sti
  657.         pop     ebx
  658.         ret
  659.  
  660.  
  661.  
  662. ;************************************************************************
  663. ;************************************************************************
  664. ;*****                                                              *****
  665. ;*****                   K E Y _ H A N D L E R                      *****
  666. ;*****                                                              *****
  667. ;************************************************************************
  668. ;************************************************************************
  669.  
  670. PUBLIC  key_handler      ; Must end with a _ so C can see the function.
  671.  
  672. key_handler:
  673.  
  674.         pushfd              ; Save flags in case we have to chain to original
  675.         push    eax
  676.         push    ebx
  677.         push    ecx
  678.         push    edx
  679.         push    ds
  680.  
  681.         mov     ax, DGROUP  ; Point to our data segment, since this is an
  682.         mov     ds, ax      ; interrupt and we don't know where we were.
  683.  
  684.         mov    eax, (0b0000h+76*2)
  685.         mov     byte ptr [eax], '1'
  686.  
  687. IFDEF DEBUG
  688.         call    CheckForDebugger
  689.         jnc     @f
  690.         mov eax, 0b0000h+78*2
  691.         mov byte ptr [eax], 'D'
  692.         jmp      PassToBios      ; If debugger is active, then skip buffer
  693.  
  694. @@:         mov eax, 0b0000h+78*2
  695.         mov byte ptr [eax], 'I'
  696.  
  697.         ; Clear the BIOS buffer
  698.         ;**mov     ebx, 041ch
  699.         ;**mov     al, byte ptr [ebx]
  700.         ;**mov     ebx, 041ah
  701.         ;**mov     byte ptr [ebx], al
  702. ENDIF
  703.  
  704.         xor     eax, eax
  705.         xor    ebx, ebx
  706.  
  707.         in      al, 060h                ; Get scan code from keyboard
  708.     
  709.         cmp     al, 0E0h
  710.         jne     NotE0Code
  711.  
  712. E0Code:        mov     E0Flag, 010000000b
  713.         jmp    LeaveHandler        ; If garbage key, then don't buffer it
  714.  
  715. NotE0Code:    mov    bl, al            ; Put break bit into bl    ; 0 = pressed, 1=released
  716.         and    al, 01111111b        ; AL = scancode
  717.         or    al, E0Flag        ; AL = extended scancode
  718.         mov     E0Flag,0        ; clear E0 flag
  719.         cmp    al, 029h
  720.         je    pause_execution
  721.         shl    bl, 1            ; put upper bit into carry flag
  722.         jc    key_mark_released    ; if upper bit of bl was set, then it was a release code
  723.  
  724. ;**************************************************************
  725. ;****************** HANDLE A NEWLY PRESSED KEY ****************
  726. ;**************************************************************
  727. ;Marks the key press in EAX in the scancode array.
  728.  
  729. key_mark_pressed:
  730.         ;cmp    al, 0eh    ; backspace
  731.         ;je    pause_execution
  732.         
  733.         mov     _keyd_last_pressed, al
  734.         ; Check if the key is repeating or if it just got pressed.
  735.         cmp     byte ptr _keyd_pressed[eax], 1
  736.         je      AlreadyDown
  737.  
  738. ;------------------------------- Code for a key pressed for the first time ------------------------
  739.         mov     byte ptr _keyd_pressed[eax], 1    
  740.         ; Set the time
  741.  
  742.         push    edx
  743.         push    eax
  744.         call    key_get_milliseconds
  745.         mov     edx, eax
  746.         pop     eax
  747.         mov     TimeKeyWentDown[eax*4], edx
  748.         pop     edx
  749.  
  750.         inc     NumDowns[eax*4]
  751.  
  752.         jmp    BufferAX
  753.  
  754. ;------------------------------- Code for a key that is already pressed ------------------------
  755. AlreadyDown:
  756.         cmp     _keyd_repeat, 0
  757.         je      DoneMarkingPressed
  758.  
  759. BufferAX:
  760.     cmp     _keyd_buffer_type, 0
  761.     je      SkipBuffer          ; Buffer = 0 means don't buffer anything.
  762.  
  763.     cmp     al, 0AAh        ; garbage key
  764.     je      SkipBuffer
  765.  
  766.     call    get_modifiers      ;returns ah
  767.     
  768.     xor     ebx, ebx
  769.     mov     bl, keytail
  770.     inc     bl
  771.     inc     bl
  772.  
  773.     ; If the buffer is full then don't buffer this key
  774.     cmp     bl, keyhead
  775.     je      SkipBuffer
  776.     dec     bl
  777.  
  778.     mov     word ptr keybuffer[ebx*2], ax
  779.     mov     keytail, bl
  780.  
  781. SkipBuffer:    
  782.         
  783. ;---------------------------------- Exit function -----------------------------
  784. DoneMarkingPressed:
  785.     jmp    LeaveHandler
  786.  
  787. ;**************************************************************
  788. ;******************* HANDLE A RELEASED KEY ********************
  789. ;**************************************************************
  790. ; Unmarks the key press in EAX from the scancode array.
  791. key_mark_released:
  792.  
  793.         mov     _keyd_last_released, al
  794.         mov     byte ptr _keyd_pressed[eax], 0
  795.         inc     NumUps[eax*4]
  796.  
  797.         cmp    _keyd_editor_mode, 0
  798.         je    NotInEditorMode
  799.         push    eax
  800.         xor     ah,ah
  801.         call    get_modifiers
  802.         or      ah,ah    ;check modifiers
  803.         pop     eax
  804.         jnz     skip_time
  805.  
  806. NotInEditorMode:    
  807.         push    eax
  808.  
  809.         call    timer_get_stamp64
  810.  
  811.         ; Timing in milliseconds
  812.         ; Can be used for up to 1000 hours
  813.         shld    edx, eax, 21            ; Keep 32+11 bits
  814.         shl     eax, 21
  815.         mov     ebx, 2502279823         ; 2^21*1193180/1000
  816.         div     ebx
  817.  
  818.         mov     edx, eax
  819.         pop     eax
  820.         sub     edx, TimeKeyWentDown[eax*4]
  821.         add     TimeKeyHeldDown[eax*4], edx
  822.  
  823. skip_time:    ;**jmp    LeaveHandler
  824.  
  825. ;**************************************************************
  826. ;*************** FINISH UP THE KEYBOARD INTERRUPT *************
  827. ;**************************************************************
  828. LeaveHandler:
  829.         mov    eax, (0b0000h+76*2)
  830.         mov     byte ptr [eax], '2'
  831.  
  832. ;;        cmp    _keyd_dump_key_array, 0
  833. ;;        je    DontPassToBios
  834.         jmp    PassToBios
  835.  
  836.         mov    ecx, 256
  837.         mov    ebx, 0
  838.  
  839. showdown:    mov    al, _keyd_pressed[ebx]
  840.         add    al, '0'
  841.         mov    [ebx*2+ 0b0000h], al
  842.         inc    ebx
  843.         loop    showdown
  844.  
  845.         mov    eax, 0b0000h
  846.         mov     byte ptr [ eax+(036h*2+1) ], 070h
  847.         mov     byte ptr [ eax+(02Ah*2+1) ], 070h
  848.         mov     byte ptr [ eax+(038h*2+1) ], 070h
  849.         mov     byte ptr [ eax+(0B8h*2+1) ], 070h
  850.         mov     byte ptr [ eax+(01Dh*2+1) ], 070h
  851.         mov     byte ptr [ eax+(09dh*2+1) ], 070h
  852.  
  853.         mov     byte ptr [ eax+(0AAh*2+1) ], 07Fh
  854.         mov     byte ptr [ eax+(0E0h*2+1) ], 07Fh
  855.  
  856.         jmp    DontPassToBios
  857.  
  858.  
  859. ; If in debugger, pass control to dos interrupt.
  860.  
  861. PassToBios:    pop     ds          ; Nothing left on stack but flags
  862.         pop     edx
  863.         pop     ecx
  864.         pop     ebx
  865.         pop     eax
  866.  
  867.         sub     esp, 8              ; Save space for IRETD frame
  868.         push    ds                  ; Save registers we use.
  869.         push    eax
  870.         mov     ax, DGROUP
  871.         mov     ds, ax              ; Set DS to our data segment
  872.         mov     eax, org_int_off   ; put original handler address
  873.         mov     [esp+8], eax        ;   in the IRETD frame
  874.         movzx   eax, org_int_sel
  875.         mov     [esp+12], eax
  876.         pop     eax                 ; Restore registers
  877.         pop     ds
  878.         iretd                       ; Chain to previous handler
  879.  
  880. pause_execution:
  881.         in      al, 61h         ; Get current port 61h state
  882.         or      al, 10000000b   ; Turn on bit 7 to signal clear keybrd
  883.         out     61h, al         ; Send to port
  884.         and     al, 01111111b   ; Turn off bit 7 to signal break
  885.         out     61h, al         ; Send to port
  886.         mov     al, 20h         ; Reset interrupt controller
  887.         out     20h, al
  888.         sti                     ; Reenable interrupts
  889.         pop     ds
  890.         pop     edx             ; Restore all of the saved registers.
  891.         pop     ecx
  892.         pop     ebx
  893.         pop     eax
  894.  
  895.         sub     esp, 8              ; Save space for IRETD frame
  896.         push    ds                  ; Save registers we use.
  897.         push    eax
  898.         mov     ax, DGROUP
  899.         mov     ds, ax              ; Set DS to our data segment
  900.         mov     eax, org_int_off   ; put original handler address
  901.         mov     [esp+8], eax        ;   in the IRETD frame
  902.         movzx   eax, org_int_sel
  903.         mov     [esp+12], eax
  904.         pop     eax                 ; Restore registers
  905.         pop     ds
  906.  
  907.         iretd                   ; Interrupt must return with IRETD
  908.  
  909. DontPassToBios:    
  910.  
  911. ; Resets the keyboard, PIC, restores stack, returns.
  912.         in      al, 61h         ; Get current port 61h state
  913.         or      al, 10000000b   ; Turn on bit 7 to signal clear keybrd
  914.         out     61h, al         ; Send to port
  915.         and     al, 01111111b   ; Turn off bit 7 to signal break
  916.         out     61h, al         ; Send to port
  917.         mov     al, 20h         ; Reset interrupt controller
  918.         out     20h, al
  919.         sti                     ; Reenable interrupts
  920.         pop     ds
  921.         pop     edx             ; Restore all of the saved registers.
  922.         pop     ecx
  923.         pop     ebx
  924.         pop     eax
  925.         popfd
  926.         iretd               ; Interrupt must return with IRETD
  927.  
  928. ;returns ah=bitmask of shift,ctrl,alt keys
  929. get_modifiers:        push    ecx
  930.  
  931.         xor     ah,ah
  932.  
  933.         ; Check the shift keys
  934.         mov     cl, _keyd_pressed[ 036h ]
  935.         or      cl, _keyd_pressed[ 02ah ]
  936.         or      ah, cl
  937.  
  938.         ; Check the alt key
  939.         mov     cl, _keyd_pressed[ 038h ]
  940.         or      cl, _keyd_pressed[ 0b8h ]
  941.         shl     cl, 1
  942.         or      ah, cl
  943.  
  944.         ; Check the ctrl key
  945.         mov     cl, _keyd_pressed[ 01dh ]
  946.         or      cl, _keyd_pressed[ 09dh ]
  947.         shl     cl, 2
  948.         or      ah, cl
  949.  
  950.         pop     ecx
  951.         ret
  952.  
  953. IFDEF DEBUG
  954. CheckForDebugger:
  955.     ; Returns CF=0 if debugger isn't active
  956.     ;         CF=1 if debugger is active
  957.  
  958.         ;*************************** DEBUG ******************************
  959.         ; When we're in the VIDEO debugger, we want to pass control to
  960.         ; the original interrupt.  So, to tell if the debugger is active,
  961.         ; I check if video page 1 is the active page since that is what
  962.         ; page the debugger uses, and if that works, I check the top of
  963.         ; the screen to see if the texxt "Control" is there, which should
  964.         ; only be there when we're in the debugger.
  965.  
  966.     
  967.  
  968.         push    eax
  969.         ;mov     eax, 0462h          ; Address 0462 stores BIOS current page
  970.         ;cmp     BYTE PTR [eax], 1
  971.         ;jne     NoDebuggerOnColor
  972.         ;mov     eax, 0b8000h+4096   ; 4096 = offset to 2nd video mem page
  973.         ;cmp     BYTE PTR [eax+2],'C'
  974.         ;jne     NoDebuggerOnColor
  975.         ;cmp     BYTE PTR [eax+4],'o'
  976.         ;jne     NoDebuggerOnColor
  977.         ;cmp     BYTE PTR [eax+6],'n'
  978.         ;jne     NoDebuggerOnColor
  979.         ;cmp     BYTE PTR [eax+8],'t'
  980.         ;jne     NoDebuggerOnColor
  981.         ;cmp     BYTE PTR [eax+10],'r'
  982.         ;jne     NoDebuggerOnColor
  983.         ;cmp     BYTE PTR [eax+12],'o'
  984.         ;jne     NoDebuggerOnColor
  985.         ;cmp     BYTE PTR [eax+14],'l'
  986.         ;jne     NoDebuggerOnColor
  987.         ;jmp     ActiveDebugger
  988.         ;NoDebuggerOnColor:
  989.         ; First, see if there is a mono debugger...
  990.  
  991.         ;mov     eax, 0b0000h        ; 4096 = offset to mono video mem
  992.         ;cmp     BYTE PTR [eax+2],'C'
  993.         ;jne     NoActiveDebugger
  994.         ;cmp     BYTE PTR [eax+4],'o'
  995.         ;jne     NoActiveDebugger
  996.         ;cmp     BYTE PTR [eax+6],'n'
  997.         ;jne     NoActiveDebugger
  998.         ;cmp     BYTE PTR [eax+8],'t'
  999.         ;jne     NoActiveDebugger
  1000.         ;cmp     BYTE PTR [eax+10],'r'
  1001.         ;jne     NoActiveDebugger
  1002.         ;cmp     BYTE PTR [eax+12],'o'
  1003.         ;jne     NoActiveDebugger
  1004.         ;cmp     BYTE PTR [eax+14],'l'
  1005.         ;jne     NoActiveDebugger
  1006.  
  1007.         mov     eax, 0b0000h        ; 4096 = offset to mono video mem
  1008.         add     eax, 24*80*2
  1009.  
  1010.  
  1011.         cmp     BYTE PTR [eax+0],'D'
  1012.         jne     NextTest
  1013.         cmp     BYTE PTR [eax+2],'B'
  1014.         jne     NextTest
  1015.         cmp     BYTE PTR [eax+4],'G'
  1016.         jne     NextTest
  1017.         cmp     BYTE PTR [eax+6],'>'
  1018.         jne     NextTest
  1019.  
  1020.         ;Found DBG>, so consider debugger active:
  1021.         jmp     ActiveDebugger
  1022.  
  1023. NextTest:
  1024.         cmp     BYTE PTR [eax+14],'<'
  1025.         jne     NextTest1
  1026.         cmp     BYTE PTR [eax+16],'i'
  1027.         jne     NextTest1
  1028.         cmp     BYTE PTR [eax+18],'>'
  1029.         jne     NextTest1
  1030.         cmp     BYTE PTR [eax+20],' '
  1031.         jne     NextTest1
  1032.         cmp     BYTE PTR [eax+22],'-'
  1033.         jne     NextTest1
  1034.  
  1035.         ; Found <i> - , so consider debugger active:
  1036.         jmp     ActiveDebugger
  1037.  
  1038. NextTest1:
  1039.         cmp     BYTE PTR [eax+0], 200
  1040.         jne     NextTest2
  1041.         cmp     BYTE PTR [eax+2], 27
  1042.         jne     NextTest2
  1043.         cmp     BYTE PTR [eax+4], 17
  1044.         jne     NextTest2
  1045.  
  1046.         ; Found either the help screen or view screen, so consider
  1047.         ; debugger active
  1048.         jmp     ActiveDebugger
  1049.  
  1050. NextTest2:
  1051.         ; Now we see if its active by looking for the "Executing..."
  1052.         ; text on the bottom of the mono screen
  1053.         ;mov     eax, 0b0000h        ; 4096 = offset to mono video mem
  1054.         ;add     eax, 24*80*2
  1055.         ;cmp     BYTE PTR [eax+0],'E'
  1056.         ;je      NoActiveDebugger
  1057.         ;cmp     BYTE PTR [eax+2],'x'
  1058.         ;je      NoActiveDebugger
  1059.         ;cmp     BYTE PTR [eax+4],'e'
  1060.         ;je      NoActiveDebugger
  1061.         ;cmp     BYTE PTR [eax+6],'c'
  1062.         ;je      NoActiveDebugger
  1063.  
  1064. NoActiveDebugger:
  1065.         pop     eax
  1066.         clc
  1067.         ret
  1068.  
  1069. ActiveDebugger:
  1070.         pop     eax
  1071.         stc
  1072.         ret
  1073.  
  1074. ENDIF
  1075.  
  1076. _TEXT   ENDS
  1077.  
  1078.         END
  1079. 
  1080.