home *** CD-ROM | disk | FTP | other *** search
/ C!T ROM 5 / ctrom5b.zip / ctrom5b / PROGRAM / ASM / ALIB30B / SYS1.ASM < prev    next >
Assembly Source File  |  1994-11-28  |  19KB  |  787 lines
  1.     page    66,132
  2. ;******************************** SYS1.ASM   *********************************
  3.  
  4. LIBSEG           segment byte public "LIB"
  5.         assume cs:LIBSEG , ds:nothing
  6.  
  7. ;----------------------------------------------------------------------------
  8. .xlist
  9.     include  mac.inc
  10.     include  common.inc
  11. .list
  12. ;----------------------------------------------------------------------------
  13.     extrn    SETUP_MOUSE:far
  14.     extrn    HIDE_CURSOR:far
  15.     extrn    SHOW_CURSOR:far
  16.     extrn    BLINK_OFF:far
  17.     extrn    BLINK_ON:far
  18.     extrn    get_ansi_color:far
  19.     extrn    clear_screen:far
  20.     extrn    mem_open:far
  21.     extrn    mem_close:far
  22.     extrn    float_open:near
  23.     extrn    float_close:near
  24.     extrn    lib_info:byte
  25.     extrn    is_stdout_console:far
  26. ;░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░
  27. ; LIBRARY_SETUP returns a pointer to the following structure.
  28. ;
  29. ;info    struc
  30. ; cpu_type    db    ?    ;0=88 1=186 2=286 3=386 4=486
  31. ; math_chip    db    ?    ;0=none 1=8087 2=287 3=387 4=487
  32. ; mouse_present    db    ?    ;0=no n=yes
  33. ; crt_type    db    ?    ;
  34. ; crt_mode    db    ?
  35. ; mono_flag    db    ?
  36. ; ansi_present    db    ?    ;0=no 1=yes
  37. ; users_color    db    ?
  38. ; crt_seg    dw    ?    ;segment of crt buffer
  39. ; crt_rows    db    ?    ;
  40. ; crt_columns    db    ?    ;
  41. ; key_type    db    ?    ;keyboard type 0=old style 1=enhanced
  42. ; psp_seg    dw    ?    ;psp segment
  43. ;info    ends
  44.  
  45. comment 
  46. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  47. LIBRARY_SETUP - setup library for use
  48. ;
  49. ;  inputs:  ax = psp segment
  50. ;           bx = number of floating variables needed
  51. ;           
  52. ;  output:  es:si = pointer to library info structure
  53. ;         carry = error, library unusable
  54. ;
  55. ;      info    struc
  56. ;       cpu_type    db    ?    ;0=88 1=186 2=286 3=386 4=486
  57. ;       math_chip    db    ?    ;0=none 1=8087 2=287 3=387 4=487
  58. ;       mouse_present    db    ?    ;0=no n=yes
  59. ;       crt_type    db    ?    ;
  60. ;       crt_mode    db    ?
  61. ;       mono_flag    db    ?
  62. ;       ansi_present    db    ?    ;0=no 1=yes
  63. ;       users_color    db    ?
  64. ;       crt_seg    dw    ?    ;segment of crt buffer
  65. ;       crt_rows    db    ?    ;
  66. ;       crt_columns    db    ?    ;
  67. ;       key_type    db    ?    ;0=old style 1=enhanced
  68. ;       psp_seg    dw    ?
  69. ;      info    ends
  70. ;         
  71. ;* * * * * * * * * * * * * *
  72. 
  73. fvar_count    dw    0        ;number of floating variables needed
  74.  
  75.     public    LIBRARY_SETUP
  76. LIBRARY_SETUP    PROC    FAR
  77.     mov    lib_info.psp_seg,ax
  78.     mov    cs:fvar_count,bx
  79.         
  80.     call    FIND_CPU_TYPE
  81.     mov    lib_info.cpu_type,al
  82.  
  83.     call    MATH_HARDWARE
  84.     mov    lib_info.math_chip,al
  85.  
  86.     call    SETUP_MOUSE
  87.     jc    ls_disp
  88.     mov    lib_info.mouse_present,1
  89. ls_disp:
  90.     call    display_info
  91.     mov    lib_info.crt_type,al
  92.     mov    lib_info.crt_rows,bl
  93.     mov    lib_info.crt_columns,cl
  94.  
  95.     call    find_display_segment
  96.  
  97.     call    set_display_flags
  98.     mov    lib_info.mono_flag,al
  99.  
  100.     call    CHECK_ANSI
  101.     mov    lib_info.ansi_present,0
  102.     jc    ansi_end
  103.     mov    lib_info.ansi_present,1
  104. ansi_end:
  105. ;;      call      HIDE_CURSOR
  106.     call    BLINK_OFF
  107.     
  108.     cmp    lib_info.ansi_present,0
  109.     je    get_bios_color
  110.     call    get_ansi_color
  111.     mov    lib_info.users_color,ah
  112.     jmp    color_end
  113. get_bios_color:
  114.     mov    ah,08h
  115.     mov    bh,0            ;page 0
  116.     int    10h            ;read display
  117.     mov    lib_info.users_color,ah
  118. color_end:
  119.  
  120.     mov    ax,0500h        ;force display
  121.     int    10h            ;  page 0
  122.     
  123.     call    keyboard_setup        ;determine keyboard type
  124.     mov    lib_info.key_type,al    ;0=old style  1=enhanced
  125.     
  126.     call    mem_open        ;setup memory
  127. ;
  128. ; if mem_open returns an error or warning the carry is set and is returned
  129. ;
  130.     jc    ls_skip1        ;jmp if memory setup error
  131.     mov    bx,cs:fvar_count
  132.     call    float_open        ;sets carry if error
  133. ls_skip1:    
  134.     push    cs
  135.     pop    es
  136.     mov    si,offset lib_info
  137. ls_error:
  138.     cld                ;force direction flag
  139.     retf
  140.  
  141. LIBRARY_SETUP    ENDP
  142.  
  143. comment 
  144. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  145. LIBRARY_TERMINATE - close out library for program exit
  146. ;
  147. ;  inputs:  ax = 0 clear screen at exit
  148. ;           ax = 1 do not clear screen
  149. ;           
  150. ;  output:  none
  151. ;* * * * * * * * * * * * * *
  152. 
  153.     public    library_terminate
  154. library_terminate    proc    far
  155.     cmp    ax,0
  156.     jne    lt_skip            ;skip clear screen if ax=n
  157.     mov    ax,0720h        ;clear_screen info
  158.     call    clear_screen
  159.     mov    dx,0            ;cursor position
  160.     jmp    lt_end
  161. lt_skip:mov    dx,1800h
  162.  
  163. lt_end:    call    SHOW_CURSOR        ;dx=cursor position to set
  164.     call    BLINK_ON
  165.     call    float_close
  166.     call    mem_close
  167.     retf
  168. library_terminate    endp
  169. ;
  170. comment 
  171. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  172. FIND_CPU_TYPE - detects cpu type
  173. ;
  174. ; inputs:  none
  175. ; 
  176. ; output:    AX = 0 if 8086/8088
  177. ;            AX = 1 if 80186/80188
  178. ;            AX = 2 if 80286
  179. ;            AX = 3 if 386 (SX or DX)
  180. ;            AX = 4 if 486 (SX or DX)
  181. ;* * * * * * * * * * * * * *
  182. 
  183.     public    FIND_CPU_TYPE
  184. FIND_CPU_TYPE    PROC    FAR
  185.      XOR     AX,AX
  186.      PUSH    AX
  187.      POPF
  188.      PUSHF
  189.      POP     AX
  190.      AND     AX,0F000h
  191.      CMP     AX,0F000h
  192.      JNZ     getcpu_2            ;jmp if not 8088,80188,8086,80186
  193.      PUSH    CX
  194.      MOV     AX,0FFFFh
  195.      MOV     CL,21h                ;286+ mask -cl- with 1fh
  196.      SHL     AX,CL
  197.      POP     CX
  198.      JNZ     getcpu_1            ;jmp if 80188 or 80186
  199. ;
  200. ; we have found an 8088 or 8086
  201. ;     
  202.      XOR     AX,AX
  203.      JMP     getcpu_exit
  204. ;
  205. ; we have found an 80188 or 80186
  206. ;     
  207. getcpu_1:
  208.      MOV     AX,0001
  209.      JMP     getcpu_exit
  210. ;
  211. ; we have a 286+ cpu, determine if this is 286
  212. ;     
  213. getcpu_2:
  214.      MOV     AX,7000h
  215.      PUSH    AX
  216.      POPF
  217.      PUSHF
  218.      POP     AX
  219.      AND     AX,7000h
  220.      JNZ     getcpu_3            ;jmp if not 80286
  221. ;
  222. ; we have found an 80286
  223. ;     
  224.      MOV     AX,0002
  225.      JMP     getcpu_exit
  226. ;
  227. ; we have found a 80386+ cpu, determine if 80386
  228. ;     
  229. getcpu_3:
  230.      PUSH    DX
  231.      MOV     DX,0003            ;preload code for 80386
  232.      DB        66H,50H            ;PUSH    EAX
  233.      DB        66H,53H            ;PUSH    EBX
  234.      DB        66H,51H            ;PUSH    ECX
  235.      DB        66H,8BH,0DCH        ;MOV     EBX,ESP
  236.      DB        66H,83H,0E4H,8CH    ;AND     ESP,-04
  237.      DB        66H,9CH            ;PUSHFD
  238.      DB        66H,58H            ;POP     EAX
  239.      DB        66H,8BH,0C8H        ;MOV     ECX,EAX
  240.      DB        66H,35H,00,00,04,00    ;XOR     EAX,00040000h
  241.      DB        66H,50H            ;PUSH    EAX
  242.      DB        66H,9DH            ;POPFD
  243.      DB        66H,9CH            ;PUSHFD
  244.      DB        66H,58H            ;POP     EAX
  245.      DB        66H,25H,00,00,04,00    ;AND     EAX,00040000h
  246.      DB        66H,81H,0E1H,0,0,04,00    ;AND     ECX,00040000h
  247.      DB        66H,3BH,0C1H        ;CMP     EAX,ECX
  248.      JZ      getcpu_4            ;jmp if 80386
  249. ;
  250. ; we have found an 80486
  251. ;     
  252.      MOV     DX,0004            ;preload 80486 code
  253. getcpu_4:
  254.      DB        66H,51H            ;PUSH    ECX
  255.      DB        66H,9DH            ;POPFD
  256.      DB        66H,8BH,0E3H        ;MOV     ESP,EBX
  257.      DB        66H,59H            ;POP     ECX
  258.      DB        66H,5BH            ;POP     EBX
  259.      DB        66H,58H            ;POP     EAX
  260.      MOV     AX,DX
  261.      POP     DX
  262. getcpu_exit:
  263.      RETF
  264. FIND_CPU_TYPE    ENDP
  265. comment 
  266. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  267. MATH_HARDWARE - determines if 80x87 math coprocessor is installed
  268. ;
  269. ; inputs:    none
  270. ; 
  271. ; output:    AX = code for 80x87 model
  272. ;            0 = not installed
  273. ;            1 = 8087
  274. ;            2 = 287
  275. ;            3 = 387 (DX or SX)
  276. ;            4 = 487 (486DX or 487SX)
  277. ;            If the coprocessor is present, it is initilaized by MATH_HARDWARE.
  278. ;            
  279. ;* * * * * * * * * * * * * *
  280. 
  281.     public    MATH_HARDWARE
  282. MATH_HARDWARE    PROC    FAR
  283.      XOR     AX,AX
  284.      PUSH    AX
  285.      POPF
  286.      PUSHF
  287.      POP     AX
  288.      AND     AX,0F000h
  289.      CMP     AX,0F000h
  290.      JZ      math_2
  291.      INT     11h
  292.      AND     AX,0002
  293.      JZ      math_exit1            ;jmp if no math chip
  294.      PUSH    BP
  295.      MOV     BP,SP
  296.      SUB     SP,+04
  297.      MOV     WORD PTR [BP-04],0000
  298.      MOV     WORD PTR [BP-02],7F80h
  299.      FLD     DWORD PTR [BP-04]
  300.      FLD     ST(0)
  301.      FCHS
  302.      FCOMPP
  303.      FSTSW   [BP-02]
  304.      MOV     AX,[BP-02]
  305.      MOV     SP,BP
  306.      POP     BP
  307.      SAHF
  308.      MOV     AX,0002            ;load code for 287
  309.      JZ      math_exit1            ;jmp if 287
  310.      CALL    FIND_CPU_TYPE
  311. math_exit1:
  312.      RETF
  313. math_2:
  314.      PUSH    BP
  315.      MOV     BP,SP
  316.      SUB     SP,+02
  317.      XOR     DX,DX
  318.      MOV     [BP-02],DX
  319.      FINIT
  320.      FSTCW   [BP-02]
  321.      PUSH    CX
  322. math_3:
  323.      MOV     CX,0003
  324.      LOOP    math_3
  325.      POP     CX
  326.      MOV     AX,[BP-02]
  327.      AND     AX,0300h
  328.      CMP     AX,0300h
  329.      JNZ     math_exit2        ;jmp if no math chip
  330.      INC     DX            ;set dx=1 (8087)
  331. math_exit2:
  332.      MOV     AX,DX
  333.      MOV     SP,BP
  334.      POP     BP
  335.      RETF
  336. MATH_HARDWARE    ENDP
  337. comment 
  338. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  339. keyboard_setup - determine type of keyboard attached
  340. ;
  341. ; inputs: none
  342. ; 
  343. ; output: al = 0(old style bios)  1(enhanced bios)
  344. ;* * * * * * * * * * * * * *
  345. 
  346.     public    keyboard_setup
  347. keyboard_setup    proc    far
  348.     push    es
  349.     mov    ax,0
  350.     mov    es,ax
  351.  
  352.     mov    ah,12h
  353.     int    16h            ;get extended bios shift status
  354.     cmp    al,byte ptr es:[417h]    ;check if memory copy correct
  355.     jne    ks_old            ;jmp if old style keyboard
  356.  
  357.     xor    byte ptr es:[417h],80h    ;toggle insert mode
  358.     mov    ah,12h
  359.     int    16h            ;get extended bios shift status
  360.     cmp    al,byte ptr es:[417h]    ;double check incase first check wrong
  361.     jne    ks_old            ;jmp if old style keyboard
  362.     mov    al,1
  363.     jmp    ks_exit            ;exit, extended keyboard status
  364. ks_old:    mov    al,0
  365. ks_exit:pop    es
  366.     retf    
  367. keyboard_setup    endp
  368. comment 
  369. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  370. FIND_MOUSE - determines if a mouse is installed
  371. ;
  372. ; inputs:    none
  373. ; 
  374. ; output:    AX = number of mouse buttons
  375. ;            AX = 0 if no mouse or mouse driver installed
  376. ;* * * * * * * * * * * * * *
  377. 
  378.     public    FIND_MOUSE
  379. FIND_MOUSE    PROC    FAR
  380.      push    bx
  381.      xor     ax,ax
  382.      or      al,cs:lib_info.mouse_present
  383.      JNZ     ism_exit
  384.      INT     33h
  385.      AND     AX,BX
  386.      MOV     cs:lib_info.mouse_present,al
  387. ism_exit:
  388.      POP     BX
  389.      RETF
  390. FIND_MOUSE    ENDP
  391. comment 
  392. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  393. CHECK_ANSI - check if ANSI active
  394. ;
  395. ; inputs:    none
  396. ; 
  397. ; output:    CF = 1 if no ANSI driver active
  398. ;            CF = 0 if ANSI active
  399. ;* * * * * * * * * * * * * *
  400. 
  401.     public    CHECK_ANSI
  402. CHECK_ANSI        PROC    FAR
  403.      APUSH   AX,DX,DS
  404.      call    is_stdout_console
  405.      test    al,al
  406.      jz      no_ansi1        ;jmp if output redirected (force no ansi)
  407.      MOV     AX,CS
  408.      MOV     DS,AX
  409.      CALL    console_input
  410.      CALL    CHECK_ANSI_cont1
  411.  
  412.      DB         1BH,'[6n$'
  413. ;
  414. CHECK_ANSI_cont1:
  415.      POP     DX
  416.      CALL    console_output
  417.      MOV     AH,0Bh        ;check STDIN status, al=ff if input
  418.      INT     21h
  419.      CMP     AL,0FFh
  420.      JZ      IA_1        ;jmp if char. is ready from ansi call
  421.      CALL    isansi_cont2
  422.  
  423.      db         0dH,'    ',0dH,'$'
  424.  
  425. isansi_cont2:
  426.      POP    DX
  427.      CALL    console_output
  428. no_ansi1:
  429.      STC
  430.      JMP     IA_2
  431. IA_1:
  432.      CALL    console_input
  433.      CLC
  434. IA_2:
  435.      APOP    DS,DX,AX
  436.      JB      NO_ANSI
  437.      CLC
  438.      RETF
  439. NO_ANSI:
  440.      STC
  441.      RETF
  442. CHECK_ANSI    ENDP
  443. ;------------------------------
  444. console_output:
  445.      MOV     AH,09
  446.      INT     21h
  447.      RET
  448.  
  449. console_input:
  450.      MOV     AH,06
  451.      MOV     DL,0FFh
  452.      INT     21h
  453.      JNZ     console_input
  454.      RET
  455.  
  456. comment 
  457. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  458. DISPLAY_INFO - determine display information
  459. ;
  460. ; inputs:    none
  461. ;            
  462. ; output:    AL = screen rows
  463. ;            CH = screen columns
  464. ;            BX:[SI] = video buffer address
  465. ;            register DX is modified
  466. ;* * * * * * * * * * * * * *
  467. 
  468.     public    display_info
  469. display_info:
  470.     push    es
  471.     call    detectvid            ;get video type
  472.     cmp    ax,0
  473.     je    display_info_exit        ;exit if no display
  474. ;
  475. ; check for special case, dual display and alternate monochrome active
  476. ;
  477.     mov    bx,0
  478.     mov    es,bx
  479.     cmp    al,3                ;check if color display
  480.     jb    mono_port            ;jmp if mono
  481.     cmp    word ptr es:[463h],3d4h        ;verify color port active
  482.     je    port_ck_end            ;jmp if port ok
  483.     mov    ax,2                ;force monochrome display
  484.     jmp    port_ck_end
  485. mono_port:
  486.     cmp    word ptr es:[463h],3b4h        ;verify mono port active
  487.     je    port_ck_end
  488.     mov    ax,5                ;force cga color
  489. port_ck_end:
  490.     
  491.     push    ax
  492.     mov    ax,0500h
  493.     int    10h                ;force page 0
  494.  
  495.     mov    ax,0
  496.     mov    es,ax
  497.     mov    bh,es:[449h]            ;get display mode
  498.     pop    ax
  499.  
  500.     cmp    al,6
  501.     jbe    get_rows            ;jmp if mono or cga
  502.     cmp    al,9
  503.     je    get_rows            ;jmp if cga compatable
  504.  
  505.     push    ax
  506.     push    bx
  507.     mov    ax,1130h
  508.     mov    bh,0
  509.     push    es
  510.     int    10h
  511.     pop    es
  512.     pop    bx
  513.     pop    ax
  514.     mov    bl,dl                ;move rows to -bl-
  515.     jmp    rows_ok      
  516.  
  517. get_rows:
  518.     mov    bl,es:[484h]            ;get rows
  519.     cmp    bl,0
  520.     je    fix_rows            ;jmp if row info bad
  521.     cmp    bl,80
  522.     jb    rows_ok                ;jmp if row info found
  523. fix_rows:
  524.     mov    bl,24                ;force 25 lines on screen
  525. rows_ok:
  526.     inc    bl
  527. get_columns:
  528.     mov    cx,word ptr es:[44ah]        ;get columns on display
  529. display_info_exit:
  530.     pop    es
  531.     ret    
  532. comment 
  533. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  534. DETECTVID -  determine display type
  535. ;
  536. ;  inputs: none
  537. ;  
  538. ;  outputs:  ax = 0  no display
  539. ;                 1  monochrome
  540. ;                 2  hercules 
  541. ;                 3  cga digital (mono)
  542. ;                 4  cga analog  (mono)
  543. ;                 5  cga analog (color)
  544. ;                 6  ega mono
  545. ;                 7  ega color 64k
  546. ;                 8  ega color 64k+
  547. ;                 9  cga compatable
  548. ;                10  vga mono
  549. ;                11  vga color 
  550. ;* * * * * * * * * * * * * *
  551. 
  552. vga_mono    equ    10
  553. vga_color    equ    11
  554. monochrome    equ    1
  555. hercules    equ    2
  556.  
  557.     public    detectvid
  558. detectvid:
  559.     mov ax,1a00h          ;used by mcga and vga
  560.     int 10h
  561.     cmp al,1ah            ;if al = 1ah then mcga or vga is present
  562.     jnz dt1
  563.     cmp bl,7              ;if active monitor is monochrome vga
  564.     jnz do1
  565.     mov ax,vga_mono       ;mono vga found
  566.     ret
  567. do1:
  568.     cmp bl,8              ;if active monitor is color vga
  569.     jnz do2
  570.     mov ax,vga_color      ;color vga found
  571.     ret
  572. do2:
  573.     cmp bl,0ah            ;if digital mcga
  574.     jnz do3
  575.     mov ax,3              ;digital mcga found
  576.     ret
  577. do3:
  578.     cmp bl,0bh            ;if monochrome mcga
  579.     jnz do4
  580.     mov ax,4              ;analog monochrome mcga found
  581.     ret
  582. do4:
  583.     cmp bl,0ch            ;if color mcga
  584.     jnz dt1
  585.     mov ax,5              ;analog color mcga found
  586.     ret
  587. dt1:
  588.     mov ah,12h            ;used by ega
  589.     mov bl,10h
  590.     int 10h
  591.     cmp bl,10h            ;if bl is not 10h then ega is present
  592.     jz dt2
  593.     cmp bh,1              ;if monochrome ega
  594.     jnz do5
  595.     mov ax,6              ;monochrome ega
  596.     ret
  597. do5:
  598.     or bl,bl              ;or 64k ega board
  599.     jnz do6
  600.     mov ax,7              ;color ega with 64k memory
  601.     ret
  602. do6:
  603.     mov ax,8              ;color ega with > 64k memory
  604.     ret
  605. dt2:
  606.     mov dx,3d4h           ;address for cga crtc
  607.     call find6845         ;look for controller
  608.     jnc dt3               ;if clear then cga present
  609.     mov dx,3b4h           ;address for hercules or mda
  610.     call find6845         ;look for controller
  611.     jnc dt4               ;jump if hercules or mda present
  612.     mov ax,0              ;unable to detect card
  613.     ret
  614. dt3:
  615.     mov ax,9              ;cga compatible present
  616.     ret
  617. dt4:
  618.     mov dl,0bah           ;read this port
  619.     in al,dx
  620.     and al,80h            ;get value in ah
  621.     mov ah,al
  622.     mov cx,8000h          ;loop this many times
  623. dt5:
  624.     in al,dx              ;read port
  625.     and al,80h
  626.     cmp ah,al             ;has value changed
  627.     loopz dt5
  628.     jcxz dt6              ;if cx = 0 then mda is present
  629.     mov ax,hercules       ;hercules card
  630.     ret
  631. dt6:
  632.     mov ax,monochrome     ;mda card
  633.     ret
  634. ;-------------------------------------------------------------------------
  635.     public    find6845
  636. find6845 proc near        ;find out if crtc is present
  637.     mov al,0fh            ;select reg ( cursor low )
  638.     out dx,al
  639.     inc dx
  640.     in al,dx              ;al = cursor low position
  641.     mov ah,al             ;save value in ah
  642.     mov al,66h            ;arbitrary value
  643.     out dx,al             ;write to crtc
  644.     mov cx,100h
  645. f61:
  646.     loop f61              ;wait for response
  647.     in al,dx
  648.     xchg ah,al            ;ah = returned value
  649.     out dx,al             ;reset port
  650.     cmp ah,66h            ;was value unchanged
  651.     je f62
  652.     stc                   ;if no response
  653. f62:
  654.     ret
  655. find6845 endp
  656.  
  657. comment 
  658. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -( SYSTEM  )
  659. FIND_DISPLAY_SEGMENT  -  scan for current display buffer segment
  660. ;
  661. ;  inputs:   display mode 3 or 7 must be set and display page must = 0
  662. ;  
  663. ;  output:   display_segment is set
  664. ;
  665. ;* * * * * * * * * * * * * *
  666. 
  667.     public    find_display_segment
  668. find_display_segment:
  669.     push    ax
  670.     push    bx
  671.     push    es
  672.     cli
  673.     mov    ax,0b000h        ;display seg?
  674.     mov    es,ax
  675.     mov    bx,es:[0]        ;save current data
  676.     mov    word ptr es:[0],0101h    ;store code 0101 at b000
  677.     mov    ax,0b800h        ;move to b800
  678.     mov    es,ax
  679.     mov    cx,es:[0]        ;save current data
  680.     mov    word ptr es:[0],0303h    ;store code 0303 at b800
  681.  
  682.     push    bx
  683.     push    cx
  684.  
  685.     mov    ah,3
  686.     mov    bh,0
  687.     int    10h            ;read cursor position -> dx
  688.     mov    cx,dx            ;save cursor posn
  689.  
  690.     mov    ah,2            ;move
  691.     mov    bh,0            ; cursor
  692.     mov    dx,0            ;   to page 0
  693.     int    10h            ;     top left
  694.  
  695.     mov    ah,8            ;read
  696.     mov    bh,0            ;  data
  697.     int    10h            ;    at cursor
  698. ;
  699. ; restore cursor position
  700. ;
  701.     push    ax            ;save data read
  702.     mov    dx,cx
  703.     mov    ah,2
  704.     int    10h
  705.     pop    ax            ;restore data read 
  706. ;
  707. ; restore origional display buffer data
  708. ;
  709.     pop    cx            ;  origional
  710.     pop    bx            ;   display contents
  711.     push    ax            ;save data read
  712.     mov    ax,0b000h
  713.     mov    es,ax
  714.     mov    word ptr es:[0],bx
  715.     mov    ax,0b800h
  716.     mov    es,ax
  717.     mov    word ptr es:[0],cx
  718. ;
  719. ; recover data read from display to determine segment location
  720. ;    
  721.     pop    ax
  722.     cmp    ax,0101h
  723.     je    use_b000
  724. use_b800:
  725.     mov    ax,0b800h
  726.     jmp    set_seg_cont
  727. use_b000:
  728.     mov    ax,0b000h
  729. set_seg_cont:
  730.     mov    lib_info.crt_seg,ax
  731.     sti
  732.     pop    es
  733.     pop    bx
  734.     pop    ax
  735.     ret
  736.  
  737. ;░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░
  738. ; set_display_flags - determine cga snow flag and mono flag default settings
  739. ;  inputs: crt_info data stored in data base
  740. ;  output: al = mono flag (1=mono)
  741. ;          dx = snow flag (cga port if cga)
  742. ;
  743. set_display_flags:
  744.     sub    ax,ax
  745.     mov    es,ax
  746. ;
  747. ; get display mode
  748. ;
  749.     mov    al,byte ptr es:[449h]    ;get display mode
  750.     mov    lib_info.crt_mode,al    
  751. ;
  752. ; force display page zero
  753. ;
  754.     mov    ah,5
  755.     mov    al,0            ;page 0
  756.     int    10h    
  757. ;
  758. ; set cga flag
  759. ;
  760.     mov    al,lib_info.crt_type
  761.     cmp    al,3
  762.     jb    mono_display
  763.     cmp    al,5
  764.     jbe    cga_display
  765.     cmp    al,9
  766.     je    cga_display
  767. ;
  768. ; we must have a color display, it is not a cga or mono
  769. ;
  770.     mov    al,0
  771.     mov    dx,0
  772.     jmp    sdf_exit    
  773. ;
  774. mono_display:
  775.     mov    al,1
  776.     mov    dx,0
  777.     jmp    sdf_exit
  778.     
  779. cga_display:
  780.     mov    al,0
  781.     mov    dx,3dah
  782. sdf_exit:
  783.     ret
  784.  
  785. LIBSEG    ENDS
  786.     end
  787.