home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DOS/V Power Report 2001 December
/
VPR0112B.ISO
/
OLS
/
JED194V
/
JEDDOC.LZH
/
BLOCK.MCR
< prev
next >
Wrap
Text File
|
1993-12-09
|
2KB
|
121 lines
;***************************************************************
; JED マクロサンプル
; 'BLOCK.MCR'
; [矩形ブロック編集マクロ]
; Ver 0.10 Nov.1993 初版
;
; Written by H.Orikawa 1993
;
;***************************************************************
;***** Begin
#85 ;コピーモード変更
ss = lx, ll = ln,
!01
(r--) >? {
{ &10 &11 &40 } ;コピー
{ &10 &11 &45 } ;カット
{ &10 &50 } ;ペースト
}
&60 &x(ss)
&99
/
;***** End
;----- 開始点入力
10:
s = "開始",
&15
ss = lx, ll = ln,
.
;----- 終了点入力
11:
s = "終了",
&15
ee = lx, mm = ln,
(ee == ss) ? { &b(1) >^ }
(ee < ss) ? { t = ee, ee = ss, ss = t }
(mm < ll) ? { t = mm, mm = ll, ll = t }
&20
#<
&60
.
;----- 矩形領域入力サブルーチン
15:
:A &m("【%s点】で[CR] (行=%5d,桁=%3d)", s, ln, lx + 1)
&p
(r == #03) ? { &99 / }
(r != #m) ? { &o(r) >A }
.
;----- クリップボードクリア
20:
&s
#71 ;Open clipboard
#b #_
#51 ;Block clear
#W
.
;----- ブロック操作
30:
&x(ss) #b &x(ee)
.
;----- コピー
40:
:A (ln <= mm) ? { &30 #B #x >A }
.
;----- カット
45:
:A (ln <= mm) ? { &30 #54 #x >A }
.
;----- ペースト
50:
&s
#71 ;Open clipboard
nn = ln,
#_
nn = ln - nn + 2, ;行数計算
#W
:A (nn--) ? {
&x(ss)
#m #i #h #> #g #x
>A
}
.
;----- 開始点y位置に戻る
60:
:A (ln > ll) ? { #e >A }
.
;----- 終了処理
99:
&m(" ")
&d
#85 ;コピーモード変更
.
;----- ポップアップメニュー
01: "矩形ブロック編集", 18, 3
"C | コピー"
"X | カット"
"V | ペースト"
.