home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 2d / modex.asm < prev    next >
Assembly Source File  |  1998-06-08  |  17KB  |  836 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/2d/rcs/modex.asm $
  13. ; $Revision: 1.19 $
  14. ; $Author: john $
  15. ; $Date: 1995/03/01 15:37:46 $
  16. ;
  17. ; Routines to access ModeX VGA memory
  18. ;
  19. ; $Log: modex.asm $
  20. ; Revision 1.19  1995/03/01  15:37:46  john
  21. ; Better ModeX support.
  22. ; 
  23. ; Revision 1.18  1994/11/24  13:24:20  john
  24. ; Made sure that some rep movs had the cld set first.
  25. ; Took some unused functions out.
  26. ; 
  27. ; Revision 1.17  1994/09/22  18:15:02  john
  28. ; Made flip page wait for retrace.
  29. ; 
  30. ; Revision 1.16  1994/09/22  16:08:27  john
  31. ; Fixed some palette stuff.
  32. ; 
  33. ; Revision 1.15  1994/07/13  12:03:05  john
  34. ; Added assembly modex line-drawer.
  35. ; 
  36. ; Revision 1.14  1994/05/06  12:50:34  john
  37. ; Added supertransparency; neatend things up; took out warnings.
  38. ; 
  39. ; Revision 1.13  1994/05/03  19:39:04  john
  40. ; *** empty log message ***
  41. ; 
  42. ; Revision 1.12  1994/02/18  15:32:32  john
  43. ; *** empty log message ***
  44. ; 
  45. ; Revision 1.11  1993/12/21  11:40:36  john
  46. ; *** empty log message ***
  47. ; 
  48. ; Revision 1.10  1993/12/09  15:02:26  john
  49. ; Changed palette stuff majorly
  50. ; 
  51. ; Revision 1.9  1993/12/03  12:11:32  john
  52. ; fixed cx/ecx loop bugs.
  53. ; 
  54. ; Revision 1.8  1993/11/16  11:28:18  john
  55. ; *** empty log message ***
  56. ; 
  57. ; Revision 1.7  1993/10/15  16:23:23  john
  58. ; y
  59. ; 
  60. ; Revision 1.6  1993/09/28  19:07:19  john
  61. ; stripped the waitforretrace out of fade to speed things up.
  62. ; 
  63. ; Revision 1.5  1993/09/26  18:58:58  john
  64. ; fade stuff
  65. ; 
  66. ; Revision 1.4  1993/09/21  14:01:15  john
  67. ; turned off video before mode set to reduce flicker.
  68. ; 
  69. ; Revision 1.3  1993/09/08  11:38:36  john
  70. ; changed rcs stuff at beginning.
  71. ; 
  72. ;
  73. ;
  74.  
  75.  
  76. .386
  77.  
  78. _DATA   SEGMENT BYTE PUBLIC USE32 'DATA'
  79.  
  80. INCLUDE psmacros.inc
  81. INCLUDE TWEAK.INC
  82. INCLUDE VGAREGS.INC
  83.  
  84. extd _gr_var_bwidth
  85.  
  86. extd _modex_line_vertincr
  87. extd _modex_line_incr1        
  88. extd _modex_line_incr2        
  89.     _modex_line_routine    dd ?
  90. extd _modex_line_x1        
  91. extd _modex_line_y1        
  92. extd _modex_line_x2        
  93. extd _modex_line_y2        
  94. extb _modex_line_Color
  95.  
  96.     SavedColor      db ?
  97.  
  98. LEFT_MASK1      = 1000b
  99. LEFT_MASK2      = 1100b
  100. LEFT_MASK3      = 1110b
  101. RIGHT_MASK1     = 0001b
  102. RIGHT_MASK2     = 0011b
  103. RIGHT_MASK3     = 0111b
  104. ALL_MASK        = 1111b
  105.  
  106. tmppal          db 768 dup (0)
  107. fb_pal          dd ?
  108. fb_add          dw ?
  109. fb_count        dd ?
  110.  
  111. MaskTable1  db  ALL_MASK AND RIGHT_MASK1,
  112.                 ALL_MASK AND RIGHT_MASK2,
  113.                 ALL_MASK AND RIGHT_MASK3,
  114.                 ALL_MASK,
  115.                 LEFT_MASK3 AND RIGHT_MASK1,
  116.                 LEFT_MASK3 AND RIGHT_MASK2,
  117.                 LEFT_MASK3 AND RIGHT_MASK3,
  118.                 LEFT_MASK3,
  119.                 LEFT_MASK2 AND RIGHT_MASK1,
  120.                 LEFT_MASK2 AND RIGHT_MASK2,
  121.                 LEFT_MASK2 AND RIGHT_MASK3,
  122.                 LEFT_MASK2,
  123.                 LEFT_MASK1 AND RIGHT_MASK1,
  124.                 LEFT_MASK1 AND RIGHT_MASK2,
  125.                 LEFT_MASK1 AND RIGHT_MASK3,
  126.                 LEFT_MASK1,
  127.  
  128. MaskTable2  db  ALL_MASK,RIGHT_MASK1,
  129.                 ALL_MASK,RIGHT_MASK2,
  130.                 ALL_MASK,RIGHT_MASK3,
  131.                 ALL_MASK,ALL_MASK,
  132.                 LEFT_MASK3,RIGHT_MASK1,
  133.                 LEFT_MASK3,RIGHT_MASK2,
  134.                 LEFT_MASK3,RIGHT_MASK3,
  135.                 LEFT_MASK3,ALL_MASK,
  136.                 LEFT_MASK2,RIGHT_MASK1,
  137.                 LEFT_MASK2,RIGHT_MASK2,
  138.                 LEFT_MASK2,RIGHT_MASK3,
  139.                 LEFT_MASK2,ALL_MASK,
  140.                 LEFT_MASK1,RIGHT_MASK1,
  141.                 LEFT_MASK1,RIGHT_MASK2,
  142.                 LEFT_MASK1,RIGHT_MASK3,
  143.                 LEFT_MASK1,ALL_MASK
  144.  
  145. DrawTable   dd  DrawMR,
  146.                 DrawMR,
  147.                 DrawMR,
  148.                 DrawM,
  149.                 DrawLMR,
  150.                 DrawLMR,
  151.                 DrawLMR,
  152.                 DrawLM,
  153.                 DrawLMR,
  154.                 DrawLMR,
  155.                 DrawLMR,
  156.                 DrawLM,
  157.                 DrawLMR,
  158.                 DrawLMR,
  159.                 DrawLMR,
  160.                 DrawLM
  161.  
  162. _DATA   ENDS
  163.  
  164. DGROUP  GROUP _DATA
  165.  
  166.  
  167. _TEXT   SEGMENT BYTE PUBLIC USE32 'CODE'
  168.  
  169.         ASSUME  DS:_DATA
  170.         ASSUME  CS:_TEXT
  171.  
  172. PUBLIC  gr_sync_display_
  173.  
  174. gr_sync_display_:
  175.  
  176.         push    ax
  177.         push    dx
  178.         mov     dx, VERT_RESCAN
  179. VS2A:   in      al, dx
  180.         and     al, 08h
  181.         jnz     VS2A        ; Loop until not in vertical retrace
  182. VS2B:   in      al, dx
  183.         and     al, 08h
  184.         jz      VS2B        ; Loop until in vertical retrace
  185.  
  186.         pop     dx
  187.         pop     ax
  188.         ret
  189.  
  190.  
  191. PUBLIC  gr_modex_uscanline_
  192.  
  193. gr_modex_uscanline_:
  194.         push    edi
  195.  
  196.         ; EAX = X1  (X1 and X2 don't need to be sorted)
  197.         ; EDX = X2
  198.         ; EBX = Y
  199.         ; ECX = Color
  200.  
  201.         mov     SavedColor, cl
  202.  
  203.         ;mov     ebx, _RowOffset[ebx*4]
  204.         mov    edi, _gr_var_bwidth
  205.         imul    edi, ebx
  206.         add     edi, 0A0000h
  207.         cmp     eax, edx
  208.         jle     @f
  209.         xchg    eax, edx
  210. @@:     mov     bl, al
  211.         shl     bl, 2
  212.         mov     bh, dl
  213.         and     bh, 011b
  214.         or      bl, bh
  215.         and     ebx, 0fh
  216.         ; BX = LeftRight switch command. (4bit)
  217.         shr     eax, 2
  218.         shr     edx, 2
  219.         add     edi, eax
  220.         ; EDI = Offset into video memory
  221.         mov     ecx, edx
  222.         sub     ecx, eax
  223.         ; ECX = X2/4 - X1/4 - 1
  224.         jnz     LargerThan4
  225.  
  226. ;======================= ONE GROUP OF 4 OR LESS TO DRAW ====================
  227.  
  228.         mov     dx, SC_INDEX
  229.         mov     al, SC_MAP_MASK
  230.         out     dx, al
  231.         inc     dx
  232.         mov     al, MaskTable1[ebx]
  233.         out     dx, al
  234.         mov     al, SavedColor
  235.         mov     [edi], al           ; Write the one pixel
  236.         pop     edi
  237.         ret
  238.  
  239. LargerThan4:
  240.         dec     ecx
  241.         jnz     LargerThan8
  242.  
  243. ;===================== TWO GROUPS OF 4 OR LESS TO DRAW ====================
  244.  
  245.         mov     cx, WORD PTR MaskTable2[ebx*2]
  246.         mov     bl, SavedColor
  247.         mov     dx, SC_INDEX
  248.         mov     al, SC_MAP_MASK
  249.         out     dx, al
  250.         inc     dx
  251.         mov     al, cl
  252.         out     dx, al
  253.         mov     [edi], bl           ; Write the left pixel
  254.         mov     al, ch
  255.         out     dx, al
  256.         mov     [edi+1], bl         ; Write the right pixel
  257.         pop     edi
  258.         ret
  259.  
  260. ;========================= MANY GROUPS OF 4 TO DRAW ======================
  261. LargerThan8:
  262.         mov     dx, SC_INDEX
  263.         mov     al, SC_MAP_MASK
  264.         out     dx, al
  265.         inc     dx
  266.         ; DX = SC_INDEX
  267.         mov     al, SavedColor
  268.         mov     ah, al
  269.         ; AL,AH = color of pixel
  270.         jmp     NEAR32 PTR DrawTable[ebx*4]
  271.  
  272.  
  273. DrawM:  ;AH=COLOR, EDI=DEST, CX=X2/4-X1/4-1, BX=Table Index
  274.         mov     al, ALL_MASK
  275.         out     dx, al
  276.         mov     al, ah
  277.         cld
  278.         add     ecx, 2
  279.         shr     ecx, 1
  280.         rep     stosw       ; Write the middle pixels
  281.         jnc     @F
  282.         stosb               ; Write the middle odd pixel
  283. @@:     pop     edi
  284.         ret
  285.  
  286. DrawLM:
  287.         ;AH=COLOR, EDI=DEST, CX=X2/4-X1/4-1, BX=Table Index
  288.         mov     al, BYTE PTR MaskTable2[ebx*2]
  289.         out     dx, al
  290.         mov     [edi], ah       ; Write leftmost pixels
  291.         inc     edi
  292.         mov     al, ALL_MASK
  293.         out     dx, al
  294.         mov     al, ah
  295.         cld
  296.         inc     ecx
  297.         shr     ecx, 1
  298.         rep     stosw       ; Write the middle pixels
  299.         jnc     @F
  300.         stosb               ; Write the middle odd pixel
  301. @@:     pop     edi
  302.         ret
  303.  
  304.  
  305. DrawLMR: ;AH=COLOR, EDI=DEST, CX=X2/4-X1/4-1, BX=Table Index
  306.         mov     bx, WORD PTR MaskTable2[ebx*2]
  307.         mov     al, bl
  308.         out     dx, al
  309.         mov     [edi], ah       ; Write leftmost pixels
  310.         inc     edi
  311.         mov     al, ALL_MASK
  312.         out     dx, al
  313.         mov     al, ah
  314.         cld
  315.         shr     ecx, 1
  316.         rep     stosw       ; Write the middle pixels
  317.         jnc     @F
  318.         stosb               ; Write the middle odd pixel
  319. @@:     mov     al, bh
  320.         out     dx, al
  321.         mov     [edi], ah   ; Write the rightmost pixels
  322.         pop     edi
  323.         ret
  324.  
  325. DrawMR: ;AH=COLOR, EDI=DEST, CX=X2/4-X1/4-1, BX=Table Index
  326.         mov     bx, WORD PTR MaskTable2[ebx*2]
  327.         mov     al, ALL_MASK
  328.         out     dx, al
  329.         mov     al, ah
  330.         cld
  331.         inc     ecx
  332.         shr     ecx, 1
  333.         rep     stosw       ; Write the middle pixels
  334.         jnc     @F
  335.         stosb               ; Write the middle odd pixel
  336. @@:     mov     al, bh
  337.         out     dx, al
  338.         mov     [edi], ah   ; Write the rightmost pixels
  339.         pop     edi
  340.         ret
  341.  
  342.  
  343. PUBLIC gr_modex_setmode_
  344.  
  345. gr_modex_setmode_:
  346.  
  347.     push  ebx
  348.     push  ecx
  349.     push  edx
  350.     push  esi
  351.     push  edi
  352.  
  353.     mov   ecx, eax
  354.     dec   ecx
  355.  
  356.     cmp   ecx, LAST_X_MODE
  357.     jbe   @f
  358.     mov   ecx, 0
  359. @@:
  360.  
  361.     ;call  turn_screen_off
  362.  
  363.     push  ecx                   ; some bios's dont preserve cx
  364.  
  365.     ;mov ax, 1201h
  366.     ;mov bl, 31h     ; disable palette loading at mode switch
  367.     ;int 10h
  368.     mov   ax,13h                ; let the BIOS set standard 256-color
  369.     int   10h                   ;  mode (320x200 linear)
  370.     ;mov ax, 1200h
  371.     ;mov bl, 31h     ; enable palette loading at mode switch
  372.     ;int 10h
  373.  
  374.     pop   ecx
  375.  
  376.     mov   dx,SC_INDEX
  377.     mov   ax,0604h
  378.     out   dx,ax                 ; disable chain4 mode
  379.  
  380.     mov   dx,SC_INDEX
  381.     mov   ax,0100h
  382.     out   dx,ax                 ; synchronous reset while setting Misc
  383.                                 ;  Output for safety, even though clock
  384.                                 ;  unchanged
  385.  
  386.     mov   esi, dword ptr ModeTable[ecx*4]
  387.     lodsb
  388.  
  389.     or    al,al
  390.     jz    DontSetDot
  391.  
  392.     mov   dx,MISC_OUTPUT
  393.     out   dx,al               ; select the dot clock and Horiz
  394.                               ;  scanning rate
  395.  
  396.     ;mov   dx,SC_INDEX
  397.     ;mov   al,01h
  398.     ;out   dx,al
  399.     ;inc   dx
  400.     ;in    al, dx
  401.     ;or    al, 1000b
  402.     ;out   dx, al
  403.  
  404. DontSetDot:
  405.     mov   dx,SC_INDEX
  406.     mov   ax,0300h
  407.     out   dx,ax        ; undo reset (restart sequencer)
  408.  
  409.     mov   dx,CRTC_INDEX       ; reprogram the CRT Controller
  410.     mov   al,11h              ; VSync End reg contains register write
  411.     out   dx,al               ; protect bit
  412.     inc   dx                  ; CRT Controller Data register
  413.     in    al,dx               ; get current VSync End register setting
  414.     and   al,07fh             ; remove write protect on various
  415.     out   dx,al               ; CRTC registers
  416.     dec   dx                  ; CRT Controller Index
  417.     cld
  418.     xor   ecx,ecx
  419.     lodsb
  420.     mov   cl,al
  421.  
  422. SetCRTParmsLoop:
  423.     lodsw                     ; get the next CRT Index/Data pair
  424.     out   dx,ax               ; set the next CRT Index/Data pair
  425.     loop  SetCRTParmsLoop
  426.  
  427.     mov   dx,SC_INDEX
  428.     mov   ax,0f02h
  429.     out   dx,ax       ; enable writes to all four planes
  430.     mov   edi, 0A0000h        ; point ES:DI to display memory
  431.     xor   ax,ax               ; clear to zero-value pixels
  432.     mov   ecx,8000h           ; # of words in display memory
  433.     rep   stosw               ; clear all of display memory
  434.  
  435.     ;  Set pysical screen dimensions
  436.  
  437.     xor   eax, eax
  438.     lodsw                               ; Load scrn pixel width
  439.     mov   cx, ax
  440.     shl   eax, 16
  441.  
  442.     mov   dx,CRTC_INDEX
  443.     mov   al,CRTC_OFFSET
  444.     out   dx,al
  445.     inc   dx
  446.     mov   ax,cx
  447.     shr   ax,3
  448.     out   dx,al
  449.  
  450.     ;mov     si, 360
  451.     ;@@:
  452.     ;mov     ax, 04f06h
  453.     ;mov     bl, 0
  454.     ;mov     cx, si
  455.     ;int     10h
  456.     ;cmp     cx, si
  457.     ;je      @f
  458.     ;inc     si
  459.     ;jmp     @B
  460.     ;@@:
  461.     ;movzx     eax, si
  462.  
  463.     lodsw                               ; Load Screen Phys. Height
  464.  
  465.     ;call  turn_screen_on
  466.  
  467.     pop  edi
  468.     pop  esi
  469.     pop  edx
  470.     pop  ecx
  471.     pop  ebx
  472.  
  473.     ret
  474.  
  475. PUBLIC gr_modex_setplane_
  476.  
  477. gr_modex_setplane_:
  478.  
  479.         push    cx
  480.         push    dx
  481.  
  482.         mov     cl, al
  483.  
  484.         ; SELECT WRITE PLANE
  485.         and     cl,011b             ;CL = plane
  486.         mov     ax,0100h + MAP_MASK ;AL = index in SC of Map Mask reg
  487.         shl     ah,cl               ;set only the bit for the required
  488.                                     ; plane to 1
  489.         mov     dx,SC_INDEX         ;set the Map Mask to enable only the
  490.        out     dx,ax               ; pixel's plane
  491.  
  492.         ; SELECT READ PLANE
  493.         mov     ah,cl               ;AH = plane
  494.         mov     al,READ_MAP         ;AL = index in GC of the Read Map reg
  495.         mov     dx,GC_INDEX         ;set the Read Map to read the pixel's
  496.         out     dx,ax               ; plane
  497.  
  498.         pop     dx
  499.         pop     cx
  500.  
  501.         ret
  502.  
  503. PUBLIC  gr_modex_setstart_
  504.  
  505. gr_modex_setstart_:
  506.  
  507.         ; EAX = X
  508.         ; EDX = Y
  509.         ; EBX = Wait for retrace
  510.  
  511.         push    ebx
  512.         push    ecx
  513.         push    ebx
  514.  
  515.         mov    ecx, _gr_var_bwidth
  516.         imul    ecx, edx
  517.  
  518.         shr     eax, 2
  519.         add     eax, ecx
  520.  
  521.         mov     ch, ah
  522.         mov     bh, al
  523.  
  524.         mov     bl, CC_START_LO
  525.         mov     cl, CC_START_HI
  526.  
  527.         cli
  528.         mov     dx, VERT_RESCAN
  529. WaitDE: in      al, dx
  530.         test    al, 01h
  531.         jnz     WaitDE
  532.  
  533.         mov     dx, CRTC_INDEX
  534.         mov     ax, bx
  535.         out     dx, ax      ; Start address low
  536.         mov     ax, cx
  537.         out     dx, ax      ; Start address high
  538.         sti
  539.  
  540.         pop    ebx
  541.         cmp    ebx, 0
  542.         je    NoWaitVS
  543.         mov     dx, VERT_RESCAN
  544. WaitVS: in      al, dx
  545.         test    al, 08h
  546.         jz      WaitVS      ; Loop until in vertical retrace
  547. NoWaitVS:
  548.  
  549.         pop     ecx
  550.         pop     ebx
  551.  
  552.         ret
  553.  
  554.  
  555.  
  556.  
  557. ModeXAddr       macro
  558. ; given: ebx=x, eax=y, return cl=plane mask, ebx=address, trash eax
  559.     mov    cl, bl
  560.     and    cl, 3
  561.     shr    ebx, 2
  562.     imul    eax, _gr_var_bwidth 
  563.     add    ebx, eax
  564.     add    ebx, 0A0000h
  565.     endm
  566.  
  567.  
  568. ;-----------------------------------------------------------------------
  569. ;
  570. ; Line drawing function for all MODE X 256 Color resolutions
  571. ; Based on code from "PC and PS/2 Video Systems" by Richard Wilton.
  572.  
  573. PUBLIC gr_modex_line_
  574.  
  575. gr_modex_line_:
  576.     pusha
  577.  
  578.     mov    dx,SC_INDEX    ; setup for plane mask access
  579.  
  580. ; check for vertical line
  581.  
  582.     mov    esi,_gr_var_bwidth
  583.     mov    ecx,_modex_line_x2
  584.     sub    ecx,_modex_line_x1
  585.     jz    VertLine
  586.  
  587. ; force x1 < x2
  588.  
  589.     jns    L01
  590.  
  591.     neg    ecx
  592.  
  593.     mov    ebx,_modex_line_x2
  594.     xchg    ebx,_modex_line_x1
  595.     mov    _modex_line_x2,ebx
  596.  
  597.     mov    ebx,_modex_line_y2
  598.     xchg    ebx,_modex_line_y1
  599.     mov    _modex_line_y2,ebx
  600.  
  601. ; calc dy = abs(y2 - y1)
  602.  
  603. L01:
  604.     mov    ebx,_modex_line_y2
  605.     sub    ebx,_modex_line_y1
  606.     jnz    short skip
  607.     jmp     HorizLine
  608. skip:        jns    L03
  609.  
  610.     neg    ebx
  611.     neg    esi
  612.  
  613. ; select appropriate routine for slope of line
  614.  
  615. L03:
  616.     mov    _modex_line_vertincr,esi
  617.     mov    _modex_line_routine,offset LoSlopeLine
  618.     cmp    ebx,ecx
  619.     jle    L04
  620.     mov    _modex_line_routine,offset HiSlopeLine
  621.     xchg    ebx,ecx
  622.  
  623. ; calc initial decision variable and increments
  624.  
  625. L04:
  626.     shl    ebx,1
  627.     mov    _modex_line_incr1,ebx
  628.     sub    ebx,ecx
  629.     mov    esi,ebx
  630.     sub    ebx,ecx
  631.     mov    _modex_line_incr2,ebx
  632.  
  633. ; calc first pixel address
  634.  
  635.     push    ecx
  636.     mov    eax,_modex_line_y1
  637.     mov    ebx,_modex_line_x1
  638.     ModeXAddr
  639.     mov    edi,ebx
  640.     mov    al,1
  641.     shl    al,cl
  642.     mov    ah,al        ; duplicate nybble
  643.     shl    al,4
  644.     add    ah,al
  645.     mov    bl,ah
  646.     pop    ecx
  647.     inc    ecx
  648.     jmp    [_modex_line_routine]
  649.  
  650. ; routine for verticle lines
  651.  
  652. VertLine:
  653.     mov    eax,_modex_line_y1
  654.     mov    ebx,_modex_line_y2
  655.     mov    ecx,ebx
  656.     sub    ecx,eax
  657.     jge    L31
  658.     neg    ecx
  659.     mov    eax,ebx
  660.  
  661. L31:
  662.     inc    ecx
  663.     mov    ebx,_modex_line_x1
  664.     push    ecx
  665.     ModeXAddr
  666.  
  667.     mov    ah,1
  668.     shl    ah,cl
  669.     mov    al,MAP_MASK
  670.     out    dx,ax
  671.     pop    ecx
  672.     mov    ax, word ptr _modex_line_Color
  673.  
  674. ; draw the line
  675.  
  676. L32:
  677.     mov    [ebx],al
  678.     add    ebx,esi
  679.     loop    L32
  680.     jmp    Lexit
  681.  
  682. ; routine for horizontal line
  683.  
  684. HorizLine:
  685.  
  686.     mov    eax,_modex_line_y1
  687.     mov    ebx,_modex_line_x1
  688.     ModeXAddr
  689.  
  690.     mov    edi,ebx     ; set dl = first byte mask
  691.     mov    dl,00fh
  692.     shl    dl,cl
  693.  
  694.     mov    ecx,_modex_line_x2 ; set dh = last byte mask
  695.     and    cl,3
  696.     mov    dh,00eh
  697.     shl    dh,cl
  698.     not    dh
  699.  
  700. ; determine byte offset of first and last pixel in line
  701.  
  702.     mov    eax,_modex_line_x2
  703.     mov    ebx,_modex_line_x1
  704.  
  705.     shr    eax,2     ; set ax = last byte column
  706.     shr    ebx,2    ; set bx = first byte column
  707.     mov    ecx,eax    ; cx = ax - bx
  708.     sub    ecx,ebx
  709.  
  710.     mov        eax,edx    ; mov end byte masks to ax
  711.     mov    dx,SC_INDEX ; setup dx for VGA outs
  712.     mov     bl,_modex_line_Color
  713.  
  714. ; set pixels in leftmost byte of line
  715.  
  716.     or    ecx,ecx      ; is start and end pt in same byte
  717.     jnz    L42        ; no !
  718.     and    ah,al      ; combine start and end masks
  719.     jmp    short L44
  720.  
  721. L42:            push    eax
  722.     mov     ah,al
  723.     mov     al,MAP_MASK
  724.     out     dx,ax
  725.     mov    al,bl
  726.     stosb
  727.     dec    ecx
  728.  
  729. ; draw remainder of the line
  730.  
  731. L43:
  732.     mov    ah,0Fh
  733.     mov    al,MAP_MASK
  734.     out    dx,ax
  735.     mov    al,bl
  736.     rep    stosb
  737.     pop     eax
  738.  
  739. ; set pixels in rightmost byte of line
  740.  
  741. L44:    
  742.     mov    al,MAP_MASK
  743.     out    dx, ax
  744.     mov     byte ptr [edi],bl
  745.     jmp    Lexit
  746.  
  747.  
  748. ; routine for dy >= dx (slope <= 1)
  749.  
  750. LoSlopeLine:
  751.     mov    al,MAP_MASK
  752.     mov    bh,byte ptr _modex_line_Color
  753. L10:
  754.     mov    ah,bl
  755.  
  756. L11:
  757.     or    ah,bl
  758.     rol    bl,1
  759.     jc    L14
  760.  
  761. ; bit mask not shifted out
  762.  
  763.     or    esi,esi
  764.     jns    L12
  765.     add    esi,_modex_line_incr1
  766.     loop    L11
  767.  
  768.     out    dx,ax
  769.     mov    [edi],bh
  770.     jmp    short Lexit
  771.  
  772. L12:
  773.     add    esi,_modex_line_incr2
  774.     out    dx,ax
  775.     mov    [edi],bh
  776.     add    edi,_modex_line_vertincr
  777.     loop    L10
  778.     jmp    short Lexit
  779.  
  780. ; bit mask shifted out
  781.  
  782. L14:            out    dx,ax
  783.     mov    [edi],bh
  784.     inc    edi
  785.     or    esi,esi
  786.     jns    L15
  787.     add    esi,_modex_line_incr1
  788.     loop    L10
  789.     jmp    short Lexit
  790.  
  791. L15:
  792.     add    esi,_modex_line_incr2
  793.     add    edi,_modex_line_vertincr
  794.     loop    L10
  795.     jmp    short Lexit
  796.  
  797. ; routine for dy > dx (slope > 1)
  798.  
  799. HiSlopeLine:
  800.     mov    ebx,_modex_line_vertincr
  801.     mov    al,MAP_MASK
  802. L21:    out    dx,ax
  803.     push    eax
  804.     mov    al,_modex_line_Color
  805.     mov    [edi],al
  806.     pop    eax
  807.     add    edi,ebx
  808.  
  809. L22:
  810.     or    esi,esi
  811.     jns    L23
  812.  
  813.     add    esi,_modex_line_incr1
  814.     loop    L21
  815.     jmp    short Lexit
  816.  
  817. L23:
  818.     add    esi,_modex_line_incr2
  819.     rol    ah,1
  820.     adc    edi,0
  821. lx21:    loop    L21
  822.  
  823. ; return to caller
  824.  
  825. Lexit:
  826.     popa
  827.     ret
  828.  
  829.  
  830.  
  831. _TEXT   ENDS
  832.  
  833.  
  834.         END
  835. 
  836.