home *** CD-ROM | disk | FTP | other *** search
/ C!T ROM 5 / ctrom5b.zip / ctrom5b / PROGRAM / ASM / ALIB30B / DBASE.ASM < prev    next >
Assembly Source File  |  1994-12-03  |  34KB  |  1,240 lines
  1.     page    66,132
  2. ;****************************** DBASE.ASM **********************************
  3. ;upper case routine names are available.
  4. ; DBASE_INIT     -setup                     DBASE_REPLACE   -replace record
  5. ; DBASE_READ -read record                   DBASE_REMOVE-delete record
  6. ; DBASE_READ_NEXT-read next record          DBASE_CLOSE - close & write
  7. ; DBASE_READ_PREV-read previous rec.        DBASE_KILL - delete database
  8. ; DBASE_RENAME    -change dbase name
  9. ; DBASE_APPEND   -write rec at end 
  10. ; DBASE_INSERT   -write rec at loc.                                         
  11. ;----------------------------------------------------------------------------
  12.  
  13. LIBSEG           segment byte public "LIB"
  14.         assume cs:LIBSEG , ds:nothing
  15. ;----------------------------------------------------------------------------
  16. .xlist
  17.     include  mac.inc
  18.     include  common.inc
  19. .list
  20. ;----------------------------------------------------------------------------
  21.     extrn    lib_info:byte
  22.     extrn    dos_mem_allocate:far
  23.     extrn    dos_mem_release:far
  24.     extrn    strlen1:far
  25. ;----------------------------------------------------------------------------
  26. ;------------------------------ data section --------------------------------
  27. ;----------------------------------------------------------------------------
  28. buf_size    equ    16384
  29. index_size    equ    512
  30. ;-----------
  31. work_area    struc
  32. buf        db     buf_size dup (?)
  33. buf_end        dw       ?
  34. index        db    index_size    dup (?)
  35. index_end    dw    ?
  36.  
  37. temp_buf    db     buf_size dup (?)            ;used by DBASE_CLOSE
  38. temp_buf_end    dw       ?                ;  and $born_again
  39. temp_index    db    index_size    dup (?)
  40. temp_index_end    dw    ?
  41.  
  42. f_key           dw      ?       ;set to 'JO' to allow verification of selector
  43. f_handle    dw    ?    ;file handle
  44. f_asciiz    db    40 dup (?)
  45. f_flags        db    ?    ;see below
  46.   created    equ    01h    ;file was created or zero length initially.
  47.   at_top    equ    02h    ;file is at start, top of file in buffers.
  48.   at_eof    equ    04h    ;file is at eof, end of file in buffers.
  49.   fdirty    equ    08h    ;current block in memory has been modified
  50.  
  51. f_rec_bak    dw    ?    ;rec# for next block towards front of file
  52. f_seek_bak    dd    ?    ;seek for next block towards front of file
  53.  
  54. f_rec        dw    ?    ;rec# for top of current block in mem
  55. f_seek        dd    ?    ;seek for top of current block in memory
  56.  
  57. f_rec_fwd    dw    ?    ;rec# for next block towards end of file
  58. f_seek_fwd    dd    ?    ;seek for next block towards end of file
  59.  
  60. buf_avail_ptr    dw    ?    ;offset of next avail. buf entry
  61. index_avail_ptr dw    ?    ;offset of index next avail. free space
  62.  
  63. active_index    dw    ?    ;index ptr for last rec# read/written
  64. active_block_size dw    ?    ;size of block in memory
  65. record_count    dw    ?    ;number of records read from disk
  66.  
  67. work_area_end    db    ?
  68. work_area    ends
  69. ;--------------
  70. ;
  71. ; index structure
  72. ;
  73. index_struc    struc
  74. rec_no        dw    ?    ;modification rec# (-1 if record removed)
  75. file_rec_no    dw    ?    ;origional file record number (-1 if insert)
  76. buf_ptr        dw    ?    ;
  77. index_struc    ends
  78. ;---------------
  79. ; error codes -> 0 = success
  80. ;                1 = database empty
  81. ;                2 = selector bad or database buffers damaged
  82. ;                3 = insuffficient memory
  83. ;                4 = disk read/write error, possibly file at eof or top
  84. ;                5 = illegal record number
  85. ;                6 = file open error, or disk full
  86. ;                7 = record length exceeds size of buffers
  87. ;                8 = unknown code error
  88. ;
  89. comment 
  90. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(DATABASE )
  91. DBASE_INIT - open and initialize an existing or new database
  92. ;
  93. ; inputs:  ds:dx = ptr to asciiz file name
  94. ;           
  95. ; output:  no carry + al = 0 (sucessfully opened an existing database)
  96. ;             carry + al = 1 (new data base created)
  97. ;             carry + al = 3 (insufficient memory to open database)
  98. ;             carry + al = 4 (disk error)
  99. ;            bx = selector needed to access database (segment)
  100. ;            cx = number of records read initially, if zero this is null file.
  101. ;            
  102. ; processing: 1. allocate memory to handle database information
  103. ;             2. open the file or create it if necessary
  104. ;             3. initialize the data area
  105. ;             4. read the first block of data
  106. ;
  107. ; Notes:  The database routines are usually called in the following
  108. ;      order:        1. DBASE_INIT
  109. ;                2. database read/write routines
  110. ;            3. dbase_close
  111. ;                      
  112. ;* * * * * * * * * * * * * *
  113. 
  114.     public    DBASE_INIT
  115. DBASE_INIT    proc    far
  116.     apush    dx,si,di,ds,es
  117.     cld
  118.     mov    bx,dx            ;save file asciiz ptr
  119. ;
  120. ;  try to allocate more memory
  121. ;
  122.     mov    dx,0
  123.     mov    ax,offset work_area_end        ;get amount of space needed
  124.     call    dos_mem_allocate
  125.     mov    al,03h                ;preload out of memory err
  126.     jc    di_error              ;jmp if out of memory
  127. ;
  128. ; A free file control block has been found and the segment is in -ax- and -es-
  129. ;    ds:dx = file asciiz name
  130. ; Setup the control block
  131. ;
  132. dinit2:        mov    cx,offset work_area_end
  133.         shr    cx,1
  134.         mov    di,offset buf
  135.         mov    ax,0
  136.         rep    stosw            ;clear the database
  137. ;
  138. ; set the individual fields in the file_control block.
  139. ;
  140.                 mov     word ptr es:[f_key],'JO' ;set check word
  141.  
  142. dinit3:        mov    ax,offset buf
  143.         mov    word ptr es:[buf_avail_ptr],ax
  144.         
  145.         mov    ax,offset index
  146.         mov    word ptr es:[index_avail_ptr],ax
  147. ;
  148. ; move the file asciiz name to file_control
  149. ;
  150.         apush    cx,si,di
  151.         mov    si,bx        ;from offset
  152.         mov    di,offset f_asciiz
  153.         mov    cx,40
  154.         rep    movsb
  155.         apop    di,si,cx
  156. ;
  157. ; attempth to open the file
  158. ;  ds:dx point to asciiz name of file
  159. ;
  160.         mov    dx,bx
  161.         mov    cx,2        ;open for write
  162.         mov    ah,3dh        ;open code
  163.         mov    al,2
  164.         int    21h
  165.         jc    open_failed
  166.         mov    word ptr es:[f_handle],ax
  167. ;
  168. ;  read first record
  169. ;
  170.         mov    al,1        ;select forward read
  171.         call    $disk_read    ;read database
  172.         jnc    di_rd_ok
  173.         cmp    al,4        ;check if eof or disk error
  174.         jne    di_error    ;jmp if bad error
  175. di_rd_ok:    mov    cx,es:record_count
  176. di_cont1:
  177.         mov    al,0
  178.         jcxz    di_e            ;jmp if file of zero length
  179.         jmp    dinit_exit
  180. ;
  181. ; the open failed, try to create the file
  182. ;
  183. open_failed:
  184.     mov    ah,3ch
  185.     mov    cx,0
  186.     int    21h        ;file create
  187.     jc    di_dsk_error
  188.     mov    word ptr es:[f_handle],ax
  189.     mov    al,1
  190. di_e:    or    es:[f_flags],created+at_top+at_eof
  191.     jmp    di_error
  192.  
  193. di_dsk_error:
  194.     mov    al,4
  195. di_error:
  196.     stc
  197. dinit_exit:
  198.     mov    bx,es        ;get database selector
  199.     apop    es,ds,di,si,dx
  200.     retf
  201. DBASE_INIT    endp
  202.  
  203. comment 
  204. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(DATABASE )
  205. DBASE_READ - read specific record from the database.
  206. ;
  207. ; inputs: es = selector from DBASE_INIT
  208. ;         dx = record# to read
  209. ;
  210. ; output: no carry + al = 00 - if successful, cx=read amount
  211. ;            carry + al = 04 - record not here, could be no records are present
  212. ;            carry + al = 02 - selector bad or database corrupted.
  213. ;            carry + al = 07 - record was too big to fit in memory
  214. ;            carry + al = 08 - unknown error
  215. ;      es:si = ptr to record read (valid only if al=0)
  216. ;      cx = record length including separator character. (present if al=0)
  217. ;
  218. ;* * * * * * * * * * * * * *
  219. 
  220.     public    DBASE_READ
  221. DBASE_READ    proc    far
  222.     apush    bx,dx,di,bp,ds
  223.     call    verify1
  224.     jc    drr_exit            ;jmp if error type 1 or 2
  225.     mov    al,0                ;request search of all buffers
  226. drr_retry_entry:
  227.     call    $is_record_in_buf        ;scan buffers
  228. ;
  229. ; is_record_in_buf returns 0 - got record , cx=size
  230. ;                          1 - try reading forward
  231. ;                          2 - try reading backwards
  232.     cmp    al,0
  233.     je    drr_got_record    
  234.     test    es:[f_flags],fdirty
  235.     jz    drr_do_disk
  236.     call    $born_again            ;write out changes
  237.     jc    drr_exit
  238.     jmp    drr_retry_entry
  239. drr_do_disk:    
  240.     call    $disk_read            ;al=1 for forward  al=2 for bak
  241.     jc    drr_exit                 ;jmp if file at eof or top
  242.     jmp    drr_retry_entry            ;go see if we have read rec
  243. ;
  244. ; es:[bx] points at index structure for the requested record.
  245. ; set es:si pointing to rec data  or cx to length
  246. ;
  247. drr_got_record:
  248.     mov    es:[active_index],bx
  249.     mov    si,es:[bx.buf_ptr]    ;get ptr to record
  250.     call    $compute_record_length
  251.     mov    al,0
  252.     clc
  253. drr_exit:
  254.     apop    ds,bp,di,dx,bx
  255.     retf
  256. DBASE_READ    endp
  257.  
  258. comment 
  259. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(DATABASE )
  260. dbase_read_next - read next sequential record.
  261. ;
  262. ; inputs:    es = selector from DBASE_INIT
  263. ;
  264. ; output: no carry or al = 00 - success
  265. ;            carry or al = 01 - record not here, could be no records are present
  266. ;            carry or al = 02 - selector bad or database corrupted.
  267. ;      es:si = ptr to record read (valid only if al=0)
  268. ;      cx = record length including separator character. (present if al=0)
  269. ;         dx = record number
  270. ;
  271. ;* * * * * * * * * * * * * *
  272. 
  273.     public    dbase_read_next
  274. dbase_read_next proc    far
  275.     apush    bx,di,ds
  276.     call    verify1
  277.     jc    drn_exit            ;jmp if error
  278.     mov    bx,es:[active_index]        ;get last record accessed
  279. drn_01: mov    dx,es:[bx.rec_no]
  280.     cmp    dx,-1                ;check if removed record
  281.     jne    drn_03
  282. ;
  283. ; the current record has been removed.    scan forward for record
  284. ;
  285.     sub    bx,size index_struc
  286.     cmp    bx,es:[index_avail_ptr]        ;check if at end of index
  287.     jne    drn_01                ; jmp if not at end of index
  288. ;
  289. ; we have scanned to the end of the index and all records have been removed
  290. ; scan back till a vaild record# found
  291. ;
  292.     mov    bx,es:[active_index]
  293. drn_02: cmp    bx,offset index
  294.     je    drn_04                ;jmp if all records removed
  295.     cmp    es:[bx.rec_no],-1
  296.     jne    drn_03                ;jmp if valid rec# found
  297.     sub    bx,size index_struc
  298.     jmp    drn_02
  299.  
  300. drn_04: mov    dx,es:[f_rec]
  301.     jmp    drn_03
  302.  
  303. drn_03: inc    dx
  304.     call    dbase_read            ;read next record
  305. drn_exit:
  306.     apop    ds,di,bx
  307.     retf
  308. dbase_read_next    endp
  309.  
  310. comment 
  311. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(DATABASE )
  312. dbase_read_prev - read previous record. (write operations do not affect)
  313. ;
  314. ; inputs:     es = selector from DBASE_INIT
  315. ;
  316. ; output: no carry or al = 00 - success
  317. ;            carry or al = 01 - record not here, could be no records are present
  318. ;            carry or al = 02 - selector bad or database corrupted.
  319. ;      es:si = ptr to record read (valid only if al=0)
  320. ;      cx = record length including separator character. (present if al=0)
  321. ;         dx = record number
  322. ;
  323. ;* * * * * * * * * * * * * *
  324. 
  325. drp_temp    dw    0
  326.  
  327.     public    dbase_read_prev
  328. dbase_read_prev proc    far
  329.     apush    bx,di,ds
  330.     call    verify1
  331.     jc    drp_ex
  332.     mov    bx,es:[active_index]
  333.     mov    dx,es:[bx.rec_no]
  334.     cmp    dx,1
  335.     jbe    drp_xx
  336.     cmp    dx,-1
  337.     jne    drp_01            ;jmp if normal record
  338. ;
  339. ; this record has been deleted.
  340. ;
  341. drp_00: mov    dx,es:[f_rec]        ;get initial rec#
  342.     cmp    bx,offset index        ;check if at top of index
  343.     je    drp_01            ; jmp if deleted rec at top
  344.     sub    bx,size index_struc
  345.     cmp    bx,offset index
  346.     je    drp_00            ;jmp if at top of index
  347.     mov    dx,es:[bx.rec_no]    ;get previous rec#
  348.     cmp    dx,-1            ;check if removed record
  349.     je    drp_00
  350.  
  351. drp_01: dec    dx
  352.     call    dbase_read
  353.     jmp    drp_ex
  354. drp_xx:    mov    al,1
  355. drp_ex:    apop    ds,di,bx
  356.     retf
  357. ;
  358. dbase_read_prev endp
  359.  
  360. ;----------------------------------------------------------------------------
  361. ;------------------------------ dbase write ---------------------------------
  362. ;----------------------------------------------------------------------------
  363. comment 
  364. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(DATABASE )
  365. dbase_append - append this record to end of databse
  366. ;
  367. ; inputs:     es = selector from DBASE_INIT
  368. ;          ds:di = source data buffer
  369. ;          cx = length of record excluding the separator character
  370. ;          
  371. ; output:  no carry,  al = 0 (success)
  372. ;            carry or al = 02 - selector bad or database corrupted.
  373. ;                     dx = record # assigned
  374. ;
  375. ;* * * * * * * * * * * * * *
  376. 
  377.     public    dbase_append
  378. dbase_append    proc    far
  379.     apush    bx,cx,bp,si,di,ds,es
  380.     call    verify2
  381.     jc    da_exit                ;jmp if error type 1 or 2
  382. da_lp1:    test    es:[f_flags],at_eof
  383.     jnz    da_at_eof            ;jmp if at end of file
  384.     mov    bx,es:[index_avail_ptr]
  385. da_lp2:    sub    bx,size index_struc
  386.     mov    dx,es:[bx.file_rec_no]
  387.     inc    dx
  388.     call    dbase_read            ;read next block
  389.     jmp    da_lp1
  390. ;
  391. ; we are at the end of file
  392. ;
  393. da_at_eof:
  394.     call    $check_if_room
  395.     jnc    da_append            ;jmp if room for this record
  396.     call    $born_again            ;assume we need to save mods
  397.     jc    da_exit                ;jmp if error
  398.     jmp    da_lp1                ;go scan to eof again
  399. ;
  400. ; append record to end of current block
  401. ;
  402. da_append:
  403.     mov    bx,es:[index_avail_ptr]
  404.     call    $build_index_entry        ;bx=index ptr  ds:si=data
  405.     mov    es:[bx.file_rec_no],-1        ;flag this record as insert
  406.     mov    dx,es:[bx.rec_no]        ;get append record#
  407.     mov    es:[active_index],bx        ;set new active index
  408.     
  409.     add    bx,size index_struc
  410.     mov    es:[index_avail_ptr],bx        ;update available index loc
  411.     mov    al,0
  412.     or    es:[f_flags],fdirty
  413.     clc
  414. da_exit:
  415.     apop    es,ds,di,si,bp,cx,bx
  416.     retf
  417. dbase_append    endp
  418. comment 
  419. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(DATABASE )
  420. dbase_insert - insert this record before specific record
  421. ;
  422. ; inputs:      es = selector from DBASE_INIT
  423. ;        ds:di = source data buffer
  424. ;           cx = length of record excluding the separator char if present
  425. ;              dx = record number to insert before
  426. ;
  427. ; output:  no carry,  al = 0 (success)
  428. ;            carry or al = 01 - record not here, could be no records are present
  429. ;            carry or al = 02 - selector bad or database corrupted.
  430. ;                     dx = record number assigned
  431. ;          
  432. ; Note: Inserts are placed in front of the record number input. 
  433. ;* * * * * * * * * * * * * *
  434. 
  435.     public    dbase_insert
  436. dbase_insert    proc    far
  437.     apush    bx,cx,si,di,bp,ds,es
  438.     call    verify1
  439.     jc    dii_exit
  440.     call    dbase_read            ;read the record
  441.     jc    dii_exit
  442.     call    $is_record_in_buf        ;get index ptr
  443.     call    $make_index_hole
  444.     mov    si,di                ;get buffer ptr -> ds:si
  445.     call    $build_index_entry
  446.     mov    es:[bx.file_rec_no],-1        ;flag this record as insert
  447.     call    $resequence
  448.     mov    al,0
  449.     or    es:[f_flags],fdirty
  450.     clc
  451. dii_exit:
  452.     apop    es,ds,bp,di,si,cx,bx
  453.     retf
  454.  
  455. dbase_insert    endp
  456. comment 
  457. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(DATABASE )
  458. dbase_replace - replace data for a specific record
  459. ;
  460. ; inputs:     es = selector from DBASE_INIT
  461. ;          ds:di = source data buffer
  462. ;          cx = length of record excluding the separator char if present
  463. ;             dx = record number to insert before
  464. ;
  465. ; output:  no carry,  al = 0 (success)
  466. ;            carry or al = 01 - record not here, could be no records are present
  467. ;            carry or al = 02 - selector bad or database corrupted.
  468. ;
  469. ;* * * * * * * * * * * * * *
  470. 
  471. dr_rec_size    dw    0    ;size of replacement record
  472. dr_file_rec    dw    0    ;record #
  473.  
  474.     public    dbase_replace
  475. dbase_replace    proc    far
  476.     apush    bx,cx,dx,si,di,bp,ds,es
  477.     call    verify1
  478.     jc    dr_exit            ;jmp if error type 1 or 2
  479.     call    dbase_read        ;read the correct record
  480.     jc    dr_exit
  481.     call    $is_record_in_buf        ;get index ptr
  482.     mov    si,di            ;get buffer ptr -> si
  483.     call    $build_index_entry
  484.     mov    al,0
  485.     or    es:[f_flags],fdirty
  486.     clc
  487. dr_exit:
  488.     apop    es,ds,bp,di,si,dx,cx,bx
  489.     retf
  490.  
  491. dbase_replace    endp
  492. comment 
  493. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(DATABASE )
  494. DBASE_REMOVE - delete specific record
  495. ;
  496. ; inputs:      es = selector from DBASE_INIT
  497. ;           dx = record number to delete
  498. ;
  499. ; output:  no carry,  al = 0 (success)
  500. ;            carry or al = 01 - record not here, could be no records are present
  501. ;             
  502. ;* * * * * * * * * * * * * *
  503. 
  504.  
  505.     public    DBASE_REMOVE
  506. DBASE_REMOVE    proc    far
  507.     apush    bx,cx,dx,si,di
  508.     call    verify1
  509.     jc    ddr_exit
  510.     call    dbase_read        ;read the correct record
  511.     jc    ddr_exit        ;jmp if record not here
  512.     call    $is_record_in_buf        ;get index ptr
  513.     mov    es:[bx.rec_no],-1    ;flag this record as removed
  514.     call    $resequence
  515.     or    es:[f_flags],fdirty
  516.     mov    al,0
  517.     clc
  518. ddr_exit:
  519.     apop    di,si,dx,cx,bx
  520.     retf
  521.  
  522. DBASE_REMOVE    endp
  523. ;----------------------------------------------------------------------------
  524. ;------------------------------ dbase close ---------------------------------
  525. ;----------------------------------------------------------------------------
  526. comment 
  527. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(DATABASE )
  528. dbase_close - close & write any pending data to file
  529. ;
  530. ; inputs:      es = database selector returned by DBASE_INIT
  531. ; 
  532. ; output:  no carry,  al = 0 (success)
  533. ;            carry or al = 02 - selector bad or database corrupted.
  534. ; 
  535. ;* * * * * * * * * * * * * *
  536. 
  537. dcc_temp_asciiz        db    'DBASE.$$$',0
  538. dcc_temp_handle        dw    0
  539.  
  540.     public    dbase_close
  541. dbase_close    proc    far
  542.     apush    bx,cx,dx,si,di,bp,ds,es
  543.     call    verify2
  544.     jc    dcc_exit
  545.     test    es:[f_flags],fdirty
  546.     jz    dc_release            ;jmp if disk still good
  547. ;
  548. ; save a copy of the buffers which contain the changes to temp buffers
  549. ;
  550.     cld
  551.     push    es
  552.     pop    ds
  553.     mov    si,offset buf
  554.     mov    di,offset temp_buf
  555.     mov    cx,offset index_end
  556.     rep    movsb
  557. ;
  558. ; open a temp output file
  559. ;
  560.     mov    ah,3ch
  561.     mov    cx,0                 ;create for write
  562.     mov    dx,offset dcc_temp_asciiz
  563.     push    cs                ;swap ds
  564.     pop    ds                ;  and cs
  565.     int    21h
  566.     jc    dcc_err2
  567.     mov    dcc_temp_handle,ax
  568. ;
  569. ; move to start of database file
  570. ;
  571. dc_lp1:    test    es:[f_flags],at_top
  572.     jnz    dc_merge        ;jmp if file at top
  573.     mov    al,2
  574.     call    $disk_read
  575.     jnc    dc_lp1            ;loop till top of file reached.
  576.     cmp    al,4            ;check if eof or disk error
  577.     jne    dcc_err            ;jmp if not possible eof
  578. ;
  579. ; merge database file and temp buffers -> temp file
  580. ;
  581. dc_merge:
  582.     call    $merge_and_write
  583. ;
  584. ; delete the database file, and rename the temp file to database file
  585. ;
  586.     mov    ah,3eh
  587.     mov    bx,dcc_temp_handle
  588.     int    21h
  589.     jc    dcc_err2
  590.  
  591.     mov    ah,3eh
  592.     mov    bx,es:[f_handle]
  593.     int    21h
  594.     jc    dcc_err2
  595. ;
  596. ; delete the origional dbase file
  597. ;
  598.     mov    ah,41h
  599.     push    es
  600.     pop    ds
  601.     mov    dx,offset f_asciiz
  602.     int    21h
  603.     jc    dcc_err2
  604. ;
  605. ; rename the temp file to origional dbase name
  606. ;
  607.     push    cs
  608.     pop    ds
  609.     mov    ah,56h            ;rename
  610.     mov    dx,offset dcc_temp_asciiz ;existing name
  611.     mov    di,offset f_asciiz
  612.     int    21h
  613.     jc    dcc_err2
  614. ;
  615. ;  release memory
  616. ;
  617. dc_release:
  618.     call    dos_mem_release
  619.     mov    al,0            ;preload success code
  620.     jnc    dcc_exit
  621.     mov    al,8            ;unknown error
  622.     jmp    dcc_err
  623.  
  624. dcc_err2:
  625.     mov    al,4            ;disk error    
  626. dcc_err:stc    
  627. dcc_exit:
  628.     apop    es,ds,bp,di,si,dx,cx,bx
  629.     retf
  630.  
  631. dbase_close    endp
  632. comment 
  633. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(DATABASE )
  634. DBASE_KILL - delete dbase file
  635. ;
  636. ; inputs:       ds:dx = asciiz file name ptr
  637. ; 
  638. ; output:    carry set if error, error code from DOS function 41h
  639. ;* * * * * * * * * * * * * *
  640. 
  641.     public    DBASE_KILL
  642. DBASE_KILL    proc    far
  643.     mov    ah,41h
  644.     int    21h
  645.     retf
  646. DBASE_KILL    endp
  647. ;-----------------------------------------------------------------------------
  648. ;------------------------------ local subroutines ----------------------------
  649. ;-----------------------------------------------------------------------------
  650. ; $disk_read - read block of data from the disk and create the index
  651. ;   inputs:  al = 1 - read next forward block
  652. ;                 2 - read back towards front of file
  653. ;   output:  no carry = success
  654. ;               carry & AL = 07 (record found exceeding buffer size)
  655. ;               carry & AL = 04 (disk read/write error or file at eof/top)
  656. ;               carry & AL = 08 (parameter error or unknown error)
  657. ;
  658. ;   processing: 1. update database of seek & record# depending upon direction
  659. ;               2. check if operation possible
  660. ;               3. read block, compute next block seek from seek_adjust,
  661. ;                  active_block_size
  662. ;               4. build index if valid read, check record_count
  663. ;               5. set f_flags to correct state
  664. ;
  665. dr_input    db    0
  666.                
  667. $disk_read:
  668.     apush    ax,bx,cx,dx,si,di,ds
  669.     mov    cs:dr_input,al
  670.     cmp    al,1
  671.     je    dr_forward
  672.     cmp    al,2
  673.     je    dr_back
  674.     mov    al,8
  675.     jmp    dr_err
  676.  
  677. dr_forward:
  678.     test    es:[f_flags],at_eof
  679.     jnz    dr_eof                ;jmp if at eof already
  680.     and    es:[f_flags],not at_top        ;clear at_top flag
  681.  
  682.     mov    dx,word ptr es:f_seek_fwd    ;setup seek low word
  683.     mov    cx,word ptr es:f_seek_fwd+2    ;setup seek high word
  684.     mov    ax,word ptr es:[f_rec_fwd]    ;get record#
  685.     jmp    do_seek
  686.     
  687. dr_back:
  688.     test    es:[f_flags],at_top
  689.     jnz    dr_err1             ;jmp if at top already
  690.     and    es:[f_flags],not at_eof        ;clear eof flag
  691.     
  692.     mov    dx,word ptr es:f_seek_bak    ;setup seek low word
  693.     mov    cx,word ptr es:f_seek_bak+2    ;setup seek high word
  694.     mov    ax,es:[f_rec_bak]        ;get record#
  695.  
  696. do_seek:
  697.     mov    word ptr es:[f_seek],dx
  698.     mov    word ptr es:[f_seek+2],cx
  699.     cmp    ax,0            ;check if record #1
  700.     jne    do_seek2        ;jmp if valid rec#
  701.     mov    ax,1
  702. do_seek2:
  703.     mov    es:[f_rec],ax        ;save record#        
  704.     mov    ah,42h            ;DOS seek code
  705.     mov    al,00h            ;seek relative to file start
  706.     mov    bx,es:[f_handle]     ;file handle
  707.     int    21h            ;
  708.     jc    dr_err1            ;jmp if seek error
  709. ;
  710. ; the file pointer has been positioned, now read block
  711. ;
  712.     mov    ah,3fh            ;DOS read code
  713.     mov    cx,buf_size/2        ;get size of read
  714.     mov    dx,offset buf        ;get buffer offset
  715.     push    ds            ;save ds
  716.     push    es            ;set ds to
  717.     pop    ds            ;  buffer segment
  718.     int    21h            ;returns ax=number of bytes read
  719.     pop    ds
  720.     jc    dr_err1            ;jmp if read error
  721.     cmp    ax,0
  722.     je    dr_eof            ;jmp if nothing read (EOF)
  723.     cmp    ax,buf_size/2
  724.     je    dr_build_index
  725.     or    es:[f_flags],at_eof    ;set eof flag
  726. ;
  727. ; the data has been read into the buffer, now build index, ax=amount read
  728. ;
  729. dr_build_index:
  730.     mov    dx,es:[f_rec]        ;get starting index#
  731.     call    $build_index
  732.     jc    dr_err            ;jmp if record exceeds buffer size
  733. ;;    cmp    es:[active_block_size],0
  734. ;;    je    dr_eof2            ;jmp if no data read
  735.     cmp    es:[record_count],0
  736.     jne    dr_compute_seeks
  737.     or    es:[f_flags],at_eof
  738. dr_compute_seeks:
  739.     cmp    es:[index.rec_no],1    ;check if at top
  740.     je    compute_fwd        ;jmp if next must be forward read
  741.     cmp    cs:dr_input,1
  742.     jne    compute_bak
  743. ;
  744. ; compute setting for f_rec_fwd, f_seek_fwd
  745. ;    
  746. compute_fwd:
  747.     mov    ax,es:[f_rec]
  748.     add    ax,es:[record_count]
  749.     mov    es:[f_rec_fwd],ax
  750.  
  751.     mov    ax,word ptr es:[f_seek]
  752.     mov    bx,word ptr es:[f_seek+2]
  753.     add    ax,es:active_block_size
  754.     adc    bx,0
  755.     mov    word ptr es:[f_seek_fwd],ax
  756.     mov    word ptr es:[f_seek_fwd+2],bx
  757.  
  758.     mov    word ptr es:[f_seek_bak],0
  759.     mov    word ptr es:[f_seek_bak+2],0
  760.     mov    es:[f_rec_bak],1
  761.     
  762.     clc
  763.     jmp    dr_quit
  764. ;
  765. ; compute setting for f_rec_bak, f_seek_bak
  766. ;
  767. compute_bak:
  768.     mov    es:f_rec_bak,1
  769.     mov    word ptr es:[f_seek_bak],0
  770.     mov    word ptr es:[f_seek_bak+2],0
  771.  
  772.     mov    es:f_rec_fwd,1
  773.     mov    word ptr es:[f_seek_fwd],0
  774.     mov    word ptr es:[f_seek_fwd+2],0
  775.     
  776.     clc
  777.     jmp    dr_quit
  778.     
  779. dr_eof: cmp    es:[index.rec_no],1
  780.     ja    dr_eof2                ;jmp if not at top
  781.     or    es:[f_flags],at_top
  782. dr_eof2:or    es:[f_flags],at_eof
  783.  
  784. dr_err1:mov    al,4                ;disk read/write error
  785. dr_err:    stc                    ;error code in AL here
  786.     jmp    dr_quit2
  787. dr_quit:
  788.     cmp    es:[index.rec_no],1
  789.     ja    dr_quit2
  790.     or    es:[f_flags],at_top
  791. dr_quit2:    
  792.     apop    ds,di,si,dx,cx,bx,ax
  793.     ret
  794. ;-----------------------------------------------------------------------------
  795. ; $is_record_in_buf - check if record in memory
  796. ;   inputs:  dx = record number
  797. ;   output:  al =          0 - got record
  798. ;                              bx=record index ptr
  799. ;                              cx=size
  800. ;                          1 - try reading forward
  801. ;                          2 - try reading backwards
  802. ;
  803. $is_record_in_buf:
  804.     apush    dx,si
  805.     cmp    dx,es:[f_rec]
  806.     jb    irib_back
  807.     mov    bx,es:[index_avail_ptr]
  808. irib_x: sub    bx,size index_struc
  809.     cmp    es:[bx.rec_no],-1        ;check if deleted record
  810.     je    irib_x
  811.     cmp    dx,es:[bx.rec_no]
  812.     ja    irib_forward
  813. ;
  814. ; record # falls somewhere in the block in memory.  scan for location
  815. ;    
  816.     mov    bx,offset index - size index_struc
  817. irib_lp:add    bx,size index_struc
  818.     cmp    dx,es:[bx.rec_no]
  819.     jne    irib_lp            ;loop till record found
  820.  
  821.     mov    si,es:[bx.buf_ptr]
  822.     call    $compute_record_length
  823.     mov    al,0
  824.     jmp    irib_exit
  825. irib_forward:
  826.     mov    al,1
  827.     jmp    irib_exit    
  828. irib_back:
  829.     mov    al,2
  830. irib_exit:
  831.     apop    si,dx
  832.     ret
  833. ;-----------------------------------------------------------------------------
  834. ;$build_index - build index for data in buf
  835. ; inputs: ax = amount of data in buffer
  836. ;         dx = starting record/sequience number
  837. ;
  838. ; output: no carry - index built ok
  839. ;            carry - al = 7 record too big
  840.  
  841. $build_index:
  842.     apush    ax,bx,cx,dx,si,di
  843. ;
  844. ; the data has been read into the buffer, now build index,
  845. ;
  846. bi_build_index:
  847.     mov    es:record_count,-1
  848.     mov    di,offset buf                   ;get buffer offset
  849.     mov    si,offset index                  ;get index top
  850.     mov    cx,ax                    ;get buffer length
  851. ;
  852. ; This file uses variable length records, registers are set as follows:
  853. ;  es:di = buffer ptr    es:si = index ptr  cx=buf len  dx=starting rec#
  854. ;
  855.     mov    al,0                     ;get record separator
  856.     sub    si,size index_struc        ;loop modification
  857.     dec    dx                ;loop modification for rec#
  858. bi_var_lp:
  859.     inc    es:record_count
  860.     add    si,size index_struc        ;move to next index
  861.     inc    dx                ;move to next rec#
  862.     cmp    si,index_end
  863.     jae    bi_var_zero_end            ;jmp if end of index buffer
  864.     mov    es:[si.file_rec_no],dx        ;store rec#
  865.     mov    es:[si.rec_no],dx
  866.     mov    es:[si.buf_ptr],di        ;store buffer ptr
  867.     jcxz    bi_var_zero_end            ;jmp if at end of disk data
  868.     repne    scasb                ;scan for next record separator
  869.     je    bi_var_lp            ;jmp if separator found
  870. ;
  871. ; the end of the buffer was reached
  872. ;
  873. bi_var_zero_end:
  874.     cmp    es:[record_count],0
  875.     je    bi_err                ;jmp if record too big
  876.     mov    es:[si.file_rec_no],0        ;mark index end
  877.     mov    es:[si.rec_no],0
  878.     mov    es:[index_avail_ptr],si
  879.  
  880.     mov    di,es:[si.buf_ptr]
  881.     mov    es:[buf_avail_ptr],di        ;set ptr past last valid rec
  882.     mov    es:[active_block_size],di    ;save size of this block
  883.     mov    es:[si.buf_ptr],0        ;zero residual buf_ptr
  884.     clc
  885.     jmp    bi_exit
  886.  
  887. bi_err:    mov    al,7                ;set record too big error
  888.     stc
  889.     jmp    bi_exit
  890.     
  891. bi_eof:    clc
  892.     or    es:[f_flags],at_eof    ;set eof flag
  893. bi_exit:
  894.     apop    di,si,dx,cx,bx,ax
  895.     ret
  896.  
  897. ;------------------------------------------------------------------------
  898. ; $build_index_entry - create index entry
  899. ;  inputs:  bx = pointer to index destination
  900. ;          ds:si = data ptr
  901. ;  output:  none
  902. ;  processing:  1. construct the index entry
  903. ;               2. move the data to database buffer
  904. ;
  905. $build_index_entry:
  906.     apush    ax,cx,si,di,ds
  907.     cmp    bx,offset index
  908.     jne    bie_cont2        ;jmp if not first index
  909.     test    es:[f_flags],at_top
  910.     jz    bie_cont1        ;jmp if not index #1
  911.     mov    ax,1
  912.     jmp    bie_cont3
  913. bie_cont1:
  914.     mov    ax,es:f_rec
  915.     jmp    bie_cont3
  916. bie_cont2:            
  917.     mov    ax,es:[bx.rec_no-size index_struc]    ;get previous rec #
  918.     inc    ax
  919. bie_cont3:
  920.     mov    es:[bx.rec_no],ax            ;store rec#
  921.     
  922.     mov    di,es:buf_avail_ptr
  923.     mov    es:[bx.buf_ptr],di            ;store buf ptr
  924.  
  925.     call    strlen1
  926.     cld
  927.     rep    movsb                    ;move data to buffer
  928.     movsb                        ;move zero at end
  929.     mov    es:[buf_avail_ptr],di
  930.     apop    ds,di,si,cx,ax
  931.     ret
  932. ;------------------------------------------------------------------------
  933. ;$make_index_hole - create space for new entry in mod indx
  934. ; inputs: es:bx points at mod index index to make hole in front of
  935. ;
  936. $make_index_hole:
  937.     apush    cx,si,di,ds
  938.     mov    di,offset index_end-1
  939.     mov    si,di
  940.     sub    si,size index_struc
  941.     mov    cx,si
  942.     sub    cx,bx
  943.     inc    cx
  944.     jcxz    maih_1        ;jmp if at end
  945.     std
  946.     push    es
  947.     pop    ds
  948.     rep    movsb
  949.     cld
  950. maih_1:
  951.     add    es:[index_avail_ptr],size index_struc
  952.     apop    ds,di,si,cx
  953.     ret
  954.     
  955. ;----------------------------------------------------------------------------
  956. ;$compute_record_length - compute size of modification record
  957. ; inputs:    es:si = pointer to modification record
  958. ; output:    cx = record size including separator character if present
  959. ;
  960. $compute_record_length:
  961.     push    ax
  962.     push    di
  963.     mov    al,0             
  964.     mov    di,si
  965.     mov    cx,-1
  966.     repne    scasb
  967.     not    cx
  968.     pop    di
  969. cars_exit:
  970.     pop    ax
  971.     ret
  972.  
  973. ;----------------------------------------------------------------------------
  974. ; $check_if_room - check if room for another operation
  975. ;   inputs:  cx = size of this record
  976. ;   output:  carry = no room
  977. ;
  978. $check_if_room:
  979.     mov    ax,es:[buf_avail_ptr]
  980.     add    ax,cx
  981.     cmp    ax,offset buf_end
  982.     ja    cir_nope
  983.     mov    ax,es:[index_avail_ptr]
  984.     cmp    ax,offset index_end -4
  985.     ja    cir_nope
  986.     clc
  987.     jmp    cir_exit
  988. cir_nope:
  989.     stc
  990. cir_exit:
  991.     ret
  992. ;----------------------------------------------------------------------------
  993. ; $born_again - close the database and reopen with a fresh copy
  994. ;   inputs:  dx = active record
  995. ;   outputs: no carry = success
  996. ;        carry = error, AL set to 1 (no records present)
  997. ;            registers  ax,bx,cx,si,di modified
  998. ;
  999. xasciiz        db    40 dup (0)
  1000. target_record    dw    0        ;record location to restore
  1001.  
  1002. $born_again:
  1003.     mov    cs:target_record,dx
  1004.     push    es
  1005.     call    dbase_close
  1006.     jc    ba_exit
  1007.     pop    es
  1008. ;
  1009. ; move a copy of the database file name locally
  1010. ;
  1011.     push    es
  1012.     pop    ds
  1013.     mov    si,offset f_asciiz
  1014.     push    cs
  1015.     pop    es
  1016.     mov    di,offset xasciiz
  1017.     mov    cx,40
  1018.     rep    movsb
  1019. ;
  1020. ; setup parameters for dbase_init
  1021. ;
  1022.     mov    dx,offset xasciiz
  1023.     push    cs
  1024.     pop    ds
  1025.     call    dbase_init
  1026.     jc    ba_exit            ;jmp if error
  1027.     mov    es,bx            ;setup the selector
  1028.  
  1029. ba_loop:mov    dx,cs:target_record
  1030.     call    $is_record_in_buf
  1031.     cmp    al,0
  1032.     je    ba_got_it
  1033.     call    $disk_read        ;go and look in next block
  1034.     jnc    ba_loop
  1035.     cmp    dx,1            ;check if null database
  1036.     je    ba_got_it
  1037. ;
  1038. ; we could not find this record
  1039. ;
  1040.     cmp    es:[record_count],0    ;check if null database
  1041.     je    ba_null
  1042. ;
  1043. ; the last record of a database was deleted, so use the previous record.
  1044. ;
  1045.     mov    bx,es:[index_avail_ptr]
  1046.     sub    bx,size index_struc
  1047.     jmp    ba_got_it
  1048.  
  1049. ba_null:
  1050.     mov    al,8
  1051.     stc
  1052.     jmp    ba_exit
  1053.         
  1054. ba_got_it:
  1055.     mov    es:[active_index],bx    
  1056.     clc
  1057. ba_exit:    
  1058.     ret
  1059. ;-----------------------------------------------------------------------------
  1060. ; $resequence - resequence the sequence numbers from current record
  1061. ;   inputs:  bx = current index ptr
  1062. ;            dx = sequence # for this record
  1063. ;   output: none
  1064. ;
  1065. $resequence:
  1066.     apush    bx,dx
  1067. res_lp:    cmp    es:[bx.rec_no],0
  1068.     je    res_done        ;jmp if end of index found
  1069.     cmp    es:[bx.rec_no],-1
  1070.     je    res_c            ;jmp if removed (deleted) record
  1071.     mov    es:[bx.rec_no],dx
  1072.     inc    dx
  1073. res_c:    add    bx,size index_struc
  1074.     jmp    res_lp
  1075. res_done:
  1076.     apop    dx,bx
  1077.     ret
  1078. ;-----------------------------------------------------------------------------
  1079. ; $merge_and_write - merge file data with modifications in memory
  1080. ;   inputs:  - file is at top
  1081. ;            - index built
  1082. ;            - temp_buf & temp_index have modificaton data
  1083. ;            - output file open & handle at dcc_temp_handle
  1084. ;
  1085. ;  output:  no carry = success
  1086. ;              carry = error
  1087. ;
  1088. ; processing:  1. write from file until disk rec# reaches first temp file rec#
  1089. ;              2. write temp data until exhausted
  1090. ;              3. read input file until it reaches last temp file rec#
  1091. ;              4. write remaining file data
  1092.  
  1093. $merge_and_write:
  1094.     mov    bx,offset temp_index
  1095.     test    es:[f_flags],created
  1096.     jnz    maw_write_temp        ;jmp if file is empty
  1097. ;
  1098. ; find first temp file rec#
  1099. ;
  1100. maw_lp1:cmp    es:[bx.file_rec_no],1    ;check if temp file at start
  1101.     je    maw_write_temp
  1102. ;
  1103. ; the modification data is not first block of file, copy file data until
  1104. ; modification block area reached.
  1105. ;
  1106. maw_copy_file:
  1107.     mov    bx,offset temp_index-size index_struc ;get first mod block rec#
  1108. maw_lpx:add    bx,size index_struc
  1109.     mov    ax,es:[bx.file_rec_no]
  1110.     cmp    ax,-1
  1111.     je    maw_lpx
  1112.     
  1113. maw_lp2:mov    bx,offset index
  1114. maw_lp3:call    write_file_record
  1115.     jc    maw_done            ;jmp if error
  1116.     add    bx,size index_struc
  1117.     cmp    ax,es:[bx.file_rec_no]
  1118.     je    maw_write_temp        ;jmp if start of modification data fnd
  1119.     cmp    es:[bx.rec_no],0    ;check if end of file block
  1120.     jne    maw_lp3            ;jmp if more data to copy
  1121.     push    ax
  1122.     mov    al,1
  1123.     call    $disk_read
  1124.     pop    ax
  1125.     jc    maw_write_temp        ;jmp if eof
  1126.     mov    bx,offset index        ;restart the index
  1127.     cmp    ax,es:[bx.file_rec_no]
  1128.     jne    maw_lp3            ;loop till modify block reached
  1129. ;
  1130. ; copy data from temp_file to disk
  1131. ;
  1132. maw_write_temp:
  1133.     mov    bx,offset temp_index - size index_struc
  1134. maw_lp4:add    bx,size index_struc
  1135.     cmp    es:[bx.rec_no],0
  1136.     je    maw_t1            ;jmp if end of temp index
  1137.     cmp    es:[bx.rec_no],-1
  1138.     je    maw_lp4            ;jmp if removed record (deleted)
  1139.     call    write_file_record
  1140.     jc    maw_done        ;jmp if error
  1141.     jmp    maw_lp4
  1142. ;
  1143. ; write data following modification block
  1144. ;
  1145. maw_t1:    mov    ax,es:[bx.file_rec_no - size index_struc]    ;find
  1146.     inc    ax                        ; next file rec
  1147.     
  1148. maw_t2:    mov    bx,offset index                
  1149. maw_lp6:cmp    es:[bx.file_rec_no],ax
  1150.     je    maw_write_tail
  1151.     cmp    es:[bx.rec_no],0
  1152.     je    maw_get_more
  1153.     add    bx,size index_struc
  1154.     jmp    maw_lp6                
  1155. maw_get_more:
  1156.     push    ax
  1157.     mov    al,1
  1158.     call    $disk_read
  1159.     pop    ax
  1160.     jnc    maw_t2
  1161.     jmp    maw_done        ;jmp if input file at eof
  1162. ;
  1163. ; copy data remaining
  1164. ;
  1165. maw_write_tail:    
  1166. maw_lp7:cmp    es:[bx.file_rec_no],0
  1167.     je    maw_more_ck        ;jmp if out of data in memory
  1168.     call    write_file_record
  1169.     jc    maw_done        ;jmp if error
  1170.     add    bx,size index_struc
  1171.     jmp    maw_lp7            ;jmp if more data to copy
  1172. maw_more_ck:
  1173.     push    ax
  1174.     mov    al,1
  1175.     call    $disk_read
  1176.     pop    ax
  1177.     jc    maw_success    ;jmp if eof
  1178.     mov    bx,offset index
  1179.     jmp    maw_lp7
  1180. maw_success:
  1181.     clc    
  1182. maw_done:
  1183.     ret
  1184. ;-----------------------------------------------------------------------------
  1185. ; write_file_record - copy data from index file to output file
  1186. ;  input:  es:bx = pointer to index for input data
  1187. ;  output:  carry set if error
  1188. ;
  1189. write_file_record:
  1190.     apush    ax,bx,cx,dx
  1191.     push    es
  1192.     pop    ds
  1193.     mov    si,es:[bx.buf_ptr]
  1194.     call    $compute_record_length
  1195.     mov    dx,si
  1196.     mov    bx,cs:dcc_temp_handle
  1197.     mov    ah,40h
  1198.     int    21h
  1199.     apop    dx,cx,bx,ax
  1200.     ret
  1201. ;-----------------------------------------------------------------------------
  1202. ; verify1 - check if database valid and has data in it
  1203. ;  inputs:    es: setup
  1204. ;  outputs:   no carry - al = 0 (success)
  1205. ;                carry - al = 1 database empty
  1206. ;                carry - al = 2 selector bad or database corrupted
  1207. ;           registers bx,cx modified
  1208. ;
  1209. verify1:test    es:[f_flags],at_top
  1210.     jz    verify2            ;jmp if database has data
  1211.     test    es:[f_flags],at_eof
  1212.     jz    verify2            ;jmp if database has data
  1213.     mov    cx,0            ;record count
  1214.     mov    bx,offset index - size index_struc
  1215. v_lp:    add    bx,size index_struc
  1216.     cmp    es:[bx.rec_no],0
  1217.     je    v_check            ;jmp if end of index
  1218.     cmp    es:[bx.rec_no],-1
  1219.     je    v_lp            ;jmp if removed record
  1220.     inc    cx
  1221.     jmp    v_lp
  1222. v_check:jcxz    verify_bad1        ;jmp if no records found
  1223. verify2:cmp     es:[f_key],'JO'
  1224.     mov    al,2            ;preload error code for bad ES:
  1225.     jne    verify_bad
  1226.     clc
  1227.     mov    al,0
  1228.     jmp    verify_end
  1229. verify_bad1:
  1230.     mov    al,1            ;signal database empty    
  1231. verify_bad:
  1232.     stc
  1233. verify_end:
  1234.     ret        
  1235.     
  1236. ;-----------------------------------------------------------------------------
  1237.  
  1238. LIBSEG    ENDS
  1239. ;;    end
  1240.