home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / bios / joy.asm < prev    next >
Assembly Source File  |  1998-06-08  |  11KB  |  445 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/bios/rcs/joy.asm $
  13. ; $Revision: 1.17 $
  14. ; $Author: john $
  15. ; $Date: 1995/10/07 13:22:11 $
  16. ;
  17. ; Contains routines for joystick interface.
  18. ;
  19. ; $Log: joy.asm $
  20. ; Revision 1.17  1995/10/07  13:22:11  john
  21. ; Added new method of reading joystick that allows higher-priority
  22. ; interrupts to go off.
  23. ; 
  24. ; Revision 1.16  1995/03/30  11:03:30  john
  25. ; Made -JoyBios read buttons using BIOS.
  26. ; 
  27. ; Revision 1.15  1995/02/14  11:39:36  john
  28. ; Added polled/bios joystick readers..
  29. ; 
  30. ; Revision 1.14  1995/01/29  18:36:00  john
  31. ; Made timer count in mode 2 instead of mode 3.
  32. ; 
  33. ; Revision 1.13  1994/12/28  15:32:21  john
  34. ; Added code to read joystick axis not all at one time.
  35. ; 
  36. ; Revision 1.12  1994/12/27  15:44:59  john
  37. ; Made the joystick timeout be at 1/100th of a second, 
  38. ; regardless of CPU speed.
  39. ; 
  40. ; Revision 1.11  1994/11/15  12:04:40  john
  41. ; Cleaned up timer code a bit... took out unused functions
  42. ; like timer_get_milliseconds, etc.
  43. ; 
  44. ; Revision 1.10  1994/07/01  10:55:54  john
  45. ; Fixed some bugs... added support for 4 axis.
  46. ; 
  47. ; Revision 1.9  1994/06/30  20:36:54  john
  48. ; Revamped joystick code.
  49. ; 
  50. ; Revision 1.8  1994/04/22  12:52:06  john
  51.  
  52. .386
  53.  
  54. _DATA   SEGMENT BYTE PUBLIC USE32 'DATA'
  55.  
  56. rcsid    db    "$Id: joy.asm 1.17 1995/10/07 13:22:11 john Exp $"
  57.  
  58.     LastTick     dd    0
  59.     TotalTicks    dd    0
  60.  
  61.     PUBLIC    _joy_bogus_reading
  62.     PUBLIC    _joy_retries
  63.     _joy_bogus_reading    dd    0
  64.     _joy_retries        dd    0
  65.     RetryCount        dd    0
  66.  
  67.     
  68. _DATA   ENDS
  69.  
  70. DGROUP  GROUP _DATA
  71.  
  72.  
  73. _TEXT   SEGMENT BYTE PUBLIC USE32 'CODE'
  74.  
  75.     ASSUME  ds:_DATA
  76.     ASSUME  cs:_TEXT
  77.  
  78.     JOY_PORT        EQU     0201h
  79.     TDATA           EQU     40h
  80.     TCOMMAND        EQU     43h
  81.  
  82. joy_get_timer:
  83.     xor    al, al                ; Latch timer 0 command
  84.     out    TCOMMAND, al        ; Latch timer
  85.     in    al, TDATA        ; Read lo byte
  86.     mov    ah, al
  87.     in    al, TDATA        ; Read hi byte
  88.     xchg    ah, al
  89.     and    eax, 0ffffh
  90.     ret    
  91.  
  92.  
  93.  
  94. PUBLIC joy_read_stick_friendly_
  95.  
  96. joy_read_stick_friendly_:    
  97.         ; ebx = read mask
  98.         ; edi = pointer to event buffer
  99.         ; ecx = timeout value
  100.         ; returns in eax the number of events
  101.  
  102.         mov    RetryCount, 0
  103.         mov    _joy_bogus_reading, 0
  104.  
  105. joy_read_stick_friendly_retry:
  106.         inc    RetryCount
  107.         cmp    RetryCount, 3
  108.         jbe    @f
  109.         mov    _joy_bogus_reading, 1
  110.         inc    _joy_retries
  111.         mov    eax, 0
  112.         ret
  113.  
  114. @@:
  115.         push    ecx
  116.         push    ebx
  117.         push    edi
  118.  
  119.         and    ebx, 01111b        ; Make sure we only check the right values                                        
  120.                         ; number of events we found will be in bh, so this also clears it to zero.
  121.  
  122.         mov     dx, JOY_PORT
  123.  
  124.         cli                ; disable interrupts while reading time...
  125.         call    joy_get_timer        ; Returns counter in EAX
  126.         sti                ; enable interrupts after reading time...
  127.         mov    LastTick, eax
  128.  
  129. waitforstable_f:    in    al, dx
  130.         and    al, bl
  131.         jz    ready_f             ; Wait for the port in question to be done reading...
  132.         
  133.         cli                ; disable interrupts while reading time...
  134.         call    joy_get_timer        ; Returns counter in EAX
  135.         sti                ; enable interrupts after reading time...
  136.         xchg    eax, LastTick
  137.         cmp    eax, LastTick
  138.         jb    @f
  139.         sub    eax, LastTick
  140. @@:        ; Higher...
  141.         add    TotalTicks, eax
  142.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  143.         jae    ready_f
  144.         jmp    waitforstable_f
  145.         
  146. ready_f:
  147.         cli            
  148.         mov     al, 0ffh
  149.         out     dx, al            ; Start joystick a readin'
  150.  
  151.         call    joy_get_timer        ; Returns counter in EAX
  152.         mov    LastTick, eax
  153.         mov    TotalTicks, 0
  154.         
  155.         mov    [edi], eax        ; Store initial count
  156.         add    edi, 4        
  157.  
  158.     again_f:    in    al, dx            ; Read Joystick port
  159.         not    al
  160.         and    al, bl            ; Mask off channels we don't want to read
  161.         jnz    flip_f            ; See if any of the channels flipped
  162.  
  163.         ; none flipped -- check any interrupts...
  164.         mov    al, 0Ah
  165.         out     20h, al
  166.         in    al, 20h        ; Get interrupts pending
  167.         cmp    al, 0
  168.         je    NoInts
  169.  
  170.         ; Need to do an interrupt
  171.         sti
  172.         nop    ; let the interrupt go on...
  173.         cli
  174.         
  175.         ; See if any axis turned
  176.         in    al, dx
  177.         not    al
  178.         and    al, bl
  179.         jz    NoInts
  180.  
  181.         ; At this point, an interrupt occured, making one or more
  182.         ; of the axis values bogus.  So, we will restart this process...
  183.  
  184.         pop    edi
  185.         pop    ebx
  186.         pop    ecx
  187.  
  188.         jmp    joy_read_stick_friendly_retry
  189.  
  190. NoInts:
  191.         call    joy_get_timer        ; Returns counter in EAX
  192.         
  193.         xchg    eax, LastTick
  194.         cmp    eax, LastTick
  195.         jb    @f
  196.         sub    eax, LastTick
  197. @@:        ; Higher...
  198.         add    TotalTicks, eax
  199.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  200.         jae    timed_out_f
  201.         jmp    again_f
  202.  
  203.     flip_f:    and    eax, 01111b        ; Only care about axis values
  204.         mov    [edi], eax        ; Record what channel(s) flipped
  205.         add    edi, 4    
  206.         xor    bl, al            ; Unmark the channels that just tripped
  207.  
  208.         call    joy_get_timer        ; Returns counter in EAX
  209.         mov    [edi], eax        ; Record the time this channel flipped
  210.         add    edi, 4        
  211.         inc    bh            ; Increment number of events
  212.  
  213.         cmp    bl, 0    
  214.         jne    again_f            ; If there are more channels to read, keep looping
  215.  
  216.     timed_out_f:
  217.         sti
  218.  
  219.         movzx    eax, bh            ; Return number of events
  220.  
  221.         pop    edi
  222.         pop    ebx
  223.         pop    ecx
  224.  
  225.         ret
  226.  
  227.  
  228.  
  229. PUBLIC joy_read_stick_asm_
  230.  
  231. joy_read_stick_asm_:    
  232.         ; ebx = read mask
  233.         ; edi = pointer to event buffer
  234.         ; ecx = timeout value
  235.         ; returns in eax the number of events
  236.         mov    _joy_bogus_reading, 0
  237.  
  238.         and    ebx, 01111b        ; Make sure we only check the right values                                        
  239.                         ; number of events we found will be in bh, so this also clears it to zero.
  240.  
  241.         mov     dx, JOY_PORT
  242.  
  243.         cli                ; disable interrupts while reading time...
  244.         call    joy_get_timer        ; Returns counter in EAX
  245.         sti                ; enable interrupts after reading time...
  246.         mov    LastTick, eax
  247.  
  248. waitforstable:    in    al, dx
  249.         and    al, bl
  250.         jz    ready             ; Wait for the port in question to be done reading...
  251.         
  252.         cli                ; disable interrupts while reading time...
  253.         call    joy_get_timer        ; Returns counter in EAX
  254.         sti                ; enable interrupts after reading time...
  255.         xchg    eax, LastTick
  256.         cmp    eax, LastTick
  257.         jb    @f
  258.         sub    eax, LastTick
  259. @@:        ; Higher...
  260.         add    TotalTicks, eax
  261.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  262.         jae    ready
  263.         jmp    waitforstable
  264.         
  265. ready:
  266.         cli
  267.         mov     al, 0ffh
  268.         out     dx, al            ; Start joystick a readin'
  269.  
  270.         call    joy_get_timer        ; Returns counter in EAX
  271.         mov    LastTick, eax
  272.         mov    TotalTicks, 0
  273.         
  274.         mov    [edi], eax        ; Store initial count
  275.         add    edi, 4        
  276.  
  277.     again:    in    al, dx            ; Read Joystick port
  278.         not    al
  279.         and    al, bl            ; Mask off channels we don't want to read
  280.         jnz    flip            ; See if any of the channels flipped
  281.  
  282.         call    joy_get_timer        ; Returns counter in EAX
  283.         
  284.         xchg    eax, LastTick
  285.         cmp    eax, LastTick
  286.         jb    @f
  287.         sub    eax, LastTick
  288. @@:        ; Higher...
  289.         add    TotalTicks, eax
  290.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  291.         jae    timedout
  292.         jmp    again
  293.  
  294.     flip:    and    eax, 01111b        ; Only care about axis values
  295.         mov    [edi], eax        ; Record what channel(s) flipped
  296.         add    edi, 4    
  297.         xor    bl, al            ; Unmark the channels that just tripped
  298.  
  299.         call    joy_get_timer        ; Returns counter in EAX
  300.         mov    [edi], eax        ; Record the time this channel flipped
  301.         add    edi, 4        
  302.         inc    bh            ; Increment number of events
  303.  
  304.         cmp    bl, 0    
  305.         jne    again            ; If there are more channels to read, keep looping
  306.  
  307.     timedout:
  308.         movzx    eax, bh            ; Return number of events
  309.  
  310.         sti
  311.         ret
  312.  
  313.  
  314. PUBLIC joy_read_stick_polled_
  315.  
  316. joy_read_stick_polled_:    
  317.         ; ebx = read mask
  318.         ; edi = pointer to event buffer
  319.         ; ecx = timeout value
  320.         ; returns in eax the number of events
  321.         mov    _joy_bogus_reading, 0
  322.  
  323.         and    ebx, 01111b        ; Make sure we only check the right values                                        
  324.                         ; number of events we found will be in bh, so this also clears it to zero.
  325.  
  326.         mov     dx, JOY_PORT
  327.  
  328.         mov    TotalTicks, 0
  329.  
  330. waitforstable1:    in    al, dx
  331.         and    al, bl
  332.         jz    ready1             ; Wait for the port in question to be done reading...
  333.         
  334.         inc    TotalTicks
  335.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  336.         jae    ready1
  337.         jmp    waitforstable1
  338. ready1:
  339.         cli
  340.         mov     al, 0ffh
  341.         out     dx, al            ; Start joystick a readin'
  342.  
  343.         mov    TotalTicks, 0
  344.  
  345.         mov    dword ptr [edi], 0        ; Store initial count
  346.         add    edi, 4        
  347.  
  348.     again1:    in    al, dx            ; Read Joystick port
  349.         not    al
  350.         and    al, bl            ; Mask off channels we don't want to read
  351.         jnz    flip1            ; See if any of the channels flipped
  352.  
  353.         inc    TotalTicks
  354.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  355.         jae    timedout1
  356.         jmp    again1
  357.  
  358.     flip1:    and    eax, 01111b        ; Only care about axis values
  359.         mov    [edi], eax        ; Record what channel(s) flipped
  360.         add    edi, 4    
  361.         xor    bl, al            ; Unmark the channels that just tripped
  362.  
  363.         mov    eax, TotalTicks
  364.         mov    [edi], eax        ; Record the time this channel flipped
  365.         add    edi, 4        
  366.         inc    bh            ; Increment number of events
  367.  
  368.         cmp    bl, 0    
  369.         jne    again1            ; If there are more channels to read, keep looping
  370.  
  371.     timedout1:
  372.         movzx    eax, bh            ; Return number of events
  373.  
  374.         sti
  375.         ret
  376.  
  377. PUBLIC joy_read_stick_bios_
  378.  
  379. joy_read_stick_bios_:    
  380.         ; ebx = read mask
  381.         ; edi = pointer to event buffer
  382.         ; ecx = timeout value
  383.         ; returns in eax the number of events
  384.  
  385.         mov    _joy_bogus_reading, 0
  386.         
  387.         pusha
  388.  
  389.         mov    dword ptr [edi], 0
  390.             
  391.         mov    eax, 08400h
  392.         mov    edx, 1
  393.         cli
  394.         int    15h
  395.         sti
  396.     
  397.         mov    dword ptr [edi+4], 1    ;    Axis 1        
  398.         and    eax, 0ffffh
  399.         mov    [edi+8], eax        ;     Axis 1 value
  400.  
  401.         mov    dword ptr [edi+12], 2    ;    Axis 2
  402.         and    ebx, 0ffffh
  403.         mov    [edi+16], ebx        ;     Axis 2 value
  404.  
  405.         mov    dword ptr [edi+20], 4    ;    Axis 3
  406.         and    ecx, 0ffffh
  407.         mov    [edi+24], ecx        ;     Axis 3 value
  408.  
  409.         mov    dword ptr [edi+28], 8    ;    Axis 3
  410.         and    edx, 0ffffh
  411.         mov    [edi+32], edx        ;     Axis 3 value
  412.  
  413.         popa
  414.         mov    eax, 4            ; 4 events
  415.  
  416.         ret
  417.  
  418.  
  419. PUBLIC joy_read_buttons_bios_
  420.  
  421. joy_read_buttons_bios_:    
  422.         ; returns in eax the button settings
  423.         
  424.         push    ebx
  425.         push    ecx
  426.         push    edx
  427.         mov    eax, 08400h
  428.         mov    edx, 0    ; Read switches
  429.         int    15h
  430.         pop    edx
  431.         pop    ecx
  432.         pop    ebx
  433.         
  434.         shr    eax, 4
  435.         not    eax
  436.         and    eax, 01111b
  437.         ret
  438.  
  439.  
  440. _TEXT   ENDS
  441.  
  442.  
  443.         END
  444. 
  445.