home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / bios / mouse.asm < prev    next >
Assembly Source File  |  1998-06-08  |  7KB  |  345 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/bios/rcs/mouse.asm $
  13. ; $Revision: 1.5 $
  14. ; $Author: john $
  15. ; $Date: 1994/04/29 12:14:12 $
  16. ;
  17. ; Contains routines for a mouse interface.
  18. ;
  19. ; $Log: mouse.asm $
  20. ; Revision 1.5  1994/04/29  12:14:12  john
  21. ; Locked all memory used during interrupts so that program
  22. ; won't hang when using virtual memory.
  23. ; 
  24. ; Revision 1.4  1993/07/26  10:47:03  john
  25. ; added sub mouse_set_pos
  26. ; 
  27. ; Revision 1.3  1993/07/22  13:57:13  john
  28. ; aligned push/pops in mouse_set_limits
  29. ; 
  30. ; Revision 1.2  1993/07/22  13:14:43  john
  31. ; added mouse set limts sub
  32. ; 
  33. ; Revision 1.1  1993/07/10  13:10:43  matt
  34. ; Initial revision
  35. ;
  36. ;
  37. ;
  38.  
  39. ;***************************************************************************
  40. ;***************************************************************************
  41. ;*****                                                                 *****
  42. ;*****                      M O U S E . A S M                          *****
  43. ;*****                                                                 *****
  44. ;***** Contains routines for a mouse interface.                        *****
  45. ;*****                                                                 *****
  46. ;*****                                                                 *****
  47. ;***** PROCEDURES                                                      *****
  48. ;*****                                                                 *****
  49. ;***** VARIABLES                                                       *****
  50. ;*****                                                                 *****
  51. ;*****                                                                 *****
  52. ;***** CONSTANTS                                                       *****
  53. ;*****                                                                 *****
  54. ;*****                                                                 *****
  55. ;***************************************************************************
  56. ;***************************************************************************
  57.  
  58. .386
  59.  
  60. ;************************************************************************
  61. ;**************** FLAT MODEL DATA SEGMENT STUFF *************************
  62. ;************************************************************************
  63.  
  64. _DATA   SEGMENT BYTE PUBLIC USE32 'DATA'
  65.  
  66. rcsid   db  "$Id: mouse.asm 1.5 1994/04/29 12:14:12 john Exp $"
  67.  
  68.         MOUSE_EVENT STRUCT 2
  69.             MouseDX         dw  ?
  70.             MouseDY         dw  ?
  71.             MouseButtons    dw  ?
  72.             MouseFlags      dw  ?
  73.         MOUSE_EVENT ENDS
  74.  
  75.         NumberOfButtons dw ?
  76.  
  77.         MyEvent             MOUSE_EVENT < >
  78.         MyEventHandler      dd  0
  79.  
  80.  
  81.  
  82. _DATA   ENDS
  83.  
  84. DGROUP  GROUP _DATA
  85.  
  86.  
  87. ;************************************************************************
  88. ;**************** FLAT MODEL CODE SEGMENT STUFF *************************
  89. ;************************************************************************
  90.  
  91. _TEXT   SEGMENT BYTE PUBLIC USE32 'CODE'
  92.  
  93.         ASSUME  ds:_DATA
  94.         ASSUME  cs:_TEXT
  95.  
  96. PUBLIC  mouse_init_
  97.  
  98. mouse_init_:
  99.  
  100.         push    bx
  101.         xor     ax, ax      ; Reset mouse
  102.         int     33h
  103.         mov     NumberOfButtons, bx
  104.         pop     bx
  105.         or      ax, ax
  106.         jnz     present
  107.         jmp     absent
  108.  
  109.  
  110. present:
  111.         mov     ax, 0020h   ; Enable driver
  112.         int     33h
  113.  
  114.         mov     ax, 1
  115.         ret
  116.  
  117. absent:
  118.         mov     ax, 0
  119.         ret
  120.  
  121.  
  122.  
  123. PUBLIC  mouse_get_pos_
  124.  
  125. mouse_get_pos_:
  126.  
  127.         push    eax
  128.         push    ebx
  129.         push    ecx
  130.         push    edx
  131.  
  132.         push    eax
  133.  
  134.         mov     ax, 03h     ; Get Mouse Position and Button Status
  135.         int     33h
  136.         ; bx = buttons, cx = x, dx = y
  137.  
  138.         pop     eax
  139.         mov     [eax], cx
  140.         pop     eax
  141.         mov     [eax], dx
  142.         mov     edx, eax
  143.  
  144.         pop     ecx
  145.         pop     ebx
  146.         pop     eax
  147.  
  148.         ret
  149.  
  150. PUBLIC  mouse_get_delta_
  151.  
  152. mouse_get_delta_:
  153.  
  154.         push    eax
  155.         push    ebx
  156.         push    ecx
  157.         push    edx
  158.  
  159.  
  160.         push    eax
  161.  
  162.         mov     eax, 0bh    ; Read Mouse Motion Counters
  163.         int     33h
  164.  
  165.         pop     eax
  166.         mov     [eax], cx
  167.         pop     eax
  168.         mov     [eax], dx
  169.         mov     edx, eax
  170.  
  171.         pop     ecx
  172.         pop     ebx
  173.         pop     eax
  174.         ret
  175.  
  176.  
  177. PUBLIC  mouse_get_btns_
  178.  
  179. mouse_get_btns_:
  180.  
  181.         push    ebx
  182.         push    ecx
  183.         push    edx
  184.  
  185.         mov     ax, 03h     ; Get Mouse Position and Button Status
  186.         int     33h
  187.         ; bx = buttons, cx = x, dx = y
  188.  
  189.         movzx   eax, bx
  190.  
  191.         pop     edx
  192.         pop     ecx
  193.         pop     ebx
  194.  
  195.         ret
  196.  
  197.  
  198. PUBLIC  mouse_close_
  199.  
  200. mouse_close_:
  201.  
  202.         push    eax
  203.         push    ebx
  204.         push    es
  205.  
  206.         mov     ax, 01fh    ; Disable mouse driver
  207.         int     33h
  208.  
  209.         pop     es
  210.         pop     ebx
  211.         pop     eax
  212.  
  213.         ret
  214.  
  215. MyHandler:
  216.  
  217.         pushad
  218.         push    ds
  219.  
  220.         push    ax
  221.         mov     ax, DGROUP
  222.         mov     ds, ax
  223.         pop     ax
  224.  
  225.         mov     MyEvent.MouseDX, cx
  226.         mov     MyEvent.MouseDY, dx
  227.         mov     MyEvent.MouseButtons, bx
  228.         mov     MyEvent.MouseFlags, ax
  229.  
  230.         mov     eax, offset MyEvent
  231.  
  232.         call    MyEventHandler
  233.  
  234.         pop     ds
  235.         popad
  236.  
  237.         retf
  238.  
  239. PUBLIC  mouse_set_handler_
  240.  
  241. mouse_set_handler_:
  242.  
  243.         push    eax
  244.         push    ebx
  245.         push    ecx
  246.         push    edx
  247.         push    es
  248.  
  249.         mov     MyEventHandler, edx
  250.  
  251.         mov     ecx, eax    ; Event flags
  252.         mov     edx, MyHandler
  253.         mov     ax, cs
  254.         mov     es, ax
  255.         mov     ax, 0Ch     ; Set User-defined Mouse Event Handler
  256.         int     33h
  257.  
  258.         pop     es
  259.         pop     edx
  260.         pop     ecx
  261.         pop     edx
  262.         pop     eax
  263.  
  264.         ret
  265.  
  266. PUBLIC  mouse_clear_handler_
  267.  
  268. mouse_clear_handler_:
  269.  
  270.         push    eax
  271.         push    ebx
  272.         push    ecx
  273.         push    edx
  274.         push    es
  275.  
  276.         mov     MyEventHandler, 0
  277.  
  278.         mov     ecx, 0    ; Event flags
  279.         mov     edx, MyHandler
  280.         mov     ax, cs
  281.         mov     es, ax
  282.         mov     ax, 0Ch     ; Set User-defined Mouse Event Handler
  283.         int     33h
  284.  
  285.         pop     es
  286.         pop     edx
  287.         pop     ecx
  288.         pop     edx
  289.         pop     eax
  290.  
  291.         ret
  292.  
  293.  
  294. PUBLIC  mouse_set_limits_
  295.  
  296. mouse_set_limits_:
  297.  
  298.         ; EAX = minx
  299.         ; EDX = miny
  300.         ; EBX = maxx
  301.         ; ECX = maxy
  302.  
  303.         push    edx     ; Save Vertical stuff
  304.         push    ecx
  305.  
  306.         mov     cx, ax
  307.         mov     dx, bx
  308.         mov     ax, 7
  309.         int     33h
  310.  
  311.         pop     edx
  312.         pop     ecx
  313.         mov     ax, 8
  314.         int     33h
  315.  
  316.         ret
  317.  
  318.  
  319. ;extern void mouse_set_pos( short x, short y);
  320.  
  321.  
  322. PUBLIC  mouse_set_pos_
  323.  
  324. mouse_set_pos_:
  325.  
  326.         ; EAX = x
  327.         ; EDX = y
  328.  
  329.         push    ecx
  330.  
  331.         mov     ecx, eax
  332.         mov     eax, 04h
  333.         int     33h
  334.         pop     ecx
  335.  
  336.  
  337.         ret
  338.  
  339.  
  340.  
  341. _TEXT   ENDS
  342.  
  343.  
  344.         END
  345.