home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 2d / lbitblt.asm < prev    next >
Assembly Source File  |  1998-06-08  |  9KB  |  447 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/2d/rcs/lbitblt.asm $
  13. ; $Revision: 1.7 $
  14. ; $Author: mike $
  15. ; $Date: 1994/08/12 17:38:28 $
  16. ; 
  17. ; Bitblt from linear to linear
  18. ; 
  19. ; $Log: lbitblt.asm $
  20. ; Revision 1.7  1994/08/12  17:38:28  mike
  21. ; Fix bug.
  22. ; 
  23. ; Revision 1.6  1994/08/11  17:59:33  mike
  24. ; Assembler versions for 3 rotations of merge functions.
  25. ; 
  26. ; Revision 1.5  1994/01/22  14:35:16  john
  27. ; Added transparency as color index 255.
  28. ; 
  29. ; Revision 1.4  1994/01/18  21:42:41  john
  30. ; unrolled loops in gr_merge_textures...
  31. ; 
  32. ; Revision 1.3  1994/01/18  10:56:04  john
  33. ; Added code to merge two ttextures.
  34. ; 
  35. ; Revision 1.2  1993/12/28  12:07:26  john
  36. ; initial version
  37. ; 
  38. ; Revision 1.1  1993/12/22  11:05:46  john
  39. ; Initial revision
  40. ; 
  41. ; 
  42.  
  43.  
  44.  
  45. .386
  46.     option    oldstructs
  47.  
  48.     .nolist
  49.     include    types.inc
  50.     include    psmacros.inc
  51.     include gr.inc
  52.     .list
  53.  
  54.     assume    cs:_TEXT, ds:_DATA
  55.  
  56. _DATA    segment    dword public USE32 'DATA'
  57.  
  58. rcsid    db    "$Id: lbitblt.asm 1.7 1994/08/12 17:38:28 mike Exp $"
  59.     align    4
  60.  
  61.  
  62.     JumpTable    dd    RowAligned0, RowAligned1, RowAligned2, RowAligned3
  63.  
  64. row_count    dd    ?
  65.  
  66. _DATA    ends
  67.  
  68.  
  69. _TEXT    segment    dword public USE32 'CODE'
  70.  
  71. ; C-calling:
  72. ; void gr_lbitblt( grs_bitmap * source, grs_bitmap * dest, int height, int width )
  73.  
  74. PUBLIC    gr_lbitblt_
  75.  
  76. gr_lbitblt_:
  77.  
  78.     ; EAX = grs_bitmap * source
  79.     ; EDX = grs_bitmap * dest
  80.     ; EBX = height
  81.     ; ECX = width
  82.  
  83.     push    esi
  84.     push    edi
  85.     push    ebp
  86.  
  87.     dec    ebx
  88.     js    Done
  89.  
  90.     mov    esi, [eax].bm_data
  91.     mov    edi, [edx].bm_data
  92.  
  93.     movzx    eax, [eax].bm_rowsize
  94.     sub    eax, ecx
  95.  
  96.     movzx    edx, [edx].bm_rowsize
  97.     sub    edx, ecx
  98.  
  99.     ; Can use ebp, eax, edx, ecx
  100.     mov    ebp, ecx
  101.     cmp    ebp, 16
  102.     jb    RowAligned0        ; If not 16 pixels wide, don't worry about alignment
  103.  
  104.     mov    ecx, edi
  105.     and    ecx, 011b
  106.     jmp     NEAR32 PTR JumpTable[ecx*4]
  107.  
  108. RowAligned0:
  109. NextRowAligned0:    
  110.     mov    ecx, ebp
  111.     shr    ecx, 2
  112.     rep     movsd
  113.     mov    ecx, ebp
  114.     and    ecx, 11b
  115.     rep    movsb
  116.  
  117.     add    esi, eax
  118.     add    edi, edx
  119.     dec    ebx
  120.     jns    NextRowAligned0
  121.  
  122.     pop    ebp
  123.     pop    edi
  124.     pop    esi
  125.     ret
  126.  
  127. RowAligned1:
  128.     sub    ebp, 3
  129.  
  130. NextRowAligned1:
  131.     movsw    
  132.     movsb    
  133.     mov    ecx, ebp
  134.     shr    ecx, 2
  135.     rep     movsd
  136.     mov    ecx, ebp
  137.     and    ecx, 11b
  138.     rep    movsb
  139.  
  140.     add    esi, eax
  141.     add    edi, edx
  142.     dec    ebx
  143.     jns    NextRowAligned1
  144.  
  145.     pop    ebp
  146.     pop    edi
  147.     pop    esi
  148.     ret
  149.  
  150. RowAligned2:
  151.     sub    ebp, 2
  152. NextRowAligned2:
  153.     movsw
  154.     mov    ecx, ebp
  155.     shr    ecx, 2
  156.     rep     movsd
  157.     mov    ecx, ebp
  158.     and    ecx, 11b
  159.     rep    movsb
  160.  
  161.     add    esi, eax
  162.     add    edi, edx
  163.     dec    ebx
  164.     jns    NextRowAligned2
  165.  
  166.     pop    ebp
  167.     pop    edi
  168.     pop    esi
  169.     ret
  170.  
  171. RowAligned3:
  172.     dec    ebp
  173. NextRowAligned3:
  174.     movsb
  175.     mov    ecx, ebp
  176.     shr    ecx, 2
  177.     rep     movsd
  178.     mov    ecx, ebp
  179.     and    ecx, 11b
  180.     rep    movsb
  181.  
  182.     add    esi, eax
  183.     add    edi, edx
  184.     dec    ebx
  185.     jns    NextRowAligned3
  186.  
  187. Done:    pop    ebp
  188.     pop    edi
  189.     pop    esi
  190.     ret
  191.  
  192.  
  193. ; C-calling:
  194. ; void gr_merge_textures( ubyte * lower, ubyte * upper, ubyte * dest )
  195.  
  196. PUBLIC    gr_merge_textures_, gr_merge_textures_1_, gr_merge_textures_2_, gr_merge_textures_3_
  197.  
  198. ; case 1:
  199. ;    // 
  200. ;    for (y=0; y<64; y++ )
  201. ;       for (x=0; x<64; x++ )   {
  202. ;          c = top_data[ 64*x+(63-y) ];      
  203. ;          if (c==255)
  204. ;             c = bottom_data[ 64*y+x ];
  205. ;          *dest_data++ = c;
  206. ;       }
  207. ;    break;
  208. ; case 2:
  209. ;    // Normal
  210. ;    for (y=0; y<64; y++ )
  211. ;       for (x=0; x<64; x++ )   {
  212. ;          c = top_data[ 64*(63-y)+(63-x) ];
  213. ;          if (c==255)
  214. ;             c = bottom_data[ 64*y+x ];
  215. ;          *dest_data++ = c;
  216. ;       }
  217. ;    break;
  218. ; case 3:
  219. ;    // Normal
  220. ;    for (y=0; y<64; y++ )
  221. ;       for (x=0; x<64; x++ )   {
  222. ;          c = top_data[ 64*(63-x)+y  ];
  223. ;          if (c==255)
  224. ;             c = bottom_data[ 64*y+x ];
  225. ;          *dest_data++ = c;
  226. ;       }
  227. ;    break;
  228. gr_merge_textures_:
  229.  
  230.     ; EAX = lower data
  231.     ; EDX = upper data
  232.     ; EBX = dest data
  233.  
  234.     push    ebp
  235.     push    edi
  236.     push    ecx
  237.     push    esi
  238.  
  239.     mov    ebp, edx
  240.     mov    edi, ebx
  241.     mov    bl, 255
  242.     mov    bh, bl
  243.     and    ebx, 0ffffh
  244.     and    edx, 0ffffh
  245.     mov    esi, eax
  246.     mov    ecx, (64*64)/2
  247.  
  248.     jmp    gmt1
  249.  
  250. second_must_be_not_trans:
  251.     mov    ah, dh
  252.     mov    [edi],ax
  253.     add    edi,2
  254.     dec    ecx
  255.     je    donegmt
  256.  
  257. gmt1:    mov    dx, [ebp]
  258.     add     ebp, 2
  259.     cmp    edx, ebx
  260.     jne    not_transparent
  261.  
  262. ; both transparent
  263.     movsw
  264.     dec    ecx
  265.     jne    gmt1
  266.     jmp    donegmt
  267.  
  268. ; DH OR DL ARE INVISIBLE
  269. not_transparent:
  270.     mov    ax,[esi]
  271.     add    esi,2
  272.         
  273.     cmp    dl, bl
  274.     je    second_must_be_not_trans
  275.     mov    al, dl
  276.     cmp    dh, bh
  277.     je    @f
  278.     mov    ah, dh
  279. @@:    mov    [edi],ax
  280.     add    edi,2
  281.     dec    ecx
  282.     jne    gmt1
  283.  
  284. donegmt:
  285.  
  286.     pop    esi
  287.     pop    ecx    
  288.     pop    edi
  289.     pop    ebp
  290.     ret
  291.  
  292. ; -----------------------------------------------------------------------------------------
  293. ; case 1, normal in x, flip in y
  294. gr_merge_textures_1_:
  295.  
  296. ; eax = background data
  297. ; edx = foreground data
  298. ; ebx = destination address
  299.  
  300.     push    ebp
  301.     push    edi
  302.     push    ecx
  303.     push    esi
  304.     push    ebx
  305.  
  306.     mov    ch, 255    ; transparent color, stick in a register, is this faster?
  307.  
  308.     mov    esi, 63    ; esi will be the offset to the current pixel
  309.     mov    row_count, esi
  310.  
  311.     mov    ebp, 64    ; do for 64 pixels
  312.  
  313.     align    4
  314. gmt1_1:    mov    cl, [edx + esi]    ; get foreground pixel
  315.     add     esi, 64    ; point at next row
  316.     cmp    cl, ch    ; see if transparent
  317.     jne    not_transparent_1    ; dl contains a solid color, just write it
  318.  
  319.     mov    cl,[eax]    ; get background pixel
  320.  
  321. not_transparent_1:    mov    [ebx], cl    ; write pixel
  322.     inc    ebx    ; point at next destination address
  323.     inc    eax
  324.  
  325.     dec    ebp    ; see if done a whole row
  326.     jne    gmt1_1    ; no, so do next pixel
  327.  
  328.     mov    ebp, 64    ; do for 64 pixels
  329.  
  330.     dec    row_count    ; advance to next row
  331.     mov    esi, row_count    ; doing next row, get offset, DANGER: DOESN'T SET FLAGS, BEWARE ON 68000, POWERPC!!
  332.     jns    gmt1_1    ; no (going down to 0)
  333.  
  334.     pop    ebx
  335.     pop    esi
  336.     pop    ecx    
  337.     pop    edi
  338.     pop    ebp
  339.     ret
  340.  
  341. ; -----------------------------------------------------------------------------------------
  342. ; case 1, normal in x, flip in y
  343. gr_merge_textures_2_:
  344.  
  345. ; eax = background data
  346. ; edx = foreground data
  347. ; ebx = destination address
  348.  
  349.     push    ebp
  350.     push    edi
  351.     push    ecx
  352.     push    esi
  353.     push    ebx
  354.  
  355.     mov    ch, 255    ; transparent color, stick in a register, is this faster?
  356.  
  357.     mov    esi, 63 + 64*63    ; esi will be the offset to the current pixel
  358.  
  359.     align    4
  360. gmt1_2:    mov    cl, [edx + esi]    ; get foreground pixel
  361.     cmp    cl, ch    ; see if transparent
  362.     jne    not_transparent_2    ; dl contains a solid color, just write it
  363.  
  364.     mov    cl,[eax]    ; get background pixel
  365.  
  366. not_transparent_2:    mov    [ebx], cl    ; write pixel
  367.     inc    ebx    ; point at next destination address
  368.     inc    eax
  369.  
  370.     dec    esi    ; advance to next row
  371.     jns    gmt1_2    ; no (going down to 0)
  372.  
  373.     pop    ebx
  374.     pop    esi
  375.     pop    ecx    
  376.     pop    edi
  377.     pop    ebp
  378.     ret
  379.  
  380. ; -----------------------------------------------------------------------------------------
  381. ; case 1, normal in x, flip in y
  382. gr_merge_textures_3_:
  383.  
  384. ; eax = background data
  385. ; edx = foreground data
  386. ; ebx = destination address
  387.  
  388.     push    ebp
  389.     push    edi
  390.     push    ecx
  391.     push    esi
  392.     push    ebx
  393.  
  394.     mov    ch, 255    ; transparent color, stick in a register, is this faster?
  395.  
  396.     mov    esi, 64*63    ; esi will be the offset to the current pixel
  397.     mov    row_count, 64
  398.  
  399.     mov    ebp, 32    ; do for 64 pixels (2x loop)
  400.  
  401. ; first copy of loop
  402.     align    4
  403. gmt1_3:    mov    cl, [edx + esi]    ; get foreground pixel
  404.     sub     esi, 64    ; point at next row
  405.     cmp    cl, ch    ; see if transparent
  406.     jne    not_transparent_3    ; dl contains a solid color, just write it
  407.  
  408.     mov    cl,[eax]    ; get background pixel
  409.  
  410. not_transparent_3:    inc    eax
  411.     mov    [ebx], cl    ; write pixel
  412.     inc    ebx    ; point at next destination address
  413.  
  414. ; second copy of loop
  415.     mov    cl, [edx + esi]    ; get foreground pixel
  416.     sub     esi, 64    ; point at next row
  417.     cmp    cl, ch    ; see if transparent
  418.     jne    nt_3a    ; dl contains a solid color, just write it
  419.  
  420.     mov    cl,[eax]    ; get background pixel
  421.  
  422. nt_3a:    inc    eax
  423.     mov    [ebx], cl    ; write pixel
  424.     inc    ebx    ; point at next destination address
  425.  
  426.     dec    ebp    ; see if done a whole row
  427.     jne    gmt1_3    ; no, so do next pixel
  428.  
  429.     mov    ebp, 32    ; do for 64 pixels
  430.  
  431.     add    esi, 64*64+1    ; doing next row, get offset, DANGER: DOESN'T SET FLAGS, BEWARE ON 68000, POWERPC!!
  432.  
  433.     dec    row_count    ; advance to next row
  434.     jne    gmt1_3    ; no (going down to 0)
  435.  
  436.     pop    ebx
  437.     pop    esi
  438.     pop    ecx    
  439.     pop    edi
  440.     pop    ebp
  441.     ret
  442.  
  443. _TEXT    ends
  444.  
  445.     end
  446.  
  447.