home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 2d / linear.asm < prev    next >
Assembly Source File  |  1998-06-08  |  40KB  |  860 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/2d/rcs/linear.asm $
  13. ; $Revision: 1.20 $
  14. ; $Author: john $
  15. ; $Date: 1994/11/28 17:08:30 $
  16. ;
  17. ; Routines to access linear VGA memory
  18. ;
  19. ; $Log: linear.asm $
  20. ; Revision 1.20  1994/11/28  17:08:30  john
  21. ; Took out some unused functions in linear.asm, moved
  22. ; gr_linear_movsd from linear.asm to bitblt.c, made sure that
  23. ; the code in ibiblt.c sets the direction flags before rep movsing.
  24. ; 
  25. ; Revision 1.19  1994/11/27  22:57:56  john
  26. ; Took out some code that was never called.
  27. ; 
  28. ; Revision 1.18  1994/09/12  14:40:16  john
  29. ; Neatend.
  30. ; 
  31. ; Revision 1.17  1994/07/27  18:30:30  john
  32. ; Took away the blending table.
  33. ; 
  34. ; Revision 1.16  1994/04/08  16:59:28  john
  35. ; Add fading poly's; Made palette fade 32 instead of 16.
  36. ; 
  37. ; Revision 1.15  1993/12/21  20:10:03  john
  38. ; *** empty log message ***
  39. ; 
  40. ; Revision 1.14  1993/12/21  19:58:31  john
  41. ; added selector stuff
  42. ; 
  43. ; Revision 1.13  1993/12/21  11:40:51  john
  44. ; *** empty log message ***
  45. ; 
  46. ; Revision 1.12  1993/12/09  15:01:52  john
  47. ; Changed palette stuff majorly
  48. ; 
  49. ; Revision 1.11  1993/12/08  16:41:02  john
  50. ; *** empty log message ***
  51. ; 
  52. ; Revision 1.10  1993/12/08  11:50:17  john
  53. ; Fixed bug with gr_init
  54. ; 
  55. ; Revision 1.9  1993/12/07  12:32:12  john
  56. ; moved bmd_palette to gr_palette
  57. ; 
  58. ; Revision 1.8  1993/12/03  12:11:25  john
  59. ; *** empty log message ***
  60. ; 
  61. ; Revision 1.7  1993/11/16  11:29:08  john
  62. ; *** empty log message ***
  63. ; 
  64. ; Revision 1.6  1993/10/15  16:22:13  john
  65. ; *** empty log message ***
  66. ; 
  67. ; Revision 1.5  1993/09/29  16:15:28  john
  68. ; added assembler linear_line
  69. ; 
  70. ; Revision 1.4  1993/09/26  18:59:27  john
  71. ; fade stuff
  72. ; 
  73. ; Revision 1.3  1993/09/21  14:00:59  john
  74. ; added code to save 43/50 line text modes.
  75. ; 
  76. ; Revision 1.2  1993/09/16  17:28:06  john
  77. ; added code to save/restore video mode
  78. ; 
  79. ; Revision 1.1  1993/09/08  11:41:30  john
  80. ; Initial revision
  81. ; 
  82. ;
  83. ;
  84.  
  85.  
  86. .386
  87.  
  88.  
  89.  
  90. _DATA   SEGMENT BYTE PUBLIC USE32 'DATA'
  91.  
  92.  
  93. INCLUDE VGAREGS.INC
  94.  
  95.  
  96.         ; Put data here
  97.  
  98.         PUBLIC _gr_var_color
  99.         PUBLIC _gr_var_bitmap
  100.         PUBLIC _gr_var_bwidth
  101.         _gr_var_color   dd  ?
  102.         _gr_var_bitmap  dd  ?
  103.         _gr_var_bwidth  dd  ?
  104.  
  105.         ; Local variables for gr_linear_line_
  106.         AdjUp           dd  ?   ;error term adjust up on each advance
  107.         AdjDown         dd  ?   ;error term adjust down when error term turns over
  108.         WholeStep       dd  ?   ;minimum run length
  109.         XAdvance        dd  ?   ;1 or -1, for direction in which X advances
  110.         XStart          dd  ?
  111.         YStart          dd  ?
  112.         XEnd            dd  ?
  113.         YEnd            dd  ?
  114.  
  115.  
  116. _DATA   ENDS
  117.  
  118. DGROUP  GROUP _DATA
  119.  
  120.  
  121. _TEXT   SEGMENT BYTE PUBLIC USE32 'CODE'
  122.  
  123.         ASSUME  DS:_DATA
  124.         ASSUME  CS:_TEXT
  125.  
  126.         include psmacros.inc
  127.         ; Args passed in EAX, EDX, EBX, ECX
  128.  
  129.  
  130. ; Fast run length slice line drawing implementation for mode 0x13, the VGA's
  131. ; 320x200 256-color mode.
  132. ; Draws a line between the specified endpoints in color Color.
  133.  
  134.  
  135. PUBLIC gr_linear_line_
  136. gr_linear_line_:
  137.  
  138.     cld
  139.  
  140.     push    esi  ;preserve C register variables
  141.     push    edi
  142.     push    ebp
  143.  
  144.     mov     XStart, eax
  145.     mov     YStart, edx
  146.     mov     XEnd, ebx
  147.     mov     YEnd, ecx
  148.  
  149.     mov     ebp, _gr_var_bwidth
  150.  
  151. ; We'll draw top to bottom, to reduce the number of cases we have to handle,
  152. ; and to make lines between the same endpoints always draw the same pixels.
  153.  
  154.     mov     eax,YStart
  155.     cmp     eax,YEnd
  156.     jle     LineIsTopToBottom
  157.     xchg    YEnd, eax    ;swap endpoints
  158.     mov     YStart, eax
  159.     mov     ebx, XStart
  160.     xchg    XEnd, ebx
  161.     mov     XStart, ebx
  162.  
  163. LineIsTopToBottom:
  164.  
  165. ; Point EDI to the first pixel to draw.
  166.     mov     edx,ebp
  167.     mul     edx             ;YStart * ebp
  168.     mov     esi, XStart
  169.     mov     edi, esi
  170.     add     edi, _gr_var_bitmap
  171.     add     edi, eax        ;EDI = YStart * ebp + XStart
  172.                             ; = offset of initial pixel
  173.  
  174. ; Figure out how far we're going vertically (guaranteed to be positive).
  175.     mov     ecx, YEnd
  176.     sub     ecx, YStart     ;ECX = YDelta
  177.  
  178. ; Figure out whether we're going left or right, and how far we're going
  179. ; horizontally. In the process, special-case vertical lines, for speed and
  180. ; to avoid nasty boundary conditions and division by 0.
  181.  
  182.     mov     edx, XEnd
  183.     sub     edx, esi        ;XDelta
  184.     jnz     NotVerticalLine ;XDelta == 0 means vertical line
  185.                             ;it is a vertical line
  186.                             ;yes, special case vertical line
  187.  
  188.     mov     eax, _gr_var_color
  189. VLoop:
  190.     mov     [edi],al
  191.     add     edi,ebp
  192.     dec     ecx
  193.     jns     VLoop
  194.     jmp     Done
  195.  
  196. ; Special-case code for horizontal lines.
  197.  
  198. IsHorizontalLine:
  199.     mov     eax, _gr_var_color
  200.     mov     ah,al           ;duplicate in high byte for word access
  201.     and     ebx,ebx         ;left to right?
  202.     jns     DirSet          ;yes
  203.     sub     edi, edx        ;currently right to left, point to left end so we
  204.                             ; can go left to right (avoids unpleasantness with
  205.                             ; right to left REP STOSW)
  206. DirSet:
  207.     mov     ecx, edx
  208.     inc     ecx             ;# of pixels to draw
  209.  
  210.     shr     ecx, 1          ;# of words to draw
  211.     rep     stosw           ;do as many words as possible
  212.     adc     ecx, ecx
  213.     rep     stosb           ;do the odd byte, if there is one
  214.  
  215.     jmp     Done
  216.  
  217. ; Special-case code for diagonal lines.
  218.  
  219. IsDiagonalLine:
  220.     mov     eax, _gr_var_color
  221.     add     ebx, ebp    ;advance distance from one pixel to next
  222.  
  223. DLoop:
  224.     mov     [edi],al
  225.     add     edi, ebx
  226.     dec     ecx
  227.     jns     DLoop
  228.     jmp     Done
  229.  
  230. NotVerticalLine:
  231.     mov     ebx,1               ;assume left to right, so XAdvance = 1
  232.                                 ;***leaves flags unchanged***
  233.     jns     LeftToRight         ;left to right, all set
  234.     neg     ebx                 ;right to left, so XAdvance = -1
  235.     neg     edx                 ;|XDelta|
  236.  
  237. LeftToRight:
  238. ; Special-case horizontal lines.
  239.  
  240.     and     ecx, ecx            ;YDelta == 0?
  241.     jz      IsHorizontalLine    ;yes
  242.  
  243. ; Special-case diagonal lines.
  244.     cmp     ecx, edx            ;YDelta == XDelta?
  245.     jz      IsDiagonalLine      ;yes
  246.  
  247. ; Determine whether the line is X or Y major, and handle accordingly.
  248.     cmp     edx, ecx
  249.     jae     XMajor
  250.     jmp     YMajor
  251.  
  252. ; X-major (more horizontal than vertical) line.
  253.  
  254. XMajor:
  255.         and     ebx,ebx         ;left to right?
  256.         jns     DFSet           ;yes, CLD is already set
  257.     std                     ;right to left, so draw backwards
  258. DFSet:
  259.         mov     eax,edx         ;XDelta
  260.         sub     edx,edx         ;prepare for division
  261.         div     ecx             ;EAX = XDelta/YDelta
  262.                 ; (minimum # of pixels in a run in this line)
  263.                                 ;EDX = XDelta % YDelta
  264.         mov     ebx,edx         ;error term adjust each time Y steps by 1;
  265.         add     ebx,ebx         ; used to tell when one extra pixel should be
  266.         mov     AdjUp, ebx      ; drawn as part of a run, to account for
  267.                 ; fractional steps along the X axis per
  268.                 ; 1-pixel steps along Y
  269.         mov     esi, ecx        ;error term adjust when the error term turns
  270.         add     esi, esi        ; over, used to factor out the X step made at
  271.         mov     AdjDown, esi    ; that time
  272.  
  273. ; Initial error term; reflects an initial step of 0.5 along the Y axis.
  274.         sub     edx, esi        ;(XDelta % YDelta) - (YDelta * 2)
  275.                 ;DX = initial error term
  276. ; The initial and last runs are partial, because Y advances only 0.5 for
  277. ; these runs, rather than 1. Divide one full run, plus the initial pixel,
  278. ; between the initial and last runs.
  279.         mov     esi, ecx        ;SI = YDelta
  280.         mov     ecx, eax        ;whole step (minimum run length)
  281.         shr     ecx,1
  282.         inc     ecx             ;initial pixel count = (whole step / 2) + 1;
  283.                 ; (may be adjusted later). This is also the
  284.         ; final run pixel count
  285.         push    ecx             ;remember final run pixel count for later
  286. ; If the basic run length is even and there's no fractional advance, we have
  287. ; one pixel that could go to either the initial or last partial run, which
  288. ; we'll arbitrarily allocate to the last run.
  289. ; If there is an odd number of pixels per run, we have one pixel that can't
  290. ; be allocated to either the initial or last partial run, so we'll add 0.5 to
  291. ; the error term so this pixel will be handled by the normal full-run loop.
  292.         add     edx,esi         ;assume odd length, add YDelta to error term
  293.         ; (add 0.5 of a pixel to the error term)
  294.     test    al,1            ;is run length even?
  295.     jnz     XMajorAdjustDone ;no, already did work for odd case, all set
  296.         sub     edx,esi         ;length is even, undo odd stuff we just did
  297.         and     ebx,ebx         ;is the adjust up equal to 0?
  298.     jnz     XMajorAdjustDone ;no (don't need to check for odd length,
  299.                                 ; because of the above test)
  300.         dec     ecx             ;both conditions met; make initial run 1
  301.                 ; shorter
  302.  
  303. XMajorAdjustDone:
  304.         mov     WholeStep,eax   ;whole step (minimum run length)
  305.         mov     eax, _gr_var_color       ;AL = drawing color
  306. ; Draw the first, partial run of pixels.
  307.     rep     stosb           ;draw the final run
  308.         add     edi,ebp ;advance along the minor axis (Y)
  309. ; Draw all full runs.
  310.         cmp     esi,1           ;are there more than 2 scans, so there are
  311.                                 ; some full runs? (SI = # scans - 1)
  312.     jna     XMajorDrawLast  ;no, no full runs
  313.         dec     edx             ;adjust error term by -1 so we can use
  314.                 ; carry test
  315.         shr     esi,1           ;convert from scan to scan-pair count
  316.     jnc     XMajorFullRunsOddEntry  ;if there is an odd number of scans,
  317.                     ; do the odd scan now
  318. XMajorFullRunsLoop:
  319.         mov     ecx, WholeStep  ;run is at least this long
  320.         add     edx,ebx         ;advance the error term and add an extra
  321.     jnc     XMajorNoExtra   ; pixel if the error term so indicates
  322.         inc     ecx             ;one extra pixel in run
  323.         sub     edx,AdjDown     ;reset the error term
  324. XMajorNoExtra:
  325.         rep     stosb           ;draw this scan line's run
  326.         add     edi,ebp ;advance along the minor axis (Y)
  327. XMajorFullRunsOddEntry:         ;enter loop here if there is an odd number
  328.                 ; of full runs
  329.         mov     ecx,WholeStep   ;run is at least this long
  330.         add     edx,ebx         ;advance the error term and add an extra
  331.     jnc     XMajorNoExtra2  ; pixel if the error term so indicates
  332.         inc     ecx             ;one extra pixel in run
  333.         sub     edx,AdjDown     ;reset the error term
  334. XMajorNoExtra2:
  335.         rep     stosb           ;draw this scan line's run
  336.         add     edi,ebp ;advance along the minor axis (Y)
  337.  
  338.         dec     esi
  339.     jnz     XMajorFullRunsLoop
  340. ; Draw the final run of pixels.
  341. XMajorDrawLast:
  342.         pop     ecx             ;get back the final run pixel length
  343.     rep     stosb           ;draw the final run
  344.  
  345.     cld                     ;restore normal direction flag
  346.     jmp     Done
  347. ; Y-major (more vertical than horizontal) line.
  348. YMajor:
  349.         mov     XAdvance,ebx    ;remember which way X advances
  350.         mov     eax,ecx         ;YDelta
  351.         mov     ecx,edx         ;XDelta
  352.         sub     edx,edx         ;prepare for division
  353.         div     ecx             ;EAX = YDelta/XDelta
  354.                 ; (minimum # of pixels in a run in this line)
  355.                                 ;EDX = YDelta % XDelta
  356.         mov     ebx,edx         ;error term adjust each time X steps by 1;
  357.         add     ebx,ebx         ; used to tell when one extra pixel should be
  358.         mov     AdjUp,ebx       ; drawn as part of a run, to account for
  359.                 ; fractional steps along the Y axis per
  360.                 ; 1-pixel steps along X
  361.         mov     esi,ecx         ;error term adjust when the error term turns
  362.         add     esi,esi         ; over, used to factor out the Y step made at
  363.         mov     AdjDown, esi    ; that time
  364.  
  365. ; Initial error term; reflects an initial step of 0.5 along the X axis.
  366.         sub     edx,esi         ;(YDelta % XDelta) - (XDelta * 2)
  367.                 ;DX = initial error term
  368. ; The initial and last runs are partial, because X advances only 0.5 for
  369. ; these runs, rather than 1. Divide one full run, plus the initial pixel,
  370. ; between the initial and last runs.
  371.         mov     esi,ecx         ;SI = XDelta
  372.         mov     ecx,eax         ;whole step (minimum run length)
  373.         shr     ecx,1
  374.         inc     ecx             ;initial pixel count = (whole step / 2) + 1;
  375.                 ; (may be adjusted later)
  376.         push    ecx             ;remember final run pixel count for later
  377.  
  378. ; If the basic run length is even and there's no fractional advance, we have
  379. ; one pixel that could go to either the initial or last partial run, which
  380. ; we'll arbitrarily allocate to the last run.
  381. ; If there is an odd number of pixels per run, we have one pixel that can't
  382. ; be allocated to either the initial or last partial run, so we'll add 0.5 to
  383. ; the error term so this pixel will be handled by the normal full-run loop.
  384.         add     edx,esi         ;assume odd length, add XDelta to error term
  385.     test    al,1            ;is run length even?
  386.     jnz     YMajorAdjustDone ;no, already did work for odd case, all set
  387.         sub     edx,esi         ;length is even, undo odd stuff we just did
  388.         and     ebx,ebx         ;is the adjust up equal to 0?
  389.     jnz     YMajorAdjustDone ;no (don't need to check for odd length,
  390.          ; because of the above test)
  391.         dec     ecx             ;both conditions met; make initial run 1
  392.                 ; shorter
  393. YMajorAdjustDone:
  394.         mov     WholeStep,eax   ;whole step (minimum run length)
  395.         mov     eax,_gr_var_color        ;AL = drawing color
  396.         mov     ebx, XAdvance   ;which way X advances
  397.  
  398. ; Draw the first, partial run of pixels.
  399. YMajorFirstLoop:
  400.         mov     [edi],al        ;draw the pixel
  401.         add     edi,ebp ;advance along the major axis (Y)
  402.         dec     ecx
  403.     jnz     YMajorFirstLoop
  404.         add     edi,ebx           ;advance along the minor axis (X)
  405. ; Draw all full runs.
  406.         cmp     esi,1            ;# of full runs. Are there more than 2
  407.         ; columns, so there are some full runs?
  408.         ; (SI = # columns - 1)
  409.     jna     YMajorDrawLast  ;no, no full runs
  410.         dec     edx              ;adjust error term by -1 so we can use
  411.                 ; carry test
  412.         shr     esi,1            ;convert from column to column-pair count
  413.     jnc     YMajorFullRunsOddEntry  ;if there is an odd number of
  414.                     ; columns, do the odd column now
  415. YMajorFullRunsLoop:
  416.         mov     ecx,WholeStep   ;run is at least this long
  417.         add     edx,AdjUp       ;advance the error term and add an extra
  418.     jnc     YMajorNoExtra   ; pixel if the error term so indicates
  419.         inc     ecx              ;one extra pixel in run
  420.         sub     edx,AdjDown     ;reset the error term
  421. YMajorNoExtra:
  422.                 ;draw the run
  423. YMajorRunLoop:
  424.         mov     [edi],al        ;draw the pixel
  425.         add     edi,ebp ;advance along the major axis (Y)
  426.         dec     ecx
  427.     jnz     YMajorRunLoop
  428.         add     edi,ebx         ;advance along the minor axis (X)
  429. YMajorFullRunsOddEntry:         ;enter loop here if there is an odd number
  430.                 ; of full runs
  431.         mov     ecx,WholeStep   ;run is at least this long
  432.         add     edx,AdjUp       ;advance the error term and add an extra
  433.     jnc     YMajorNoExtra2  ; pixel if the error term so indicates
  434.         inc     ecx              ;one extra pixel in run
  435.         sub     edx, AdjDown    ;reset the error term
  436. YMajorNoExtra2:
  437.                 ;draw the run
  438. YMajorRunLoop2:
  439.         mov     [edi],al         ;draw the pixel
  440.         add     edi,ebp ;advance along the major axis (Y)
  441.         dec     ecx
  442.     jnz     YMajorRunLoop2
  443.         add     edi,ebx           ;advance along the minor axis (X)
  444.  
  445.         dec     esi
  446.     jnz     YMajorFullRunsLoop
  447. ; Draw the final run of pixels.
  448. YMajorDrawLast:
  449.         pop     ecx              ;get back the final run pixel length
  450. YMajorLastLoop:
  451.         mov     [edi],al         ;draw the pixel
  452.         add     edi,ebp ;advance along the major axis (Y)
  453.         dec     ecx
  454.     jnz     YMajorLastLoop
  455. Done:
  456.     pop ebp
  457.     pop edi
  458.     pop esi  ;restore C register variables
  459.     ret
  460.  
  461. PUBLIC gr_linear_stosd_
  462.  
  463. gr_linear_stosd_:
  464.  
  465.             ; EAX -> Destination buffer
  466.             ; EDX -> Byte to store
  467.             ; EBX -> Number of bytes to move
  468.  
  469.             push    ecx
  470.             push    edi
  471.             mov     edi, eax
  472.             mov     dh, dl
  473.             mov     ax, dx
  474.             shl     eax, 16
  475.             mov     ax, dx
  476.             cld
  477.             mov     ecx, ebx
  478.             shr     ecx, 2
  479.             rep     stosd
  480.             mov     ecx, ebx
  481.             and     ecx, 011b
  482.             rep     stosb
  483.             pop     edi
  484.             pop     ecx
  485.             ret
  486.  
  487. PUBLIC gr_update_buffer_
  488.  
  489. gr_update_buffer_:
  490.  
  491.         ; EAX = Latest source buffer
  492.         ; EDX = Earlier source buffer
  493.         ; EBX = Dest source buffer
  494.         ; ECX = Size of buffer
  495.  
  496.  
  497.         push    esi
  498.         push    edi
  499.         push    ebp
  500.         cld
  501.  
  502.         mov     esi, eax
  503.         mov     edi, edx
  504.  
  505.         mov     ebp, esi
  506.         shr     ecx, 2
  507.  
  508. FindNextMismatch:
  509.         repe    cmpsd
  510.  
  511.         mov     eax, [esi-4]
  512.  
  513.         mov     edx, ebx
  514.         add     edx, esi
  515.         sub     edx, ebp
  516.         mov     [edx], eax       ; EDX = dest + size - bytes to end
  517.  
  518.         cmp     ecx, 0
  519.         jne     FindNextMismatch
  520.  
  521. Done11:
  522.         pop     ebp
  523.         pop     edi
  524.         pop     esi
  525.         ret
  526.  
  527.  
  528. ;--NOT USED!!-- X0  dd  ?               ;X coordinate of line start point
  529. ;--NOT USED!!-- Y0  dd  ?               ;Y coordinate of line start point
  530. ;--NOT USED!!-- X1  dd  ?               ;X coordinate of line end point
  531. ;--NOT USED!!-- Y1  dd  ?               ;Y coordinate of line end point
  532. ;--NOT USED!!-- BaseColor db    ?       ;color # of first color in block used for
  533. ;--NOT USED!!--                                                 ; antialiasing, the 100% intensity version of the
  534. ;--NOT USED!!--                                                 ; drawing color
  535. ;--NOT USED!!-- NumLevels db    16      ;size of color block, with BaseColor+NumLevels-1
  536. ;--NOT USED!!--                                                 ; being the 0% intensity version of the drawing color
  537. ;--NOT USED!!--                                                 ; (maximum NumLevels = 256)
  538. ;--NOT USED!!-- IntensityBits db 4      ;log base 2 of NumLevels; the # of bits used to
  539. ;--NOT USED!!--                                                 ; describe the intensity of the drawing color.
  540. ;--NOT USED!!--                                                 ; 2**IntensityBits==NumLevels
  541. ;--NOT USED!!--                                                 ; (maximum IntensityBits = 8)
  542. ;--NOT USED!!-- ; C near-callable function to draw an antialiased line from
  543. ;--NOT USED!!-- ; (X0,Y0) to (X1,Y1), in mode 13h, the VGA's standard 320x200 256-color
  544. ;--NOT USED!!-- ; mode. Uses an antialiasing approach published by Xiaolin Wu in the July
  545. ;--NOT USED!!-- ; 1991 issue of Computer Graphics. Requires that the palette be set up so
  546. ;--NOT USED!!-- ; that there are NumLevels intensity levels of the desired drawing color,
  547. ;--NOT USED!!-- ; starting at color BaseColor (100% intensity) and followed by (NumLevels-1)
  548. ;--NOT USED!!-- ; levels of evenly decreasing intensity, with color (BaseColor+NumLevels-1)
  549. ;--NOT USED!!-- ; being 0% intensity of the desired drawing color (black). No clipping is
  550. ;--NOT USED!!-- ; performed in DrawWuLine. Handles a maximum of 256 intensity levels per
  551. ;--NOT USED!!-- ; antialiased color. This code is suitable for use at screen resolutions,
  552. ;--NOT USED!!-- ; with lines typically no more than 1K long; for longer lines, 32-bit error
  553. ;--NOT USED!!-- ; arithmetic must be used to avoid problems with fixed-point inaccuracy.
  554. ;--NOT USED!!-- ; Tested with TASM 3.0.
  555. ;--NOT USED!!-- ;
  556. ;--NOT USED!!-- ; C near-callable as:
  557. ;--NOT USED!!-- ;   void DrawWuLine(int X0, int Y0, int X1, int Y1, int BaseColor,
  558. ;--NOT USED!!-- ;       int NumLevels, unsigned int IntensityBits);
  559. ;--NOT USED!!-- 
  560. ;--NOT USED!!-- SCREEN_WIDTH_IN_BYTES equ 320   ;# of bytes from the start of one scan line
  561. ;--NOT USED!!--                                                                 ; to the start of the next
  562. ;--NOT USED!!-- SCREEN_SEGMENT  equ 0a000h  ;segment in which screen memory resides
  563. ;--NOT USED!!-- 
  564. ;--NOT USED!!-- ; Parameters passed in stack frame.
  565. ;--NOT USED!!-- 
  566. ;--NOT USED!!-- 
  567. ;--NOT USED!!--                 ;_gr_var_color, _gr_var_bitmap, _gr_var_bwidth
  568. ;--NOT USED!!-- 
  569. ;--NOT USED!!--                 public  gr_linear_aaline_
  570. ;--NOT USED!!-- gr_linear_aaline_:
  571. ;--NOT USED!!-- 
  572. ;--NOT USED!!--                 push    ebp
  573. ;--NOT USED!!--                 push    esi  ;preserve C's register variables
  574. ;--NOT USED!!--                 push    edi
  575. ;--NOT USED!!--                 cld     ;make string instructions increment their pointers
  576. ;--NOT USED!!-- 
  577. ;--NOT USED!!--                 mov     X0, eax
  578. ;--NOT USED!!--                 mov     Y0, edx
  579. ;--NOT USED!!--                 mov     X1, ebx
  580. ;--NOT USED!!--                 mov     Y1, ecx
  581. ;--NOT USED!!-- 
  582. ;--NOT USED!!--                 mov     eax, _gr_var_color
  583. ;--NOT USED!!--                 mov     BaseColor, al
  584. ;--NOT USED!!-- 
  585. ;--NOT USED!!-- ; Make sure the line runs top to bottom.
  586. ;--NOT USED!!--                 mov     esi,X0
  587. ;--NOT USED!!--                 mov     eax,Y0
  588. ;--NOT USED!!--                 cmp     eax,Y1       ;swap endpoints if necessary to ensure that
  589. ;--NOT USED!!--                 jna     NoSwap      ; Y0 <= Y1
  590. ;--NOT USED!!--                 xchg    Y1,eax
  591. ;--NOT USED!!--                 mov     Y0,eax
  592. ;--NOT USED!!--                 xchg    X1,esi
  593. ;--NOT USED!!--                 mov     X0,esi
  594. ;--NOT USED!!-- NoSwap:
  595. ;--NOT USED!!-- 
  596. ;--NOT USED!!-- ; Draw the initial pixel, which is always exactly intersected by the line
  597. ;--NOT USED!!-- ; and so needs no weighting.
  598. ;--NOT USED!!-- 
  599. ;--NOT USED!!--                 mov     edx,_gr_var_bwidth
  600. ;--NOT USED!!--                 mul     edx         ;Y0 * SCREEN_WIDTH_IN_BYTES yields the offset
  601. ;--NOT USED!!--                                                         ; of the start of the row start the initial
  602. ;--NOT USED!!--                                                         ; pixel is on
  603. ;--NOT USED!!--                 add     esi,eax         ;point DS:SI to the initial pixel
  604. ;--NOT USED!!--                 add     esi,_gr_var_bitmap
  605. ;--NOT USED!!--                 mov     al, BaseColor ;color with which to draw
  606. ;--NOT USED!!--                 mov     [esi],al     ;draw the initial pixel
  607. ;--NOT USED!!-- 
  608. ;--NOT USED!!--                 mov     ebx,1        ;XDir = 1; assume DeltaX >= 0
  609. ;--NOT USED!!--                 mov     ecx,X1
  610. ;--NOT USED!!--                 sub     ecx,X0  ;DeltaX; is it >= 1?
  611. ;--NOT USED!!--                 jns     DeltaXSet   ;yes, move left->right, all set
  612. ;--NOT USED!!--                                                                 ;no, move right->left
  613. ;--NOT USED!!--                 neg     ecx      ;make DeltaX positive
  614. ;--NOT USED!!--                 neg     ebx      ;XDir = -1
  615. ;--NOT USED!!-- DeltaXSet:
  616. ;--NOT USED!!-- 
  617. ;--NOT USED!!-- ; Special-case horizontal, vertical, and diagonal lines, which require no
  618. ;--NOT USED!!-- ; weighting because they go right through the center of every pixel.
  619. ;--NOT USED!!--                 mov     edx,Y1
  620. ;--NOT USED!!--                 sub     edx,Y0  ;DeltaY; is it 0?
  621. ;--NOT USED!!--                 jnz     NotHorz     ;no, not horizontal
  622. ;--NOT USED!!--                                                                 ;yes, is horizontal, special case
  623. ;--NOT USED!!--                 and     ebx,ebx       ;draw from left->right?
  624. ;--NOT USED!!--                 jns     DoHorz      ;yes, all set
  625. ;--NOT USED!!--                 std         ;no, draw right->left
  626. ;--NOT USED!!-- DoHorz:
  627. ;--NOT USED!!--                 lea     edi,[ebx+esi]  ;point DI to next pixel to draw
  628. ;--NOT USED!!--                                                                 ;point ES:DI to next pixel to draw
  629. ;--NOT USED!!--                 mov     al,BaseColor ;color with which to draw
  630. ;--NOT USED!!--                                                                 ;CX = DeltaX at this point
  631. ;--NOT USED!!--                 rep     stosb       ;draw the rest of the horizontal line
  632. ;--NOT USED!!--                 cld                 ;restore default direction flag
  633. ;--NOT USED!!--                 jmp     DoneAA        ;and we're done
  634. ;--NOT USED!!-- 
  635. ;--NOT USED!!-- NotHorz:
  636. ;--NOT USED!!--                 and     ecx,ecx       ;is DeltaX 0?
  637. ;--NOT USED!!--                 jnz     NotVert     ;no, not a vertical line
  638. ;--NOT USED!!--                                                                 ;yes, is vertical, special case
  639. ;--NOT USED!!--                 mov     al,BaseColor ;color with which to draw
  640. ;--NOT USED!!-- VertLoop:
  641. ;--NOT USED!!--                 add     esi,_gr_var_bwidth ;point to next pixel to draw
  642. ;--NOT USED!!--                 mov     [esi], al     ;draw the next pixel
  643. ;--NOT USED!!--                 dec     edx           ;--DeltaY
  644. ;--NOT USED!!--                 jnz     VertLoop
  645. ;--NOT USED!!--                 jmp     DoneAA        ;and we're done
  646. ;--NOT USED!!-- 
  647. ;--NOT USED!!-- NotVert:
  648. ;--NOT USED!!--                 cmp     ecx,edx       ;DeltaX == DeltaY?
  649. ;--NOT USED!!--                 jnz     NotDiag     ;no, not diagonal
  650. ;--NOT USED!!--                                                                 ;yes, is diagonal, special case
  651. ;--NOT USED!!--                 mov     al,BaseColor ;color with which to draw
  652. ;--NOT USED!!-- DiagLoop:
  653. ;--NOT USED!!--                 lea     esi,[esi+ebx]
  654. ;--NOT USED!!--                 add     esi,_gr_var_bwidth
  655. ;--NOT USED!!--                                                                 ;advance to next pixel to draw by
  656. ;--NOT USED!!--                                                                 ; incrementing Y and adding XDir to X
  657. ;--NOT USED!!--                 mov     [esi],al     ;draw the next pixel
  658. ;--NOT USED!!--                 dec     edx      ;--DeltaY
  659. ;--NOT USED!!--                 jnz     DiagLoop
  660. ;--NOT USED!!--                 jmp     DoneAA        ;and we're done
  661. ;--NOT USED!!-- 
  662. ;--NOT USED!!-- ; Line is not horizontal, diagonal, or vertical.
  663. ;--NOT USED!!-- NotDiag:
  664. ;--NOT USED!!-- ; Is this an X-major or Y-major line?
  665. ;--NOT USED!!--                 cmp     edx,ecx
  666. ;--NOT USED!!--                 jb      XMajorAA          ;it's X-major
  667. ;--NOT USED!!-- 
  668. ;--NOT USED!!-- ; It's a Y-major line. Calculate the 16-bit fixed-point fractional part of a
  669. ;--NOT USED!!-- ; pixel that X advances each time Y advances 1 pixel, truncating the result
  670. ;--NOT USED!!-- ; to avoid overrunning the endpoint along the X axis.
  671. ;--NOT USED!!--                 xchg    edx,ecx       ;DX = DeltaX, CX = DeltaY
  672. ;--NOT USED!!--                 sub     ax,ax       ;make DeltaX 16.16 fixed-point value in DX:AX
  673. ;--NOT USED!!--                 div     cx      ;AX = (DeltaX << 16) / DeltaY. Won't overflow
  674. ;--NOT USED!!--                                                                 ; because DeltaX < DeltaY
  675. ;--NOT USED!!--                 mov     di,cx       ;DI = DeltaY (loop count)
  676. ;--NOT USED!!--                 sub     esi,ebx       ;back up the start X by 1, as explained below
  677. ;--NOT USED!!--                 mov     dx,-1       ;initialize the line error accumulator to -1,
  678. ;--NOT USED!!--                                                                 ; so that it will turn over immediately and
  679. ;--NOT USED!!--                                                                 ; advance X to the start X. This is necessary
  680. ;--NOT USED!!--                                                                 ; properly to bias error sums of 0 to mean
  681. ;--NOT USED!!--                                                                 ; "advance next time" rather than "advance
  682. ;--NOT USED!!--                                                                 ; this time," so that the final error sum can
  683. ;--NOT USED!!--                                                                 ; never cause drawing to overrun the final X
  684. ;--NOT USED!!--                                                                 ; coordinate (works in conjunction with
  685. ;--NOT USED!!--                                                                 ; truncating ErrorAdj, to make sure X can't
  686. ;--NOT USED!!--                                                                 ; overrun)
  687. ;--NOT USED!!--                 mov     cl,8           ;CL = # of bits by which to shift
  688. ;--NOT USED!!--                 sub     cl,IntensityBits   ; ErrorAcc to get intensity level (8
  689. ;--NOT USED!!--                                                                                 ; instead of 16 because we work only
  690. ;--NOT USED!!--                                                                                 ; with the high byte of ErrorAcc)
  691. ;--NOT USED!!--                 mov     ch,NumLevels ;mask used to flip all bits in an
  692. ;--NOT USED!!--                 dec     ch             ; intensity weighting, producing
  693. ;--NOT USED!!--                                                                                    ; result (1 - intensity weighting)
  694. ;--NOT USED!!--                 mov     bp, ax
  695. ;--NOT USED!!--                 mov     al, BaseColor
  696. ;--NOT USED!!--                          ;BP = ErrorAdj, AL = BaseColor,
  697. ;--NOT USED!!--                          ; AH = scratch register
  698. ;--NOT USED!!-- 
  699. ;--NOT USED!!-- 
  700. ;--NOT USED!!-- 
  701. ;--NOT USED!!-- ; Draw all remaining pixels.
  702. ;--NOT USED!!-- YMajorLoop:
  703. ;--NOT USED!!--                 add     dx,bp           ;calculate error for next pixel
  704. ;--NOT USED!!--                         jnc     NoXAdvance              ;not time to step in X yet
  705. ;--NOT USED!!--                                                                                                                                                                 ;the error accumulator turned over,
  706. ;--NOT USED!!--                                                                                                                                                                 ; so advance the X coord
  707. ;--NOT USED!!--                                 add     esi,ebx                   ;add XDir to the pixel pointer
  708. ;--NOT USED!!-- NoXAdvance:
  709. ;--NOT USED!!--                                 add     esi,_gr_var_bwidth ;Y-major, so always advance Y
  710. ;--NOT USED!!-- 
  711. ;--NOT USED!!-- ; The IntensityBits most significant bits of ErrorAcc give us the intensity
  712. ;--NOT USED!!-- ; weighting for this pixel, and the complement of the weighting for the
  713. ;--NOT USED!!-- ; paired pixel.
  714. ;--NOT USED!!--                 mov     ah,dh   ;msb of ErrorAcc
  715. ;--NOT USED!!--                 shr     ah,cl   ;Weighting = ErrorAcc >> IntensityShift;
  716. ;--NOT USED!!--                 ;add     ah,al   ;BaseColor + Weighting
  717. ;--NOT USED!!-- 
  718. ;--NOT USED!!--                 ; Make ah =   _gr_fade_table + BaseColor+(15-ah)*256
  719. ;--NOT USED!!--                 push    ecx
  720. ;--NOT USED!!--                 push    ebx
  721. ;--NOT USED!!--                 mov     ebx, 15
  722. ;--NOT USED!!--                 sub     bl, ah
  723. ;--NOT USED!!--                 shl     ebx, 8
  724. ;--NOT USED!!--                 movzx   ecx, BaseColor
  725. ;--NOT USED!!--                 add     ebx, ecx
  726. ;--NOT USED!!--                 add     ebx, offset _gr_fade_table
  727. ;--NOT USED!!--                 mov     ah, [ebx]
  728. ;--NOT USED!!--                 pop     ebx
  729. ;--NOT USED!!--                 pop     ecx
  730. ;--NOT USED!!-- 
  731. ;--NOT USED!!--                 mov     [esi],ah ;DrawPixel(X, Y, BaseColor + Weighting);
  732. ;--NOT USED!!-- 
  733. ;--NOT USED!!--                 mov     ah,dh   ;msb of ErrorAcc
  734. ;--NOT USED!!--                 shr     ah,cl   ;Weighting = ErrorAcc >> IntensityShift;
  735. ;--NOT USED!!--                 xor     ah,ch   ;Weighting ^ WeightingComplementMask
  736. ;--NOT USED!!--                 ;add     ah,al   ;BaseColor + (Weighting ^ WeightingComplementMask)
  737. ;--NOT USED!!-- 
  738. ;--NOT USED!!--                 ; Make ah =   _gr_fade_table + BaseColor+(15-ah)*256
  739. ;--NOT USED!!--                 push    ecx
  740. ;--NOT USED!!--                 push    ebx
  741. ;--NOT USED!!--                 mov     ebx, 15
  742. ;--NOT USED!!--                 sub     bl, 0
  743. ;--NOT USED!!--                 shl     ebx, 8
  744. ;--NOT USED!!--                 movzx   ecx, BaseColor
  745. ;--NOT USED!!--                 add     ebx, ecx
  746. ;--NOT USED!!--                 add     ebx, offset _gr_fade_table
  747. ;--NOT USED!!--                 mov     ah, [ebx]
  748. ;--NOT USED!!--                 pop     ebx
  749. ;--NOT USED!!--                 pop     ecx
  750. ;--NOT USED!!-- 
  751. ;--NOT USED!!-- 
  752. ;--NOT USED!!--                 mov     [esi+ebx],ah ;DrawPixel(X+XDir, Y,
  753. ;--NOT USED!!--                                                 ; BaseColor + (Weighting ^ WeightingComplementMask));
  754. ;--NOT USED!!--                 dec     di  ;--DeltaY
  755. ;--NOT USED!!--                 jnz     YMajorLoop
  756. ;--NOT USED!!--                 jmp     DoneAA    ;we're done with this line
  757. ;--NOT USED!!-- 
  758. ;--NOT USED!!-- ; It's an X-major line.
  759. ;--NOT USED!!-- XMajorAA:
  760. ;--NOT USED!!-- ; Calculate the 16-bit fixed-point fractional part of a pixel that Y advances
  761. ;--NOT USED!!-- ; each time X advances 1 pixel, truncating the result to avoid overrunning
  762. ;--NOT USED!!-- ; the endpoint along the X axis.
  763. ;--NOT USED!!--                 sub     eax,eax       ;make DeltaY 16.16 fixed-point value in DX:AX
  764. ;--NOT USED!!--                 div     ecx      ;AX = (DeltaY << 16) / Deltax. Won't overflow
  765. ;--NOT USED!!--                                                                 ; because DeltaY < DeltaX
  766. ;--NOT USED!!--                 mov     edi,ecx       ;DI = DeltaX (loop count)
  767. ;--NOT USED!!--                 sub     esi,_gr_var_bwidth ;back up the start X by 1, as
  768. ;--NOT USED!!--                                                                 ; explained below
  769. ;--NOT USED!!--                 mov     edx,-1       ;initialize the line error accumulator to -1,
  770. ;--NOT USED!!--                                                                 ; so that it will turn over immediately and
  771. ;--NOT USED!!--                                                                 ; advance Y to the start Y. This is necessary
  772. ;--NOT USED!!--                                                                 ; properly to bias error sums of 0 to mean
  773. ;--NOT USED!!--                                                                 ; "advance next time" rather than "advance
  774. ;--NOT USED!!--                                                                 ; this time," so that the final error sum can
  775. ;--NOT USED!!--                                                                 ; never cause drawing to overrun the final Y
  776. ;--NOT USED!!--                                                                 ; coordinate (works in conjunction with
  777. ;--NOT USED!!--                                                                 ; truncating ErrorAdj, to make sure Y can't
  778. ;--NOT USED!!--                                                                 ; overrun)
  779. ;--NOT USED!!--                 mov     cl,8            ;CL = # of bits by which to shift
  780. ;--NOT USED!!--                 sub     cl,IntensityBits   ; ErrorAcc to get intensity level (8
  781. ;--NOT USED!!--                                                                                 ; instead of 16 because we work only
  782. ;--NOT USED!!--                                                                                 ; with the high byte of ErrorAcc)
  783. ;--NOT USED!!--                 mov     ch,NumLevels ;mask used to flip all bits in an
  784. ;--NOT USED!!--                 dec     ch             ; intensity weighting, producing
  785. ;--NOT USED!!--                                                                                    ; result (1 - intensity weighting)
  786. ;--NOT USED!!-- 
  787. ;--NOT USED!!--                 mov     ebp, eax
  788. ;--NOT USED!!--                 mov     al, BaseColor
  789. ;--NOT USED!!-- 
  790. ;--NOT USED!!-- ; Draw all remaining pixels.
  791. ;--NOT USED!!-- XMajorLoop:
  792. ;--NOT USED!!--                 add     edx,ebp           ;calculate error for next pixel
  793. ;--NOT USED!!--                         jnc     NoYAdvance              ;not time to step in Y yet
  794. ;--NOT USED!!--                                                                                                                                                                 ;the error accumulator turned over,
  795. ;--NOT USED!!--                                                                                                                                                                 ; so advance the Y coord
  796. ;--NOT USED!!--                                 add     esi,_gr_var_bwidth ;advance Y
  797. ;--NOT USED!!-- NoYAdvance:
  798. ;--NOT USED!!--                                 add     esi,ebx       ;X-major, so add XDir to the pixel pointer
  799. ;--NOT USED!!-- 
  800. ;--NOT USED!!-- ; The IntensityBits most significant bits of ErrorAcc give us the intensity
  801. ;--NOT USED!!-- ; weighting for this pixel, and the complement of the weighting for the
  802. ;--NOT USED!!-- ; paired pixel.
  803. ;--NOT USED!!--                 mov     ah,dh   ;msb of ErrorAcc
  804. ;--NOT USED!!--                 shr     ah,cl   ;Weighting = ErrorAcc >> IntensityShift;
  805. ;--NOT USED!!--                 ;add     ah,al   ;BaseColor + Weighting
  806. ;--NOT USED!!-- 
  807. ;--NOT USED!!--                 ; Make ah =   _gr_fade_table + BaseColor+(15-ah)*256
  808. ;--NOT USED!!--                 push    ecx
  809. ;--NOT USED!!--                 push    ebx
  810. ;--NOT USED!!--                 mov     ebx, 15
  811. ;--NOT USED!!--                 sub     bl, ah
  812. ;--NOT USED!!--                 shl     ebx, 8
  813. ;--NOT USED!!--                 movzx   ecx, BaseColor
  814. ;--NOT USED!!--                 add     ebx, ecx
  815. ;--NOT USED!!--                 add     ebx, offset _gr_fade_table
  816. ;--NOT USED!!--                 mov     ah, [ebx]
  817. ;--NOT USED!!--                 pop     ebx
  818. ;--NOT USED!!--                 pop     ecx
  819. ;--NOT USED!!-- 
  820. ;--NOT USED!!-- 
  821. ;--NOT USED!!--                 mov     [esi],ah ;DrawPixel(X, Y, BaseColor + Weighting);
  822. ;--NOT USED!!--                 mov     ah,dh   ;msb of ErrorAcc
  823. ;--NOT USED!!--                 shr     ah,cl   ;Weighting = ErrorAcc >> IntensityShift;
  824. ;--NOT USED!!--                 xor     ah,ch   ;Weighting ^ WeightingComplementMask
  825. ;--NOT USED!!--                 ;add     ah,al   ;BaseColor + (Weighting ^ WeightingComplementMask)
  826. ;--NOT USED!!--                 add     esi, _gr_var_bwidth
  827. ;--NOT USED!!-- 
  828. ;--NOT USED!!--                 ; Make ah =   _gr_fade_table + BaseColor+(15-ah)*256
  829. ;--NOT USED!!--                 push    ecx
  830. ;--NOT USED!!--                 push    ebx
  831. ;--NOT USED!!--                 mov     ebx, 15
  832. ;--NOT USED!!--                 sub     bl, ah
  833. ;--NOT USED!!--                 shl     ebx, 8
  834. ;--NOT USED!!--                 movzx   ecx, BaseColor
  835. ;--NOT USED!!--                 add     ebx, ecx
  836. ;--NOT USED!!--                 add     ebx, offset _gr_fade_table
  837. ;--NOT USED!!--                 mov     ah, [ebx]
  838. ;--NOT USED!!--                 pop     ebx
  839. ;--NOT USED!!--                 pop     ecx
  840. ;--NOT USED!!-- 
  841. ;--NOT USED!!-- 
  842. ;--NOT USED!!--                 mov     [esi],ah    ;DrawPixel(X, Y+SCREEN_WIDTH_IN_BYTES,
  843. ;--NOT USED!!--                                                 ; BaseColor + (Weighting ^ WeightingComplementMask));
  844. ;--NOT USED!!--                 sub     esi, _gr_var_bwidth
  845. ;--NOT USED!!--                 dec     edi  ;--DeltaX
  846. ;--NOT USED!!--                 jnz     XMajorLoop
  847. ;--NOT USED!!-- 
  848. ;--NOT USED!!-- DoneAA:               ;we're done with this line
  849. ;--NOT USED!!--                 pop edi  ;restore C's register variables
  850. ;--NOT USED!!--                 pop esi
  851. ;--NOT USED!!--                 pop ebp  ;restore caller's stack frame
  852. ;--NOT USED!!--                 ret     ;done
  853.  
  854.  
  855.  
  856. _TEXT   ENDS
  857.  
  858.  
  859.         END
  860.