home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / bios / csstuff / timer.asm < prev   
Assembly Source File  |  1998-06-08  |  20KB  |  686 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/bios/rcs/timer.asm $
  13. ; $Revision: 1.28 $
  14. ; $Author: matt $
  15. ; $Date: 1995/02/15 01:36:56 $
  16. ;
  17. ; Routines for setting and using system timers
  18. ;
  19. ; $Log: timer.asm $
  20. ; Revision 1.28  1995/02/15  01:36:56  matt
  21. ; Cleaned up code to avoid doing out 20,20 more than once
  22. ; 
  23. ; Revision 1.27  1995/02/14  11:39:37  john
  24. ; Fixed bug with joystick handler not having enough
  25. ; stack space under Windows.
  26. ; 
  27. ; Revision 1.26  1995/02/09  21:51:39  john
  28. ; Made so that DOS timer interrupt gets called before interrupts are
  29. ; enabled in timer interpt because not doing this cause conflicts with
  30. ; ps2 style mice and smartdrv with write caching enabled that hangs the
  31. ; program and trashes the FAT.
  32. ; 
  33. ; Revision 1.25  1995/02/04  15:39:33  john
  34. ; More time interrupt changes.
  35. ; 
  36. ; Revision 1.24  1995/02/03  23:25:21  john
  37. ; Made so that when interrupts are nested, the time interrupt still
  38. ; calls the DOS one.
  39. ; 
  40. ; Revision 1.23  1995/01/29  19:00:42  john
  41. ; Made latching timer value more readable.
  42. ; 
  43. ; Revision 1.22  1995/01/17  10:34:53  mike
  44. ; prevent divide overflows.
  45. ; 
  46. ; Revision 1.21  1994/12/15  11:10:54  john
  47. ; Added code that should make DOS 18.2 callbacks 
  48. ; a bit more accurate.
  49. ; 
  50. ; Revision 1.20  1994/12/10  12:47:34  john
  51. ; Made so that timer_get_fixed seconds and get_approx seconds are always equal.
  52. ; 
  53. ; Revision 1.19  1994/12/10  12:27:34  john
  54. ; Added timer_get_approx_seconds.
  55. ; 
  56. ; Revision 1.18  1994/12/10  12:07:14  john
  57. ; Added tick counter variable.
  58. ; 
  59. ; Revision 1.17  1994/12/04  11:55:16  john
  60. ; Made stick read at whatever rate the clock is at, not
  61. ; at 18.2 times/second.
  62. ; 
  63. ; Revision 1.16  1994/11/28  15:24:10  john
  64. ; Cleaned up timer interrupt a bit.
  65. ; 
  66. ; Revision 1.15  1994/11/22  17:00:43  john
  67. ; Made the timer handler fill in ES along with DS.
  68. ; The HMI drivers expect this.
  69. ; 
  70. ; Revision 1.14  1994/11/15  12:04:38  john
  71. ; Cleaned up timer code a bit... took out unused functions
  72. ; like timer_get_milliseconds, etc.
  73. ; 
  74. ; Revision 1.13  1994/10/05  16:17:40  john
  75. ; Made interrupts more stable.
  76. ; 
  77. ; Revision 1.12  1994/09/29  18:29:57  john
  78. ; Enabled interrupts whil calling the user_function.
  79. ; 
  80. ; Revision 1.11  1994/09/23  16:00:31  john
  81. ; MAde the timer interrupt switch to a 4K stack
  82. ; before calling the timer_function.
  83. ; 
  84. ; Revision 1.10  1994/09/22  16:09:21  john
  85. ; Fixed some virtual memory lockdown problems with timer and
  86. ; joystick.
  87. ; 
  88. ; Revision 1.9  1994/04/29  12:13:48  john
  89. ; Locked all memory used during interrupts so that program
  90. ; won't hang when using virtual memory.
  91. ; 
  92. ; Revision 1.8  1994/04/28  23:50:49  john
  93. ; Changed calling for init_timer.  Made the function that the
  94. ; timer calls be a far function. All of this was done to make
  95. ; our timer system compatible with the HMI sound stuff.
  96. ; 
  97. ; Revision 1.7  1994/02/17  15:57:15  john
  98. ; Changed key libary to C.
  99. ; 
  100. ; Revision 1.6  1994/01/18  20:19:17  john
  101. ; Fixed minor flaws with pending interrupts,
  102. ; interfaced with joystick code.
  103. ; 
  104. ; Revision 1.5  1994/01/18  13:54:18  john
  105. ; Fixed a few miner flaws.
  106. ; 
  107. ; Revision 1.4  1994/01/18  10:58:25  john
  108. ; Added timer_get_fixed_seconds
  109. ; 
  110. ; Revision 1.3  1993/12/20  15:40:59  john
  111. ; *** empty log message ***
  112. ; 
  113. ; Revision 1.2  1993/09/23  18:08:44  john
  114. ; added code so that timer_init can handle multiple calls.
  115. ; added code so that atexit is called.
  116. ; 
  117. ; Revision 1.1  1993/07/10  13:10:43  matt
  118. ; Initial revision
  119. ; 
  120. ;
  121. ;
  122.  
  123. ;***************************************************************************
  124. ;***************************************************************************
  125. ;*****                                                                 *****
  126. ;*****                     T I M E R . A S M                           *****
  127. ;*****                                                                 *****
  128. ;*****                                                                 *****
  129. ;***** PROCEDURES                                                      *****
  130. ;*****                                                                 *****
  131. ;*****                                                                 *****
  132. ;*****                                                                 *****
  133. ;***** VARIABLES                                                       *****
  134. ;*****                                                                 *****
  135. ;*****                                                                 *****
  136. ;***** CONSTANTS                                                       *****
  137. ;*****                                                                 *****
  138. ;*****                                                                 *****
  139. ;***************************************************************************
  140. ;***************************************************************************
  141.  
  142. .386
  143.  
  144. ;************************************************************************
  145. ;**************** FLAT MODEL DATA SEGMENT STUFF *************************
  146. ;************************************************************************
  147.  
  148. _DATA   SEGMENT BYTE PUBLIC USE32 'DATA'
  149.  
  150. rcsid    db    "$Id: timer.asm 1.28 1995/02/15 01:36:56 matt Exp $"
  151.  
  152. TDATA           EQU     40h
  153. TCOMMAND        EQU     43h
  154. PIC             EQU     020h
  155. STACK_SIZE    EQU    4096    ; A 4K stack
  156.  
  157. TIMER_DATA STRUCT   
  158.     in_timer    db  0
  159.  
  160.     nested_counter    dd    0
  161.  
  162.     _timer_cnt      dd  65536
  163.     dos_timer          dd  0
  164.     sound_timer     dd  0
  165.     joystick_timer  dd  0
  166.  
  167.     joystick_poller    dd  0
  168.  
  169.     user_function   df  0
  170.     
  171.     org_interrupt    df  0    
  172.  
  173.     saved_stack    df  0
  174.  
  175.     new_stack    df  0
  176.  
  177.     tick_count    dd  0
  178.  
  179.     Installed db     0
  180.  
  181.     TimerStack    db  STACK_SIZE dup (0)        
  182. TIMER_DATA ENDS
  183.  
  184.     TimerData    TIMER_DATA <>    
  185.  
  186. _DATA   ENDS
  187.  
  188. DGROUP  GROUP _DATA
  189.  
  190.  
  191. ;************************************************************************
  192. ;**************** FLAT MODEL CODE SEGMENT STUFF *************************
  193. ;************************************************************************
  194.  
  195. _TEXT   SEGMENT BYTE PUBLIC USE32 'CODE'
  196.  
  197.         ASSUME  ds:_DATA
  198.         ASSUME  cs:_TEXT
  199.  
  200. INCLUDE PSMACROS.INC
  201.  
  202. TIMER_LOCKED_CODE_START:
  203.  
  204.         extn atexit_
  205.  
  206. PUBLIC timer_get_stamp64
  207.  
  208. timer_get_stamp64:
  209.         ; Return a 64-bit stamp that is the number of 1.19Mhz pulses
  210.         ; since the time was initialized.  Returns in EDX:EAX.
  211.         ; Also, interrupts must be disabled.
  212.  
  213.         xor     eax, eax            ; Clear all of EAX
  214.         out     TCOMMAND, al        ; Tell timer to latch
  215.  
  216.         mov     al, 0ah             ; Find if interrupt pending
  217.         out     PIC, al
  218.         jmp    @f
  219. @@:        in      al, PIC
  220.         and     eax, 01b
  221.         jz      NoInterrupt
  222.  
  223.         in      al, TDATA           ; Read in lo byte
  224.         mov     dl, al
  225.             in      al, TDATA           ; Read in hi byte
  226.         mov    dh, al
  227.         and    edx, 0ffffh
  228.         mov    eax, TimerData._timer_cnt
  229.         shl    eax, 1        
  230.         sub    eax, edx
  231.             
  232.         push    ebx
  233.         mov    ebx, eax
  234.         mov    eax, TimerData.tick_count
  235.         imul    TimerData._timer_cnt    ; edx:eax = Number of 1.19 MHz ticks elapsed...
  236.         add    eax, ebx
  237.         adc    edx, 0                
  238.         pop    ebx
  239.  
  240.         ret
  241.  
  242. NoInterrupt:
  243.         in      al, TDATA           ; Read in lo byte
  244.         mov     ah, al
  245.         in      al, TDATA           ; Read in hi byte
  246.         xchg    ah, al              ; arrange em correctly
  247.         mov     edx, TimerData._timer_cnt
  248.         sub     dx, ax              ; BX = timer ticks
  249.         mov     ax, dx
  250.  
  251.         push    ebx
  252.         mov    ebx, eax
  253.         mov    eax, TimerData.tick_count
  254.         imul    TimerData._timer_cnt    ; edx:eax = Number of 1.19 MHz ticks elapsed...
  255.         add    eax, ebx
  256.         adc    edx, 0                
  257.         pop    ebx
  258.  
  259.         ret
  260.  
  261.  
  262. PUBLIC  timer_get_fixed_seconds_
  263.  
  264. timer_get_fixed_seconds_:
  265.         push    ebx
  266.         push    edx
  267.  
  268.         cli
  269.         call    timer_get_stamp64
  270.         sti
  271.  
  272.         ; Timing in fixed point (16.16) seconds.
  273.         ; Can be used for up to 1000 hours
  274.         shld    edx, eax, 16            ; Keep 32+11 bits
  275.         shl     eax, 16            
  276.         ; edx:eax = number of 1.19Mhz pulses elapsed.
  277.         mov     ebx, 1193180
  278.  
  279. ; Make sure we won't divide overflow.  Make time wrap at about 9 hours
  280. sub_again:        sub     edx, ebx    ; subtract until negative...
  281.         jns     sub_again    ; ...to prevent divide overflow...
  282.         add     edx, ebx    ; ...then add in to get correct value.
  283.         div     ebx
  284.         ; eax = fixed point seconds elapsed...
  285.  
  286.         pop     edx
  287.         pop     ebx
  288.  
  289.         ret
  290.  
  291. PUBLIC  timer_get_fixed_secondsX_
  292.  
  293. timer_get_fixed_secondsX_:
  294.         push    ebx
  295.         push    edx
  296.  
  297.         call    timer_get_stamp64
  298.  
  299.         ; Timing in fixed point (16.16) seconds.
  300.         ; Can be used for up to 1000 hours
  301.         shld    edx, eax, 16            ; Keep 32+11 bits
  302.         shl     eax, 16            
  303.         ; edx:eax = number of 1.19Mhz pulses elapsed.
  304.         mov     ebx, 1193180
  305.  
  306. xsub_again:        sub     edx, ebx    ; subtract until negative...
  307.         jns     xsub_again    ; ...to prevent divide overflow...
  308.         add     edx, ebx    ; ...then add in to get correct value.
  309.  
  310.         div     ebx
  311.         ; eax = fixed point seconds elapsed...
  312.  
  313.         pop     edx
  314.         pop     ebx
  315.  
  316.         ret
  317.  
  318. PUBLIC timer_get_approx_seconds_
  319. timer_get_approx_seconds_:
  320.     push    ebx
  321.     push    edx
  322.  
  323.     mov    eax, TimerData.tick_count
  324.     imul    TimerData._timer_cnt    ; edx:eax = Number of 1.19 MHz ticks elapsed...
  325.     shld    edx, eax, 16            ; Keep 32+16 bits, for conversion to fixed point
  326.     shl     eax, 16            
  327.     ; edx:eax = number of 1.19Mhz pulses elapsed.
  328.     mov     ebx, 1193180
  329.  
  330. approx_sub_again:    sub     edx, ebx    ; subtract until negative...
  331.     jns     approx_sub_again    ; ...to prevent divide overflow...
  332.     add     edx, ebx    ; ...then add in to get correct value.
  333.  
  334.     div     ebx
  335.     ; eax = fixed point seconds elapsed...
  336.  
  337.     pop    edx
  338.     pop    ebx
  339.     ret
  340.  
  341.  
  342.  
  343. ;extern void timer_set_rate(int count_val);
  344. ;extern void timer_set_function( void _far * function );
  345.  
  346. PUBLIC  timer_set_rate_
  347. timer_set_rate_:
  348.     ; eax = rate
  349.     pushad
  350.  
  351.     ; Make sure eax below or equal to 65535 and above 0
  352.     ; if its not, make it be 65536 which is normal dos
  353.     ; timing.
  354.     cmp    eax, 65535
  355.     jbe    @f
  356.     mov    eax, 65536
  357. @@:    cmp    eax, 0
  358.     jne    @f
  359.     mov    eax, 65536
  360. @@:    ; Set the timer rate to eax
  361.     cli
  362.     mov    TimerData.tick_count, 0
  363.     mov     TimerData._timer_cnt, eax        
  364.     mov     al, 34h        ; count in binary, mode 2, load low byte then hi byte, counter 0:  00 11 010 0
  365.     out     TCOMMAND, al    ; Reset PIT channel 0
  366.     mov     eax, TimerData._timer_cnt
  367.     out     TDATA, al
  368.     mov     al, ah
  369.     out     TDATA, al
  370.     sti
  371.     popad
  372.     ret
  373.  
  374. PUBLIC  timer_set_function_
  375. timer_set_function_:
  376.     ; dx:eax = far pointer to user function
  377.     pushad
  378.     cli
  379.     mov    dword ptr TimerData.user_function[0], eax    ; offset
  380.     mov     word ptr TimerData.user_function[4], dx        ; selector
  381.     sti
  382.     popad
  383.     ret
  384.  
  385. PUBLIC timer_set_joyhandler_
  386. timer_set_joyhandler_:
  387.     cli
  388.     mov    TimerData.joystick_poller, eax
  389.     sti
  390.     ret
  391.  
  392.  
  393. ;************************************************************************
  394. ;************************************************************************
  395. ;*****                                                              *****
  396. ;*****                T I M E R _ H A N D L E R                     *****
  397. ;*****                                                              *****
  398. ;************************************************************************
  399. ;************************************************************************
  400.  
  401. timer_handler:
  402.         push    ds
  403.         push    es
  404.         push    eax
  405.  
  406.         mov     ax, DGROUP       ; Interrupt, so point to our data segment
  407.         mov     ds, ax
  408.         mov     es, ax
  409.  
  410.         ; Increment time counter...
  411.         inc    TimerData.tick_count
  412.                 
  413.         cmp    TimerData._timer_cnt, 9940
  414.         ja    NotEveryOtherTime            
  415.         
  416.         test    TimerData.tick_count, 1
  417.         jz    NotEveryOtherTime
  418.         
  419.         ; every other time, do vsync...
  420.         push    edx
  421.         mov     dx, 3DAh
  422. VS2B:       in      al, dx
  423.         and     al, 08h
  424.         jz      VS2B        ; Loop until in vertical retrace
  425.         pop    edx
  426.  
  427.         mov     al, 34h        ; count in binary, mode 2, load low byte then hi byte, counter 0:  00 11 010 0
  428.         out     TCOMMAND, al    ; Reset PIT channel 0
  429.         mov     eax, TimerData._timer_cnt
  430.         out     TDATA, al
  431.         mov     al, ah
  432.         out     TDATA, al
  433.  
  434. NotEveryOtherTime:
  435.         mov    eax, TimerData._timer_cnt
  436.         add     TimerData.dos_timer, eax        ; Increment DOS timer
  437.         add    TimerData.sound_timer, eax
  438.         add    TimerData.joystick_timer, eax
  439.         cmp    TimerData.dos_timer, 65536
  440.         jb    NoChainToOld            ; See if we need to chain to DOS 18.2
  441.         and    TimerData.dos_timer, 0ffffh
  442.  
  443.         ;
  444.         ; Call the original DOS handler....
  445.         ;
  446.         pushfd
  447.         call    fword ptr [TimerData.org_interrupt]
  448.  
  449.         jmp    NoReset        ;old handler has reset, so we don't
  450.  
  451. NoChainToOld:
  452.         ; Reset controller
  453.         mov     al, 20h         ; Reset interrupt controller
  454.         out     20h, al
  455.  
  456. NoReset:
  457.         cmp    TimerData.in_timer, 0
  458.         jne    ExitInterrupt
  459.  
  460.         mov    TimerData.in_timer, 1        ; Mark that we're in a timer interrupt...
  461.  
  462.         ; Reenable interrupts
  463.         sti            ; Reenable interrupts
  464.  
  465.         cmp     word ptr TimerData.user_function[4], 0        ; Check the selector...
  466.         je      NoUserFunction
  467.  
  468.         cmp    TimerData.sound_timer, 9943
  469.         jb    NoUserFunction            ; See if we need to call the 120 hz sound mixer.
  470.         sub    TimerData.sound_timer, 9943
  471.  
  472.         ; Switch stacks while calling the user-definable function...
  473.         pushad
  474.         push    fs
  475.         push    gs
  476.         mov    dword ptr TimerData.saved_stack[0], esp
  477.         mov    word ptr TimerData.saved_stack[4], ss
  478.         lss    esp, TimerData.new_stack    ; Switch to new stack
  479.         call    fword ptr [TimerData.user_function]    ; Call new function
  480.         lss    esp,  TimerData.saved_stack    ; Switch back to original stack
  481.         pop    gs
  482.         pop    fs
  483.         popad
  484.  
  485. NoUserFunction:    
  486.         cmp    dword ptr TimerData.joystick_poller, 0
  487.         je    NoJoyPolling
  488.  
  489.         
  490.         mov    eax, 39772
  491.         cmp    TimerData.joystick_timer, eax
  492.         jb    NoJoyPolling            ; See if we poll the joystick buttons
  493.         sub    TimerData.joystick_timer, eax
  494.  
  495.         mov    dword ptr TimerData.saved_stack[0], esp
  496.         mov    word ptr TimerData.saved_stack[4], ss
  497.         lss    esp, TimerData.new_stack    ; Switch to new stack
  498.         call    dword ptr TimerData.joystick_poller
  499.         lss    esp,  TimerData.saved_stack    ; Switch back to original stack
  500.  
  501. NoJoyPolling:
  502.         cli
  503.         mov    TimerData.in_timer, 0
  504.  
  505. ExitInterrupt:
  506.         pop    eax
  507.         pop    es
  508.         pop    ds
  509.         iretd                ; Return from timer interrupt
  510.  
  511.  
  512. TIMER_LOCKED_CODE_STOP:
  513.  
  514. ;************************************************************************
  515. ;************************************************************************
  516. ;*****                                                              *****
  517. ;*****                   T I M E R _ I N I T                        *****
  518. ;*****                                                              *****
  519. ;************************************************************************
  520. ;************************************************************************
  521.  
  522.  
  523. PUBLIC  timer_init_
  524.  
  525. timer_init_:
  526.         pushad
  527.         push    ds
  528.         push    es
  529.  
  530.         cmp     TimerData.Installed, 1
  531.         je      AlreadyInstalled
  532.  
  533.         mov     TimerData._timer_cnt, 65536    ; Set to BIOS's normal 18.2 Hz
  534.         mov     TimerData.dos_timer, 0        ; clear DOS Interrupt counter
  535.         mov    TimerData.sound_timer, 0    ; clear 120 hz handler
  536.         mov    TimerData.joystick_timer, 0    ; clear joystick poller
  537.         mov     dword ptr TimerData.user_function[0], 0    ; offset of user function
  538.         mov     word ptr TimerData.user_function[4], 0    ; selector of user function
  539.  
  540.         lea    eax, ds:[TimerData.TimerStack]    ; Use EAX as temp stack pointer
  541.         add    eax, STACK_SIZE            ; Top of stack minus space for saving old ss:esp
  542.         mov    dword ptr TimerData.new_stack[0], eax
  543.         mov    word ptr TimerData.new_stack[4], ds
  544.  
  545.         ;--------------- lock data used in interrupt
  546.         mov    eax, SIZEOF TIMER_DATA
  547.         mov    esi, eax
  548.         shr    esi, 16            
  549.         mov    edi, eax
  550.         and    edi, 0ffffh    ; si:di = length of region to lock in bytes
  551.         lea    ebx, ds:TimerData
  552.         lea    ecx, ds:TimerData
  553.         shr    ebx, 16
  554.         and    ecx, 0ffffh    ; bx:cx = start of linear address to lock
  555.         mov    eax, 0600h    ; DPMI lock address function
  556.         int    31h        ; call dpmi
  557.         jnc    @f
  558.         int    3        ; LOCK FAILED!!
  559. @@:
  560.         ;--------------- lock code used in interrupt
  561.         lea    eax, cs:TIMER_LOCKED_CODE_STOP
  562.         lea    ecx, cs:TIMER_LOCKED_CODE_START
  563.         sub    eax, ecx
  564.         inc    eax        ; EAX = size of timer interrupt handler
  565.         mov    esi, eax
  566.         shr    esi, 16            
  567.         mov    edi, eax
  568.         and    edi, 0ffffh    ; si:di = length of region to lock in bytes
  569.         lea    ebx, cs:TIMER_LOCKED_CODE_START
  570.         lea    ecx, cs:TIMER_LOCKED_CODE_START
  571.         shr    ebx, 16
  572.         and    ecx, 0ffffh    ; bx:cx = start of linear address to lock
  573.         mov    eax, 0600h    ; DPMI lock address function
  574.         int    31h        ; call dpmi
  575.         jnc    @f
  576.         int    3        ; LOCK FAILED!!
  577. @@:
  578.  
  579.         ;**************************************************************
  580.         ;******************* SAVE OLD INT8 HANDLER ********************
  581.         ;**************************************************************
  582.         mov     eax, 03508h             ; DOS Get Vector 08h
  583.         int     21h                     ; Call DOS
  584.  
  585.         mov     dword ptr TimerData.org_interrupt[0], ebx    ; offset of user function
  586.         mov    word ptr TimerData.org_interrupt[4], es        ; selector of user function
  587.  
  588.         ;**************************************************************
  589.         ;***************** INSTALL NEW INT8 HANDLER *******************
  590.         ;**************************************************************
  591.  
  592.         cli
  593.  
  594.         mov     al, 34h        ; count in binary, mode 2, load low byte then hi byte, counter 0:  00 11 010 0
  595.         out     TCOMMAND, al    ; Reset PIT channel 0
  596.         mov     eax, TimerData._timer_cnt
  597.         out     TDATA, al
  598.         mov     al, ah
  599.         out     TDATA, al
  600.  
  601.         mov     TimerData.tick_count, 0
  602.         mov     TimerData.Installed,1
  603.  
  604.         mov     eax, 02508h             ; DOS Set Vector 08h
  605.         mov     edx, offset timer_handler  ; Point DS:EDX to new handler
  606.         mov     bx, cs
  607.         push    ds
  608.         mov     ds, bx
  609.         int     21h
  610.         pop     ds
  611.         sti
  612.         lea     eax, cs:timer_close_
  613.         call    atexit_
  614.  
  615. AlreadyInstalled:
  616.  
  617.         pop     es
  618.         pop     ds
  619.         popad
  620.  
  621.         ret
  622.  
  623.  
  624. ;************************************************************************
  625. ;************************************************************************
  626. ;*****                                                              *****
  627. ;*****                  T I M E R _ C L O S E _                     *****
  628. ;*****                                                              *****
  629. ;************************************************************************
  630. ;************************************************************************
  631.  
  632. PUBLIC  timer_close_
  633.  
  634. timer_close_:
  635.         push    eax
  636.         push    edx
  637.         push    ds
  638.  
  639.  
  640.         cmp     TimerData.Installed, 0
  641.         je      NotInstalled
  642.         mov     TimerData.Installed, 0
  643.  
  644.         ;**************************************************************
  645.         ;***************** RESTORE OLD INT9 HANDLER *******************
  646.         ;**************************************************************
  647.  
  648.         cli
  649.         mov     al, 36h        ; count in binary, mode 3, load low byte then hi byte, counter 0:  00 11 011 0
  650.         out     TCOMMAND, al    ; Reser PIT channel 0
  651.         mov     ax, 0h
  652.         out     TDATA, al
  653.         mov     al, ah
  654.         out     TDATA, al
  655.  
  656.         push    ds
  657.         mov     eax, 02508h         ; DOS Set Vector 08h
  658.         mov     edx, dword ptr TimerData.org_interrupt[0]
  659.         mov     ds, word ptr TimerData.org_interrupt[4]
  660.         int     21h
  661.         pop    ds
  662.  
  663.         sti
  664.         
  665.         cmp    TimerData.nested_counter, 0
  666.         je    NoNestedInterrupts
  667.         mov    eax, TimerData.nested_counter
  668.         ;int     3        ; Get John!!
  669.     
  670. NoNestedInterrupts:
  671.         
  672.  
  673. NotInstalled:
  674.         pop     ds
  675.         pop     edx
  676.         pop     eax
  677.  
  678.         ret
  679.  
  680.  
  681. _TEXT           ENDS
  682.  
  683.  
  684.         END
  685. 
  686.