home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / bios / key2.asm < prev    next >
Assembly Source File  |  1998-06-08  |  30KB  |  1,047 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/bios/rcs/key.asm $
  13. ; $Revision: 1.20 $
  14. ; $Author: john $
  15. ; $Date: 1994/01/18 10:58:55 $
  16. ;
  17. ; Contains routines to get, buffer, and check key presses.
  18. ;
  19. ; $Log: key.asm $
  20. ; Revision 1.20  1994/01/18  10:58:55  john
  21. ; *** empty log message ***
  22. ; 
  23. ; Revision 1.19  1993/12/22  13:28:40  john
  24. ; Added back changes Matt made in r1.14
  25. ; 
  26. ; Revision 1.18  1993/12/22  13:18:32  john
  27. ; *** empty log message ***
  28. ; 
  29. ; Revision 1.17  1993/12/20  16:48:47  john
  30. ; Put cli/sti around clear keybuffer in key_close
  31. ; 
  32. ; Revision 1.16  1993/12/20  15:39:13  john
  33. ; Tried to neaten handler code... also, moved some cli's and sti's around
  34. ; trying to find bug.  Made the code call key_get_milliseconds instead
  35. ; of timer_get_milliseconds, because we don't want the cli and sti
  36. ; stuff in the interrupt handler.  
  37. ; 
  38. ; Revision 1.15  1993/12/02  10:54:48  john
  39. ; Made the Ctrl,Shift,Alt keys buffer like all the other keys.
  40. ; 
  41. ; Revision 1.14  1993/10/29  11:25:18  matt
  42. ; Made key_down_time() not accumulate time if shift,alt,ctrl down
  43. ; 
  44. ; Revision 1.13  1993/10/29  10:47:00  john
  45. ; *** empty log message ***
  46. ; 
  47. ; Revision 1.12  1993/10/16  19:24:16  matt
  48. ; Added new function key_clear_times() & key_clear_counts()
  49. ; 
  50. ; Revision 1.11  1993/10/15  10:16:49  john
  51. ; bunch of stuff, mainly with detecting debugger.
  52. ; 
  53. ; Revision 1.10  1993/10/04  13:25:57  john
  54. ; Changed the way extended keys are processed.
  55. ; 
  56. ; Revision 1.9  1993/09/28  11:35:32  john
  57. ; added key_peekkey
  58. ; 
  59. ; Revision 1.8  1993/09/23  18:09:23  john
  60. ; fixed bug checking for DBG
  61. ; 
  62. ; Revision 1.7  1993/09/23  17:28:01  john
  63. ; made debug check look for DBG> instead of CONTROL
  64. ; 
  65. ; Revision 1.6  1993/09/20  17:08:19  john
  66. ; Made so that keys pressed in debugger don't get passed through to
  67. ; the keyboard handler. I also discovered, but didn't fix a error
  68. ; (page fault) caused by jumping back and forth between the debugger
  69. ; and the program...
  70. ; 
  71. ; Revision 1.5  1993/09/17  09:58:12  john
  72. ; Added checks for already installed, not installed, etc.
  73. ; 
  74. ; Revision 1.4  1993/09/15  17:28:00  john
  75. ; Fixed bug in FlushBuffer that used CX before a REP instead of ECX.
  76. ; 
  77. ; Revision 1.3  1993/09/08  14:48:00  john
  78. ; made getch() return an int instead of a char that has shift states, etc.
  79. ; 
  80. ; Revision 1.2  1993/07/22  13:12:23  john
  81. ; fixed comment
  82. ; ,.
  83. ; 
  84. ; Revision 1.1  1993/07/10  13:10:42  matt
  85. ; Initial revision
  86. ; 
  87. ;
  88. ;
  89.  
  90. ;***************************************************************************
  91. ;***************************************************************************
  92. ;*****                                                                 *****
  93. ;*****                                                                 *****
  94. ;*****                        K E Y . A S M                            *****
  95. ;*****                                                                 *****
  96. ;***** Contains routines to get, buffer, and check key presses.        *****
  97. ;*****                                                                 *****
  98. ;*****                                                                 *****
  99. ;***** PROCEDURES                                                      *****
  100. ;*****                                                                 *****
  101. ;***** key_init()  - Activates the keyboard package.                   *****
  102. ;***** key_close() - Deactivates the keyboard package.                 *****
  103. ;***** key_check() - Returns 1 if a buffered key is waiting.           *****
  104. ;***** key_getch() - Waits for and returns a buffered keypress.        *****
  105. ;***** key_flush() - Clears buffers and state array.                   *****
  106. ;***** key_time() - Index by scan code. Contains the time key has been *****
  107. ;*****             held down. NOT DONE YET.                            *****
  108. ;*****                                                                 *****
  109. ;*****                                                                 *****
  110. ;***** VARIABLES                                                       *****
  111. ;*****                                                                 *****
  112. ;***** keyd_buffer_type -Set to 0 and key_getch() always returns 0.    *****
  113. ;*****                  Set to 1 to so that ASCII codes are returned   *****
  114. ;*****                  by key_getch().  Set to 2 and key_getch() returns*****
  115. ;*****                  the buffered keyboard scan codes.              *****
  116. ;***** keyd_repeat     - Set to 0 to not allow repeated keys in the    *****
  117. ;*****                  keyboard buffer.  Set to 1 to allow repeats.   *****
  118. ;***** keyd_pressed[] -Index by scan code. Contains 1 if key down else 0*****
  119. ;*****                                                                 *****
  120. ;*****                                                                 *****
  121. ;***** CONSTANTS                                                       *****
  122. ;*****                                                                 *****
  123. ;***** Setting the DEBUG to 1 at compile time passes SysReq through    *****
  124. ;***** to the debugger, and when the debugger is active, it will give  *****
  125. ;***** the debugger any keys that are pressed.  Note that this only    *****
  126. ;***** works with the Watcom VIDEO debugger at this time.  Setting     *****
  127. ;***** DEBUG to 0 takes out all the debugging stuff.                   *****
  128. ;*****                                                                 *****
  129. ;***************************************************************************
  130. ;***************************************************************************
  131.  
  132. DEBUG EQU 1
  133. .386
  134.  
  135. ;************************************************************************
  136. ;**************** FLAT MODEL DATA SEGMENT STUFF *************************
  137. ;************************************************************************
  138.  
  139. _DATA   SEGMENT BYTE PUBLIC USE32 'DATA'
  140.  
  141. rcsid    db    "$Id: key.asm 1.20 1994/01/18 10:58:55 john Exp $"
  142.  
  143. PUBLIC  _keyd_pressed     ; Must start with a _ so C can see the variable.
  144.  
  145.         _keyd_pressed   db  256 dup (?)
  146.  
  147.         keybuffer       dw  256 dup (?)     ; Use 256 so an inc wraps around
  148.  
  149.         TimeKeyWentDown dd  256 dup(0)
  150.         TimeKeyHeldDown dd  256 dup(0)
  151.         NumDowns        dd  256 dup(0)
  152.         NumUps          dd  256 dup(0)
  153.  
  154.         MyCodeSegment   dw  ?
  155.  
  156. PUBLIC _keyd_editor_mode
  157.  
  158.         _keyd_editor_mode db 0
  159.  
  160. PUBLIC         _keyd_use_bios
  161.  
  162.         _keyd_use_bios    db 1
  163.  
  164. PUBLIC      _keyd_last_pressed
  165.         _keyd_last_pressed  db 0
  166. PUBLIC      _keyd_last_released
  167.         _keyd_last_released db 0
  168.  
  169. PUBLIC         _keyd_dump_key_array
  170.         _keyd_dump_key_array    db 0
  171.         org_int_sel dw  ?
  172.         org_int_off dd  ?
  173.         keyhead      db  ?
  174.         keytail      db  ?
  175. PUBLIC  _keyd_buffer_type
  176. PUBLIC  _keyd_repeat
  177.         _keyd_buffer_type db  ?   ; 0=No buffer, 1=buffer ASCII, 2=buffer scans
  178.         _keyd_repeat      db  ?
  179.  
  180.         E0Flag      db     0
  181.  
  182.         Installed   db  0
  183.  
  184. INCLUDE KEYS.INC
  185.  
  186.  
  187. _DATA   ENDS
  188.  
  189. DGROUP  GROUP _DATA
  190.  
  191.  
  192. ;************************************************************************
  193. ;**************** FLAT MODEL CODE SEGMENT STUFF *************************
  194. ;************************************************************************
  195.  
  196. _TEXT   SEGMENT BYTE PUBLIC USE32 'CODE'
  197.  
  198.         ASSUME  ds:_DATA
  199.         ASSUME  cs:_TEXT
  200.  
  201. key_get_milliseconds:
  202.         EXTERNDEF   timer_get_stamp64:NEAR
  203.  
  204.         push    ebx
  205.         push    edx
  206.  
  207.         call    timer_get_stamp64
  208.  
  209.         ; Timing in milliseconds
  210.         ; Can be used for up to 1000 hours
  211.         shld    edx, eax, 21            ; Keep 32+11 bits
  212.         shl     eax, 21
  213.         mov     ebx, 2502279823         ; 2^21*1193180/1000
  214.         div     ebx
  215.  
  216.         pop     edx
  217.         pop     ebx
  218.  
  219.         ret
  220.  
  221. ;************************************************************************
  222. ;************************************************************************
  223. ;*****                                                              *****
  224. ;*****                   K E Y _ T O _ A S C I I _                  *****
  225. ;*****                                                              *****
  226. ;************************************************************************
  227. ;************************************************************************
  228.  
  229. PUBLIC  key_to_ascii_
  230.  
  231. key_to_ascii_:
  232.  
  233.         ; EAX = scancode
  234.         push    ebx
  235.  
  236.         mov     bl, ah
  237.         and     bl, 011111110b
  238.         cmp     bl, 0
  239.         jne     CantDoKey
  240.  
  241.         cmp     al, 127
  242.         jae     CantDoKey
  243.  
  244.         and     ah, 01b        ; take away ctrl and alt codes
  245.         shl     al, 1
  246.         shr     eax, 1
  247.         and     eax, 0ffh
  248.         mov     al, byte ptr key1[eax]
  249.         pop     ebx
  250.         ret
  251.  
  252. CantDoKey:
  253.         pop     ebx
  254.         mov     eax, 255
  255.         ret
  256.  
  257.  
  258. public key_clear_times_,key_clear_counts_
  259.  
  260. ;clear the array of key down times.
  261. key_clear_times_:    
  262.     cli
  263.     push    eax
  264.     push    ecx
  265.     push    edi
  266.     xor    eax,eax
  267.     mov    ecx,256
  268.     lea    edi,TimeKeyHeldDown
  269.     rep    stosd    ;clear array
  270.     pop    edi
  271.     pop    ecx
  272.     pop    eax
  273.     sti
  274.     ret
  275.  
  276. ;clear the arrays of key down counts
  277. key_clear_counts_:    
  278.     cli
  279.     push    eax
  280.     push    ecx
  281.     push    edi
  282.     xor    eax,eax
  283.     mov    ecx,256
  284.     lea    edi,NumDowns
  285.     rep    stosd    ;clear array
  286.     mov    ecx,256
  287.     lea    edi,NumUps
  288.     rep    stosd    ;clear array
  289.     pop    edi
  290.     pop    ecx
  291.     pop    eax
  292.     sti
  293.     ret
  294.  
  295.  
  296. PUBLIC  key_down_time_
  297.  
  298. key_down_time_:
  299.         cli
  300.  
  301.         push    edx
  302.         push    ecx
  303.         push    ebx
  304.  
  305.  
  306.         mov     ebx, eax
  307.         xor     eax, eax
  308.  
  309.         cmp     _keyd_pressed[ebx], 0
  310.         je      NotPressed
  311.  
  312.         
  313.         cmp    _keyd_editor_mode, 0
  314.         je    read_time
  315.  
  316.         call    get_modifiers    ;shift,alt,ctrl?
  317.         or      ah,ah
  318.         jz      read_time
  319.         xor     eax,eax
  320.         jmp     NotPressed
  321.  
  322. read_time:    mov     ecx, TimeKeyWentDown[ebx*4]
  323.         call    key_get_milliseconds
  324.         mov     TimeKeyWentDown[ebx*4], eax
  325.         sub     eax, ecx        ; EAX = time held since last
  326.  
  327. NotPressed:
  328.         add     eax, TimeKeyHeldDown[ebx*4]
  329.         mov     TimeKeyHeldDown[ebx*4], 0
  330.  
  331.         pop     ebx
  332.         pop     ecx
  333.         pop     edx
  334.         sti
  335.         ret
  336.  
  337. PUBLIC  key_down_count_
  338. key_down_count_:
  339.         cli
  340.         push    ebx
  341.         mov     ebx, eax
  342.         mov     eax, NumDowns[ebx*4]
  343.         mov     NumDowns[ebx*4], 0
  344.         pop     ebx
  345.         sti
  346.         ret
  347.  
  348. PUBLIC  key_up_count_
  349. key_up_count_:
  350.         cli
  351.         push    ebx
  352.         mov     ebx, eax
  353.         mov     eax, NumUps[ebx*4]
  354.         mov     NumUps[ebx*4], 0
  355.         pop     ebx
  356.         sti
  357.         ret
  358.  
  359.  
  360.  
  361. ;************************************************************************
  362. ;************************************************************************
  363. ;*****                                                              *****
  364. ;*****                   K E Y _ F L U S H                          *****
  365. ;*****                                                              *****
  366. ;************************************************************************
  367. ;************************************************************************
  368.  
  369. PUBLIC  key_flush_
  370.  
  371. key_flush_:
  372.         cli
  373.  
  374.         push    eax
  375.         push    ecx
  376.         push    edi
  377.  
  378.         mov     keyhead,0
  379.         mov     keytail,255
  380.         mov     E0Flag, 0
  381.  
  382.         ; Clear the keyboard array
  383.         mov     edi, offset _keyd_pressed
  384.         mov     ecx, 32
  385.         mov     eax,0
  386.         rep     stosd
  387.  
  388.         pop     edi
  389.         pop     ecx
  390.         pop     eax
  391.         sti
  392.         ret
  393.  
  394. ;************************************************************************
  395. ;************************************************************************
  396. ;*****                                                              *****
  397. ;*****                   K E Y _ I N I T                            *****
  398. ;*****                                                              *****
  399. ;************************************************************************
  400. ;************************************************************************
  401.  
  402. PUBLIC  key_init_
  403.  
  404. key_init_:
  405.         push    eax
  406.         push    ebx
  407.         push    ds
  408.         push    es
  409.  
  410.         ;**************************************************************
  411.         ;******************* INITIALIZE key QUEUE **********************
  412.         ;**************************************************************
  413.  
  414.         mov     _keyd_buffer_type,1
  415.         mov     _keyd_repeat,1
  416.         mov     E0Flag, 0
  417.  
  418.         ; Clear the keyboard array
  419.         call    key_flush_
  420.  
  421.         cmp     Installed, 0
  422.         jne     AlreadyInstalled
  423.  
  424.         ;**************************************************************
  425.         ;******************* SAVE OLD INT9 HANDLER ********************
  426.         ;**************************************************************
  427.  
  428.         mov     Installed, 1
  429.  
  430.         mov     eax, 03509h             ; DOS Get Vector 09h
  431.         int     21h                     ; Call DOS
  432.         mov     org_int_sel, es         ; Save old interrupt selector
  433.         mov     org_int_off, ebx        ; Save old interrupt offset
  434.  
  435.  
  436.         ;**************************************************************
  437.         ;***************** INSTALL NEW INT9 HANDLER *******************
  438.         ;**************************************************************
  439.  
  440.         mov     eax, 02509h             ; DOS Set Vector 09h
  441.         mov     edx, offset key_handler  ; Point DS:EDX to new handler
  442.         mov     bx, cs
  443.         mov     MyCodeSegment, bx
  444.         mov     ds, bx
  445.         int     21h
  446.  
  447.  
  448. AlreadyInstalled:
  449.  
  450.         pop     es
  451.         pop     ds
  452.         pop     ebx
  453.         pop     eax
  454.  
  455.         ret
  456.  
  457.  
  458. ;************************************************************************
  459. ;************************************************************************
  460. ;*****                                                              *****
  461. ;*****                   K E Y _ C L O S E _                          *****
  462. ;*****                                                              *****
  463. ;************************************************************************
  464. ;************************************************************************
  465.  
  466. PUBLIC  key_close_
  467.  
  468. key_close_:
  469.         push    eax
  470.         push    ebx
  471.         push    edx
  472.         push    ds
  473.  
  474.  
  475.         cmp     Installed, 0
  476.         je      @f
  477.  
  478.         ;**************************************************************
  479.         ;***************** RESTORE OLD INT9 HANDLER *******************
  480.         ;**************************************************************
  481.  
  482.         mov     Installed, 0
  483.  
  484.         ; Clear the BIOS buffer
  485.         cli
  486.         mov     ebx, 041ch
  487.         mov     al, byte ptr [ebx]
  488.         mov     ebx, 041ah
  489.         mov     byte ptr [ebx], al
  490.         sti
  491.  
  492.         mov     eax, 02509h         ; DOS Set Vector 09h
  493.         mov     edx, org_int_off
  494.         mov     ds, org_int_sel
  495.         int     21h
  496.  
  497. @@:         pop     ds
  498.         pop     edx
  499.         pop     ebx
  500.         pop     eax
  501.  
  502.         ret
  503.  
  504. ;************************************************************************
  505. ;************************************************************************
  506. ;*****                                                              *****
  507. ;*****                   K E Y _ C H E C K _                          *****
  508. ;*****                                                              *****
  509. ;************************************************************************
  510. ;************************************************************************
  511.  
  512. PUBLIC  key_checkch_       ; Must end with a _ so C can see the function.
  513.  
  514. key_checkch_:
  515.         cli
  516.         push    ebx
  517.  
  518.         xor     eax, eax
  519.         cmp     Installed, 0
  520.         je      NoKey
  521.  
  522.         mov     bl, keytail
  523.         inc     bl
  524.         cmp     bl, keyhead
  525.         je      Nokey
  526.         mov     eax, 1
  527. Nokey:
  528.         pop     ebx
  529.         sti
  530.         ret
  531.  
  532. ;************************************************************************
  533. ;************************************************************************
  534. ;*****                                                              *****
  535. ;*****                 K E Y _ D E B U G                              *****
  536. ;*****                                                              *****
  537. ;************************************************************************
  538. ;************************************************************************
  539.  
  540. PUBLIC  key_debug_
  541. key_debug_:
  542.         int 3h
  543.         ret
  544.  
  545.  
  546. ;************************************************************************
  547. ;************************************************************************
  548. ;*****                                                              *****
  549. ;*****                   K E Y _ G E T C H _                        *****
  550. ;*****                                                              *****
  551. ;************************************************************************
  552. ;************************************************************************
  553.  
  554. PUBLIC  key_getch_       ; Must end with a _ so C can see the function.
  555.  
  556. key_getch_:
  557.         push    ebx
  558.  
  559.         xor     eax, eax
  560.         xor     ebx, ebx
  561.         cmp     Installed, 0
  562.         jne     StillNoKey
  563.         pop     ebx
  564.         ret
  565.  
  566. StillNoKey:
  567.         cli             ; Critical section
  568.         mov     bl, keytail
  569.         inc     bl
  570.         cmp     bl, keyhead
  571.         sti
  572.         je      StillNoKey
  573.  
  574.         cli             ; Critical section
  575.         xor     ebx, ebx
  576.         mov     bl, keyhead
  577.         mov     ax, word ptr keybuffer[ebx*2]
  578.         inc     BYTE PTR keyhead
  579.         sti
  580.  
  581.         pop     ebx
  582.         ret
  583.  
  584.  
  585. ;************************************************************************
  586. ;************************************************************************
  587. ;*****                                                              *****
  588. ;*****                   K E Y _ I N K E Y _                        *****
  589. ;*****                                                              *****
  590. ;************************************************************************
  591. ;************************************************************************
  592.  
  593. PUBLIC  key_inkey_       ; Must end with a _ so C can see the function.
  594.  
  595. key_inkey_:
  596.         push    ebx
  597.  
  598.         xor     eax, eax
  599.         xor     ebx, ebx
  600.  
  601.         cmp     Installed, 0
  602.         je      NoInkey
  603.  
  604.         cli             ; Critical section
  605.         mov     bl, keytail
  606.         inc     bl
  607.         cmp     bl, keyhead
  608.         sti
  609.         je      NoInkey
  610.  
  611.         cli             ; Critical section
  612.         mov     bl, keyhead
  613.         mov     ax, word ptr keybuffer[ebx*2]
  614.         inc     BYTE PTR keyhead
  615.         sti
  616. NoInkey:
  617.         pop     ebx
  618.         ret
  619.  
  620. PUBLIC  key_peekkey_       ; Must end with a _ so C can see the function.
  621.  
  622. key_peekkey_:
  623.         push    ebx
  624.  
  625.         xor     eax, eax
  626.         xor     ebx, ebx
  627.  
  628.         cli             ; Critical section
  629.  
  630.         cmp     Installed, 0
  631.         je      NoPeek
  632.         mov     bl, keytail
  633.         inc     bl
  634.         cmp     bl, keyhead
  635.         je      NoPeek
  636.         mov     bl, keyhead
  637.         mov     ax, word ptr keybuffer[ebx*2]
  638.         
  639. NoPeek:        sti
  640.         pop     ebx
  641.         ret
  642.  
  643.  
  644.  
  645. ;************************************************************************
  646. ;************************************************************************
  647. ;*****                                                              *****
  648. ;*****                   K E Y _ H A N D L E R                      *****
  649. ;*****                                                              *****
  650. ;************************************************************************
  651. ;************************************************************************
  652.  
  653. PUBLIC  key_handler      ; Must end with a _ so C can see the function.
  654.  
  655. key_handler:
  656.  
  657.         pushfd              ; Save flags in case we have to chain to original
  658.         push    eax
  659.         push    ebx
  660.         push    ecx
  661.         push    edx
  662.         push    ds
  663.  
  664.         mov     ax, DGROUP  ; Point to our data segment, since this is an
  665.         mov     ds, ax      ; interrupt and we don't know where we were.
  666.  
  667. IFDEF DEBUG
  668.         call    CheckForDebugger
  669.         jnc     @f
  670. ;****        mov eax, 0b0000h+78*2
  671. ;****        mov byte ptr [eax], 'D'
  672.         jmp      PassToBios      ; If debugger is active, then skip buffer
  673.  
  674. @@:
  675. ;****         mov eax, 0b0000h+78*2
  676. ;****        mov byte ptr [eax], 'I'
  677.  
  678.         ; Clear the BIOS buffer
  679.         mov     ebx, 041ch
  680.         mov     al, byte ptr [ebx]
  681.         mov     ebx, 041ah
  682.         mov     byte ptr [ebx], al
  683. ENDIF
  684.  
  685.         xor     eax, eax
  686.         xor    ebx, ebx
  687.  
  688.         in      al, 060h                ; Get scan code from keyboard
  689.         cmp     al, 0E0h
  690.         jne     NotE0Code
  691.  
  692. E0Code:        mov     E0Flag, 010000000b
  693.         jmp    LeaveHandler        ; If garbage key, then don't buffer it
  694.  
  695. NotE0Code:    mov    bl, al            ; Put break bit into bl    ; 0 = pressed, 1=released
  696.         and    al, 01111111b        ; AL = scancode
  697.         or    al, E0Flag        ; AL = extended scancode
  698.         mov     E0Flag,0        ; clear E0 flag
  699.         shl    bl, 1            ; put upper bit into carry flag
  700.         jc    key_mark_released    ; if upper bit of bl was set, then it was a release code
  701.  
  702. ;**************************************************************
  703. ;****************** HANDLE A NEWLY PRESSED KEY ****************
  704. ;**************************************************************
  705. ;Marks the key press in EAX in the scancode array.
  706.  
  707. key_mark_pressed:
  708.         ;cmp    al, 0eh    ; backspace
  709.         ;je    pause_execution
  710.         
  711.         mov     _keyd_last_pressed, al
  712.         ; Check if the key is repeating or if it just got pressed.
  713.         cmp     byte ptr _keyd_pressed[eax], 1
  714.         je      AlreadyDown
  715.  
  716. ;------------------------------- Code for a key pressed for the first time ------------------------
  717.         mov     byte ptr _keyd_pressed[eax], 1    
  718.         ; Set the time
  719.  
  720.         push    edx
  721.         push    eax
  722.         call    key_get_milliseconds
  723.         mov     edx, eax
  724.         pop     eax
  725.         mov     TimeKeyWentDown[eax*4], edx
  726.         pop     edx
  727.  
  728.         inc     NumDowns[eax*4]
  729.  
  730.         jmp    BufferAX
  731.  
  732. ;------------------------------- Code for a key that is already pressed ------------------------
  733. AlreadyDown:
  734.         cmp     _keyd_repeat, 0
  735.         je      DoneMarkingPressed
  736.  
  737. BufferAX:
  738.     cmp     _keyd_buffer_type, 0
  739.     je      SkipBuffer          ; Buffer = 0 means don't buffer anything.
  740.  
  741.     cmp     al, 0AAh        ; garbage key
  742.     je      SkipBuffer
  743.  
  744.     call    get_modifiers      ;returns ah
  745.     
  746.     xor     ebx, ebx
  747.     mov     bl, keytail
  748.     inc     bl
  749.     inc     bl
  750.  
  751.     ; If the buffer is full then don't buffer this key
  752.     cmp     bl, keyhead
  753.     je      SkipBuffer
  754.     dec     bl
  755.  
  756.     mov     word ptr keybuffer[ebx*2], ax
  757.     mov     keytail, bl
  758.  
  759. SkipBuffer:    
  760.         
  761. ;---------------------------------- Exit function -----------------------------
  762. DoneMarkingPressed:
  763.     jmp    LeaveHandler
  764.  
  765. ;**************************************************************
  766. ;******************* HANDLE A RELEASED KEY ********************
  767. ;**************************************************************
  768. ; Unmarks the key press in EAX from the scancode array.
  769. key_mark_released:
  770.  
  771.         mov     _keyd_last_released, al
  772.         mov     byte ptr _keyd_pressed[eax], 0
  773.         inc     NumUps[eax*4]
  774.  
  775.         cmp    _keyd_editor_mode, 0
  776.         je    NotInEditorMode
  777.         push    eax
  778.         xor     ah,ah
  779.         call    get_modifiers
  780.         or      ah,ah    ;check modifiers
  781.         pop     eax
  782.         jnz     skip_time
  783.  
  784. NotInEditorMode:    
  785.         push    eax
  786.  
  787.         call    timer_get_stamp64
  788.  
  789.         ; Timing in milliseconds
  790.         ; Can be used for up to 1000 hours
  791.         shld    edx, eax, 21            ; Keep 32+11 bits
  792.         shl     eax, 21
  793.         mov     ebx, 2502279823         ; 2^21*1193180/1000
  794.         div     ebx
  795.  
  796.         mov     edx, eax
  797.         pop     eax
  798.         sub     edx, TimeKeyWentDown[eax*4]
  799.         add     TimeKeyHeldDown[eax*4], edx
  800.  
  801. skip_time:    ;**jmp    LeaveHandler
  802.  
  803. ;**************************************************************
  804. ;*************** FINISH UP THE KEYBOARD INTERRUPT *************
  805. ;**************************************************************
  806. LeaveHandler:
  807.         ;jmp    DontPassToBios
  808.         jmp    PassToBios
  809.  
  810. ;****        cmp    _keyd_dump_key_array, 0
  811. ;****        je    DontPassToBios
  812. ;****        mov    ecx, 256
  813. ;****        mov    ebx, 0
  814. ;****
  815. ;****showdown:    mov    al, _keyd_pressed[ebx]
  816. ;****        add    al, '0'
  817. ;****        mov    [ebx*2+ 0b0000h], al
  818. ;****        inc    ebx
  819. ;****        loop    showdown
  820. ;****
  821. ;****        mov    eax, 0b0000h
  822. ;****        mov     byte ptr [ eax+(036h*2+1) ], 070h
  823. ;****        mov     byte ptr [ eax+(02Ah*2+1) ], 070h
  824. ;****        mov     byte ptr [ eax+(038h*2+1) ], 070h
  825. ;****        mov     byte ptr [ eax+(0B8h*2+1) ], 070h
  826. ;****        mov     byte ptr [ eax+(01Dh*2+1) ], 070h
  827. ;****        mov     byte ptr [ eax+(09dh*2+1) ], 070h
  828. ;****
  829. ;****        mov     byte ptr [ eax+(0AAh*2+1) ], 07Fh
  830. ;****        mov     byte ptr [ eax+(0E0h*2+1) ], 07Fh
  831. ;****
  832. ;****        jmp    DontPassToBios
  833. ;****
  834.  
  835. ; If in debugger, pass control to dos interrupt.
  836.  
  837. PassToBios:    pop     ds          ; Nothing left on stack but flags
  838.         pop     edx
  839.         pop     ecx
  840.         pop     ebx
  841.         pop     eax
  842.  
  843.         sub     esp, 8              ; Save space for IRETD frame
  844.         push    ds                  ; Save registers we use.
  845.         push    eax
  846.         mov     ax, DGROUP
  847.         mov     ds, ax              ; Set DS to our data segment
  848.         mov     eax, org_int_off   ; put original handler address
  849.         mov     [esp+8], eax        ;   in the IRETD frame
  850.         movzx   eax, org_int_sel
  851.         mov     [esp+12], eax
  852.         pop     eax                 ; Restore registers
  853.         pop     ds
  854.         iretd                       ; Chain to previous handler
  855.  
  856. pause_execution:
  857.         in      al, 61h         ; Get current port 61h state
  858.         or      al, 10000000b   ; Turn on bit 7 to signal clear keybrd
  859.         out     61h, al         ; Send to port
  860.         and     al, 01111111b   ; Turn off bit 7 to signal break
  861.         out     61h, al         ; Send to port
  862.         mov     al, 20h         ; Reset interrupt controller
  863.         out     20h, al
  864.         sti                     ; Reenable interrupts
  865.         pop     ds
  866.         pop     edx             ; Restore all of the saved registers.
  867.         pop     ecx
  868.         pop     ebx
  869.         pop     eax
  870.         popfd
  871.  
  872.         iretd                   ; Interrupt must return with IRETD
  873.  
  874. DontPassToBios:    
  875.  
  876. ; Resets the keyboard, PIC, restores stack, returns.
  877.         in      al, 61h         ; Get current port 61h state
  878.         or      al, 10000000b   ; Turn on bit 7 to signal clear keybrd
  879.         out     61h, al         ; Send to port
  880.         and     al, 01111111b   ; Turn off bit 7 to signal break
  881.         out     61h, al         ; Send to port
  882.         mov     al, 20h         ; Reset interrupt controller
  883.         out     20h, al
  884.         sti                     ; Reenable interrupts
  885.         pop     ds
  886.         pop     edx             ; Restore all of the saved registers.
  887.         pop     ecx
  888.         pop     ebx
  889.         pop     eax
  890.         popfd
  891.         iretd               ; Interrupt must return with IRETD
  892.  
  893. ;returns ah=bitmask of shift,ctrl,alt keys
  894. get_modifiers:        push    ecx
  895.  
  896.         xor     ah,ah
  897.  
  898.         ; Check the shift keys
  899.         mov     cl, _keyd_pressed[ 036h ]
  900.         or      cl, _keyd_pressed[ 02ah ]
  901.         or      ah, cl
  902.  
  903.         ; Check the alt key
  904.         mov     cl, _keyd_pressed[ 038h ]
  905.         or      cl, _keyd_pressed[ 0b8h ]
  906.         shl     cl, 1
  907.         or      ah, cl
  908.  
  909.         ; Check the ctrl key
  910.         mov     cl, _keyd_pressed[ 01dh ]
  911.         or      cl, _keyd_pressed[ 09dh ]
  912.         shl     cl, 2
  913.         or      ah, cl
  914.  
  915.         pop     ecx
  916.         ret
  917.  
  918. IFDEF DEBUG
  919. CheckForDebugger:
  920.     ; Returns CF=0 if debugger isn't active
  921.     ;         CF=1 if debugger is active
  922.  
  923.         ;*************************** DEBUG ******************************
  924.         ; When we're in the VIDEO debugger, we want to pass control to
  925.         ; the original interrupt.  So, to tell if the debugger is active,
  926.         ; I check if video page 1 is the active page since that is what
  927.         ; page the debugger uses, and if that works, I check the top of
  928.         ; the screen to see if the texxt "Control" is there, which should
  929.         ; only be there when we're in the debugger.
  930.  
  931.     
  932.  
  933.         push    eax
  934.         ;mov     eax, 0462h          ; Address 0462 stores BIOS current page
  935.         ;cmp     BYTE PTR [eax], 1
  936.         ;jne     NoDebuggerOnColor
  937.         ;mov     eax, 0b8000h+4096   ; 4096 = offset to 2nd video mem page
  938.         ;cmp     BYTE PTR [eax+2],'C'
  939.         ;jne     NoDebuggerOnColor
  940.         ;cmp     BYTE PTR [eax+4],'o'
  941.         ;jne     NoDebuggerOnColor
  942.         ;cmp     BYTE PTR [eax+6],'n'
  943.         ;jne     NoDebuggerOnColor
  944.         ;cmp     BYTE PTR [eax+8],'t'
  945.         ;jne     NoDebuggerOnColor
  946.         ;cmp     BYTE PTR [eax+10],'r'
  947.         ;jne     NoDebuggerOnColor
  948.         ;cmp     BYTE PTR [eax+12],'o'
  949.         ;jne     NoDebuggerOnColor
  950.         ;cmp     BYTE PTR [eax+14],'l'
  951.         ;jne     NoDebuggerOnColor
  952.         ;jmp     ActiveDebugger
  953.         ;NoDebuggerOnColor:
  954.         ; First, see if there is a mono debugger...
  955.  
  956.         ;mov     eax, 0b0000h        ; 4096 = offset to mono video mem
  957.         ;cmp     BYTE PTR [eax+2],'C'
  958.         ;jne     NoActiveDebugger
  959.         ;cmp     BYTE PTR [eax+4],'o'
  960.         ;jne     NoActiveDebugger
  961.         ;cmp     BYTE PTR [eax+6],'n'
  962.         ;jne     NoActiveDebugger
  963.         ;cmp     BYTE PTR [eax+8],'t'
  964.         ;jne     NoActiveDebugger
  965.         ;cmp     BYTE PTR [eax+10],'r'
  966.         ;jne     NoActiveDebugger
  967.         ;cmp     BYTE PTR [eax+12],'o'
  968.         ;jne     NoActiveDebugger
  969.         ;cmp     BYTE PTR [eax+14],'l'
  970.         ;jne     NoActiveDebugger
  971.  
  972.         mov     eax, 0b0000h        ; 4096 = offset to mono video mem
  973.         add     eax, 24*80*2
  974.  
  975.  
  976.         cmp     BYTE PTR [eax+0],'D'
  977.         jne     NextTest
  978.         cmp     BYTE PTR [eax+2],'B'
  979.         jne     NextTest
  980.         cmp     BYTE PTR [eax+4],'G'
  981.         jne     NextTest
  982.         cmp     BYTE PTR [eax+6],'>'
  983.         jne     NextTest
  984.  
  985.         ;Found DBG>, so consider debugger active:
  986.         jmp     ActiveDebugger
  987.  
  988. NextTest:
  989.         cmp     BYTE PTR [eax+14],'<'
  990.         jne     NextTest1
  991.         cmp     BYTE PTR [eax+16],'i'
  992.         jne     NextTest1
  993.         cmp     BYTE PTR [eax+18],'>'
  994.         jne     NextTest1
  995.         cmp     BYTE PTR [eax+20],' '
  996.         jne     NextTest1
  997.         cmp     BYTE PTR [eax+22],'-'
  998.         jne     NextTest1
  999.  
  1000.         ; Found <i> - , so consider debugger active:
  1001.         jmp     ActiveDebugger
  1002.  
  1003. NextTest1:
  1004.         cmp     BYTE PTR [eax+0], 200
  1005.         jne     NextTest2
  1006.         cmp     BYTE PTR [eax+2], 27
  1007.         jne     NextTest2
  1008.         cmp     BYTE PTR [eax+4], 17
  1009.         jne     NextTest2
  1010.  
  1011.         ; Found either the help screen or view screen, so consider
  1012.         ; debugger active
  1013.         jmp     ActiveDebugger
  1014.  
  1015. NextTest2:
  1016.         ; Now we see if its active by looking for the "Executing..."
  1017.         ; text on the bottom of the mono screen
  1018.         ;mov     eax, 0b0000h        ; 4096 = offset to mono video mem
  1019.         ;add     eax, 24*80*2
  1020.         ;cmp     BYTE PTR [eax+0],'E'
  1021.         ;je      NoActiveDebugger
  1022.         ;cmp     BYTE PTR [eax+2],'x'
  1023.         ;je      NoActiveDebugger
  1024.         ;cmp     BYTE PTR [eax+4],'e'
  1025.         ;je      NoActiveDebugger
  1026.         ;cmp     BYTE PTR [eax+6],'c'
  1027.         ;je      NoActiveDebugger
  1028.  
  1029. NoActiveDebugger:
  1030.         pop     eax
  1031.         clc
  1032.         ret
  1033.  
  1034. ActiveDebugger:
  1035.         pop     eax
  1036.         stc
  1037.         ret
  1038.  
  1039. ENDIF
  1040.  
  1041. _TEXT   ENDS
  1042.  
  1043.         END
  1044.  
  1045.  
  1046. 
  1047.