home *** CD-ROM | disk | FTP | other *** search
/ C!T ROM 5 / ctrom5b.zip / ctrom5b / PROGRAM / ASM / ALIB30B / PARSE.ASM < prev    next >
Assembly Source File  |  1994-10-31  |  6KB  |  224 lines
  1.     PAGE    66,132
  2. ;******************************** PARSE.LIB ***********************************
  3. ;
  4. ; PARSE_FIRST  - Parse first argument from command line
  5. ; PARSE_NEXT   - Parse next argument from command line
  6. ;
  7. ;------------------------------------------------------------------------------
  8.  
  9. LIBSEG           segment byte public "LIB"
  10.         assume cs:LIBSEG , ds:nothing
  11.  
  12. ;----------------------------------------------------------------------------
  13. .xlist
  14.     include  mac.inc
  15.     include  common.inc
  16. .list
  17. ;----------------------------------------------------------------------------
  18.     extrn    DEC_STR_TO_DWORD:far
  19.     extrn    lib_info:byte
  20. ;----------------------------------------------------------------------------
  21.  
  22. parse_ptr    dw    81h
  23. parameter_length dw    0    ;length of last parameter found
  24.  
  25. comment 
  26. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(  PARSE  )
  27. PARSE_FIRST - parse first arguement from command line
  28. ;
  29. ; inputs: es:di = location to store parsed string
  30. ; 
  31. ; output: es:di = (unchanged) parsed string ptr
  32. ;          cx = length of parsed string (0=no more parameters available)
  33. ;    bh,dx,ax   are set as specified by the flag value in -bh-
  34. ;          bh = 0 - end of parameters
  35. ;                 1 - single alpha parameter was found of form "\x". The
  36. ;                     "x" character was placed in register -bl-
  37. ;                2 - single numeric parameter was found of form "\n". The
  38. ;                     "n" binary value was placed in register -bl-
  39. ;                3 - compound alpha parameter of form "\x:yyyy" was found.
  40. ;                     register -bl- has "x" character.
  41. ;                 4 - compound numeric parameter of form "\x:nnnn" was found.
  42. ;                     register -bl- has "x" character, dx,ax has value of nnnn
  43. ;                 5 - found alpha string of form "\xxxxx"
  44. ;                 6 - found value of form "\nnnn".  The decimal value of
  45. ;               nnnn was placed in registers dx,ax
  46. ;                 7 - found alpha string of form "xxxx"
  47. ;                 8 - found numeric string of form "nnnn".  The decimal
  48. ;               value of nnnn was placed in registers dx,ax
  49. ;
  50. ;* * * * * * * * * * * * * *
  51. 
  52.     PUBLIC    PARSE_FIRST
  53. PARSE_FIRST    PROC    FAR
  54.     mov    cs:parse_ptr,81h    ;start parse at beginning
  55. PARSE_FIRST    ENDP
  56.  
  57. comment 
  58. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(  PARSE  )
  59. PARSE_NEXT - parse next command line parameter
  60. ;
  61. ; inputs:  (see PARSE_FIRST)
  62. ; 
  63. ; outputs: (see PARSE_FIRST)
  64. ;* * * * * * * * * * * * * *
  65. 
  66.     PUBLIC    PARSE_NEXT
  67. PARSE_NEXT    PROC    FAR
  68.     apush    si,di,bp,ds,es
  69.     cld
  70.     mov    ds,cs:lib_info.psp_seg
  71.     mov    si,cs:parse_ptr
  72.     mov    cx,0                ;set parameter lenght to zero
  73. ;
  74. ; registers: es:di = callers storage buffer
  75. ;         ds:si = command line parameter ptr
  76. ;        cx = 0
  77. ;
  78. parse_01:
  79.     lodsb                    ;get next parameter
  80.     cmp    al,0dh
  81.     je    parse_no_more            ;jmp if no parameters
  82.         cmp     al,' '
  83.     je    parse_01            ;jmp if leading space (ignore)
  84.     cmp    al,09
  85.     je    parse_01            ;jmp if tab (ignore)
  86. ;
  87. ; the character in -al- is valid, move string to callers buffer.
  88. ;
  89.     push    si
  90.     push    di
  91. parse_02:
  92.     stosb
  93.     inc    cx
  94.     lodsb
  95.         cmp     al,' '
  96.     je    parse_10            ;jmp if end of string found
  97.     cmp    al,0dh
  98.     je    parse_10            ;jmp if end of string found
  99.         cmp     al,'\'                          ;
  100.     je    parse_10            ;jmp if next string found
  101.     cmp    al,09h                ;tab?
  102.     jne    parse_02            ;jmp if string is still valid
  103. ;
  104. ; the next string has now been placed in the callers buffer, next begin decode
  105. ;
  106. parse_10:
  107.     mov    cs:parse_ptr,si
  108.     mov    cs:parameter_length,cx
  109.     mov    byte ptr es:[di],0        ;put zero at end of string
  110.     pop    di
  111.     pop    si
  112.     dec    si                ;move back to string start
  113. ;
  114. ; registers = ds:si - start of parameter
  115. ;
  116.     mov    al,byte ptr [si]        ;get initial char. again
  117.         cmp     al,'\'                          ;check if flag type char.
  118.     je    parse_slash            ;jmp if slash first char
  119. ;
  120. ; this string is either an alpha string or numeric string, determine which
  121. ;
  122.     call    DEC_STR_TO_DWORD
  123.     jc    parse_alpha               ;jmp if alpha found
  124. ;
  125. ; we have a numeric string of form "nnnn'.  The value is in dx,ax
  126. ;
  127.     mov    bh,8
  128.     jmp    parse_exit
  129. ;
  130. ; we have a alpha string of form "xxxx".
  131. ;
  132. parse_alpha:
  133.     mov    bh,7
  134.     jmp    parse_exit
  135. ;
  136. ; we have found an "\" at the beginning of this parameter, decode
  137. ;  ds:si - point at "\"
  138. ;
  139. parse_slash:
  140.         inc     si                      ;move past "\"
  141. ;
  142. ; check if single character after slash
  143. ;
  144.     mov    al,byte ptr [si+1]    ;get second char. of string
  145.         cmp     al,' '
  146.         je      single_char             ;jmp if parsing "\x"
  147.     cmp    al,09
  148.         je      single_char             ;jmp if parsing "\x"
  149.     cmp    al,0dh
  150.         je      single_char             ;jmp if parsing "\x"
  151.         cmp     al,'\'
  152.         je      single_char             ;jmp if parsing "\x"
  153. ;
  154. ; this parameter is of form "\xxxx" or "\x:yyyy"
  155. ;
  156.         cmp     al,':'
  157.         je      flag_plus               ;jmp if parsing "\x:xxxx"
  158. ;
  159. ; this parameter is of form "\xxxx", check if numeric or alpha
  160. ;
  161.     call    DEC_STR_TO_DWORD
  162.         jc     slash_alpha             ;jmp if parsing alpha "\xxxx"
  163. ;
  164. ; this parameter numeric of form "\nnnn".  dx,ax has value of nnnn
  165. ;
  166.     mov    bh,6
  167.     jmp    parse_exit
  168. ;
  169. ; this parameter is alpha of form "\xxxx"
  170. ;
  171. slash_alpha:
  172.     mov    bh,5
  173.     jmp    parse_exit
  174. ;
  175. ; this parameter is of form "\x:xxxx" check if alpha or numeric
  176. ;
  177. flag_plus:
  178.     mov    bl,byte ptr [si]    ;put flag in register -bl-
  179.         add     si,2                    ;move past "x:"
  180.     call    DEC_STR_TO_DWORD
  181.     jc    colin_alpha
  182. ;
  183. ; this parameter is of form "\x:nnnn".  The value nnnn is in dx,ax
  184. ;
  185.     mov    bh,4
  186.     jmp    parse_exit
  187. ;
  188. ; this parameter is of form "\x:yyyy".  The yyyy is an alpha string
  189. ;
  190. colin_alpha:
  191.     mov    bh,3
  192.     jmp    parse_exit
  193. ;
  194. ; we are parsing "\x".  Check if alpha or binary
  195. ;
  196. single_char:
  197.     call    DEC_STR_TO_DWORD
  198.     jc    single_alpha
  199. ;
  200. ; we are parseing "\n"
  201. ;
  202.     mov    bl,al                ;put value in register -bl-
  203.     mov    bh,2
  204.     jmp    parse_exit
  205. ;
  206. ; we are parsing "\x"
  207. ;
  208. single_alpha:
  209.     mov    bl,byte ptr [si]
  210.     mov    bh,1
  211.     jmp    parse_exit
  212.  
  213. parse_no_more:
  214.     mov    bh,0
  215. parse_exit:
  216.     mov    cx,cs:parameter_length
  217.     apop    es,ds,bp,di,si
  218.     retf
  219. PARSE_NEXT    ENDP
  220. ;------------------------------------------------------------------------------
  221.  
  222. LIBSEG    ENDS
  223.     end
  224.