home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga ACS 1997 #4
/
amigaacscoverdisc1997-041997.iso
/
utilities
/
patches
/
studiov2.13_part_i
/
install-studioupdate
< prev
next >
Wrap
Text File
|
1996-10-07
|
23KB
|
784 lines
; $VER: StudioUpdate 2.13 Part I (07.10.96)
; Copyright (C)1992-96 Wolf Faust
(complete 0)
(delopts "oknodelete" "force" "askuser")
(set #waitmsg
(cat "\n\n\n\nWorking. Please wait..."
))
(set #bad-kick
(cat "\nYour system software is very old. "
"You must use at least Kickstart 2.04 for all Studio programs. "
))
(set #bad-version
(cat "This update will only update Studio V2.12 and older. "
"Your Studio disks are version %ld.%ld. Running this update doesn't make sense. "
))
(set #bad-version2
(cat "This update will only update Studio V2.13 and older. "
"Your installed Studio program has version %ld.%ld. "
"I will skip updating your Studio printing program. "
))
(set #w-studio
(cat "Select the action(s) to perform."
))
(set #w-studio-help
(cat "This disk comes with new and additional software for some printers.\n"
"You can update your current used software.\n"
"Or you can update the software and add the additional printer software.\n\n"
@askchoice-help
))
(set #w-studio-choices1
(cat "Update Studio driver and printing program"
))
(set #w-studio-choices2
(cat "And add new Deskjet 6xx software"
))
(set #w-studio-choices3
(cat "And add new Deskjet 8xx software"
))
(set #w-studio-choices4
(cat "And add new Deskjet 1600 software"
))
(set #abortunpack
(cat "\nError occured while running the installation decompression program. "
"The error occured during decompressing of the file:\n\n\"%s\"\n\n"
))
(set #foundstudio
(cat "\nI found your Studio printing program. Can I update the program in the drawer:\n\n%s\n\n"
))
(set #foundstudiohelp
(cat "When selecting yes, the Studio program will be updated in the location found.\n\n"
"When selecting no, you will be asked for a Studio filename you want to update\n\n"
))
(set #ask-studiomod
(cat "\nSelect the disk or drawer the 'Studio' application program is placed in. "
))
(set #ask-studiomod-help
(cat "You should now select the drawer the 'Studio' application program is placed in. "
"Usually the program is placed in the Studio drawer and thus the Studio drawer "
"should be selected.\n\n"
@askdir-help
))
(set #nostudiopro
(cat "\nSorry, I can't find the \"Studio\" program. I tried to access %s. "
"Please check the drawer and program name try installing again. "
))
(set #updatescan
(cat "\nI can't find the CMSScan program in your Studio drawer.\n\n"
"Select YES, if you want to update the CMSScan and CMSEdit program. "
"You will be asked for a drawer containing the CMSScan program.\n\n"
"Select NO, if you want to continue the installation without updating "
"the CMSScan and CMSEdit utilties. "
))
(set #ask-cmsmod
(cat "\nSelect the disk or drawer the 'CMSScan' program is placed in. "
))
(set #ask-cmsmod-help
(cat "You should now select the drawer the 'CMSScan' and 'CMSEdit' application program is placed in. "
"Usually the program is placed in the Studio drawer and thus the Studio drawer "
"should be selected.\n\n"
"The programs can be found on the second floppy disk, if Studio was "
"originaly installed on a floppy disk.\n\n"
@askdir-help
))
(set #nocmspro
(cat "\nSorry, I can't find the \"CMSScan\" program. I tried to access %s. "
"Please check the drawer and program name try installing again. "
))
(set #ask-prefs
(cat "\nIn which disk or drawer are the Studio printer preferences program(s) installed?"
))
(set #ask-prefs-help
(cat "\nThis section lets you choose in which drawer or on which disk the "
"Studio printer driver preferences programs (DeskPref, ...) are installed. "
"These are normally placed in the \"sys:prefs\" directory of your system "
"disk.\n\n"
@askdir-help
))
(set #nodesk
(cat "If found the DeskDriver printer driver on your system. It seems you used "
"the DeskDriver for your Deskjet so far. Please note that with this "
"update Deskjet 6xx/1600 users should use the DeskDriver4C with DeskPref4C.\n\n"
"Shall I remove the old DeskDriver and DeskPref program before installing "
"the new DeskDriver4C driver?"
))
(set #nodeskhelp
(cat "When selecting no, the Studio program will be add the new DeskDriver4C "
"to your system without deleting the DeskDriver.\n\n"
"When selecting yes, the old DeskDriver/DeskPref programs are removed "
"from your system before installing the new driver software for your Deskjet 6xx\n\n"
))
(set #delenv
(cat "Can I overwrite your old driver settings? I want to overwrite your settings in "
"order to setup the driver for your printer.\n\n"
"Note: you can keep your old driver settings if you like. Use the Preset "
"menu of the preferences program to change the settings to the default "
"settings anytime later."
))
(set #delenvhelp
(cat "The installation program wants to setup the default settings for your printer. "
"In order to do so, your old settings have to be deleted. You can skip overwriting the driver "
"settings and setup the driver later for your printer using the Preset menu "
"of the drivers prefences program."
))
(set #sdelenv
(cat "Can I delete the old settings of your Studio printing program? I want to overwrite your settings in "
"order to setup Studio for your printer.\n\n"
"Note: you can keep your old Studio printing program settings if you like. Use the \"Reset To Default\" "
"menu item of the printing program to change the settings anytime later if required. "
))
(set #sdelenvhelp
(cat "The installation program wants to setup the default settings for your printer. "
"In order to do so, your old settings have to be deleted. You can skip overwriting the Studio "
"settings and setup the printing program later for your printer using the \"Reset To Default\" menu item "
"of the Studio printing program."
))
(set #mydisk
(cat "Please insert the disk named\n\n\"StudioDisk_%ld\"\n\nin any drive."
))
(set #yesupdate
(cat "Yes, update"
))
(set #nodrawer
(cat "No, select new drawer"
))
(set #noupdate
(cat "No, don't change"
))
(set #nochange
(cat "No, don't change"
))
(set #installed
(cat "\n\nA new driver named \"%s\" has been installed for your printer. "
"The driver is controlled by the installed \"%s\" preferences "
"program.\n\n"
))
;--------------
;*** German
(if (= @language "deutsch")
(
(set #waitmsg
(cat "\n\n\n\nIch arbeite! Bitte warten..."
))
(set #bad-kick
(cat "\nIhre System-Software ist sehr alt. "
"Sie brauchen mindestens Kickstart 2.04 für alle Studio-Programme."
))
(set #bad-version
(cat "Dieses Update benötigt Studio V2.12 oder älter. "
"Ihre Studio Originaldisketten haben Version %ld.%ld. Es hat daher "
"keinen Sinn, ein Update durchzuführen. "
))
(set #bad-version2
(cat "Dieses Update funktioniert nur mit Studio V2.13 und älter. "
"Ihr installiertes Programm hat bereits Version %ld.%ld. "
"Ich werde daher nicht das Programm updaten. "
))
(set #w-studio
(cat "Welche Studio-Software wollen Sie updaten?"
))
(set #w-studio-help
(cat "\nDieses Studio Update enthält neben einem generellen Update der vorhandenen "
"Software auch zusätzliche neue Treiber Software. Bitte wählen Sie, ob "
"Sie einfach nur vorhandenes Updaten wollen, oder ob Sie zusätzlich noch "
"weitere Software installieren wollen.\n\n"
@askoptions-help
))
(set #w-studio-choices1
(cat "Studio Treiber und Programm updaten."
))
(set #w-studio-choices2
(cat "Updaten und Deskjet 6xx Software installieren"
))
(set #w-studio-choices3
(cat "Updaten und Deskjet 8xx Software installieren"
))
(set #w-studio-choices4
(cat "Updaten und Deskjet 1600 Software installieren"
))
(set #abortunpack
(cat "\nEin Fehler trat beim Entpacken/Schreiben einer Datei auf!\n"
"Das zu entpackende Archiv lautete:\n\n\"%s\"\n\n"
))
(set #foundstudio
(cat "\nIch habe Ihr installiertes Studio Druckprogramm gefunden. Kann ich das Studio Programm in der folgenden Schublade updaten:\n\n%s\n\n"
))
(set #foundstudiohelp
(cat "Wählen Sie ja, dann wird das Studio Programm in der angegebenen Schublade erneuert.\n\n"
"Wählen Sie Nein, erscheint ein Dateiauswahlfenster und Sie können eine "
"andere Schublade mit dem Studio Programm angeben.\n\n"
))
(set #ask-studiomod
(cat "\nBitte wählen Sie die Schublade, in dem sich das 'Studio'-Programm befindet."
))
(set #ask-studiomod-help
(cat @askdir-help
))
(set #nostudiopro
(cat "Ich kann das \"Studio\" Programm nicht unter\n\n'%s'\n\nfinden. "
"Bitte prüfen Sie die angegebenen Dateinamen und versuchen Sie die Installation erneut."
))
(set #updatescan
(cat "\nIch kann das CMSScan Programm nicht in Ihrer angegebenen Studio Schublade finden.\n\n"
"Wollen Sie CMSScan und CMSEdit Updaten?"
))
(set #ask-cmsmod
(cat "\nBitte wählen Sie die Schublade, in dem sich das 'CMSScan'-Programm befindet."
))
(set #ask-cmsmod-help
(cat "Bitte wählen Sie die Schublade, in dem sich das 'CMSScan'-Programm befindet. "
"Das Programm befindet sich normal in der Studio Schublade.\n"
"Wurde Studio auf Disketten installiert, finden Sie CMSScan "
"auf der zweiten installierten Studio Diskette.\n\n"
@askdir-help
))
(set #nocmspro
(cat "Ich kann das \"CMSScan\" Programm nicht unter\n\n'%s'\n\nfinden. "
"Bitte prüfen Sie die angegebenen Dateinamen und versuchen Sie die Installation erneut."
))
(set #ask-prefs
(cat "\nIn welcher Schublade wurden die Studio Treiber-Voreinsteller installiert?"
))
(set #ask-prefs-help
(cat "\nNormal installiert Studio die Voreinsteller DeskPref, LaserPref, PinPref, CanonBJECPref usw. "
"in die SYS:Prefs Schublade. Sollten Sie diese Programme woanders installiert haben, "
"geben Sie bitte die entsprechende Schublade an, damit die Programme upgedated werden können.\n\n"
@askdir-help
))
(set #nodesk
(cat "Scheinbar haben Sie bislang den DeskDriver für Ihren Deskjet 6xx oder 1600 verwendet. "
"Bitte wechseln Sie jetzt zu den neu installierten DeskDriver4C Treiber mit dem "
"DeskPref4C Voreinsteller.\n\n"
"Soll ich den alten DeskDriver und das DeskPref-Programm entfernen? "
))
(set #nodeskhelp
(cat "Wählen Sie Nein, dann wird Ihr alte DeskDriver/DeskPref Software nicht von Ihrem "
"System gelöscht. Es wird nur die neue DeskDriver4C und DeskPref4C Software installiert.\n\n"
))
(set #delenv
(cat "Kann ich Ihre alten Treibereinstellungen löschen, damit ich den Treiber "
"für Ihren Drucker neu konfigurieren kann?\n\n"
"Sie können Ihre Einstellungen mit 'Nein' aber auch behalten und jederzeit "
"später mit dem Preset Menü von DeskPref4C den Treiber neu einstellen."
))
(set #delenvhelp
(cat "Das Installationsprogramm muß Ihre alten Treibereinstellungen löschen, "
"um die neuen Standardeinstellungen für Ihren Drucker zu aktivieren. "
"Sie können darauf aber auch verzichten, und später das Preset-Menü "
"von DeskPref4C zum Einstellen benutzen."
))
(set #sdelenv
(cat "Kann ich Ihre Einstellungen des Studio Druckprogramms löschen, damit ich das Programm "
"für Ihren Drucker neu konfigurieren kann?\n\n"
"Sie können Ihre Einstellungen mit 'Nein' aber auch behalten und jederzeit "
"später mit dem 'Reset To Default' Menüpunkt die Einstellungen vornehmen."
))
(set #sdelenvhelp
(cat "Das Installationsprogramm muß Ihre alten Studio Einstellungen löschen, "
"um die neuen Standardeinstellungen für Ihren Drucker zu aktivieren. "
"Sie können darauf aber auch verzichten, und später das Menü "
"von Studio zum Einstellen benutzen."
))
(set #mydisk
(cat "Bitte legen Sie die Diskette\n\n\"StudioDisk_%ld\"\n\nin ein beliebiges Laufwerk."
))
(set #yesupdate
(cat "Ja, updaten"
))
(set #noupdate
(cat "Nein, nicht ändern"
))
(set #nodrawer
(cat "Nein, andere Schublade"
))
(set #nochange
(cat "Nein, nicht ändern"
))
(set #installed
(cat "\n\nEin neuer Treiber namens \"%s\" wurde für den Deskjet Drucker installiert. "
"Zusätzlich wurde das Voreinsteller-Programm \"%s\" installiert.\n\n"
))
))
(procedure Meter
(
(set accum (+ accum addm))
(complete (/ (* accum 100) total))
))
(complete 0)
;(message #welcome-pirate)
(set total 0)
(set accum 0)
(set addm 0)
(set firstdisk "")
(if (< (/ (getversion) 65536) 37)
(abort #bad-kick)
)
(if (= (exists "StudioDisk_1:VER") 1)
(
(set vernum (getversion "StudioDisk_1:VER"))
(set ver (/ vernum 65536))
(set rev (- vernum (* ver 65536) ) )
(if (OR (> ver 2) (> rev 12))
(
(abort (#bad-version ver rev))
))
))
(complete 1)
(set studio (askchoice (prompt #w-studio)
(help #w-studio-help)
(choices #w-studio-choices1 #w-studio-choices2 #w-studio-choices3 #w-studio-choices4 )
(default 0)
))
(working #waitmsg)
(set total 50)
(if (> studio 0)
(
(set total 100)
))
(set @default-dest "")
(copyfiles (source "StudioDisk_1:lx")
(dest "RAM:")
(nogauge)
)
(set exerr (run "RAM:lx n"))
(if (> exerr 0)
(
(abort (#abortunpack "-none-"))
))
(set addm 5)
(Meter)
(set studiopath "");
(if (= (exists "ENV:STUDIOPATH") 1)
(
(set studiopath (getenv "StudioPath"))
))
(set found 1)
(if (> (strlen studiopath) 1)
(
(if (= (substr studiopath 0 1) "\"")
(
(set studiopath (substr studiopath 1 (- (strlen studiopath) 2)))
))
(if (= (exists studiopath) 1)
(
(if (= (fileonly studiopath) "Studio")
(
(set found 2)
(if (askbool (prompt (#foundstudio (pathonly studiopath)))
(choices #yesupdate #nodrawer)
(help (#foundstudiohelp ))
(default 1))
(
(set found 0)
))
))
))
))
(set addm 5)
(Meter)
(if (> found 0)
(
(if (= found 1)
(
(set studiopath (getassign "WORK" "d"))
(if (= studiopath "")
(
(set studiopath (getassign "DH0" "d"))
(if (= studiopath "")
(
(set studiopath (getassign "DH2" "d"))
(if (= studiopath "")
(
(set studiopath "SYS:")
))
))
))
(set studiopath (tackon studiopath "Studio"))
))
(set studiopath (askdir (prompt #ask-studiomod)
(help #ask-studiomod-help)
(default (pathonly (studiopath)))
))
(set studiopath (tackon studiopath "Studio"))
(if (<> (exists studiopath) 1)
(
(abort (#nostudiopro studiopath))
))
(textfile (dest "Env:StudioPath")
(append (cat "\"" studiopath "\"")) )
(textfile (dest "Envarc:StudioPath")
(append (cat "\"" studiopath "\"")) )
))
(set addm 5)
(Meter)
(working #waitmsg)
(makeassign "STUDIOPARENT" (pathonly (studiopath)))
(set ver 0)
(set rev 0)
(if (= (exists "STUDIOPARENT:Studio") 1)
(
(set vernum (getversion "STUDIOPARENT:Studio"))
(set ver (/ vernum 65536))
(set rev (- vernum (* ver 65536) ) )
))
(set addm 20)
(Meter)
(if (OR (> ver 2) (> rev 13))
(
(message (#bad-version2 ver rev))
)
(
(set exerr (run (cat "RAM:lx x \"Studio/Studio.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Studio/Studio.pkd"))
))
(makeassign "STUDIOPARENT" (tackon (pathonly (studiopath)) "Studio_Output"))
(if (= (exists "STUDIOPARENT:CanonBJC800.output") 1)
(
(set exerr (run (cat "RAM:lx x \"Output/CanonBJC800.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Output/CanonBJC800.pkd"))
))
))
(set cmspath (tackon (pathonly studiopath) "CMSScan"))
(set found 1)
(if (<> (exists cmspath) 1)
(
(if (askbool (prompt (#updatescan (pathonly cmspath)))
(choices "Yes, update CMSScan" "No, continue")
(help (#foundstudiohelp ))
(default 1))
(
(set found 1)
(set cmspath (askdir (prompt #ask-cmsmod)
(help #ask-cmsmod-help)
(default (pathonly (cmspath))))
)
(set cmspath (tackon cmspath "CMSScan"))
(if (<> (exists cmspath) 1)
(
(abort (#nocmspro cmspath))
))
)
(
(set found 0)
))
))
(if (> found 0)
(
(working #waitmsg)
(makeassign "STUDIOPARENT" (pathonly (cmspath)))
(set exerr (run (cat "RAM:lx x \"Studio/Scan.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Studio/Scan.pkd"))
))
))
(makeassign "STUDIOPARENT" (tackon (pathonly (studiopath)) "Studio_Output"))
(if (= (exists "STUDIOPARENT:CanonBJC800.output") 1)
(
(set exerr (run (cat "RAM:lx x \"Output/CanonBJC800.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Output/CanonBJC800.pkd"))
))
))
(if (= (exists "STUDIOPARENT:Fargo_Primera.output") 1)
(
(set exerr (run (cat "RAM:lx x \"Output/Fargo_Primera.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Output/Fargo_Primera.pkd"))
))
))
(if (= (exists "STUDIOPARENT:Deskjet8xx.output") 1)
(
(set exerr (run (cat "RAM:lx x \"Output/Deskjet8xx.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Output/Deskjet8xx.pkd"))
))
))
(if (= (exists "STUDIOPARENT:Deskjet6xx.output") 1)
(
(set exerr (run (cat "RAM:lx x \"Output/Deskjet6xx.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Output/Deskjet6xx.pkd"))
))
))
(if (= (exists "STUDIOPARENT:Deskjet1600.output") 1)
(
(set exerr (run (cat "RAM:lx x \"Output/Deskjet1600.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Output/Deskjet1600.pkd"))
))
))
(if (= (exists "STUDIOPARENT:PCL_5C.output") 1)
(
(set exerr (run (cat "RAM:lx x \"Output/pcl_5c.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Output/PCL_5C.pkd"))
))
))
))
(set addm 15)
(Meter)
(working #waitmsg)
(makeassign "STUDIOPARENT" "Devs:printers")
(if (= (exists "STUDIOPARENT:CanonBJ-EC") 1)
(
(set exerr (run (cat "RAM:lx x \"Drivers/CanonBJEC.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Drivers/CanonBJEC.pkd"))
))
))
(if (= (exists "STUDIOPARENT:DeskDriver") 1)
(
(set exerr (run (cat "RAM:lx x \"Drivers/DeskDriver.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Drivers/DeskDriver.pkd"))
))
))
(if (= (exists "STUDIOPARENT:DeskDriver4C") 1)
(
(set exerr (run (cat "RAM:lx x \"Drivers/DeskDriver4C.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Drivers/DeskDriver4C.pkd"))
))
))
(if (= (exists "STUDIOPARENT:LaserDriver") 1)
(
(set exerr (run (cat "RAM:lx x \"Drivers/LaserDriver.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Drivers/LaserDriver.pkd"))
))
))
(set prefdisk ("SYS:Prefs"))
(if (exists "sys:preferences")
(
(set prefdisk ("SYS:Preferences"))
))
(if (exists "SYS:Prefs")
(
(set prefdisk ("SYS:Prefs"))
))
(set prefdisk (askdir (prompt #ask-prefs)
(help #ask-prefs-help)
(default prefdisk))
)
(set addm 3)
(Meter)
(working #waitmsg)
(if (= (exists prefdisk) 2)
(
(makeassign "STUDIOPARENT" prefdisk)
(if (= (exists "STUDIOPARENT:DeskPref4C") 1)
(
(set exerr (run (cat "RAM:lx x \"Prefs/DeskPref4C.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Prefs/DeskPref4C.pkd"))
))
))
(if (= (exists "STUDIOPARENT:CanonBJECPref") 1)
(
(set exerr (run (cat "RAM:lx x \"Prefs/CanonBJECPref.pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack "Prefs/CanonBJECPref.pkd"))
))
))
))
; DJ 6xx
(if (= studio 1)
(
(if (= (exists "devs:printers/DeskDriver") 1)
(
(if (<> (exists "devs:printers/DeskDriver4C") 1)
(
(if (NOT (askbool (prompt (#nodesk))
(choices #noupdate #yesupdate)
(help (#nodeskhelp))
(default 1)))
(
(working #waitmsg)
(delete "Devs:printers/DeskDriver")
(if (= (exists (tackon prefdisk "DeskPref") 1))
(
(delete (tackon prefdisk "DeskPref"))
))
))
))
))
(set drivername "DeskDriver4C")
(set prefname "prefs/DeskPref4C")
(set envname "DeskPref4C")
(set studiodefault "Deskjet_6xx")
(set presetname "DriverPresets/dj6xx")
(set soutput "Output/Deskjet6xx")
(set sprofile "Profiles/Deskjet6xx_8xx")
))
; DJ 8xx
(if (= studio 2)
(
(set drivername "DeskDriver4C")
(set prefname "prefs/DeskPref4C")
(set envname "DeskPref4C")
(set studiodefault "Deskjet_8xx")
(set presetname "DriverPresets/dj8xx")
(set soutput "Output/Deskjet8xx")
(set sprofile "Profiles/Deskjet6xx_8xx")
))
; DJ 1600
(if (= studio 3)
(
(set drivername "DeskDriver4C")
(set prefname "prefs/DeskPref4C")
(set envname "DeskPref4C")
(set studiodefault "Deskjet_1600")
(set presetname "DriverPresets/DJ16004C")
(set soutput "Output/Deskjet1600")
(set sprofile "Profiles/Deskjet6xx_8xx")
))
(if (> studio 0)
(
(set addm 10)
(Meter)
(makeassign "STUDIOPARENT" "Devs:Printers")
(set exerr (run (cat "RAM:lx x drivers/" drivername ".pkd \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack (tackon "Drivers" drivername)))
))
(makeassign "STUDIOPARENT" prefdisk)
(set exerr (run (cat "RAM:lx x " prefname ".pkd \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack prefname))
))
(set addm 10)
(Meter)
(set delenv 1)
(if (= (exists (cat "ENV:" envname)) 1)
(
(if (NOT (askbool (prompt (#delenv))
(choices "Yes, overwrite" "No, don't delete")
(help (#delenvhelp))
(default 1)))
(
(set delenv 0)
))
))
(if (> delenv 0)
(
(if (exists "ENV:")
(
(delete (cat "ENV:" envname))
))
(if (exists "ENVARC:")
(
(delete (cat "ENVARC:" envname))
))
(if (<> presetname "")
(
(if (= (exists presetname) 1)
(
(copyfiles (source presetname)
(dest "ENV:")
(newname envname)
(nogauge)
)
)
(
(if (= (exists (cat presetname ".pkd")) 1)
(
(set exerr (run (cat "RAM:lx x " presetname ".pkd ENV:")))
(if (> exerr 0)
(
(abort (#abortunpack (cat presetname ".pkd")))
))
(if (exists (cat "ENV:" envname))
(
(delete (cat "ENV:" envname))
))
(rename (cat "ENV:" (fileonly presetname)) (cat "ENV:" envname))
))
))
(if (= (exists (cat "ENV:" envname)) 1)
(
(if (exists "ENVARC:")
(
(copyfiles (source (cat "ENV:" envname))
(dest "ENVARC:")
(newname envname)
(nogauge)
)
))
))
))
))
(set addm 10)
(Meter)
(working #waitmsg)
(makeassign "STUDIOPARENT" (tackon (pathonly (studiopath)) "Studio_Prefs"))
(set exerr (run (cat "RAM:lx x \"" (tackon "StudioPresets" (cat studiodefault ".pkd\"")) "\"T:\"")))
(if (> exerr 0)
(
(abort (#abortunpack (tackon "StudioPresets" (cat studiodefault ".pkd"))))
))
(copyfiles (source (cat "T:" studiodefault ".prefs"))
(dest "STUDIOPARENT:")
(newname "DefaultSettings")
(nogauge)
)
(set addm 10)
(Meter)
(if (exists "STUDIOPARENT:Studio.prefs")
(
(if (askbool (prompt (#sdelenv))
(choices "Yes, delete" "No, don't delete")
(help (#sdelenvhelp))
(default 1))
(
(delete "STUDIOPARENT:Studio.prefs")
))
))
(working #waitmsg)
(makeassign "STUDIOPARENT" (tackon (pathonly (studiopath)) "Studio_Output"))
(set exerr (run (cat "RAM:lx x \"" soutput ".pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack (cat soutput ".pkd")))
))
(set addm 5)
(Meter)
(makeassign "STUDIOPARENT" (tackon (pathonly (studiopath)) "Studio_Profiles"))
(set exerr (run (cat "RAM:lx x \"" sprofile ".pkd\" \"STUDIOPARENT:\"")))
(if (> exerr 0)
(
(abort (#abortunpack (cat sprofile ".pkd")))
))
(message (#installed drivername (fileonly prefname)))
))
(run "RAM:lx n")
(delete "RAM:lx")
(makeassign "STUDIOPARENT")
(complete 100)