home *** CD-ROM | disk | FTP | other *** search
/ C!T ROM 5 / ctrom5b.zip / ctrom5b / PROGRAM / ASM / ALIB30B / TIME7.ASM < prev   
Assembly Source File  |  1994-11-28  |  7KB  |  313 lines
  1.     PAGE    66,132
  2. ;******************************** TIME7.ASM  *********************************
  3. LIBSEG           segment byte public "LIB"
  4.         assume cs:LIBSEG , ds:LIBSEG
  5. ;----------------------------------------------------------------------------
  6.     include    mac.inc
  7.     extrn    word_to_dec_stdout:far
  8.     extrn    dword_to_dec_stdout:far
  9.     extrn    stdout_string:far
  10.     extrn    quad_multiply1:far
  11.     extrn    quad_divide:far
  12. ;
  13. ; General information.  This collection of timer functions use the
  14. ; 8243 timer.  The 8253 has three timers, and timer 0 is used to
  15. ; keep the system clock (attached to interrupt 8) current.  We will
  16. ; also use timer 0.  The timer 0 is accessed at port 43h (commands) and
  17. ; port 40h (data).  One timer tick is roughly 840 nano secods.
  18. ;             
  19. timer_low    equ    046ch
  20. timer_mode    equ    43h
  21. timer0        equ    40h
  22.  
  23. comment 
  24. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(  MISC   )
  25. ;START_TIMER - start high resolution timer
  26. ;  inputs:  none
  27. ;  output:  none
  28. ; 
  29. ; note:  the maximum time which can be measured is one hour.  code
  30. ;        fragments can be timed accuratly up to 55ms.  Programs
  31. ;        can be timed for longer periods, but interrupts have to
  32. ;        be enabled.  It is usually best to disable interrupts
  33. ;        while timing short code fragments.  For program timing
  34. ;        the reported time will include the time required to
  35. ;        service interrupts.
  36. ;
  37. ; note:  The timer functions are usually called in the following order
  38. ;           call  calibrate_timer
  39. ;           call  start_timer
  40. ;           (timed program or code here)
  41. ;           call  read_timer
  42. ;           call  convert_timer
  43. ;           call  display_timer
  44. ;
  45. ; note:  See sample program TIMER.ASM for usage hints.
  46. ;* * * * * * * * * * * * * *
  47. 
  48.     public    start_timer
  49. start_timer    proc    far
  50.     apush    ax,dx,ds
  51.     pushf
  52.     cli
  53. ;
  54. ; initialize the 8253 to count down max count of 65536 by setting zero
  55. ;
  56.     mov    al,00110100b        ;select mode
  57.     out    timer_mode,al        ;request mode
  58.     call    delay
  59.     sub    ax,ax            ;starting count
  60.     out    timer0,al
  61.     call    delay
  62.     out    timer0,al
  63. ;
  64. ; wait for timer tick before starting
  65. ;
  66.     sti
  67.     call    delay
  68.     in    al,timer0
  69.     mov    ah,al
  70. twait:    call    delay
  71.     in    al,timer0
  72.     cmp    al,ah
  73.     je    twait
  74.     call    delay
  75. ;
  76. ;wait for interrupt
  77. ;
  78.     sub    dx,dx
  79.     mov    ds,dx            ;point at seg 0
  80.     mov    dx,word ptr ds:[timer_low]
  81. ilop:    mov    ax,word ptr ds:[timer_low]
  82.     cmp    ax,dx
  83.     je    ilop
  84. ;
  85. ; restart the timer back at count of zero again.
  86. ;
  87.     mov    al,00110100b        ;select mode
  88.     out    timer_mode,al        ;request mode
  89.     call    delay
  90.     sub    ax,ax            ;starting count
  91.     out    timer0,al
  92.     call    delay
  93.     out    timer0,al
  94. ;
  95. ; get the current bios time of day
  96. ;
  97.     mov    ax,word ptr ds:[timer_low]
  98.     mov    cs:interrupt_count,ax
  99.     popf
  100.     apop    ds,dx,ax
  101.     retf
  102. start_timer    endp
  103.  
  104. delay:    jmp    d1
  105. d1:    jmp    d2
  106. d2:    jmp    d3
  107. d3:    jmp    d4
  108. d4:    ret
  109.  
  110. comment 
  111. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(  MISC   )
  112. ;read_timer - read high resolution timer
  113. ;  inputs:  none
  114. ;  output:  dx,ax = total 8253 timer ticks at rate of 1,193,182 per second
  115. ;           
  116. ;* * * * * * * * * * * * * *
  117. 
  118.     public    read_timer
  119. read_timer    proc    far
  120.     apush    ds,es
  121.     pushf
  122.     cli
  123.     mov    ax,cs
  124.     mov    ds,ax
  125.     xor    ax,ax
  126.     mov    es,ax
  127. ;
  128. ; stop timer by setting mode to zero
  129. ;
  130.     out    timer_mode,al    ;timer interrupts off
  131.     call    delay
  132.     in    al,timer0
  133.     call    delay
  134.     mov    ah,al
  135.     in    al,timer0
  136.     xchg    ah,al
  137.     neg    ax
  138.     mov    timer_count,ax    ;ax now has 16 bit timer count
  139. ;
  140. ; read interrupt count from bios
  141. ;
  142.     mov    ax,es:[timer_low]
  143.     sub    ax,interrupt_count
  144.     mov    interrupt_count,ax
  145. ;
  146. ; restart the timer by resetting default value of control word
  147. ;
  148.     mov    al,00110110b    ;binary,mode 3,timer 0
  149.     out    timer_mode,al
  150.     mov    al,0
  151.     call    delay
  152.     out    timer0,al
  153.     call    delay
  154.     out    timer0,al
  155. ;
  156. ; return values to caller
  157. ;
  158.     mov    ax,timer_count
  159.     mov    dx,interrupt_count
  160.  
  161.     sub    ax,calibrate
  162.     sbb    dx,0            ;calibrate timer value
  163.     popf
  164. exit:    apop    es,ds
  165.     retf
  166. read_timer    endp
  167.  
  168. comment 
  169. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(  MISC   )
  170. ;CONVERT_TIMER - convert timer ticks to seconds and microseconds
  171. ;  inputs:  dx,ax = total 8253 timer ticks at rate of 1,193,182 per second
  172. ;  output:  ax = seconds
  173. ;           cx,bx = microseconds
  174. ;
  175. ;* * * * * * * * * * * * * *
  176. 
  177.     public    CONVERT_TIMER
  178. CONVERT_TIMER    proc    far
  179.     apush    si,ds
  180.     mov    si,cs
  181.     mov    ds,si
  182.  
  183.     mov    cx,word ptr timer_convert+2
  184.     mov    bx,word ptr timer_convert
  185.     call    quad_multiply1        ;result to dx,cx,bx,ax
  186.     mov    si,word ptr hundred_thousand+2
  187.     mov    di,word ptr hundred_thousand
  188.     call    quad_divide        ;result dx,ax  remainder cx,bx
  189.  
  190. ;
  191. ; dx,ax now contains the total number of micro seconds, cx,bx = remainder
  192. ;
  193.     cmp    cx,1
  194.     je    round_up
  195.     cmp    bx,0c350h        ;(100000/2)
  196.     jb    compute_seconds
  197. round_up:
  198.     add    ax,1
  199.     adc    dx,0            ;round up 1
  200.  
  201. compute_seconds:
  202.     mov    bx,dx
  203.     xor    dx,dx
  204.     xor    cx,cx
  205.     mov    si,word ptr million+2
  206.     mov    di,word ptr million
  207.     call    quad_divide        ;compute seconds & microseconds
  208. ;
  209. ; dx,ax = seconds   cx,bx = microseconds
  210. ;
  211.     apop    ds,si
  212.     retf        
  213.  
  214. CONVERT_TIMER    endp
  215.  
  216. comment 
  217. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(  MISC   )
  218. ;DISPLAY_TIMER - display timer values to stdout
  219. ;  inputs:   ax = seconds
  220. ;          cx,bx = microseconds
  221. ;  output:  none
  222. ;           
  223. ;* * * * * * * * * * * * * *
  224. 
  225.     public    display_timer
  226. DISPLAY_TIMER    proc    far
  227.     apush    si,ds
  228.  
  229.     mov    si,cs
  230.     mov    ds,si
  231.     mov    seconds,ax
  232.     mov    word ptr microseconds+2,cx
  233.     mov    word ptr microseconds,bx
  234.  
  235.     mov    si,offset msg1
  236.     call    stdout_string            ;display 'Elapsed time ="
  237.     
  238.     mov    ax,seconds
  239.     call    word_to_dec_stdout        ;seconds
  240.     mov    si,offset message_sec
  241.     call    stdout_string
  242.     
  243.     mov    ax,word ptr microseconds
  244.     mov    dx,word ptr microseconds+2
  245.     call    dword_to_dec_stdout
  246.     mov    si,offset message_micro
  247.     call    stdout_string
  248.     apop    ds,si
  249.     retf
  250. DISPLAY_TIMER    endp
  251. comment 
  252. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(  MISC   )
  253. ;CALIBRATE_TIMER - calibrate timer
  254. ;  inputs:  none
  255. ;  output:  none
  256. ; 
  257. ; note:  This function computes the overhead needed to call
  258. ;        START_TIMER and read_timer on current computer and
  259. ;        calibrates the time calculation so that it will
  260. ;        compute zero if nothing is being timed.           
  261. ;
  262. ; note:  This function only needs to be called once.  It saves
  263. ;        a calibration factor which is used by read_timer as
  264. ;        long as read_timer is in memory.
  265. ;* * * * * * * * * * * * * *
  266. 
  267.  
  268.     public    calibrate_timer
  269. calibrate_timer    proc    far
  270.     apush    ax,bx,cx,dx
  271.     mov    cs:calibrate,0
  272.     mov    cs:seconds,0
  273.     mov    cx,8
  274. ct_lp1:    push    cx
  275.            call    start_timer
  276.     call    read_timer
  277.     add    cs:seconds,ax
  278.     pop    cx
  279.     loop    ct_lp1
  280.  
  281.     mov    ax,cs:seconds
  282.     mov    cl,3
  283.     shr    ax,cl
  284.     mov    cs:calibrate,ax
  285.     
  286.     mov    cx,5000
  287. ct_lp:    call    delay
  288.     loop    ct_lp
  289.     apop    dx,cx,bx,ax
  290.     retf
  291. calibrate_timer    endp
  292. ;--------------------------------------------------------------------------
  293.  
  294. timer_count    dw    0    ;read from 8253
  295. interrupt_count    dw    0    ;read from BIOS
  296.  
  297. microseconds    dd    0    ;total microseconds
  298. seconds        dw    0    ;total seconds
  299.  
  300. calibrate    dw    0    ;calibration factor from read_timer
  301.  
  302. timer_convert    dd    83809    ;838.096 nsec per tick
  303. hundred_thousand dd    100000
  304. million        dd    1000000
  305.  
  306. msg1        db    0dh,0ah,0dh,0ah,'Elapsed time = ',0
  307. message_sec    db    ' (seconds)   ',0
  308. message_micro    db    ' (Micro seconds)',0dh,0ah,0
  309.  
  310.  
  311. LIBSEG    ENDS
  312. ;;    end
  313.