home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / bios / csstuff / joy.asm next >
Assembly Source File  |  1998-06-08  |  10KB  |  441 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/bios/rcs/joy.asm $
  13. ; $Revision: 1.16 $
  14. ; $Author: john $
  15. ; $Date: 1995/03/30 11:03:30 $
  16. ;
  17. ; Contains routines for joystick interface.
  18. ;
  19. ; $Log: joy.asm $
  20. ; Revision 1.16  1995/03/30  11:03:30  john
  21. ; Made -JoyBios read buttons using BIOS.
  22. ; 
  23. ; Revision 1.15  1995/02/14  11:39:36  john
  24. ; Added polled/bios joystick readers..
  25. ; 
  26. ; Revision 1.14  1995/01/29  18:36:00  john
  27. ; Made timer count in mode 2 instead of mode 3.
  28. ; 
  29. ; Revision 1.13  1994/12/28  15:32:21  john
  30. ; Added code to read joystick axis not all at one time.
  31. ; 
  32. ; Revision 1.12  1994/12/27  15:44:59  john
  33. ; Made the joystick timeout be at 1/100th of a second, 
  34. ; regardless of CPU speed.
  35. ; 
  36. ; Revision 1.11  1994/11/15  12:04:40  john
  37. ; Cleaned up timer code a bit... took out unused functions
  38. ; like timer_get_milliseconds, etc.
  39. ; 
  40. ; Revision 1.10  1994/07/01  10:55:54  john
  41. ; Fixed some bugs... added support for 4 axis.
  42. ; 
  43. ; Revision 1.9  1994/06/30  20:36:54  john
  44. ; Revamped joystick code.
  45. ; 
  46. ; Revision 1.8  1994/04/22  12:52:06  john
  47.  
  48. .386
  49.  
  50. _DATA   SEGMENT BYTE PUBLIC USE32 'DATA'
  51.  
  52. rcsid    db    "$Id: joy.asm 1.16 1995/03/30 11:03:30 john Exp $"
  53.  
  54.     LastTick     dd    0
  55.     TotalTicks    dd    0
  56.  
  57.     PUBLIC    _joy_bogus_reading
  58.     PUBLIC    _joy_retries
  59.     _joy_bogus_reading    dd    0
  60.     _joy_retries        dd    0
  61.     RetryCount        dd    0
  62.  
  63.     
  64. _DATA   ENDS
  65.  
  66. DGROUP  GROUP _DATA
  67.  
  68.  
  69. _TEXT   SEGMENT BYTE PUBLIC USE32 'CODE'
  70.  
  71.     ASSUME  ds:_DATA
  72.     ASSUME  cs:_TEXT
  73.  
  74.     JOY_PORT        EQU     0201h
  75.     TDATA           EQU     40h
  76.     TCOMMAND        EQU     43h
  77.  
  78. joy_get_timer:
  79.     xor    al, al                ; Latch timer 0 command
  80.     out    TCOMMAND, al        ; Latch timer
  81.     in    al, TDATA        ; Read lo byte
  82.     mov    ah, al
  83.     in    al, TDATA        ; Read hi byte
  84.     xchg    ah, al
  85.     and    eax, 0ffffh
  86.     ret    
  87.  
  88.  
  89.  
  90. PUBLIC joy_read_stick_friendly_
  91.  
  92. joy_read_stick_friendly_:    
  93.         ; ebx = read mask
  94.         ; edi = pointer to event buffer
  95.         ; ecx = timeout value
  96.         ; returns in eax the number of events
  97.  
  98.         mov    RetryCount, 0
  99.         mov    _joy_bogus_reading, 0
  100.  
  101. joy_read_stick_friendly_retry:
  102.         inc    RetryCount
  103.         cmp    RetryCount, 3
  104.         jbe    @f
  105.         mov    _joy_bogus_reading, 1
  106.         inc    _joy_retries
  107.         mov    eax, 0
  108.         ret
  109.  
  110. @@:
  111.         push    ecx
  112.         push    ebx
  113.         push    edi
  114.  
  115.         and    ebx, 01111b        ; Make sure we only check the right values                                        
  116.                         ; number of events we found will be in bh, so this also clears it to zero.
  117.  
  118.         mov     dx, JOY_PORT
  119.  
  120.         cli                ; disable interrupts while reading time...
  121.         call    joy_get_timer        ; Returns counter in EAX
  122.         sti                ; enable interrupts after reading time...
  123.         mov    LastTick, eax
  124.  
  125. waitforstable_f:    in    al, dx
  126.         and    al, bl
  127.         jz    ready_f             ; Wait for the port in question to be done reading...
  128.         
  129.         cli                ; disable interrupts while reading time...
  130.         call    joy_get_timer        ; Returns counter in EAX
  131.         sti                ; enable interrupts after reading time...
  132.         xchg    eax, LastTick
  133.         cmp    eax, LastTick
  134.         jb    @f
  135.         sub    eax, LastTick
  136. @@:        ; Higher...
  137.         add    TotalTicks, eax
  138.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  139.         jae    ready_f
  140.         jmp    waitforstable_f
  141.         
  142. ready_f:
  143.         cli            
  144.         mov     al, 0ffh
  145.         out     dx, al            ; Start joystick a readin'
  146.  
  147.         call    joy_get_timer        ; Returns counter in EAX
  148.         mov    LastTick, eax
  149.         mov    TotalTicks, 0
  150.         
  151.         mov    [edi], eax        ; Store initial count
  152.         add    edi, 4        
  153.  
  154.     again_f:    in    al, dx            ; Read Joystick port
  155.         not    al
  156.         and    al, bl            ; Mask off channels we don't want to read
  157.         jnz    flip_f            ; See if any of the channels flipped
  158.  
  159.         ; none flipped -- check any interrupts...
  160.         mov    al, 0Ah
  161.         out     20h, al
  162.         in    al, 20h        ; Get interrupts pending
  163.         cmp    al, 0
  164.         je    NoInts
  165.  
  166.         ; Need to do an interrupt
  167.         sti
  168.         nop    ; let the interrupt go on...
  169.         cli
  170.         
  171.         ; See if any axis turned
  172.         in    al, dx
  173.         not    al
  174.         and    al, bl
  175.         jz    NoInts
  176.  
  177.         ; At this point, an interrupt occured, making one or more
  178.         ; of the axis values bogus.  So, we will restart this process...
  179.  
  180.         pop    edi
  181.         pop    ebx
  182.         pop    ecx
  183.  
  184.         jmp    joy_read_stick_friendly_retry
  185.  
  186. NoInts:
  187.         call    joy_get_timer        ; Returns counter in EAX
  188.         
  189.         xchg    eax, LastTick
  190.         cmp    eax, LastTick
  191.         jb    @f
  192.         sub    eax, LastTick
  193. @@:        ; Higher...
  194.         add    TotalTicks, eax
  195.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  196.         jae    timed_out_f
  197.         jmp    again_f
  198.  
  199.     flip_f:    and    eax, 01111b        ; Only care about axis values
  200.         mov    [edi], eax        ; Record what channel(s) flipped
  201.         add    edi, 4    
  202.         xor    bl, al            ; Unmark the channels that just tripped
  203.  
  204.         call    joy_get_timer        ; Returns counter in EAX
  205.         mov    [edi], eax        ; Record the time this channel flipped
  206.         add    edi, 4        
  207.         inc    bh            ; Increment number of events
  208.  
  209.         cmp    bl, 0    
  210.         jne    again_f            ; If there are more channels to read, keep looping
  211.  
  212.     timed_out_f:
  213.         sti
  214.  
  215.         movzx    eax, bh            ; Return number of events
  216.  
  217.         pop    edi
  218.         pop    ebx
  219.         pop    ecx
  220.  
  221.         ret
  222.  
  223.  
  224.  
  225. PUBLIC joy_read_stick_asm_
  226.  
  227. joy_read_stick_asm_:    
  228.         ; ebx = read mask
  229.         ; edi = pointer to event buffer
  230.         ; ecx = timeout value
  231.         ; returns in eax the number of events
  232.         mov    _joy_bogus_reading, 0
  233.  
  234.         and    ebx, 01111b        ; Make sure we only check the right values                                        
  235.                         ; number of events we found will be in bh, so this also clears it to zero.
  236.  
  237.         mov     dx, JOY_PORT
  238.  
  239.         cli                ; disable interrupts while reading time...
  240.         call    joy_get_timer        ; Returns counter in EAX
  241.         sti                ; enable interrupts after reading time...
  242.         mov    LastTick, eax
  243.  
  244. waitforstable:    in    al, dx
  245.         and    al, bl
  246.         jz    ready             ; Wait for the port in question to be done reading...
  247.         
  248.         cli                ; disable interrupts while reading time...
  249.         call    joy_get_timer        ; Returns counter in EAX
  250.         sti                ; enable interrupts after reading time...
  251.         xchg    eax, LastTick
  252.         cmp    eax, LastTick
  253.         jb    @f
  254.         sub    eax, LastTick
  255. @@:        ; Higher...
  256.         add    TotalTicks, eax
  257.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  258.         jae    ready
  259.         jmp    waitforstable
  260.         
  261. ready:
  262.         cli
  263.         mov     al, 0ffh
  264.         out     dx, al            ; Start joystick a readin'
  265.  
  266.         call    joy_get_timer        ; Returns counter in EAX
  267.         mov    LastTick, eax
  268.         mov    TotalTicks, 0
  269.         
  270.         mov    [edi], eax        ; Store initial count
  271.         add    edi, 4        
  272.  
  273.     again:    in    al, dx            ; Read Joystick port
  274.         not    al
  275.         and    al, bl            ; Mask off channels we don't want to read
  276.         jnz    flip            ; See if any of the channels flipped
  277.  
  278.         call    joy_get_timer        ; Returns counter in EAX
  279.         
  280.         xchg    eax, LastTick
  281.         cmp    eax, LastTick
  282.         jb    @f
  283.         sub    eax, LastTick
  284. @@:        ; Higher...
  285.         add    TotalTicks, eax
  286.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  287.         jae    timedout
  288.         jmp    again
  289.  
  290.     flip:    and    eax, 01111b        ; Only care about axis values
  291.         mov    [edi], eax        ; Record what channel(s) flipped
  292.         add    edi, 4    
  293.         xor    bl, al            ; Unmark the channels that just tripped
  294.  
  295.         call    joy_get_timer        ; Returns counter in EAX
  296.         mov    [edi], eax        ; Record the time this channel flipped
  297.         add    edi, 4        
  298.         inc    bh            ; Increment number of events
  299.  
  300.         cmp    bl, 0    
  301.         jne    again            ; If there are more channels to read, keep looping
  302.  
  303.     timedout:
  304.         movzx    eax, bh            ; Return number of events
  305.  
  306.         sti
  307.         ret
  308.  
  309.  
  310. PUBLIC joy_read_stick_polled_
  311.  
  312. joy_read_stick_polled_:    
  313.         ; ebx = read mask
  314.         ; edi = pointer to event buffer
  315.         ; ecx = timeout value
  316.         ; returns in eax the number of events
  317.         mov    _joy_bogus_reading, 0
  318.  
  319.         and    ebx, 01111b        ; Make sure we only check the right values                                        
  320.                         ; number of events we found will be in bh, so this also clears it to zero.
  321.  
  322.         mov     dx, JOY_PORT
  323.  
  324.         mov    TotalTicks, 0
  325.  
  326. waitforstable1:    in    al, dx
  327.         and    al, bl
  328.         jz    ready1             ; Wait for the port in question to be done reading...
  329.         
  330.         inc    TotalTicks
  331.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  332.         jae    ready1
  333.         jmp    waitforstable1
  334. ready1:
  335.         cli
  336.         mov     al, 0ffh
  337.         out     dx, al            ; Start joystick a readin'
  338.  
  339.         mov    TotalTicks, 0
  340.  
  341.         mov    dword ptr [edi], 0        ; Store initial count
  342.         add    edi, 4        
  343.  
  344.     again1:    in    al, dx            ; Read Joystick port
  345.         not    al
  346.         and    al, bl            ; Mask off channels we don't want to read
  347.         jnz    flip1            ; See if any of the channels flipped
  348.  
  349.         inc    TotalTicks
  350.         cmp    TotalTicks, ecx        ; Timeout at 1/200'th of a second
  351.         jae    timedout1
  352.         jmp    again1
  353.  
  354.     flip1:    and    eax, 01111b        ; Only care about axis values
  355.         mov    [edi], eax        ; Record what channel(s) flipped
  356.         add    edi, 4    
  357.         xor    bl, al            ; Unmark the channels that just tripped
  358.  
  359.         mov    eax, TotalTicks
  360.         mov    [edi], eax        ; Record the time this channel flipped
  361.         add    edi, 4        
  362.         inc    bh            ; Increment number of events
  363.  
  364.         cmp    bl, 0    
  365.         jne    again1            ; If there are more channels to read, keep looping
  366.  
  367.     timedout1:
  368.         movzx    eax, bh            ; Return number of events
  369.  
  370.         sti
  371.         ret
  372.  
  373. PUBLIC joy_read_stick_bios_
  374.  
  375. joy_read_stick_bios_:    
  376.         ; ebx = read mask
  377.         ; edi = pointer to event buffer
  378.         ; ecx = timeout value
  379.         ; returns in eax the number of events
  380.  
  381.         mov    _joy_bogus_reading, 0
  382.         
  383.         pusha
  384.  
  385.         mov    dword ptr [edi], 0
  386.             
  387.         mov    eax, 08400h
  388.         mov    edx, 1
  389.         cli
  390.         int    15h
  391.         sti
  392.     
  393.         mov    dword ptr [edi+4], 1    ;    Axis 1        
  394.         and    eax, 0ffffh
  395.         mov    [edi+8], eax        ;     Axis 1 value
  396.  
  397.         mov    dword ptr [edi+12], 2    ;    Axis 2
  398.         and    ebx, 0ffffh
  399.         mov    [edi+16], ebx        ;     Axis 2 value
  400.  
  401.         mov    dword ptr [edi+20], 4    ;    Axis 3
  402.         and    ecx, 0ffffh
  403.         mov    [edi+24], ecx        ;     Axis 3 value
  404.  
  405.         mov    dword ptr [edi+28], 8    ;    Axis 3
  406.         and    edx, 0ffffh
  407.         mov    [edi+32], edx        ;     Axis 3 value
  408.  
  409.         popa
  410.         mov    eax, 4            ; 4 events
  411.  
  412.         ret
  413.  
  414.  
  415. PUBLIC joy_read_buttons_bios_
  416.  
  417. joy_read_buttons_bios_:    
  418.         ; returns in eax the button settings
  419.         
  420.         push    ebx
  421.         push    ecx
  422.         push    edx
  423.         mov    eax, 08400h
  424.         mov    edx, 0    ; Read switches
  425.         int    15h
  426.         pop    edx
  427.         pop    ecx
  428.         pop    ebx
  429.         
  430.         shr    eax, 4
  431.         not    eax
  432.         and    eax, 01111b
  433.         ret
  434.  
  435.  
  436. _TEXT   ENDS
  437.  
  438.  
  439.         END
  440. 
  441.