home *** CD-ROM | disk | FTP | other *** search
/ C!T ROM 5 / ctrom5b.zip / ctrom5b / PROGRAM / ASM / ALIB30A / MEMORY.ASM < prev    next >
Assembly Source File  |  1994-12-18  |  8KB  |  338 lines
  1. ;**************************** MEMORY.ASM ********************************
  2. PAGE  70,132
  3. comment 
  4.                              MEMORY.ASM
  5.                              ----------
  6.  
  7.      Purpose:
  8.      --------
  9.  
  10.      MEMORY.ASM display the memory information available from
  11.      ALIB.  Include are the MCB chain, and the size of DOS,
  12.      XMS, and EMS memory.
  13.  
  14.      Compiling
  15.      ---------
  16.  
  17.      MEMORY.ASM was compiled using MASM and then linked with LINK.
  18.      
  19.      The following commands can be used:
  20.  
  21.         masm MEMORY;
  22.         link MEMORY,MEMORY,,alib.lib;
  23.  
  24.  
  25. 
  26.  
  27. ;----------------------------------------------------------------------------
  28. .xlist
  29.     include  mac.inc
  30.     include  common.inc
  31.     extrn    library_setup:far
  32.     extrn    library_terminate:far
  33.     extrn    stdout_string:far
  34.     extrn    stdout_char:far
  35.     extrn    word_to_hex_stdout:far
  36.     extrn    stdout_crlf:far
  37.     extrn    stdout_spaces:far
  38.     extrn    word_to_dec_stdout:far
  39.     extrn    dword_to_dec_stdout:far
  40.     extrn    a20_check:far
  41.     extrn    xms_check:far
  42.     extrn    mcb_find_first:far
  43.     extrn    mcb_find_next:far
  44.     extrn    mcb_find_name:far
  45.     extrn    mcb_display_name:far
  46.     extrn    check_dos_memory:far
  47.     extrn    xms_umb_check:far
  48.     extrn    ems_check:far
  49.     extrn    ext_check:far    
  50. .list
  51.     
  52. ;------------------------------------------------------------------------------
  53. code        segment para public 'CODE'
  54.         assume    cs:code, ds:code
  55. ;-----------------------------------------------------------------------------
  56. ; 
  57.  
  58. stacksize    equ    1024
  59.     db    stacksize dup (0)
  60. stack_    label    word
  61. ;
  62. pspseg        dw    0        ;program segment prefix
  63. ;-----------------------------------------------------------------------------
  64. start:    cli
  65.     mov    cs:pspseg,es    ;save PSP segment
  66.     mov    ax,cs        ;get CODE segment
  67.     mov    ss,ax
  68.     mov    ds,ax
  69.     mov    es,ax
  70.     mov    sp,offset stack_
  71.     sti
  72.     
  73. ; next, release memory beyond the end of the program
  74. ; The  definition for ZSEG marks the
  75. ; end of the program's code, data and stack area.
  76. ; When linking be sure ZSEG is at the end of the program.
  77.  
  78.     mov    ax,zseg
  79.  
  80.     mov    bx,cs:pspseg        ;
  81.     mov    es,bx
  82.     sub    bx,ax
  83.     neg    bx            ; size of program in paragraphs
  84.     mov    ah,4Ah            ; resize memory block
  85.     int    21h
  86.  
  87.     mov    ax,cs
  88.     mov    es,ax
  89. ;
  90. ; setup the library information
  91. ;
  92.     mov    ax,pspseg        ;pass psp segment to setup
  93.     mov    bx,0            ;number of floating point variables
  94.     call    library_setup
  95. ;
  96. ; now remove the memory manager so we can check available memory.
  97. ; The memory manager grabs all available memory, and we will always
  98. ; get zero available if it is active.
  99. ;
  100.     mov    ax,1
  101.     call    library_terminate
  102.  
  103.     call    a20_status
  104.     call    mcb_status
  105.     call    conventional_status
  106.     call    xms_status
  107.     call    ems_status
  108.     call    ext_status
  109.     
  110. exit2:
  111.           mov    ax,4C00h
  112.     int    21h
  113. ;--------------------------------------------------------------------------
  114. wrap_msg    db    'A20 line is wrapping',0
  115. no_wrap_msg    db    'A20 line is not wrapping',0
  116. xwrap_msg    db    ', XMS driver reports A20 is wrapping',0
  117. xno_wrap_msg    db    ', XMS driver reports A20 is not wrapping',0
  118. break        label    byte
  119.  db '------------------------------------------------------------------------'
  120. crlf        db    0dh,0ah,0
  121.  
  122. a20_status:
  123.     mov    si,offset break
  124.     call    stdout_string
  125.     call    a20_check
  126.     mov    si,offset wrap_msg
  127.     cmp    al,0
  128.     je    a20_1            ;jmp if wrapping
  129.     mov    si,offset no_wrap_msg
  130. a20_1:    call    stdout_string
  131.     call    xms_check
  132.     mov    si,offset crlf
  133.     cmp    bx,0
  134.     je    a20_2            ;jmp if no xms driver
  135.     mov    si,offset xwrap_msg
  136.     cmp    cx,0
  137.     je    a20_2
  138.     mov    si,offset xno_wrap_msg
  139. a20_2:    call    stdout_string
  140.     call    stdout_crlf
  141.     ret
  142. ;--------------------------------------------------------------------------
  143.  
  144. MCB    STRUC
  145.   mcb_code1    db    0        ;4d=start 5a=end
  146.   prog_seg1    dw    0        ;program segment
  147.   mcb_len1    dw    0        ;length of memory ctrl    block
  148. MCB    ENDS
  149. ;
  150. mcb_status:
  151.     mov    si,offset break
  152.     call    stdout_string
  153.     mov    si,offset header
  154.     call    stdout_string
  155. ;
  156. ; chain high mcb's in
  157. ;
  158.     mov    ax,5803h
  159.     mov    bx,1
  160.     int    21h
  161.     
  162.     call    mcb_find_first
  163.     jmp    show_mcb
  164. mcb_loop:
  165.     call    mcb_find_next
  166. show_mcb:
  167.     pushf
  168.     mov    ah,2
  169.     call    stdout_spaces
  170.     mov    ax,es
  171.     call    word_to_hex_stdout
  172.     mov    ah,4
  173.     call    stdout_spaces
  174.     mov    ax,es:[prog_seg1]
  175.     call    word_to_hex_stdout
  176.     mov    ah,4
  177.     call    stdout_spaces
  178.     mov    ax,es:[mcb_len1]
  179.     call    word_to_hex_stdout
  180.     mov    ah,4
  181.     call    stdout_spaces
  182.     call    mcb_find_name
  183.     jnc    skip
  184.     call    mcb_display_name
  185. skip:    call    stdout_crlf
  186.     popf
  187.     jnc    mcb_loop
  188. ;
  189. ; unchain high mcb's
  190. ;
  191.      mov    ax,5803h
  192.     mov    bx,0
  193.     int    21h
  194.        ret
  195.  
  196. header    db    0dh,0ah,0dh,0ah
  197.     db    '  MCB     Block   Block   Process',0dh,0ah
  198.     db    '  Seg     Owner   Size    Name   ',0dh,0ah
  199.          db    '  -----------------------------------------------',0dh,0ah
  200.     db    0
  201. ;---------------------------------------------------------------------------
  202.  
  203. c_msg1    db    'Available DOS memory = ',0
  204. c_msg2    db    '  Total memory size (bytes) = ',0
  205. ;
  206. ; display conventional memory status
  207. ;
  208. conventional_status:
  209.     mov    si,offset break
  210.     call    stdout_string
  211.     mov    ax,zseg
  212.     call    check_dos_memory
  213.     mov    si,offset c_msg1
  214.     call    stdout_string
  215.     mov    cx,16
  216.     mul    cx
  217.     call    dword_to_dec_stdout
  218.     mov    ah,4
  219.     call    stdout_spaces
  220.     mov    si,offset c_msg2
  221.     call    stdout_string
  222.     mov    ax,bx
  223.     mov    cx,16
  224.     mul    cx
  225.     call    dword_to_dec_stdout
  226.     call    stdout_crlf
  227.     ret
  228. ;---------------------------------------------------------------------------
  229. no_xms    db    'The XMS driver was not found',0
  230. found_xms db    'The total avaliable XMS memory (bytes) = ',0
  231. no_umb    db    'XMS reports the UMB area is not available',0
  232. found_umb db    'XMS reports available UMB area (bytes) = ',0
  233.  
  234. ;
  235. ; display xms status
  236. ;
  237. xms_status:
  238.     mov    si,offset break
  239.     call    stdout_string
  240.     call    xms_check
  241.     mov    si,offset no_xms
  242.     cmp    bx,0
  243.     je    xms1            ;jmp if no xms
  244.     mov    si,offset found_xms
  245. xms1:    call    stdout_string
  246.     cmp    bx,0
  247.     je    xms9            ;jmp if no xms
  248.     mov    ax,dx
  249.     mov    cx,1024
  250.     mul    cx
  251.     call    dword_to_dec_stdout
  252.     call    stdout_crlf
  253.  
  254.     call    xms_umb_check
  255.     mov    si,offset no_umb
  256.     cmp    bx,0
  257.     je    xms2            ;jmp if no xms
  258.     mov    si,offset found_umb
  259. xms2:    call    stdout_string
  260.     cmp    bx,0
  261.     je    xms9            ;jmp if no xms
  262.     mov    ax,dx
  263.     mov    cx,1024
  264.     mul    cx
  265.     call    dword_to_dec_stdout
  266. xms9:    call    stdout_crlf
  267.     ret
  268. ;---------------------------------------------------------------------------
  269. no_ems_msg db 'EMS memory was not found',0dh,0ah,0
  270. ems_size_msg db 'EMS free memory was found, size (bytes) = ',0
  271. ems_tsize_msg db 'Total EMS size is (bytes) = ',0
  272.  
  273. ems_status:
  274.     mov    si,offset break
  275.     call    stdout_string
  276.     call    ems_check
  277.     mov    si,offset no_ems_msg
  278.     jc    ems9
  279.     push    dx
  280.     mov    si,offset ems_size_msg
  281.     call    stdout_string
  282.     mov    ax,bx
  283.     mov    cx,16384
  284.     mul    cx
  285.     call    dword_to_dec_stdout
  286.     call    stdout_crlf
  287.     mov    si,offset ems_tsize_msg
  288.     call    stdout_string
  289.     pop    ax
  290.     mul    cx
  291.     call    dword_to_dec_stdout
  292.     mov    si,offset crlf
  293. ems9:    call    stdout_string
  294.     ret
  295. ;---------------------------------------------------------------------------
  296. ext_msg1 db 'Available EXT memory reported by BIOS (bytes) = ',0
  297. ext_msg2 db 'Total EXT reported by CMOS (bytes) = ',0
  298.  
  299. ext_status:
  300.     mov    si,offset break
  301.     call    stdout_string
  302.     mov    si,offset ext_msg1
  303.     call    stdout_string
  304.     call    ext_check
  305.     mov    cx,1024
  306.     mul    cx
  307.     call    dword_to_dec_stdout
  308.     call    stdout_crlf
  309.  
  310.     mov    si,offset ext_msg2
  311.     call    stdout_string
  312.     mov    ax,bx
  313.     mov    cx,1024
  314.     mul    cx
  315.     call    dword_to_dec_stdout
  316.     call    stdout_crlf
  317.     
  318.     ret
  319. ;---------------------------------------------------------------------------
  320.  
  321. code        ends
  322.  
  323. ;-------------------------------------------------------------------------
  324. ;
  325. ; This segment definition is needed so linker will put the LIBSEG here
  326. ; before the ZSEG.  We want ZSEG to be last so memory allocation will
  327. ; work correctly.
  328. ;
  329. LIBSEG           segment byte public 'LIB'
  330. LIBSEG    ENDS
  331. ;-------------------------------------------------------------------------
  332. ; zseg must be at the end of the program for memory allocation from
  333. ; DOS.
  334. ;
  335. zseg    segment    para public 'ZZ'
  336. zseg    ends
  337.         end    start
  338.