home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DOS/V Power Report 1997 December
/
VPR9712A.ISO
/
OLS
/
WIN16
/
HT219
/
HT219.LZH
/
CSC.SCR
< prev
next >
Wrap
Text File
|
1995-06-02
|
4KB
|
176 lines
;Chat Scirpt Compact version 2.10 for HideTerm & HideTerm32
;copyright (c)1995 OFFICE-OA (PFA03003)
setautohangup 10
%CS = ""
call MnuReset
if( %C_H == "" ) input "あなたのハンドルが未登録です", %C_H
keyassign reset
keyassign F1 ,"1:選択1", script, Mnu1
keyassign F2 ,"2:選択2", script, Mnu2
keyassign F3 ,"3:取消" , script, Undo
keyassign F5 ,"5:SEND" , script, SetSend
keyassign F6 ,"6:PAGE" , script, SetPage
keyassign F12,"2:終了" , script, Quit
keyassign B4 ,"4:消去" , script, MnuReset
keyassign B9 ,"9:名前" , script, Name
keyassign B10,"0:敬称" , script, Foot
keyassign B11,"1:音" , script, Snd
call SendRepOn
call PageRepOn
send "/EC OFF^M/HA " + %C_H + "^M"
gethostname #HostName
title "NIFTYでChat中[" + #HostName + "]"
chat on
timeout 600
beginloop
if( %CS != "" ) goto Ed
switch
case "^J("
call Sub1
case "^J- JOB番号"
if( @PageRep == "Off" ) loopagain
wait "^M"
readbuffer 0, #B
@JOB = tohankaku( drop( part( #B, 10, 6 ), "の" ) )
input "JOB番号" + @JOB + "に送り返すメッセージ", #Mes
if( #Mes != "" ) send "/P " + @JOB + " (PAGE:" + %C_H + ") " + #Mes + "^M"
case " のユーザーからのメッセージです-^M"
if( @SendRep == "Off" ) loopagain
readbuffer 0, #B
if( part( #B, 0, 2 ) != "-" ) loopagain
@ID = part( #B, 2, 8 )
input @ID + "に送り返すメッセージ", #Mes
if( #Mes != "" ) send "/SEND " + @ID + " (SEND:" + %C_H + ") " + #Mes + "^M"
case "^J>", "^JFORUM>", "^JCCS(N)>", "^JCCS(R)>", "^JBBS>", "^JLIB>", "^JMAIL>", timeout
timeoutquestion "CSCを終了しますか?", 30
if( yes ) goto Ed
if( timeout ) goto Ed
endswitch
endloop
Sub1:
wait "^M"
readbuffer 0, #B
if( part( #B, 0, 1 ) != "(" )
readbuffer 1, #C
#B = #C + #B
if( part( #B, 0, 1 ) != "(" )
readbuffer 2, #C
#B = #C + #B
endif
endif
#H = part( search( drop( #B, ")" ), "," ), 1, 20 )
switch #H
case %C_H, "", @H[0], @H[1], @H[2], @H[3], @H[4], @H[5], @H[6], @H[7], @H[8], @H[9], @H[10], @H[11], @H[12], @H[13], @H[14]
case @H[15], @H[16], @H[17], @H[18], @H[19], @H[20], @H[21], @H[22], @H[23], @H[24], @H[25], @H[26], @H[27], @H[28], @H[29]
case default
play %C_S
send "/Who " + #H + "^M"
@H[ @@T ] = #H
@@T = @@T + 1
if( @@T > 29 ) @@T = 0
endswitch
return
Quit:
send "/SC CSC^M◇CSC:終了(このメッセージは通常は他の人には見えません)^M/UNS^M"
%CS = "E"
return
Mnu2:
##M = 15
Mnu1:
while( ##T < 15 )
addnumbermenu @H[ ##M + ##T ]
##T = ##T + 1
endwhile
showmenu
switch result
case -1
case default
getchat #E
setchat #E + ">" + @H[ result + ##M ] + %C_F
endswitch
return
Undo:
getchat #E
#E = dropback( #E, ">" )
setchat #E
return
MnuReset:
while( ##T < 30 )
@H[ ##T ] = ""
##T = ##T + 1
endwhile
@@T = 0
return
SetSend:
input "相手のID", @ID, @ID
if( cancel ) return
if( length( tohankaku( @ID ) ) != 8 )
message "IDが不正です!"
return
endif
input @ID + "に送るメッセージ", #Mes
if( #Mes != "" ) send "/SEND " + @ID + " (SEND:" + %C_H + ") " + #Mes + "^M"
return
SetPage:
input "相手のJOB番号", @JOB, @JOB
if( cancel ) return
##JOB = @JOB
if( ##JOB < 1 or ##JOB > 999 )
message "JOB番号が不正です!"
return
endif
input "JOB番号" + @JOB + "に送るメッセージ", #Mes
if( #Mes != "" ) send "/P " + @JOB + " (PAGE:" + %C_H + ") " + #Mes + "^M"
return
SendRepOn:
@SendRep = "On"
keyassign B5 ,"5:SEND返切" , script, SendRepOff
return
SendRepOff:
@SendRep = "Off"
keyassign B5 ,"5:SEND返入" , script, SendRepOn
return
PageRepOn:
@PageRep = "On"
keyassign B6 ,"6:PAGE返切" , script, PageRepOff
return
PageRepOff:
@PageRep = "Off"
keyassign B6 ,"6:PAGE返入" , script, PageRepOn
return
Name:
input "自分のハンドル", %C_H, %C_H
question "ハンドルの変更コマンドを送信しますか?"
if( yes ) send "/HA " + %C_H + "^M"
return
Foot:
input "敬称", %C_F, %C_F
return
Snd:
input "新しいハンドルの警告音", %C_S, %C_S
return
Ed:
%CS= ""
timeout 0
title #HostName
chat off
keyassign reset
call NIF.SCR:SetNifKeyAssign
return