home *** CD-ROM | disk | FTP | other *** search
/ C!T ROM 2 / ctrom_ii_b.zip / ctrom_ii_b / PROGRAM / ASSEMBLE / 80X0992 / VGAMODEX.ASM < prev    next >
Assembly Source File  |  1992-09-30  |  8KB  |  275 lines
  1. ;VGA non-standard 256 color routines
  2. ;By Matt Pritchard
  3. :Placed in public domain
  4. ;With Input from Michael Abrash
  5. ;MASM v5.10a used for this
  6.  
  7.         .MODEL Medium
  8.  
  9.         VGA_SEGMENT     EQU  0A000H     ;Vga Memory Segment
  10.         SCREEN_XWIDTH   EQU  360        ;Width of screen in Pixels
  11.         SCREEN_WIDTH    EQU  90         ;Width of screen in bytes
  12.         SCREEN_HEIGHT   EQU  240        ;Height of screen
  13.  
  14.         GC_INDEX        EQU  03CEH      ;VGA Graphics Controller
  15.         SC_INDEX        EQU  03C4H      ;VGA Sequence controller
  16.         CRTC_INDEX      EQU  03D4H      ;VGA CRT Controller
  17.         MISC_OUTPUT     EQU  03C2H      ;VGA Misc Register
  18.         MAP_MASK        EQU  02         ;Map Register #
  19.         READ_MAP        EQU  04         ;Read Map Register #
  20.  
  21.         FALSE   EQU     0               ;Boolean false constant
  22.         TRUE    EQU     -1              ;boolean true constant
  23.  
  24.         .DATA
  25.  
  26.         .CODE
  27.  
  28.         ;360 x 240 VGA Mode data
  29.  
  30.  
  31. VMODE_DATA
  32.         DW      06B00H          ; Horz total
  33.         DW      05901H          ; Horz Displayed
  34.         DW      05A02H          ; Start Horz Blanking
  35.         DW      08E03H          ; End Horz Blanking
  36.         DW      05E04H          ; Start H Sync
  37.         DW      08A05H          ; End H Sync
  38.         DW      00D06H          ; Vertical Total
  39.         DW      03E07H          ; Overflow
  40.         DW      04109H          ; Cell Heigth
  41.         DW      0EA10H          ; V Sync Start
  42.         DW      0AC11H          ; V Sync End/Prot Cr0 Cr7
  43.         DW      0DF12H          ; Vertical Displayed
  44.         DW      02D13H          ; Offset
  45.         DW      00014H          ; Dword Mode off
  46.         DW      0E715H          ; V Blank Start
  47.         DW      00616H          ; V Blank End
  48.         DW      0E317H          ; turn on Byte Mode
  49.  
  50. ; Routine: SET_VGA_MODE
  51. ;  Sets up Super high VGA 256 Color RES mode (360 x 240) 
  52. ; 
  53. ; BASIC: DECLARE SUB SET.VGA.MODEX ALIAS "SET_VGA_MODE" 
  54. ; C: void SET_VGA_MODE ();
  55. ;
  56.  
  57.     PUBLIC      SET_VGA_MODE
  58.  
  59. SET_VGA_MODE    PROC    FAR
  60.  
  61.     PUSH    BP          ;Save Registers
  62.     PUSH    DS
  63.     PUSH    SI
  64.     PUSH    DI
  65.  
  66.     MOV     AX, 13H             ; Start with Mode 13H
  67.     INT     10H                 ; Let BIOS Set Mode
  68.  
  69.     MOV     DX, SC_INDEX        ; Sequencer Addr
  70.     MOV     AX, 0604H           ; Disable Chain 4 Mode
  71.     OUT     DX, AX
  72.  
  73.     MOV     AX, 0100H           ; (A)synchronous Reset
  74.     OUT     DX, AX
  75.  
  76.     MOV     DX, MISC_OUTPUT     ; VGA Misc Register
  77.     MOV     AL, 0E7H            ; Use 28Mhz Clock & 60Hz
  78.     OUT     DX, AL
  79.  
  80.     MOV     DX, SC_INDEX        ; VGA Sequencer Regs
  81.     MOV     AX, 0300H           ; Restart Sequencer...
  82.     OUT     DX, AX
  83.  
  84.     MOV     DX, CRTC_INDEX      ; Vga crtc Registers
  85.     MOV     AL, 11H             ; cr11
  86.     OUT     DX, AL              ; Load Current Value
  87.     INC     DX                  ; Point to Data
  88.     IN      AL, DX              ; Get CR11
  89.     AND     AL, 7FH             ; Mask out Write Protect
  90.     OUT     DX, AL              ; And send it back
  91.  
  92.     MOV     DX, CRTC_INDEX      ; Vga Crtc Registers
  93.     CLD                         ; Forward Block Load
  94.     MOV     SI, OFFSET VMODE_DATA       ; Get Parameter Data
  95.     MOV     CX, 17              ; Number of Data Entries
  96.  
  97. SV3_CPY:
  98.     MOV     AX,CS:[SI]          ; Get Data from Code Segment
  99.     INC     SI                  ; Advance to next word
  100.     INC     SI
  101.     OUT     DX, AX              ; Send to VGA
  102.     LOOP    SV3_CPY             ; Copy all data...
  103.  
  104.     ;Clear all VGA memory to black
  105.  
  106.     MOV     DX, SC_INDEX        ; Select All Planes
  107.     MOV     AX, 0F02H
  108.     OUT     DX, AX
  109.  
  110.     MOV     AX, VGA_SEGMENT     ; Point to VGA memory
  111.     MOV     ES, AX
  112.     MOV     DI, 000
  113.  
  114.     XOR     AX, AX              ; Clear 256K...
  115.     MOV     CX, 8000H           ; (32K * 2 * 4 planes)
  116.     REP     STOSW
  117.  
  118.     POP     DI                  ; Restore registers
  119.     POP     SI
  120.     POP     DS
  121.     POP     BP
  122.  
  123.     RET                         ;We Done.. Outa here
  124.  
  125. SET_VGA_MODE    ENDP
  126.  
  127. ; Routine: CLEAR_VGA_SCREEN (*Color%)
  128. ;  Sets the Entire Screen to one Color
  129. ;
  130. ; BASIC: DECLARE SUB CLEAR.VGA ALIAS "CLEAR_VGA_SCREEN" _ 
  131. ;        (BYVAL ColorNum%) 
  132. ; C: pascal void CLEAR_VGA_SCREEN (int Color_Num); 
  133. ;
  134.  
  135. CVS_STACK STRUC
  136.                 DW      ?       ;saved DI
  137.                 DW      ?       ;saved BP
  138.                 DD      ?       ;Caller
  139.     CVS_COLOR   DB      ?,?     ;Color to Fill With CVS_STACK ENDS
  140.  
  141.     PUBLIC      CLEAR_VGA_SCREEN
  142.  
  143. CLEAR_VGA_SCREEN        PROC    FAR
  144.  
  145.     PUSH    BP                  ; Save registers
  146.     PUSH    DI
  147.  
  148.     MOV     BP,SP               ; Setup Stack frame
  149.  
  150.     MOV     DX, SC_INDEX        ; Select All Panes
  151.     MOV     AX, 0F02H           ; Map Mask (02) = 0F
  152.     OUT     DX, AX
  153.  
  154.     MOV     AX, VGA_SEGMENT     ; Point to VGA memory
  155.     MOV     ES, AX
  156.     MOV     DI, 0
  157.  
  158.     MOV     AL,[BP].CVS_COLOR   ; Get Color to set
  159.     MOV     AH,AL               ; Copy for Word Write
  160.  
  161.     MOV     CX, 10800           ; # of bytes in 360x240 mode
  162.     REP     STOSW               ; Blast it!
  163.  
  164.     POP     DI                  ; restore registers
  165.     POP     BP
  166.  
  167.     RET     2                   ; exit & clean up stack
  168.  
  169. CLEAR_VGA_SCREEN        ENDP
  170.  
  171. ; Routine: SETPOINT (*Xpos1, *Ypos1%, *ColorNum%) 
  172. ;   Sets a single pixel in 360x240 256 color mode 
  173. ; 
  174. ; BASIC: DECLARE SUB SETPOINT (BYVAL X%, BYVAL Y%, BYVAL ColorNum%) 
  175. ; C: pascal void SETPOINT (int Xpos, int Ypos, int Color_num);
  176. ;
  177.  
  178. SP_STACK STRUC
  179.                 DW      ?       ;saved BP
  180.                 DD      ?       ;Caller
  181.     SETP_COLOR  DB      ?,?     ;Pixel color
  182.     SETP_YPOS   DW      ?       ;Pixel Y pos
  183.     SETP_XPOS   DW      ?       ;Pixel X pos SP_STACK ENDS
  184.  
  185.     PUBLIC SETPOINT
  186.  
  187. SETPOINT    PROC    FAR
  188.  
  189.     PUSH    BP                  ;Save base pointer
  190.  
  191.     MOV     BP,SP               ;Set up stack frame
  192.  
  193.     MOV     AX, SCREEN_WIDTH    ;Get Screen Line Width
  194.     MUL     [BP].SETP_YPOS      ;AX = Ypos * 90
  195.  
  196.     MOV     BX,[BP].SETP_XPOS   ;Get Xpos
  197.     MOV     CX, BX              ;Save copy of Xpos
  198.     SHR     BX, 1               ;XByte = Xpos/4
  199.     SHR     BX, 1
  200.  
  201.     ADD     BX,AX               ;BX = 90 * Ypos + Xpos/4
  202.  
  203.     MOV     AX, 0102h           ;Plane Mask & Select Register
  204.     AND     CL, 3               ;Get plane # from Xpos
  205.     SHL     AH, CL              ;Shift to Get Plane Value
  206.     MOV     DX, SC_INDEX        ;Setup to select plane
  207.  
  208.     OUT     DX, AX              ;Select Plane...
  209.  
  210.     MOV     AX,VGA_SEGMENT      ;Setup Vga Segment
  211.     MOV     ES,AX
  212.  
  213.     MOV     AL,[BP].SETP_COLOR  ;Get Color
  214.  
  215.     MOV     ES:[BX], AL         ;Draw Point
  216.  
  217.     POP     BP                  ;Restore Bp
  218.  
  219.     RET     6                   ;Exit and Clean up Stack
  220.  
  221. SETPOINT    ENDP
  222.  
  223. ; Routine: int READPOINT (*Xpos, *Ypos%)
  224. ;    Returns the color of single pixel in AX 
  225. ; 
  226. ; BASIC: DECLARE FUNCTION READPOINT% (BYVAL X%, BYVAL Y%) 
  227. ; C: pascal void READPOINT (int Xpos, int Ypos);
  228. ;
  229.  
  230. RP_STACK STRUC
  231.                 DW      ?       ;saved Bp
  232.                 DD      ?       ;Caller
  233.     RP_YPOS     DW      ?       ;Pixel Y pos
  234.     RP_XPOS     DW      ?       ;Pixel X pos RP_STACK ENDS
  235.  
  236.     PUBLIC      READPOINT
  237.  
  238. READPOINT        PROC    FAR
  239.  
  240.     PUSH    BP
  241.  
  242.     MOV     BP,SP               ;Set up stack frame
  243.  
  244.     MOV     AX, SCREEN_WIDTH    ;Get Screen Line Width
  245.     MUL     [BP].RP_YPOS        ;AX = Ypos * Screen Width
  246.  
  247.     MOV     BX,[BP].RP_XPOS     ;Get Xpos
  248.     MOV     CX, BX              ;Save Copy of Xpos
  249.     SHR     BX, 1               ;XByte = Xpos/4
  250.     SHR     BX, 1
  251.  
  252.     ADD     BX,AX               ;BX = Screen_Width * Ypos + Xpos/4
  253.  
  254.     MOV     AL, READ_MAP        ;GC Read Mask Register
  255.     MOV     AH, CL              ;Get Xpos
  256.     AND     AH, 3               ;& mask out Plane #
  257.     MOV     DX, GC_INDEX        ;Setup to select Read Mask
  258.  
  259.     OUT     DX, AX              ;Select Plane...
  260.  
  261.     MOV     AX,VGA_SEGMENT      ;Setup Vga Segment
  262.     MOV     ES,AX
  263.  
  264.     XOR     AX,AX               ;Clear Return Value
  265.  
  266.     MOV     AL,ES:[BX]          ;Get Color of Pixel
  267.  
  268.     POP     BP                  ;Restore registers
  269.  
  270.     RET     4                   ;Exit and Clean up Stack
  271.  
  272. READPOINT        ENDP
  273.  
  274. ; EOF VGAMODEX.ASM
  275.