home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 2d / scalea.asm < prev    next >
Assembly Source File  |  1998-06-08  |  6KB  |  249 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/2d/rcs/scalea.asm $
  13. ; $Revision: 1.2 $
  14. ; $Author: john $
  15. ; $Date: 1994/01/12 18:02:52 $
  16. ; 
  17. ; Asm inner loop for scaler.
  18. ; 
  19. ; $Log: scalea.asm $
  20. ; Revision 1.2  1994/01/12  18:02:52  john
  21. ; Asm code for the scaler... first iteration here
  22. ; has compiled code that works!!
  23. ; 
  24. ; Revision 1.1  1994/01/12  12:20:11  john
  25. ; Initial revision
  26. ; 
  27. ; 
  28.  
  29.  
  30.  
  31. .386
  32.     option    oldstructs
  33.  
  34.     .nolist
  35.     include    types.inc
  36.     include    psmacros.inc
  37.     .list
  38.  
  39.     assume    cs:_TEXT, ds:_DATA
  40.  
  41. _DATA    segment    dword public USE32 'DATA'
  42.  
  43. rcsid    db    "$Id: scalea.asm 1.2 1994/01/12 18:02:52 john Exp $"
  44.     align    4
  45.     
  46.  
  47.     public _scale_trans_color        
  48.     public _scale_error_term        
  49.     public _scale_initial_pixel_count    
  50.     public _scale_adj_up            
  51.     public _scale_adj_down            
  52.     public _scale_final_pixel_count    
  53.     public _scale_ydelta_minus_1        
  54.     public _scale_whole_step        
  55.     public _scale_source_ptr        
  56.     public _scale_dest_ptr            
  57.  
  58.         
  59.     _scale_trans_color        db    ?
  60.     _scale_error_term        dd    ?
  61.     _scale_initial_pixel_count    dd    ?
  62.     _scale_adj_up            dd    ?
  63.     _scale_adj_down            dd    ?
  64.     _scale_final_pixel_count    dd    ?
  65.     _scale_ydelta_minus_1        dd    ?
  66.     _scale_whole_step        dd    ?
  67.     _scale_source_ptr        dd    ?
  68.     _scale_dest_ptr            dd    ?
  69.     _scale_cc_jump_spot        dd    ?
  70.     _scale_slice_length_1        dd    ?
  71.     _scale_slice_length_2        dd    ?
  72.  
  73. _DATA    ends
  74.  
  75.  
  76. _TEXT    segment    dword public USE32 'CODE'
  77.  
  78.  
  79. PUBLIC rls_stretch_scanline_asm_
  80.  
  81. rls_stretch_scanline_asm_:
  82.         cld
  83.         pusha
  84.         mov    esi, _scale_source_ptr
  85.         mov    edi, _scale_dest_ptr
  86.         mov    edx, _scale_ydelta_minus_1
  87.         mov    ebx, _scale_whole_step
  88.         mov    ah,  _scale_trans_color
  89.         mov    ebp, _scale_error_term
  90.  
  91.         mov    ecx, _scale_initial_pixel_count
  92.         lodsb
  93.         cmp    al, ah
  94.         je    first_pixel_transparent
  95.         rep    stosb
  96.         jmp    next_pixel
  97.  
  98. first_pixel_transparent:
  99.         add    edi, ecx
  100.         jmp    next_pixel
  101.  
  102. skip_this_pixel:    add    edi, ecx
  103.             dec    edx
  104.             jz    done
  105.  
  106. next_pixel:        lodsb                ; get next source pixel
  107.             mov    ecx, ebx                    
  108.             add    ebp, _scale_adj_up
  109.             jle    no_inc_error_term
  110.             inc    ecx
  111.             sub    ebp, _scale_adj_down
  112. no_inc_error_term:                        
  113.             cmp    al, ah
  114.             je    skip_this_pixel
  115.             rep    stosb            ; write source pixel to n locations
  116.             dec    edx
  117.             jnz    next_pixel
  118.  
  119. done:            lodsb
  120.             cmp    al, ah
  121.             je    exit_sub
  122.             mov    ecx, _scale_final_pixel_count
  123.             rep    stosb
  124.  
  125. exit_sub:
  126.             popa
  127.             ret
  128.  
  129. PUBLIC scale_do_cc_scanline_
  130. PUBLIC rls_do_cc_setup_asm_
  131.  
  132. scale_do_cc_scanline_:
  133.     cld
  134.     pusha
  135.     mov    esi, _scale_source_ptr
  136.     mov    edi, _scale_dest_ptr
  137.     mov    ah,  _scale_trans_color
  138.     mov    ebx, _scale_slice_length_1
  139.     mov    edx, _scale_slice_length_2
  140.  
  141.     mov    ecx, _scale_initial_pixel_count
  142.  
  143.     ; Do the first texture pixel
  144.     mov    ecx, _scale_initial_pixel_count
  145.     lodsb
  146.     cmp    al, ah
  147.     je    @f
  148.     rep    stosb
  149. @@:    add    edi, ecx
  150.  
  151.     mov    ecx, _scale_cc_jump_spot
  152.     jmp    ecx
  153.  
  154.     ; This is the compiled code to do the middle pixels...
  155. scale_cc_start:        mov    al, [esi]
  156. scale_cc_changer:    mov    ecx, ebx    ;<==== CODE CHANGES TO EBX OR EDX !!!!!!
  157.             inc    esi
  158.             cmp    al, ah
  159.             je    @f
  160.             rep    stosb
  161.         @@:    add    edi, ecx
  162. scale_cc_end:
  163.  
  164.     REPT 319
  165.             mov    al, [esi]
  166.             mov    ecx, ebx    ;<==== CODE CHANGES TO EBX OR EDX !!!!!!
  167.             inc    esi
  168.             cmp    al, ah
  169.             je    @f
  170.             rep    stosb
  171.         @@:    add    edi, ecx
  172.     ENDM
  173. last_cc_instruction:
  174.  
  175.     mov    ecx, _scale_final_pixel_count
  176.     lodsb
  177.     cmp    al, ah
  178.     je    last_one_transparent
  179.     rep    stosb
  180. last_one_transparent:
  181.  
  182.     popa
  183.     ret
  184.  
  185. rls_do_cc_setup_asm_:
  186.  
  187.         pusha
  188.  
  189.         mov    ebx, _scale_whole_step
  190.         mov      _scale_slice_length_1, ebx
  191.         inc    ebx
  192.         mov      _scale_slice_length_2, ebx
  193.  
  194.         mov    ebp, _scale_error_term
  195.         mov    edx, _scale_ydelta_minus_1
  196.  
  197.         mov    ebx, offset scale_cc_end
  198.         sub    ebx, offset scale_cc_start    ; ebx = distance to next changer inst.
  199.  
  200.         mov    eax, _scale_ydelta_minus_1
  201.  
  202.         
  203.         imul    eax, ebx        ; eax = sizeof 1 iteration * numiterations.
  204.                         
  205.         mov    edi, offset last_cc_instruction
  206.         sub    edi, eax        ; edi = address of first iteration that we need
  207.                         ;       to jump to
  208.         mov    _scale_cc_jump_spot, edi
  209.  
  210.         mov    ecx, offset scale_cc_changer
  211.         sub    ecx, offset scale_cc_start    ; ecx = distance from start to to next changer inst.
  212.         
  213.         add    edi, ecx
  214.  
  215. next_pixel1:        add    ebp, _scale_adj_up
  216.             jle    no_inc_error_term1
  217.             ; Modify code in scale_do_cc_scanline_ to write 'edx' pixels
  218.         mov    al, byte ptr [edi]
  219.         cmp    al, 08bh
  220.         jne    BigError
  221.             mov    word ptr [edi], 0CA8Bh    ; 0x8BCA = mov ecx, edx
  222.             add    edi, ebx        
  223.             sub    ebp, _scale_adj_down
  224.             dec    edx
  225.             jnz    next_pixel1
  226.             jmp    done1
  227.  
  228. no_inc_error_term1:    ; Modify code in scale_do_cc_scanline_ to write 'ebx' pixels
  229.         mov    al, byte ptr [edi]
  230.         cmp    al, 08bh
  231.         jne    BigError
  232.             mov    word ptr [edi], 0CB8Bh    ; 0x8BCB = mov ecx, ebx
  233.             add    edi, ebx        
  234.             dec    edx
  235.             jnz    next_pixel1
  236.  
  237. done1:        popa
  238.         ret
  239.  
  240. BigError:    int 3    ; Stop, buddy!!
  241.         popa
  242.         ret
  243.  
  244. _TEXT    ends
  245.  
  246.     end
  247.  
  248. 
  249.