home *** CD-ROM | disk | FTP | other *** search
/ C!T ROM 5 / ctrom5b.zip / ctrom5b / PROGRAM / ASM / ALIB30B / CONFIG.ASM < prev    next >
Assembly Source File  |  1994-11-15  |  40KB  |  1,622 lines
  1.     PAGE    66,132
  2. ;******************************** CONFIG.ASM *******************************
  3. LIBSEG    SEGMENT BYTE PUBLIC "LIB"
  4.     ASSUME    CS:LIBSEG,DS:LIBSEG
  5.  
  6.     EXTRN    DOS_MEM_ALLOCATE:FAR,DOS_MEM_RELEASE:FAR
  7.     extrn    buffer_searchc:far
  8.     extrn    find_home_path:far
  9.     extrn    menu_system:far
  10.     extrn    clear_screen:far
  11.     extrn    display_string:far
  12.     extrn    message:far
  13.     extrn    str_copy:far
  14.     extrn    str_cleanl:far
  15.     extrn    BYTE_TO_HEX_STR:far
  16.     extrn    WORD_TO_HEX_STR:far
  17.     extrn    DWORD_TO_HEX_STR:far
  18.     extrn    DWORD_TO_DEC_STR:far
  19.     extrn    DEC_STR_TO_WORD:far
  20.     extrn    DEC_STR_TO_DWORD:far
  21.     extrn    HEX_STR_TO_BYTE:far
  22.     extrn    HEX_STR_TO_WORD:far
  23.     extrn    get_string:far
  24.     extrn    key_put:far
  25.     extrn    posn_to_adr:near
  26.     extrn    $put_crt_blk:near
  27.     extrn    put_crt_chr:far
  28.     extrn    $put_crt_chr:near
  29.     extrn    to_upper:far
  30.     extrn    one_beep:far
  31.  
  32.     extrn    lib_info:byte
  33.     extrn    bar_text_color:byte
  34.     extrn    bar_select_color:byte
  35.     extrn    bar_hotkey_color:byte
  36.     extrn    submenu_text_color:byte
  37.     extrn    submenu_select_color:byte
  38.     extrn    msg_text_color:byte
  39.     extrn    msg_hyper_color:byte
  40.     extrn    pick_color:byte
  41.     extrn    pick_select_color:byte
  42.             
  43.     INCLUDE    MAC.INC
  44.     INCLUDE    COMMON.INC
  45. ;----------------------------------------------------------------------------
  46. ;------------------------------ data section --------------------------------
  47. ;----------------------------------------------------------------------------
  48. top_data_line    equ    4
  49. last_data_line    equ    top_data_line+19
  50.  
  51. ;-----------
  52. work_area    struc
  53. default_ptr    dw    ?    ;ptr to default setup block
  54. header_count    db    ?    ;number of headers in block
  55. cursor_page_ptr    dw    ?    ;pointer into summary_table
  56. cursor_line_ptr    dw    ?    ;pointer into page_detail
  57. cursor_line    db    ?    ;display line
  58.  
  59. ;--- summary_table ---  table end has headerx_ptr set to zero
  60.  
  61. header1_ptr    dw    ?
  62. h1_line1_ptr    dw    ?
  63. header1_entries    dw    ?
  64. header2_ptr    dw    ?
  65. h2_line1_ptr    dw    ?
  66. header2_entries    dw    ?
  67. header3_ptr    dw    ?
  68. h3_line1_ptr    dw    ?
  69. header3_entries    dw    ?
  70. header4_ptr    dw    ?
  71. h4_line1_ptr    dw    ?
  72. header4_entries    dw    ?
  73. header5_ptr    dw    ?
  74. h5_line1_ptr    dw    ?
  75. header5_entries    dw    ?
  76. header6_ptr    dw    ?
  77. h6_line1_ptr    dw    ?
  78. header6_entries    dw    ?
  79. header7_ptr    dw    ?
  80. h7_line1_ptr    dw    ?
  81. header7_entries    dw    ?
  82.  
  83. ;--- page_detail (lines)  --- table end has linexx_ptr set to zero
  84.  
  85. line01_ptr    dw    ?
  86. line02_ptr    dw    ?
  87. line03_ptr    dw    ?
  88. line04_ptr    dw    ?
  89. line05_ptr    dw    ?
  90. line06_ptr    dw    ?
  91. line07_ptr    dw    ?
  92. line08_ptr    dw    ?
  93. line09_ptr    dw    ?
  94. line10_ptr    dw    ?
  95. line11_ptr    dw    ?
  96. line12_ptr    dw    ?
  97. line13_ptr    dw    ?
  98. line14_ptr    dw    ?
  99. line15_ptr    dw    ?
  100. line16_ptr    dw    ?
  101. line17_ptr    dw    ?
  102. line18_ptr    dw    ?
  103. line19_ptr    dw    ?
  104. line20_ptr    dw    ?
  105. line21_ptr    dw    ?
  106. line22_ptr    dw    ?
  107.  
  108. ;--- line detail
  109.  
  110. cursor_column    db    ?    ;display column
  111. ld_type        db    ?    ;1=bool 2=hex 3=decimal 4=color 5=string
  112. ld_len        db    ?    ;1=byte 2=word 4=dword n=string len
  113. ld_minimum    dd    ?    ;minimum setting
  114. ld_max        dd    ?    ;maximum setting
  115. ld_default_ptr    dw    ?    ;ptr to default/current setting
  116. ld_descrip_ptr    dw    ?    ;ptr to descriptive text
  117. ld_str_len    db    ?    ;length of get_string buffer & edit field
  118. temp_string    db    80 dup (?)
  119.  
  120. ;--- working_setup
  121.  
  122. working_setup    db    ?
  123.  
  124. ;--- default_setup
  125.  
  126. work_area    ends
  127. ;----------------------------------------
  128. callers_setup_block_off    dw    0
  129. callers_setup_block_seg    dw    0
  130. setup_block_len        dw    0
  131.  
  132. allocated_mem_seg    dw    0
  133.  
  134. end_string    db    '<<end>>',0
  135. setup_filename    db    13 dup (0)
  136. file_found    db    0        ;0=file not found  1=file found
  137.  
  138. off_string    db    'OFF',0
  139. on_string    db    'ON ',0
  140.  
  141. comment 
  142. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(  CONFIG )
  143. GET_SETUP - read setup file from disk
  144. ;
  145. ; inputs: ds:si = pointer to default setup block
  146. ;
  147. ; ouptut:  AL = 0 (setup block is ok, input block updated if file found)
  148. ;               1 (setup block is bad)
  149. ;          AH = 0 (setup file was not found, so it was created using defaults)
  150. ;               1 (setup file read from disk)
  151. ;
  152. ; processing: 0. allocate memory and copy default setup information.
  153. ;             1. build setup file name using executable plus ".CFG"
  154. ;             2. look for existing setup file & use if found
  155. ;             3. if setup not found write defaults to disk
  156. ;             4. parse setup block and build summary_table
  157. ;             5. feed color information to library
  158. ;
  159. ; notes:  GET_SETUP establishes the setup data block for program and
  160. ;         library code.  Each variable in the setup block is placed under
  161. ;         a header and is described by a structure.  The header format
  162. ;         is "<<header text>>" followed by a zero character.  Up to
  163. ;         six headers can be definded.  The variable data is described
  164. ;         by a structure with the following format:
  165. ;
  166. ;           struc  variable
  167. ;             db    ?    ;data type 1=boolian,2=hex,3=decimal,4=color,5=string
  168. ;             db    ?   ;data length 1=byte,2=word,4=dword, or n for string len
  169. ;             xx    ?   ;minimum value,used for data types 1,2,3,4 (see note1)
  170. ;             xx    ?   ;maximum value,used for data types 1,2,3,4 (see note1)
  171. ;             xx    ?   ;default setting, all data types, strings end with zero
  172. ;             db    ?   ;description of this variable (string) ending with zero
  173. ;
  174. ;             note1 - the length of minimum value and maximum value fields
  175. ;                     depends upon the data types and data length.  It will
  176. ;                     be a byte for all types except 2 & 3.  For 2&3 the
  177. ;                     length will track the length field setting.
  178. ;
  179. ;         The setup block must have color descriptions in the first block
  180. ;         and these color descripitions must be in the order needed by
  181. ;         library functions.  A typical setup block consisting of two sections
  182. ;         would look like this:
  183. ;
  184. ;         setup_block    label    byte
  185. ;              db    "<<color settings>>",0
  186. ;              db    4,1,0,0ff,1bh,"menu bar text color",0
  187. ;              db       4,1,0,0ff,2bh,"menu bar select color",0
  188. ;                         .
  189. ;                         .
  190. ;              db       "<<setup block 2>>",0
  191. ;              db       1,1,0,1,0,"turn sound on",0              ;yes/no setup
  192. ;              db       2,1,0,0ff,0,"enter hex value",0          ;hex byte
  193. ;              db       3, 0,0, 8,0, 4,0, 'enter decimal word",0 ;decimal word
  194. ;              db       5,15,0,0,"default string",0,"enter string",0
  195. ;                         .
  196. ;              db       "<<end>>"
  197. ;
  198. ;              note2 - The length of strings include the zero byte at end.
  199. ;              note3 - For correct order and wording of color setup entries
  200. ;                      see sample file EDREC.ASM and EDREC.CFG.
  201. ;
  202. ;           
  203. ;* * * * * * * * * * * * * *
  204. 
  205.     public    GET_SETUP
  206. GET_SETUP    proc    far
  207.     apush    bx,cx,dx,si,di,bp,ds,es
  208.     mov    cs:callers_setup_block_off,si
  209.     mov    cs:callers_setup_block_seg,ds
  210.     mov    cs:file_found,0
  211. ;
  212. ; scan input block to find length
  213. ;
  214.     call    find_block_end
  215.         
  216.     jc    gss_err1            ;jmp if <<end>> not found
  217. ;
  218. ; compute amount of memory needed
  219. ;
  220.     sub    di,cs:callers_setup_block_off    ;compute length of
  221.     add    di,7                ; setup block
  222.     mov    cs:setup_block_len,di        ;save length
  223.  
  224.     shl    di,1                ;double it
  225.     add    di,offset working_setup        ;include table area
  226. ;
  227. ; allocate memory
  228. ;
  229.     mov    ax,di
  230.     mov    dx,0
  231.     call    dos_mem_allocate
  232.     jnc    gss_1            ;jmp if memory allocated in -es-
  233.     mov    al,1
  234.     jmp    gss_exit
  235. ;
  236. ; compute pointer to default setup block area
  237. ;
  238. gss_1:    mov    di,offset working_setup
  239.     add    di,cs:setup_block_len
  240.     mov    es:default_ptr,di        ;save in allocated mem
  241. ;
  242. ; copy callers setup block into allocated memory (defaults)
  243. ;
  244.     cld
  245.     mov    cs:allocated_mem_seg,es
  246.     lds    si,dword ptr cs:callers_setup_block_off
  247.     mov    cx,cs:setup_block_len
  248.     rep    movsb
  249. ;
  250. ; copy callers setup block into allocated memory (working)
  251. ;
  252.     mov    si,cs:callers_setup_block_off
  253.     mov    cx,cs:setup_block_len
  254.     mov    di,offset working_setup
  255.     rep    movsb
  256. ;
  257. ; build name of setup file on disk
  258. ;
  259.     push    cs
  260.     pop    ds
  261.     call    build_filename
  262. ;
  263. ; read setup file into memory, first open file
  264. ;
  265.     mov    dx,offset setup_filename
  266.     mov    ax,3d00h
  267.     int    21h            ;open file
  268.     jc    gss_fcreate        ;jmp if file not found
  269.     push    ax            ;save file handle
  270. ;
  271. ; read the setup file into allocated memory
  272. ;
  273.           pop    bx            ;get file handle
  274.     mov    dx,offset working_setup    ;buffer offset
  275.     push    es            ;set ds:dx
  276.     pop    ds            ;  to point at buffer
  277.     mov    cx,cs:setup_block_len
  278.     mov    ah,3fh            ;read 
  279.     int    21h            ;read into buffer
  280.     jc    gss_fcreate        ; if bad read go to create
  281.     mov    cs:file_found,1
  282.     jmp    gss_parse        ; jmp if good read
  283. ;
  284. ; if bad read, try to write setup block to memory
  285. ;
  286. gss_fcreate:
  287.     push    cs
  288.     pop    ds
  289.     mov    dx,offset setup_filename
  290.     mov    cx,0            ;file attributes
  291.     mov    ah,3ch
  292.     int    21h
  293.     jc    gss_err1        ;jmp if error
  294. ;
  295. ; write data to file
  296. ;
  297.     lds    dx,dword ptr cs:callers_setup_block_off
  298.     mov    bx,ax            ;move file handle to -bx-
  299.     mov    cx,cs:setup_block_len
  300.     mov    ah,40h
  301.     int    21h
  302. ;
  303. ; parse setup block and build summary_table
  304. ;
  305. gss_parse:
  306.     mov    ah,3eh
  307.     int    21h            ;close file    
  308.     call    summary_parse        ;parse file & build summary_table
  309.     jc    gss_err1        ; jmp if parse error
  310. ;
  311. ; feed color information into library
  312. ;
  313.     call    feed_colors
  314. ;
  315. ; move working setup block to callers area
  316. ;
  317.     call    working_to_caller    
  318.     mov    al,0            ;successful parse
  319.     jmp    gss_exit
  320.     
  321. gss_err1:
  322.     mov    al,1
  323. gss_exit:
  324.     mov    ah,cs:file_found    ;get file or memory defaults used flag
  325.     apop    es,ds,bp,di,si,dx,cx,bx
  326.     retf
  327. GET_SETUP    endp
  328.  
  329. comment 
  330. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(  CONFIG )
  331. CHANGE_SETUP - modify setup data in memory
  332. ;
  333. ; inputs:  none
  334. ; 
  335. ; ouptut:  none
  336. ; 
  337. ; processing: 1. displaly setup block and accept user changes.
  338. ;             2. write setup block to disk only if user requests it.
  339. ;
  340. ; Notes:  The input to this routine are the setup block which
  341. ;         has been processed by GET_SETUP.  CHANGE_SETUP can
  342. ;         not be called until GET_SETUP has set up the data it needs.
  343. ;
  344. ;* * * * * * * * * * * * * *
  345. 
  346.     PUBLIC    CHANGE_SETUP
  347. CHANGE_SETUP       proc    far
  348.     apush    ax,bx,cx,dx,si,di,bp,ds,es
  349. ;
  350. ; initialize variables
  351. ;
  352. cs_1:    mov    ax,cs:allocated_mem_seg
  353.     mov    ds,ax
  354.     mov    es,ax
  355.     mov    ds:cursor_page_ptr,offset header1_ptr    ;summary_table ptr
  356. cs_2:    mov    ds:cursor_line_ptr,offset line01_ptr    ;detail_table ptr
  357.     mov    ds:cursor_line,top_data_line
  358. ;
  359. ; build page details
  360. ;
  361.     call    build_page_detail
  362. ;
  363. ; clear the screen
  364. ;
  365.     mov    ah,cs:submenu_text_color
  366.     mov    al,' '
  367.     call    clear_screen
  368. ;
  369. ; display header
  370. ;
  371.     mov    si,ds:cursor_page_ptr
  372.     mov    si,word ptr ds:[si]        ;get header ptr
  373.     
  374.     mov    ax,ds:line01_ptr        ;center
  375.     sub    ax,si                ;  the header
  376.     mov    dx,80                ;
  377.     sub    dx,ax
  378.     shr    dx,1                ;dx now has starting column
  379.     
  380.     mov    dh,2                ;display row
  381.     mov    ah,cs:submenu_select_color
  382.     call    display_string
  383. ;
  384. ; setup to display lines
  385. ;
  386.     mov    si,offset line01_ptr
  387. ;
  388. ; display all lines
  389. ;
  390. cs_lpp:    call    display_line
  391.     add    ds:cursor_line,1        ;move to next display column
  392.     add    ds:cursor_line_ptr,2        ;move to next line
  393.     add    si,2
  394.     cmp    word ptr ds:[si],0        ;check if done
  395.     jne    cs_lpp                ; loop till done
  396.          mov    ds:cursor_line_ptr,offset line01_ptr    ;detail_table ptr
  397.     mov    ds:cursor_line,top_data_line
  398.  
  399. ;
  400. ; get keyboard inputs from user
  401. ;
  402. cs_5:    call    grab_keyboard_inputs
  403. ;
  404. ; decode user request, carry =abort key  else ax=process to perform
  405. ;
  406.     jc    cs_abortx            ;jmp if abort request
  407.     jmp    ax
  408. ;
  409. config_restore:
  410.     mov    si,ds:default_ptr
  411.     mov    di,offset working_setup
  412.     mov    cx,cs:setup_block_len
  413.     rep    movsb
  414.     jmp    cs_1
  415.     
  416. config_save:
  417.     mov    si,offset working_setup
  418.     call    write_setup
  419.     jmp    cs_5
  420.     
  421. config_next:
  422.     mov    si,ds:cursor_page_ptr
  423.     add    si,6                    ;move to next page
  424.     cmp    word ptr ds:[si],0
  425.     jne    cn_ok                    ;jmp if next page avail
  426.     mov    si,offset header1_ptr            ;move to top
  427. cn_ok:    mov    ds:cursor_page_ptr,si
  428.     jmp    cs_2
  429.         
  430. config_help:
  431.     mov    ah,cs:msg_text_color
  432.     mov    al,0                ;seperator
  433.     mov    cx,1                ;record#
  434.     mov    bx,1048h            ;box size
  435.     mov    dx,0404h            ;box location
  436.     mov    si,offset config_help_msg
  437.     mov    bp,msg_save_win+msg_restore_win+msg_anykey+msg_ram+msg_disp
  438.     call    message
  439.     jmp    cs_5
  440.  
  441. config_help_msg label    byte
  442.  db 'The NEXT-PAGE menu selection can be used to view each page '
  443.  db 'of configuration information.  Changes can be made within '
  444.  db 'a page by selecting the correct field using arrow keys, then '
  445.  db 'entering the information.',0
  446.  
  447. config_exit:
  448.     call    feed_colors
  449.     call    working_to_caller            ;give caller changes
  450. cs_abortx:    
  451.     apop    es,ds,bp,di,si,dx,cx,bx,ax
  452.     retf
  453. CHANGE_SETUP       endp
  454. comment 
  455. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(  CONFIG )
  456. ;WRITE_SETUP - write setup to disk
  457. ;
  458. ; inputs:   ds:si = setup block ptr
  459. ;           cx = setup block length
  460. ;
  461. ; ouptut:   no carry = success
  462. ;           carry = problem creating the file
  463. ;             register changed are:  bx,dx
  464. ;             
  465. ;* * * * * * * * * * * * * *
  466. 
  467. callers_setup_blk_off    dw    0
  468. callers_setup_blk_seg    dw    0
  469.  
  470.     PUBLIC    WRITE_SETUP
  471. WRITE_SETUP      proc      far
  472.     apush    ax,cx,si,di,ds,es
  473.     mov    cs:callers_setup_blk_off,si
  474.     mov    cs:callers_setup_blk_seg,ds
  475. ;
  476. ; search for <<end>> string
  477. ;
  478.     les    di,dword ptr cs:callers_setup_blk_off
  479.     push    cs
  480.     pop    ds
  481.     mov    si,offset end_string
  482.     mov    cx,2000
  483.     call    buffer_searchc
  484.     jc    wss_exit            ;jmp if <<end>> not found
  485. ;
  486. ; compute length of setup block
  487. ;    
  488.     sub    di,cs:callers_setup_blk_off
  489.     add    di,7
  490.     mov    cs:setup_block_len,di
  491. ;
  492. ; build name of setup file on disk
  493. ;
  494.     push    cs
  495.     pop    ds
  496.     call    build_filename
  497. ;
  498. ; create the file
  499. ;
  500.     mov    dx,offset setup_filename
  501.     mov    cx,0            ;file attributes
  502.     mov    ah,3ch
  503.     int    21h
  504.     jc    wss_exit        ;jmp if error
  505. ;
  506. ; write data to file
  507. ;
  508.     mov    bx,ax            ;move file handle to -bx-
  509.     lds    dx,dword ptr cs:callers_setup_blk_off
  510.     mov    cx,cs:setup_block_len
  511.     mov    ah,40h
  512.     int    21h
  513. ;
  514. ; close the write file
  515. ;
  516.     mov    ah,3eh
  517.     int    21h            ;close file    
  518. wss_exit:
  519.     apop    es,ds,di,si,cx,ax
  520.     retf
  521. write_setup      endp
  522. comment 
  523. ;- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -(  CONFIG )
  524. SET_LIB_COLORS - set colors to be used by the library
  525. ;
  526. ; inputs:  al = color attributes
  527. ;          bx = color number (position in table)
  528. ;
  529. ;            options available are:           defaults:
  530. ;              0 = menu bar text color          07h
  531. ;              1 = menu bar select color        70h
  532. ;              2 = menu bar hotkey color        0Fh         (1)
  533. ;              3 = submenu box color            0Fh
  534. ;              4 = submenu selection color
  535. ;              5 = msg text color
  536. ;              6 = msg_hyper_color
  537. ;              7 = pick color
  538. ;              8 = pick selection color
  539. ;
  540. ; outputs: none
  541. ; 
  542. ;* * * * * * * * * * * * * *
  543. 
  544.     PUBLIC    SET_LIB_COLORS
  545. SET_LIB_COLORS    PROC    FAR
  546.     APUSH   AX,BX
  547.     cmp     bx,8
  548.     ja      slc_exit            ;jmp if out of range
  549.     add        bx,offset bar_text_color
  550.     mov     byte ptr cs:[bx],al        ;store new color
  551. slc_exit:
  552.     apop    bx,ax
  553.     retf
  554. SET_LIB_COLORS    ENDP
  555. ;---------------------------------------------------------------------------
  556. ; setup common subroutines
  557. ;---------------------------------------------------------------------------
  558. ; summary_parse - parse input block & build summary_table
  559. ;
  560. ;  inputs:  allocated_mem_seg:working_setup has input block
  561. ;           setup_block_len = block lenght
  562. ;
  563. ;  output:  if no carry - allocated_mem_seg:header1_ptr (summary_table) is built
  564. ;                       - header_count is initialized
  565. ;           if carry - parse error
  566. ;
  567. summary_parse:
  568.     mov    ax,cs:allocated_mem_seg
  569.     mov    ds,ax
  570.     mov    es,ax
  571.     mov    ds:header_count,0
  572.  
  573.     mov    si,offset working_setup
  574.     mov    di,offset header1_ptr
  575. ;
  576. ; ds:si = block  es:di=summary table ptr
  577. ;
  578. sp_loop:
  579.     cmp    byte ptr ds:[si],'<'
  580.     je    sp_1            ;jmp if header start
  581.     inc    si
  582.     jmp    sp_loop
  583.  
  584. sp_1:    cmp    word ptr ds:[si],'<<'
  585.     jne    sp_err            ;jmp if parse error
  586.     cmp    word ptr ds:[si+2],'ne'
  587.     jne    sp_2            ;jmp if not "<<end>>"
  588.     cmp    word ptr ds:[si+4],'>d'
  589.     je    sp_end            ;jmp if end of parse
  590. ;
  591. ; look for end of header
  592. ;
  593. sp_2:    mov    ax,si
  594.     stosw                ;store     header_ptr into summary
  595.     inc    ds:header_count        ;bump header count
  596. sp_3:    lodsb
  597.     cmp    al,'>'
  598.     jne    sp_3            ;loop till end of header
  599.     lodsb
  600.     cmp    al,'>'
  601.     jne    sp_err            ;jmp if no ">>" at end
  602.     lodsb
  603.     cmp    al,0
  604.     jne    sp_err            ;jmp if no zero at end
  605.     mov    ax,si
  606.     stosw                ;store ptr to first line under header
  607.     mov    cx,0            ;set count =0
  608. sp_4:    call    parse_line
  609.     jc    sp_err            ;jmp if line bad
  610.     cmp    al,0
  611.     jne    sp_5            ;jmp if no more lines
  612.     inc    cx
  613.     jmp    sp_4            ;loop till all lines counted
  614. sp_5:    mov    ax,cx
  615.     stosw                ;store line count
  616.     jmp    sp_loop    
  617.     
  618. sp_end:    mov    word ptr es:[di],0    ;termainate parse table
  619.     clc
  620.     jmp    sp_exit
  621. sp_err:    stc
  622. sp_exit:ret
  623. ;---------------------------------------------------------------------------
  624. ; parse_line - parse one input block data item
  625. ;
  626. ;  inputs:  ds:si = pointer to start of data item
  627. ;
  628. ;  output:  if no carry - al = 0 found good line
  629. ;                         al = 1 found start of next header
  630. ;                       - si = pointer to next line or header
  631. ;                       - bx = pointer to max value
  632. ;                       - dx = pointer to default data
  633. ;                       - bp = pointer to descriptive string
  634. ;
  635. ;           if carry - parse error
  636. ;
  637. parse_line:
  638.     apush    cx,di
  639.           cmp    word ptr ds:[si],'<<'
  640.     je    pl_header        ;jmp if header next
  641.     lodsb                ;get data type
  642.     cmp    al,5
  643.     je    pl_string        ;jmp if string data
  644.     lodsb                ;get data length
  645.     cmp    al,1
  646.     je    pl_byte            ;jm if byte data
  647.     cmp    al,2
  648.     je    pl_word            ;jmp if word data
  649.     cmp    al,4
  650.     jne    pl_err            ;jmp if unknown data type
  651. ;
  652. ; a dword data type was found
  653. ;
  654.     add    si,4            ;move to maximum value
  655.     mov    bx,si            ;save ptr to max
  656.     add    si,4
  657.     mov    dx,si            ;save ptr to default value
  658.     add    si,4
  659.     mov    bp,si            ;save ptr to descriptive string
  660.     jmp    pl_skip_string
  661. ;
  662. ; a byte data type was found
  663. ;
  664. pl_byte:
  665.     add    si,1            ;move to maximum value
  666.     mov    bx,si            ;save ptr to max
  667.     add    si,1
  668.     mov    dx,si            ;save ptr to default value
  669.     add    si,1
  670.     mov    bp,si            ;save ptr to descriptive string
  671.     jmp    pl_skip_string
  672. ;
  673. ; a word data type was found
  674. ;
  675. pl_word:
  676.     add    si,2            ;move to maximum value
  677.     mov    bx,si            ;save ptr to max
  678.     add    si,2
  679.     mov    dx,si            ;save ptr to default value
  680.     add    si,2
  681.     mov    bp,si            ;save ptr to descriptive string
  682.     jmp    pl_skip_string
  683. ;
  684. ; a string data type was found
  685. ;
  686. pl_string:
  687.     lodsb                ;get string length
  688.     sub    cx,cx
  689.     mov    cl,al            ;al = string length
  690.     
  691.     add    si,1            ;move to maximum value
  692.     mov    bx,si            ;save ptr to max
  693.     add    si,1
  694.     mov    dx,si            ;save ptr to default value
  695. pl_string1:
  696.     lodsb
  697.     loop    pl_string1        ;loop to end of string
  698.     cmp    al,0            ;check if expected zero at end
  699.     jne    pl_err    
  700.     mov    bp,si            ;save ptr to descriptive string
  701. ;
  702. ; skip to end of descriptive string by looking for zero at end
  703. ;
  704. pl_skip_string:
  705.     lodsb
  706.     cmp    al,0
  707.     jne    pl_skip_string
  708.     
  709. pl_done:mov    al,0
  710.     jmp    pl_exit1
  711.     
  712. pl_err:    stc
  713.     jmp    pl_exit        
  714.     
  715. pl_header:
  716.     mov    al,1
  717. pl_exit1:    
  718.     clc
  719. pl_exit:apop    di,cx
  720.     ret    
  721. ;---------------------------------------------------------------------------
  722. ; build_line_detail - expand line information for grab_keyboard_input
  723. ;
  724. build_line_detail:
  725.     mov    ds,cs:allocated_mem_seg
  726.     mov    si,ds:cursor_line_ptr
  727.     mov    si,word ptr ds:[si]        ;get line ptr
  728.     
  729.     mov    al,byte ptr ds:[si]        ;get data type
  730.     mov    ds:ld_type,al
  731.  
  732.     mov    al,byte ptr ds:[si+1]        ;get data len
  733.     mov    ds:ld_len,al
  734.  
  735.     mov    ax,word ptr ds:[si+2]        ;get data min
  736.     mov    word ptr ds:ld_minimum,ax
  737.     mov    ax,word ptr ds:[si+4]
  738.     mov    word ptr ds:ld_minimum+2,ax
  739.  
  740.     call    parse_line
  741.  
  742.     mov    ax,word ptr ds:[bx]        ;get max data
  743.     mov    word ptr ds:ld_max,ax
  744.     mov    ax,word ptr ds:[bx+2]
  745.     mov    word ptr ds:ld_max+2,ax
  746.  
  747.     mov    ds:ld_default_ptr,dx        ;save default data ptr
  748.     mov    ds:ld_descrip_ptr,bp
  749.     mov    ds:cursor_column,1
  750.     ret
  751. ;----------------------------------------------------------------------------
  752. ; fill_temp_string - fill in temp string
  753. ;  inputs:  line_detail
  754. ;  output:  
  755. ;
  756. fill_temp_string:
  757.     apush    si,di
  758.     mov    al,ds:ld_type             ;get data type
  759.     cmp    al,5
  760.     je    fts_string        ;jmp if data_type = string
  761.     cmp    al,4
  762.     je    fts_color        ;jmp if data_type = color
  763.     cmp    al,1
  764.     je    fts_boolean        ;jmp if yes/no flag
  765.     cmp    al,2
  766.     jne    fts_1            ;jmp if not hex
  767.     mov    al,byte ptr ds:ld_len    ;get length
  768.     cmp    al,1
  769.     je    fts_hex_byte
  770.     cmp    al,2
  771.     je    fts_hex_word
  772. ;    cmp    al,4
  773.     jmp    fts_hex_dword
  774. fts_1:    mov    al,byte ptr ds:ld_len    ;get length
  775.     cmp    al,1
  776.     je    fts_dec_byte
  777.     cmp    al,2
  778.     je    fts_dec_word
  779. ;    cmp    al,4
  780.     jmp    fts_dec_dword
  781.     
  782. fts_string:
  783.     mov    si,ds:ld_default_ptr
  784.     mov    di,offset temp_string
  785.     push    ds
  786.     pop    es
  787.     call    str_copy
  788.     mov    ds:ld_str_len,cl        ;save string length
  789.     jmp    fts_exit
  790.     
  791. fts_color:
  792.     mov    si,ds:ld_default_ptr
  793.     mov    al,byte ptr ds:[si]        ;get color
  794.     mov    ah,0
  795.     mov    word ptr ds:temp_string,ax
  796.     mov    ds:ld_str_len,1
  797.     jmp    fts_exit
  798.     
  799. fts_boolean:
  800.     mov    si,ds:ld_default_ptr
  801.     cmp    byte ptr ds:[si],0        ;check if "off"
  802.     mov    si,offset off_string
  803.     je    fts_b2
  804.     mov    si,offset on_string
  805. fts_b2:    push    cs
  806.     pop    ds
  807.     mov    es,cs:allocated_mem_seg
  808.     mov    di,offset temp_string
  809.     call    str_copy
  810.     mov    ds,cs:allocated_mem_seg
  811.     mov    ds:ld_str_len,cl        ;save string length
  812.     jmp    fts_exit
  813.     
  814. fts_hex_byte:
  815.     mov    si,ds:ld_default_ptr
  816.     mov    al,byte ptr ds:[si]    ;get hex byte
  817.     mov    si,offset temp_string
  818.     call    BYTE_TO_HEX_STR
  819.     mov    byte ptr ds:[si],0    ;terminate string
  820.     mov    ds:ld_str_len,2
  821.     jmp    fts_exit
  822.         
  823. fts_hex_word:
  824.     mov    si,ds:ld_default_ptr
  825.     mov    ax,word ptr ds:[si]    ;get hex word
  826.     mov    si,offset temp_string
  827.     call    WORD_TO_HEX_STR
  828.     mov    byte ptr ds:[si],0    ;terminate string
  829.     mov    ds:ld_str_len,4
  830.     jmp    fts_exit
  831.     
  832. fts_hex_dword:
  833.     mov    si,ds:ld_default_ptr
  834.     mov    ax,word ptr ds:[si]    ;get hex word
  835.     mov    dx,word ptr ds:[si+2]    ;get hex dword
  836.     mov    si,offset temp_string
  837.     call    DWORD_TO_HEX_STR
  838.     mov    byte ptr ds:[si],0    ;terminate string
  839.     mov    ds:ld_str_len,8
  840.     jmp    fts_exit
  841.     
  842. fts_dec_byte:
  843.     mov    si,ds:ld_default_ptr
  844.     mov    al,byte ptr ds:[si]    ;get dec byte
  845.     mov    ah,0
  846.     mov    dx,0
  847.     mov    si,offset temp_string
  848.     call    DWORD_TO_DEC_STR
  849.     mov    ds:ld_str_len,3
  850.     jmp    fts_scan
  851.  
  852. fts_dec_word:
  853.     mov    si,ds:ld_default_ptr
  854.     mov    ax,word ptr ds:[si]    ;get dec word
  855.     mov    dx,0
  856.     mov    si,offset temp_string
  857.     call    DWORD_TO_DEC_STR
  858.     mov    ds:ld_str_len,5
  859.     jmp    fts_scan
  860.  
  861. fts_dec_dword:
  862.     mov    si,ds:ld_default_ptr
  863.     mov    ax,word ptr ds:[si]    ;get dec word
  864.     mov    dx,word ptr ds:[si+2]
  865.     mov    si,offset temp_string
  866.     call    DWORD_TO_DEC_STR
  867.     mov    ds:ld_str_len,10
  868. fts_scan:
  869.     call    str_cleanl
  870. fts_exit:
  871.     apop    di,si
  872.     ret    
  873.  
  874. ;---------------------------------------------------------------------------
  875. ; store_temp_string - move data from temp string to to working_setup
  876. ;  inputs:  none
  877. ;  outputs: carry set if conversion error
  878. ;
  879. store_temp_string:
  880.     apush    ax,cx,dx
  881.     mov    ax,cs:allocated_mem_seg
  882.     mov    ds,ax
  883.     mov    es,ax
  884.     
  885.     mov    di,ds:ld_default_ptr
  886.     mov    al,ds:ld_type             ;get data type
  887.     cmp    al,5
  888.     je    sts_string        ;jmp if data_type = string
  889.     cmp    al,4
  890.     je    sts_color        ;jmp if data_type = color
  891.     cmp    al,1
  892.     je    sts_boolean        ;jmp if yes/no flag
  893.     cmp    al,2
  894.     jne    sts_1            ;jmp if not hex
  895.     mov    al,byte ptr ds:ld_len    ;get length
  896.     cmp    al,1
  897.     je    sts_hex_byte
  898.     cmp    al,2
  899.     je    sts_hex_word
  900. ;    cmp    al,4
  901.     jmp    sts_hex_dword
  902. sts_1:    mov    al,byte ptr ds:ld_len
  903.     cmp    al,1
  904.     je    sts_dec_byte
  905.     cmp    al,2
  906.     je    sts_dec_word
  907. ;    cmp    al,4
  908.     jmp    sts_dec_dword
  909.     
  910. sts_string:
  911.     mov    si,offset temp_string
  912.     call    str_copy
  913.     jmp    sts_done
  914.     
  915. sts_color:
  916.     mov    al,byte ptr ds:temp_string    ;get color
  917.     mov    byte ptr ds:[di],al        ;store color
  918.     jmp    sts_done
  919.     
  920. sts_boolean:
  921.     mov    al,ds:temp_string
  922.     cmp    al,'o'
  923.     je    sts_bool1            ;jmp if ok
  924.     cmp    al,'O'
  925.     jne    sts_err                ;jmp if bad
  926. sts_bool1:
  927.     mov    al,ds:temp_string+1
  928.     cmp    al,'n'
  929.     je    sts_on                ;jmp if 'on' found
  930.     cmp    al,'N'
  931.     je    sts_on                ;jmp if 'ON' found
  932.     cmp    al,'f'
  933.     je    sts_off                ;jmp if 'of' found
  934.     cmp    al,'F'                
  935.     jne    sts_err                ;jmp if bad
  936. sts_off:
  937.     mov    al,ds:temp_string+2
  938.         cmp     al,'f'
  939.         je      sts_off1                        ;jmp if "off"
  940.         cmp     al,'F'
  941.     jne    sts_err
  942. sts_off1:
  943.     mov    byte ptr ds:[di],0        ;set off
  944.     jmp    sts_done
  945. sts_on: mov    al,ds:temp_string+2
  946.         cmp     al,' '
  947.         je      sts_on1                         ;jmp if 'on'
  948.     cmp    al,0
  949.     jne    sts_err
  950. sts_on1:mov    byte ptr ds:[di],1
  951.     jmp    sts_done    
  952.     
  953. sts_hex_byte:
  954.     mov    si,offset temp_string
  955.     call    HEX_STR_TO_BYTE
  956.     jc    sts_err
  957.     cmp    al,byte ptr ds:ld_minimum
  958.     jb    sts_err
  959.     cmp    al,byte ptr ds:ld_max
  960.     ja    sts_err
  961.     mov    byte ptr ds:[di],al
  962.     jmp    sts_done
  963.         
  964. sts_hex_word:
  965.     mov    si,offset temp_string
  966.     call    HEX_STR_TO_WORD
  967.     jc    sts_err
  968.     cmp    ax,word ptr ds:ld_minimum
  969.     jb    sts_err
  970.     cmp    ax,word ptr ds:ld_max
  971.     ja    sts_err
  972.     mov    word ptr ds:[di],ax
  973.     jmp    sts_done
  974.     
  975. sts_hex_dword:
  976.     mov    si,offset temp_string
  977.     call    HEX_STR_TO_WORD
  978.     xchg    ax,dx
  979.     add    si,4
  980.     call    HEX_STR_TO_WORD
  981.     jc    sts_err
  982. ; skip min & max checks for dwords    
  983.     mov    word ptr ds:[di],ax
  984.     mov    word ptr ds:[di+2],dx
  985.     jmp    sts_done
  986.     
  987. sts_dec_byte:
  988.     mov    si,offset temp_string
  989.     call    DEC_STR_TO_WORD
  990.     jc    sts_err
  991.     cmp    al,byte ptr ds:ld_minimum
  992.     jb    sts_err
  993.     cmp    al,byte ptr ds:ld_max
  994.     ja    sts_err
  995.     mov    byte ptr ds:[di],al
  996.     jmp    sts_done
  997.  
  998. sts_dec_word:
  999.     mov    si,offset temp_string
  1000.     call    DEC_STR_TO_WORD
  1001.     jc    sts_err
  1002.     cmp    ax,word ptr ds:ld_minimum
  1003.     jb    sts_err
  1004.     cmp    ax,word ptr ds:ld_max
  1005.     ja    sts_err
  1006.     mov    word ptr ds:[di],ax
  1007.     jmp    sts_done
  1008.  
  1009. sts_dec_dword:
  1010.     mov    si,offset temp_string
  1011.     call    DEC_STR_TO_DWORD
  1012.     jc    sts_err
  1013.     cmp    dx,word ptr ds:ld_minimum+2
  1014.     jb    sts_err
  1015.     jne    sts_dec1            ;jmp if check done
  1016.     cmp    ax,word ptr ds:ld_minimum
  1017.     jb    sts_err
  1018. sts_dec1:
  1019.     cmp    dx,word ptr ds:ld_max+2
  1020.     ja    sts_err
  1021.     jne    sts_dec2            ;jmp if check done
  1022.     cmp    ax,word ptr ld_max
  1023.     ja    sts_err
  1024. sts_dec2:    
  1025.     mov    word ptr ds:[di],ax
  1026.     mov    word ptr ds:[di+2],dx
  1027.     
  1028. sts_done:
  1029.     clc    
  1030.     jmp    sts_exit
  1031. sts_err:
  1032.     stc    
  1033. sts_exit:
  1034.     apop    dx,cx,ax
  1035.     ret    
  1036.     
  1037. ;---------------------------------------------------------------------------
  1038. ; build_page_detail - fill in detail table
  1039. ;  inputs:  data area variables
  1040. ;  output:  detail_table
  1041. ;
  1042. build_page_detail:
  1043.     mov    ax,cs:allocated_mem_seg
  1044.     mov    ds,ax
  1045.     mov    es,ax
  1046.     mov    si,ds:cursor_page_ptr
  1047.     mov    si,word ptr ds:[si+2]        ;get ptr to first line
  1048.     mov    di,offset line01_ptr
  1049. bdt_loop:
  1050.     mov    ax,si
  1051.     stosw                    ;put data into detail_table
  1052.     call    parse_line
  1053.     cmp    al,0
  1054.     je    bdt_loop            ;loop till end
  1055.  
  1056.     sub    di,2                ;move back one and zero it
  1057.     mov    ax,0
  1058. bdt_1:    stosw                    ;put zero at end
  1059.     cmp    di,offset line22_ptr+2
  1060.     jne    bdt_1                ;loop till remainder zeroed
  1061.     ret
  1062.     
  1063. ;---------------------------------------------------------------------------
  1064. ; grab_keyboard_inputs - check for pulldown keys and decode them
  1065. ;
  1066. ;   inputs:    none (database variables used as inputs)
  1067. ;
  1068. ;   output:    no carry  ax = processing ptr (restore,save,next,help,exit)
  1069. ;                 carry     = abort
  1070. ;
  1071. grab_keyboard_inputs:
  1072.     mov    ax,cs:allocated_mem_seg
  1073.     mov    ds,ax
  1074.     mov    es,ax    
  1075.     call    build_line_detail
  1076.     call    fill_temp_string
  1077.     mov    al,ds:ld_type
  1078.     cmp    al,1
  1079.     je    string_disp
  1080.     cmp    al,4
  1081.     je    color_disp    
  1082.  
  1083. ;--------  string entry ---------
  1084. string_disp:
  1085.     mov    al,cs:pick_color
  1086.     mov    ah,cs:pick_select_color
  1087.     mov    ch,ds:ld_str_len        ;get length of input window
  1088.     mov    cl,ch                ;get length of buffer
  1089.  
  1090.     mov    dh,ds:cursor_line        ;get display row
  1091.     
  1092.     mov    dl,1                     ;get display column
  1093.     mov    di,offset temp_string
  1094.     mov    bl,gs_init
  1095.     
  1096.     call    get_string
  1097. str_1:    push    cs
  1098.     pop    es                ; es = local seg, ds=allocated
  1099.     
  1100.     call    do_pulldown            ;get input
  1101. ;
  1102. ; restore seg reg's
  1103. ;    
  1104.     mov    ds,cs:allocated_mem_seg
  1105.     push    ds
  1106.     pop    es
  1107. ;
  1108. ;  dx=location  ax=key cl=flag ch= (0-abort) (1-process) (2-up) (3=down) (4=??)
  1109. ;
  1110.     cmp    ax,0149h
  1111.     je    str_5                ;jmp if not pgdn
  1112.     cmp    ax,0151h
  1113.     jne    str_6                ;jmp if not pgup
  1114. str_5:    call    store_temp_string
  1115.     mov    ch,1
  1116.     mov    ax,offset config_next
  1117.     jmp    dp_exit1
  1118.     
  1119. str_6:    cmp    ch,4
  1120.     je    string_decode            ;jmp if unknown key
  1121.  
  1122. str_2:    mov    bl,gs_close
  1123.     call    get_string
  1124.     
  1125.     cmp    ch,0                ;check if abort
  1126.     jne    str_3                ;  jmp if not abort
  1127.     stc
  1128.     jmp    dp_exit2
  1129. ;
  1130. ; check if process(1) up arrow(2)  down arrow(3)
  1131. ;
  1132. str_3:    call    store_temp_string
  1133.     jnc    str_4                ;jmp if inputs ok
  1134.     call    one_beep
  1135.     jmp    grab_keyboard_inputs
  1136. str_4:    cmp    ch,1
  1137.     je    dp_exit1            ;jmp if ax=process request
  1138. ;
  1139. ; must be up or down arrow, check if color pointers present
  1140. ;
  1141.     cmp    ds:ld_type,4
  1142.     jne    move_cursor            ;jmp if not color
  1143.     mov    dl,ds:cursor_column        ;get display column (input area)
  1144.     mov    dh,ds:cursor_line
  1145.     dec    dl
  1146.     mov    al,' '
  1147.     call    put_crt_chr
  1148.     add    dl,2
  1149.     mov    al,' '
  1150.     call    put_crt_chr
  1151. move_cursor:
  1152.     call    display_line            ;remove highlight
  1153.     cmp    ch,2
  1154.     je    sts_up
  1155. ;
  1156. ; down arrow
  1157. ;
  1158.     add    ds:cursor_line_ptr,2
  1159.     add    ds:cursor_line,1
  1160.     jmp    grab_keyboard_inputs
  1161. ;
  1162. ; up arrow
  1163. ;
  1164. sts_up: sub    ds:cursor_line_ptr,2
  1165.     sub    ds:cursor_line,1
  1166.     jmp    grab_keyboard_inputs    
  1167. ;
  1168. ; unknown key was pressed, see if it can be added to the string        
  1169. ;    
  1170. string_decode:
  1171.     cmp    cl,3                ;check if mouse click
  1172.     jne    string_key0            ; jmp if keystroke
  1173.     jmp    str_1                   ;ignore all mouse clicks
  1174.     
  1175. string_key0:
  1176.     push    ax                ;save key
  1177.     call    KEY_PUT                ;setup key for get_string
  1178.     mov    bl,gs_key_check
  1179.     call    get_string
  1180.     cmp    cx,-1
  1181.     pop    cx                ;restore origional key
  1182.     je    str_end
  1183.     cmp    ax,0                ;check if no keys available
  1184.     je    str_lp                ; jmp if no keys unprocessed
  1185.     cmp    ax,cx                ;check if different key
  1186.     je    str_end                ;jmp if same key
  1187.     call    KEY_PUT                ;    
  1188. str_lp:    jmp    str_1                   ;let pulldown look at this key
  1189. str_end:
  1190.     mov    bl,gs_close
  1191.     call    get_string
  1192.     call    store_temp_string
  1193.     jmp    grab_keyboard_inputs
  1194. ;
  1195. ; ---------- color entry -----------
  1196. ;
  1197. color_disp:
  1198.     call    store_temp_string        ;needed if loop back from below
  1199.     mov    dh,ds:cursor_line        ;get display line
  1200.     mov    dl,ds:cursor_column        ;get display column (input area)
  1201.     mov    ah,ds:temp_string        ;get color from raw data
  1202.     mov    al,''                ;get character
  1203.     call    put_crt_chr
  1204. ;
  1205. ; put pointers around selected color
  1206. ;    
  1207.     dec    dl
  1208.     mov    al,'>'
  1209.     call    put_crt_chr
  1210.     add    dl,2
  1211.     mov    al,'<'
  1212.     call    put_crt_chr
  1213.         
  1214. cd_1:    call    do_pulldown            ;check pulldown keys
  1215. ;
  1216. ;  dx=location  ax=key cl=flag ch= (0-abort) (1-process) (2-up) (3=down) (4=??)
  1217. ;
  1218.     cmp    ch,0
  1219.     jne    cd_2                ;jmp if not abort
  1220.     stc
  1221.     jmp    dp_exit2
  1222.  
  1223. cd_2:    call    store_temp_string
  1224.     jc    cd_1                ;jmp if string bad
  1225.     cmp    ch,1
  1226.     je    dp_exit1            ;jmp process (ax) request
  1227.     cmp    ax,0149h
  1228.     jne    cd_3                ;jmp if not pgdn
  1229.     mov    ch,1
  1230.     mov    ax,offset config_next 
  1231.     jmp    dp_exit1
  1232. cd_3:    cmp    ax,0151h
  1233.     jne    cd_4                ;jmp if not pgup
  1234.     mov    ch,1
  1235.     mov    ax,offset config_next
  1236.     jmp    dp_exit1
  1237. cd_4:        
  1238.     cmp    ch,4
  1239.     je    color_decode            ;jmp if color change?
  1240. ;
  1241. ; must be up or down arrow
  1242. ;
  1243.     call    display_line            ;remove highlights
  1244.     cmp    ch,2
  1245.     je    cd_up
  1246. ;
  1247. ; down arrow
  1248. ;
  1249.     add    ds:cursor_line_ptr,2
  1250.     add    ds:cursor_line,1
  1251.     jmp    grab_keyboard_inputs
  1252. ;
  1253. ; up arrow
  1254. ;
  1255. cd_up:    sub    ds:cursor_line_ptr,2
  1256.     sub    ds:cursor_line,1
  1257.     jmp    grab_keyboard_inputs    
  1258.         
  1259. color_decode:
  1260.     cmp    cl,3                ;check if mouse click
  1261.     jne    color_key0            ; jmp if keystroke
  1262. ;
  1263. ; mouse click, check if right/left color change
  1264. ;
  1265.     cmp    dl,5
  1266.     je    color_right
  1267.     cmp    dl,7
  1268.     je    color_left
  1269.     jmp    cd_1
  1270.     
  1271. color_key0:    
  1272.     cmp    ax,014dh            ;check if right arrow
  1273.     jne    color_key1            ; jmp if not right arrow
  1274. color_right:    
  1275.     add    ds:temp_string,10h        ;bump background color
  1276.     and    ds:temp_string,7fh        ;remove high bit
  1277.     jmp    color_disp
  1278.     
  1279. color_key1:
  1280.     cmp    ax,014bh            ;check if left arrow
  1281.     jne    cd_1                  ; jmp if not left arrow (ignore)
  1282. color_left:    
  1283.     mov    al,ds:temp_string        ;get color
  1284.     mov    ah,al
  1285.     and    ah,0f0h
  1286.     inc    al
  1287.     and    al,0fh
  1288.     or    al,ah
  1289.     mov    ds:temp_string,al
  1290.     jmp    color_disp
  1291. ;
  1292. ; normal exit, ax=process (restore,save,next,help,exit)
  1293. ;
  1294. dp_exit1:
  1295.     clc
  1296. dp_exit2:
  1297.     ret
  1298. ;--------------------------------------------------------------------------
  1299. ; do_pulldown - check for pulldown keys and decode them
  1300. ;   inputs: none
  1301. ;   output: es:   = raw data segment
  1302. ;              dx = click/key location
  1303. ;              cl = pulldown decode flag
  1304. ;              ax = key if -ch- =0,1,2
  1305. ;              ch = 0(abort or exit request)
  1306. ;                   1(process request, ax=process from menu)
  1307. ;                   2(legal up key)
  1308. ;                   3(legal down key)
  1309. ;                   4(unknown key/click in ax,dx,cl
  1310. ;
  1311.  
  1312. do_pulldown:    
  1313.     push    cs
  1314.     pop    ds
  1315. ;    
  1316. ; put up the menu bar
  1317. ;
  1318.     mov    bx,offset config_menu
  1319.     mov    ah,bar_display+return_bad_key+no_mouse_sim+no_mouse_show
  1320.     call    MENU_SYSTEM
  1321.     mov    ds,cs:allocated_mem_seg
  1322.     mov    bx,ds:cursor_line_ptr        ;ptr to current line
  1323.     cmp    cl,1                ;check if process hit
  1324.     jne    dp_02                ; jmp if not process hit
  1325.     mov    ch,1
  1326.     jmp    dp_exit
  1327. dp_02:
  1328.     cmp    cl,4
  1329.     jne    dp_3
  1330.     mov    ch,0
  1331.     jmp    dp_exit                ;exit if abort key found
  1332. ;
  1333. ; an unknown key or mouse click occured, check if up/down arrow first
  1334. ;
  1335. dp_3:    cmp    cl,2                ;check if unknown keystroke
  1336.     jne    dp_08                ; jmp if mouse click
  1337.     cmp    ax,0148h            ;check if up arrow
  1338.     jne    dp_05                ; jmp if not up-arrow
  1339. ;
  1340. ; up arrow - check if we are at top of section
  1341. ;    
  1342.     cmp    bx,offset line01_ptr
  1343.     jne    dp_03                ; jmp if we can move up
  1344.     jmp    do_pulldown            ;jmp if we illegal key
  1345. dp_03:
  1346.     mov    ch,2
  1347.     jmp    dp_exit
  1348.  
  1349. dp_05:
  1350.     cmp    ax,0150h            ;check if down arrow
  1351.     jne    dp_07                ;  jmp if not down_arrow
  1352. ;
  1353. ; down arrow - check if we are at bottom already
  1354. ;    
  1355.     cmp    word ptr ds:[bx+2],0        ;check if another line
  1356.     je    do_pulldown            ; jmp if at last line
  1357.     mov    ch,3
  1358.     jmp    dp_exit
  1359. ;
  1360. ; unknown key press
  1361. ;
  1362. dp_07:    mov    ch,4
  1363.     jmp    dp_exit
  1364. ;
  1365. ; check if click on option, mouse checks
  1366. ;
  1367. dp_08:    cmp    dh,ds:cursor_line        ;check if click in same row
  1368.     je    dp_07                ;jmp if same row
  1369. ;
  1370. ; we have a click on non-selected row, try to move to this row
  1371. ;    
  1372.     mov    bl,dh
  1373.     sub    bh,bh
  1374.     shl    bx,1
  1375.     add    bx,offset line01_ptr
  1376.     cmp    word ptr ds:[bx],0
  1377.     je    do_pulldown            ;jmp if click out of range
  1378.     mov    ch,3                ;pre load down arrow code
  1379.     cmp    dh,ds:cursor_line
  1380.     jb    dp_exit                ;jmp if down arrow sim
  1381.     mov    ch,2
  1382. dp_exit:
  1383.     ret
  1384.  
  1385. ;----------------------------------------------------------------------------
  1386. ; display_line - display one line of config data
  1387. ;  inputs: ds & es point at allocated memory
  1388. ;               si = ptr into page_detail (lines)
  1389. ;
  1390.  
  1391. display_line:
  1392.     apush    cx,si
  1393. ;
  1394. ; parse the current line
  1395. ;
  1396.     call    build_line_detail
  1397.     call    fill_temp_string
  1398.  
  1399.     mov    si,offset temp_string
  1400.     mov    dl,1
  1401.     mov    dh,ds:cursor_line
  1402.     call    posn_to_adr
  1403.     cmp    ds:ld_type,4        ;check if color
  1404.     jne    dl_1
  1405.     sub    di,2            ;move back one char
  1406.     mov    ah,cs:submenu_text_color
  1407.         mov     al,' '
  1408.     call    $put_crt_chr
  1409.     mov    ah,ds:temp_string    ;get color
  1410.     mov    al,''
  1411.     call    $put_crt_chr
  1412.     mov    ah,cs:submenu_text_color
  1413.         mov     al,' '
  1414.     call    $put_crt_chr
  1415.     add    di,4
  1416.     jmp    dl_4
  1417.         
  1418. dl_1:    mov    ah,cs:submenu_text_color
  1419.     mov    cx,-1            ;set display length to max
  1420.     call    $put_crt_blk
  1421.     mov    dh,ds:cursor_line
  1422.     cmp    ds:ld_type,5        ;check if string
  1423.     je    dl_2            ;  jmp if string
  1424.     mov    dl,13
  1425.     call    posn_to_adr
  1426.     jmp    dl_4
  1427. ;
  1428. ; find text location for string description
  1429. ;
  1430. dl_2:    mov    dl,ds:ld_str_len
  1431.     add    dl,4
  1432.     call    posn_to_adr
  1433. ;
  1434. ; display descsriptive string
  1435. ;
  1436. dl_4:    mov    ah,cs:submenu_text_color
  1437.     mov    cx,-1            ;set display length to max
  1438.     mov    ds,cs:allocated_mem_seg
  1439.     mov    si,ds:ld_descrip_ptr
  1440.     call    $put_crt_blk
  1441.     apop    si,cx
  1442.     ret
  1443. ;----------------------------------------------------------------------------
  1444. ; build setup file name
  1445. ;  inputs:  ds = library segment
  1446. ;  output:  setup_filename is created.
  1447. ;
  1448. build_filename:
  1449.     apush    cx,si,di,es
  1450.     mov    es,lib_info.psp_seg
  1451.     call    find_home_path        ;returns ES:DI pointing at full path
  1452. ;
  1453. ; scan to end of name
  1454. ;
  1455.     mov    si,di
  1456. bf_lp1:    inc    si
  1457.     cmp    byte ptr es:[si],0
  1458.     jne    bf_lp1            ;loop till end found
  1459. bf_lp2:    dec    si
  1460.     cmp    byte ptr es:[si-1],'\'
  1461.     je    bf_copyf
  1462.     cmp    byte ptr es:[si-1],':'
  1463.     je    bf_copyf
  1464.     cmp    di,si
  1465.     jne    bf_lp2
  1466. bf_copyf:
  1467.     mov    di,offset setup_filename
  1468. bf_loop:    
  1469.     mov    al,es:[si]
  1470.     cmp    al,0
  1471.     je    bf_done            ;jmp if name moved
  1472.     mov    ds:[di],al
  1473.     inc    si
  1474.     inc    di
  1475.     loop    bf_loop
  1476. bf_done:
  1477.     sub    di,3
  1478.         mov     word ptr [di],'FC'
  1479.     add    di,2
  1480.         mov     byte ptr [di],'G'
  1481.     add    di,1
  1482.     mov    byte ptr [di],0
  1483.     apop    es,di,si,cx
  1484.     ret
  1485. ;------------------------------------------------------------------------------
  1486. ; find_block_end - find length of setup block
  1487. ;  inputs:  address of setup block stored at cs:callers_setup_block_off
  1488. ;  output:  di = match pointer if no carry
  1489. ;           if carry then block too big or no <<end>> statement
  1490. ;         
  1491. find_block_end:
  1492.     push    cs
  1493.     pop    ds
  1494.     mov    si,offset end_string
  1495.     les    di,dword ptr cs:callers_setup_block_off
  1496.     mov    cx,2000                ;maximum setup block size
  1497.     call    buffer_searchc            ;look of end string
  1498. fbe_exit:    
  1499.     ret
  1500. ;----------------------------------------------------------------------------
  1501. ; working_to_caller - copy working setup block to callers area
  1502. ;  inputs:  cs:callers_setup_block_off = destination
  1503. ;           cs:allocated_mem_seg:working_setup = source
  1504. ;           cs:setup_block_len = length
  1505. ;
  1506. working_to_caller:
  1507.     apush    ds,es
  1508.     les    di,dword ptr cs:callers_setup_block_off
  1509.     mov    ds,cs:allocated_mem_seg
  1510.     mov    si,offset working_setup
  1511.     mov    cx,cs:setup_block_len
  1512.     cld
  1513.     rep    movsb
  1514.     apop    es,ds
  1515.     ret
  1516. ;
  1517. ;----------------------------------------------------------------------------
  1518. feed_colors:
  1519.     apush     bx,si,di,ds
  1520.  
  1521.     mov    ds,cs:allocated_mem_seg
  1522.  
  1523.     mov    ds:cursor_page_ptr,offset header1_ptr
  1524.     call    build_page_detail
  1525.  
  1526.     mov    si,offset line01_ptr        ;get ptr to line 1
  1527.     mov    bx,0                ;color store #
  1528.  
  1529. fc_loop:mov    di,word ptr ds:[si]        ;get line ptr
  1530.     mov    al,ds:[di+4]            ;get color
  1531.     call    set_lib_colors
  1532.     inc    bx                ;move to next color
  1533.     add    si,2                ;move to next setup line
  1534.     cmp    bx,8
  1535.     jb    fc_loop                ;loop till done
  1536.  
  1537.     apop     ds,di,si,bx
  1538.     ret
  1539. ;----------------------------------------------------------------------------
  1540. ; CONFIG data section
  1541. ;----------------------------------------------------------------------------
  1542. ; The summary_table built by GET_SETUP and a copy of setup is kept in
  1543. ; memory.
  1544. ;---------------------------
  1545. ; config menu (top menu bar)
  1546. ;
  1547. config_menu    label    byte
  1548.     db    0            ;m_flag
  1549.     db    0            ;top row
  1550.     db    0            ;left column
  1551.     db    1            ;total rows
  1552.     db    80            ;total columns
  1553.     db    5            ;menu options
  1554.     dw    0            ;main selection
  1555.     dw    0            ;sub selection
  1556. ; config option #0 -RESTORE_DEFAULTS-
  1557.     db    0            ;e_count
  1558.     db    0            ;e_sub_length
  1559.     db    19            ;e_hot_key (alt-t)
  1560.     db    16            ;e_length
  1561.     dw    config_opt0_text    ;e_text_ptr
  1562.     dw    config_restore         ;e_process
  1563.     db    1            ;e_column
  1564.           db    0            ;e_row
  1565. ; config option #1 -SAVE_DATA-
  1566.     db    0            ;e_count
  1567.     db    0            ;e_sub_length
  1568.     db    31            ;e_hot_key (alt-a)
  1569.     db    09            ;e_length
  1570.     dw    config_opt1_text    ;e_text_ptr
  1571.     dw    config_save        ;e_process
  1572.     db    19            ;e_column
  1573.           db    0            ;e_row
  1574. ; config option #2 -NEXT_PAGE-
  1575.     db    0            ;e_count
  1576.     db    0            ;e_sub_length
  1577.     db    49            ;e_hot_key (alt-b)
  1578.     db    09            ;e_length
  1579.     dw    config_opt2_text    ;e_text_ptr
  1580.     dw    config_next        ;e_process
  1581.     db    30            ;e_column
  1582.           db    0            ;e_row
  1583. ; config option #3 -HELP-
  1584.     db    0            ;e_count
  1585.     db    0            ;e_sub_length
  1586.     db    35            ;e_hot_key (alt-b)
  1587.     db    04            ;e_length
  1588.     dw    config_opt3_text    ;e_text_ptr
  1589.     dw    config_help        ;e_process
  1590.     db    41            ;e_column
  1591.           db    0            ;e_row
  1592. ; config option #4 -EXIT-config-
  1593.     db    0            ;e_count
  1594.     db    0            ;e_sub_length
  1595.     db    18            ;e_hot_key (alt-b)
  1596.     db    11            ;e_length
  1597.     dw    config_opt4_text    ;e_text_ptr
  1598.     dw    config_exit        ;e_process
  1599.     db    47            ;e_column
  1600.           db    0            ;e_row
  1601. ; config option end, dummy option
  1602.     db    0            ;e_count
  1603.     db    0            ;e_sub_length
  1604.     db    00            ;e_hot_key (alt-b)
  1605.     db    0            ;e_length
  1606.     dw    0                     ;e_text_ptr
  1607.     dw    0            ;e_process
  1608.     db    0            ;e_column
  1609.     db    0            ;e_row
  1610.  
  1611. config_opt0_text     db 'Restore_defaluts',0
  1612. config_opt1_text     db 'Save_data',0
  1613. config_opt2_text     db 'Next_page',0
  1614. config_opt3_text     db 'Help',0
  1615. config_opt4_text     db 'Exit-config',0
  1616. config_opt5_text     label    byte    ;dummy for menu placement calc
  1617.  
  1618. ;------------------------------------------------------------------------------
  1619.  
  1620. LIBSEG    ENDS
  1621.     END
  1622.