home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: Science / Science.zip / PSPICEP2.ZIP / NOM.LIB < prev    next >
Text File  |  1990-01-23  |  28KB  |  744 lines
  1. * Sample master library of standard devices
  2. *
  3. * Copyright 1989 by MicroSim Corporation
  4. * This is a reduced version of the master library for MicroSim's standard 
  5. * parts libraries. Some components from each type of component library have
  6. * been included here.
  7. *   You are welcome to make as many copies of it as you find convenient.
  8. *
  9. * Release date: July 1989
  10. *
  11. * It takes time for PSpice to scan a library file.  When possible, PSpice
  12. * creates an index file, called <filename>.IDX, to speed up the search process.
  13. * The index file is re-created whenever PSpice senses that it might be invalid.
  14.  
  15. *     The following is a summary of parts in this library:
  16. *
  17. *           Part name           Part type
  18. *           ---------           ---------
  19. *           Q2N2222A            NPN bipolar transistor
  20. *           Q2N2907A            PNP bipolar transistor
  21. *           Q2N3904             NPN bipolar transistor
  22. *           Q2N3906             PNP bipolar transistor
  23. *
  24. *           D1N750              zener diode
  25. *           MV2201              voltage variable capacitance diode
  26. *           D1N4148             switching diode
  27. *           MBD101              switching diode
  28. *
  29. *           J2N3819             N-channel Junction field effect transistor
  30. *           J2N4393             N-channel Junction field effect transistor
  31. *
  32. *           LM324               linear operational amplifier
  33. *           UA741               linear operational amplifier
  34. *           LM111               voltage comparator
  35. *
  36. *           K3019PL_3C8         ferroxcube pot magnetic core
  37. *           KRM8PL_3C8          ferroxcube pot magnetic core
  38. *           K502T300_3C8        ferroxcube pot magnetic core
  39. *
  40. *           IRF150              N-type power MOS field effect transistor
  41. *           IRF9140             P-type power MOS field effect transistor
  42. *
  43. *           7402                TTL digital 2-input NOR gate
  44. *           7404                TTL digital inverter
  45. *           7474                TTL digital D-type flip-flop
  46. *           74393               TTL digital 4-bit binary counter
  47. *
  48. *           A4N25               optocoupler
  49. *
  50. *-------------------------------------------------------------------------------
  51. * Library of bipolar transistor model parameters
  52. *
  53. * This is a reduced version of MicroSim's bipolar transistor model library.
  54. *   You are welcome to make as many copies of it as you find convenient.
  55. *
  56. * The parameters in this model library were derived from the data sheets for
  57. * each part.  Each part was characterize using the Parts option.
  58. * Devices can also be characterized without Parts as follows:
  59. *
  60. *    NE, NC        Normally set to 4
  61. *    BF, ISE, IKF    These are adjusted to give the nominal beta vs.
  62. *            collector current curve.  BF controls the mid-
  63. *            range beta.  ISE/IS controls the low-current
  64. *            roll-off.  IKF controls the high-current rolloff.
  65. *    ISC        Set to ISE.
  66. *    IS, RB, RE, RC    These are adjusted to give the nominal VBE vs.
  67. *            IC and VCE vs. IC curves in saturation.  IS
  68. *            controls the low-current value of VBE.  RB+RE
  69. *            controls the rise of VBE with IC.  RE+RC controls
  70. *            the rise of VCE with IC.  RC is normally set to 0.
  71. *    VAF        Using the voltages specified on the data sheet
  72. *            VAF is set to give the nominal output impedance
  73. *            (RO on the .OP printout) on the data sheet.
  74. *    CJC, CJE    Using the voltages specified on the data sheet
  75. *            CJC and CJE are set to give the nominal input
  76. *            and output capacitances (CPI and CMU on the .OP
  77. *            printout; Cibo and Cobo on the data sheet).
  78. *    TF        Using the voltages and currents specified on the
  79. *            data sheet for FT, TF is adjusted to produce the
  80. *            nominal value of FT on the .OP printout.
  81. *    TR        Using the rise and fall time circuits on the
  82. *            data sheet, TR (and if necessary TF) are adjusted
  83. *            to give a transient analysis which shows the
  84. *            nominal values of the turn-on delay, rise time,
  85. *            storage time, and fall time.
  86. *    KF, AF        These parameters are only set if the data sheet has
  87. *            a spec for noise.  Then, AF is set to 1 and KF
  88. *            is set to produce a total noise at the collector
  89. *            which is greater than the generator noise at the
  90. *            collector by the rated number of decibels.
  91. *
  92. *
  93. .model Q2N2222A NPN(Is=14.34f Xti=3 Eg=1.11 Vaf=74.03 Bf=255.9 Ne=1.307
  94. +        Ise=14.34f Ikf=.2847 Xtb=1.5 Br=6.092 Nc=2 Isc=0 Ikr=0 Rc=1
  95. +        Cjc=7.306p Mjc=.3416 Vjc=.75 Fc=.5 Cje=22.01p Mje=.377 Vje=.75
  96. +        Tr=46.91n Tf=411.1p Itf=.6 Vtf=1.7 Xtf=3 Rb=10)
  97. *        National    pid=19        case=TO18
  98. *        88-09-07 bam    creation
  99.  
  100. .model Q2N2907A PNP(Is=650.6E-18 Xti=3 Eg=1.11 Vaf=115.7 Bf=231.7 Ne=1.829
  101. +        Ise=54.81f Ikf=1.079 Xtb=1.5 Br=3.563 Nc=2 Isc=0 Ikr=0 Rc=.715
  102. +        Cjc=14.76p Mjc=.5383 Vjc=.75 Fc=.5 Cje=19.82p Mje=.3357 Vje=.75
  103. +        Tr=111.3n Tf=603.7p Itf=.65 Vtf=5 Xtf=1.7 Rb=10)
  104. *        National    pid=63        case=TO18
  105. *        88-09-09 bam    creation
  106.  
  107. .model Q2N3904    NPN(Is=6.734f Xti=3 Eg=1.11 Vaf=74.03 Bf=416.4 Ne=1.259
  108. +        Ise=6.734f Ikf=66.78m Xtb=1.5 Br=.7371 Nc=2 Isc=0 Ikr=0 Rc=1
  109. +        Cjc=3.638p Mjc=.3085 Vjc=.75 Fc=.5 Cje=4.493p Mje=.2593 Vje=.75
  110. +        Tr=239.5n Tf=301.2p Itf=.4 Vtf=4 Xtf=2 Rb=10)
  111. *        National    pid=23        case=TO92
  112. *        88-09-08 bam    creation
  113.  
  114. .model Q2N3906    PNP(Is=1.41f Xti=3 Eg=1.11 Vaf=18.7 Bf=180.7 Ne=1.5 Ise=0
  115. +        Ikf=80m Xtb=1.5 Br=4.977 Nc=2 Isc=0 Ikr=0 Rc=2.5 Cjc=9.728p
  116. +        Mjc=.5776 Vjc=.75 Fc=.5 Cje=8.063p Mje=.3677 Vje=.75 Tr=33.42n
  117. +        Tf=179.3p Itf=.4 Vtf=4 Xtf=6 Rb=10)
  118. *        National    pid=66        case=TO92
  119. *        88-09-09 bam    creation
  120.  
  121. *-------------------------------------------------------------------------------
  122. * Library of diode model parameters
  123. *
  124. * Copyright 1989 by MicroSim Corporation
  125. * This is a reduced version of MicroSim's diode model library.
  126. *   You are welcome to make as many copies of it as you find convenient.
  127. *
  128. * The parameters in this model library were derived from the data sheets for
  129. * each part.  Most parts were characterize using the Parts option.
  130. * Devices can also be characterized without Parts as follows:
  131. *    IS        nominal leakage current
  132. *    RS        for zener diodes: nominal small-signal impedance
  133. *            at specified operating current
  134. *    IB        for zener diodes: set to nominal leakage current
  135. *    IBV        for zener diodes: at specified operating current
  136. *            IBV is adjusted to give the rated zener voltage
  137. *
  138. *
  139. *** Zener Diodes ***
  140. *
  141. * "A" suffix zeners have the same parameters (e.g., 1N750A has the same
  142. * parameters as 1N750)
  143. *
  144. .model D1N750    D(Is=1u Rs=10 Bv=4.24 Ibv=1u)
  145.  
  146. *** Voltage-variable capacitance diodes
  147.  
  148. * The parameters in this model library were derived from the data sheets for
  149. * each part.  Each part was characterize using the Parts option.
  150. *
  151. .model MV2201   D(Is=1.365p Rs=1 Ikf=0 N=1 Xti=3 Eg=1.11 Cjo=14.93p M=.4261
  152. +        Vj=.75 Fc=.5 Isr=16.02p Nr=2 Bv=25 Ibv=10u)
  153. *        Motorola    pid=MV2201    case=182-03
  154. *        88-09-22 bam    creation
  155.  
  156. *** Switching Diodes ***
  157.  
  158. .model D1N4148    D(Is=0.1p Rs=16 CJO=2p Tt=12n Bv=100 Ibv=0.1p)
  159. *        85-??-??    Original library
  160.  
  161. .model MBD101   D(Is=192.1p Rs=.1 Ikf=0 N=1 Xti=3 Eg=1.11 Cjo=893.8f M=98.29m
  162. +        Vj=.75 Fc=.5 Isr=16.91n Nr=2 Bv=5 Ibv=10u)
  163. *        Motorola    pid=MBD101    case=182-03
  164. *        88-09-22 bam    creation
  165.  
  166. *-------------------------------------------------------------------------------
  167. * Library of junction field-effect transistor (JFET) model parameters
  168.  
  169. * This is a reduced version of MicroSim's JFET model library.
  170. *   You are welcome to make as many copies of it as you find convenient.
  171.  
  172. * The parameters in this model library were derived from the data sheets for
  173. * each part.  Each part was characterize using the Parts option.
  174.  
  175. .model J2N3819    NJF(Beta=1.304m Betatce=-.5 Rd=1 Rs=1 Lambda=2.25m Vto=-3
  176. +        Vtotc=-2.5m Is=33.57f Isr=322.4f N=1 Nr=2 Xti=3 Alpha=311.7
  177. +        Vk=243.6 Cgd=1.6p M=.3622 Pb=1 Fc=.5 Cgs=2.414p Kf=9.882E-18
  178. +        Af=1)
  179. *        National    pid=50        case=TO92
  180. *        88-08-01 rmn    BVmin=25
  181.  
  182. .model J2N4393    NJF(Beta=9.109m Betatce=-.5 Rd=1 Rs=1 Lambda=6m Vto=-1.422
  183. +        Vtotc=-2.5m Is=205.2f Isr=1.988p N=1 Nr=2 Xti=3 Alpha=20.98u
  184. +        Vk=123.7 Cgd=4.57p M=.4069 Pb=1 Fc=.5 Cgs=4.06p Kf=123E-18
  185. +        Af=1)
  186. *        National    pid=51        case=TO18
  187. *        88-07-13 bam    BVmin=40
  188.  
  189. *-------------------------------------------------------------------------------
  190. * Library of linear IC definitions
  191.  
  192. * This is a reduced version of MicroSim's linear subcircuit library.
  193. *   You are welcome to make as many copies of it as you find convenient.
  194. *
  195. * The parameters in the opamp library were derived from the data sheets for
  196. * each part.  The macromodel used is similar to the one described in:
  197. *
  198. *    Macromodeling of Integrated Circuit Operational Amplifiers
  199. *      by Graeme Boyle, Barry Cohn, Donald Pederson, and James Solomon
  200. *    IEEE Journal of SoliE-State Circuits, Vol. SC-9, no. 6,    Dec. 1974
  201. *
  202. * Differences from the reference (above) occur in the output limiting stage
  203. * which was modified to reduce internally generated currents associated with
  204. * output voltage limiting, as well as short-circuit current limiting.
  205. *
  206. * The opamps are modelled at room temperature and do not track changes with
  207. * temperature.  This library file contains models for nominal, not worst case,
  208. * devices.
  209. *
  210. *-----------------------------------------------------------------------------
  211. * connections:   non-inverting input
  212. *                | inverting input
  213. *                | | positive power supply
  214. *                | | | negative power supply
  215. *                | | | | output
  216. *                | | | | |
  217. .subckt LM324    1 2 3 4 5
  218. *
  219.   c1   11 12 2.887E-12
  220.   c2    6  7 30.00E-12
  221.   dc    5 53 dx
  222.   de   54  5 dx
  223.   dlp  90 91 dx
  224.   dln  92 90 dx
  225.   dp    4  3 dx
  226.   egnd 99  0 poly(2) (3,0) (4,0) 0 .5 .5
  227.   fb    7 99 poly(5) vb vc ve vlp vln 0 21.22E6 -20E6 20E6 20E6 -20E6
  228.   ga    6  0 11 12 188.5E-6
  229.   gcm   0  6 10 99 59.61E-9
  230.   iee   3 10 dc 15.09E-6
  231.   hlim 90  0 vlim 1K
  232.   q1   11  2 13 qx
  233.   q2   12  1 14 qx
  234.   r2    6  9 100.0E3
  235.   rc1   4 11 5.305E3
  236.   rc2   4 12 5.305E3
  237.   re1  13 10 1.845E3
  238.   re2  14 10 1.845E3
  239.   ree  10 99 13.25E6
  240.   ro1   8  5 50
  241.   ro2   7 99 25
  242.   rp    3  4 9.082E3
  243.   vb    9  0 dc 0
  244.   vc    3 53 dc 1.500
  245.   ve   54  4 dc 0
  246.   vlim  7  8 dc 0
  247.   vlp  91  0 dc 40
  248.   vln   0 92 dc 40
  249. .model dx D(Is=800.0E-18 Rs=1)
  250. .model qx PNP(Is=800.0E-18 Bf=166.7)
  251. .ends
  252. *-----------------------------------------------------------------------------
  253. * connections:   non-inverting input
  254. *                | inverting input
  255. *                | | positive power supply
  256. *                | | | negative power supply
  257. *                | | | | output
  258. *                | | | | |
  259. .subckt uA741    1 2 3 4 5
  260. *
  261.   c1   11 12 8.661E-12
  262.   c2    6  7 30.00E-12
  263.   dc    5 53 dx
  264.   de   54  5 dx
  265.   dlp  90 91 dx
  266.   dln  92 90 dx
  267.   dp    4  3 dx
  268.   egnd 99  0 poly(2) (3,0) (4,0) 0 .5 .5
  269.   fb    7 99 poly(5) vb vc ve vlp vln 0 10.61E6 -10E6 10E6 10E6 -10E6
  270.   ga    6  0 11 12 188.5E-6
  271.   gcm   0  6 10 99 5.961E-9
  272.   iee  10  4 dc 15.16E-6
  273.   hlim 90  0 vlim 1K
  274.   q1   11  2 13 qx
  275.   q2   12  1 14 qx
  276.   r2    6  9 100.0E3
  277.   rc1   3 11 5.305E3
  278.   rc2   3 12 5.305E3
  279.   re1  13 10 1.836E3
  280.   re2  14 10 1.836E3
  281.   ree  10 99 13.19E6
  282.   ro1   8  5 50
  283.   ro2   7 99 100
  284.   rp    3  4 18.16E3
  285.   vb    9  0 dc 0
  286.   vc    3 53 dc 1
  287.   ve   54  4 dc 1
  288.   vlim  7  8 dc 0
  289.   vlp  91  0 dc 40
  290.   vln   0 92 dc 40
  291. .model dx D(Is=800.0E-18 Rs=1)
  292. .model qx NPN(Is=800.0E-18 Bf=93.75)
  293. .ends
  294. *-----------------------------------------------------------------------------
  295.  
  296. *** Voltage comparators
  297.  
  298. * The parameters in this comparator library were derived from data sheets for
  299. * each parts.  The macromodel used was developed by MicroSim Corporation, and
  300. * is produced by the "Parts" option to PSpice.
  301. *
  302. * Although we do not use it, another comparator macro model is described in:
  303. *
  304. *    An Integrated-Circuit Comparator Macromodel
  305. *      by Ian Getreu, Andreas Hadiwidjaja, and Johan Brinch
  306. *    IEEE Journal of Solid-State Circuits, Vol. SC-11, no. 6, Dec. 1976
  307. *
  308. * This reference covers the considerations that go into duplicating the
  309. * behavior of voltage comparators.
  310. *
  311. * The comparators are modelled at room temperature.  The macro model does not
  312. * track changes with temperature.  This library file contains models for
  313. * nominal, not worst case, devices.
  314. *
  315. *-----------------------------------------------------------------------------
  316. * connections:   non-inverting input
  317. *                | inverting input
  318. *                | | positive power supply
  319. *                | | | negative power supply
  320. *                | | | | open collector output
  321. *                | | | | | output ground
  322. *                | | | | | |
  323. .subckt LM111    1 2 3 4 5 6
  324. *
  325.   f1    9  3 v1 1
  326.   iee   3  7 dc 100.0E-6
  327.   vi1  21  1 dc .45
  328.   vi2  22  2 dc .45
  329.   q1    9 21  7 qin
  330.   q2    8 22  7 qin
  331.   q3    9  8  4 qmo
  332.   q4    8  8  4 qmi
  333. .model qin PNP(Is=800.0E-18 Bf=833.3)
  334. .model qmi NPN(Is=800.0E-18 Bf=1002)
  335. .model qmo NPN(Is=800.0E-18 Bf=1000 Cjc=1E-15 Tr=118.8E-9)
  336.   e1   10  6  9  4  1
  337.   v1   10 11 dc 0
  338.   q5    5 11  6 qoc
  339. .model qoc NPN(Is=800.0E-18 Bf=34.49E3 Cjc=1E-15 Tf=364.6E-12 Tr=79.34E-9)
  340.   dp    4  3 dx
  341.   rp    3  4 6.122E3
  342. .model dx  D(Is=800.0E-18 Rs=1)
  343. *
  344. .ends
  345.  
  346. *-------------------------------------------------------------------------------
  347. * Library of magnetic core model parameters
  348.  
  349. * This is a reduced version of MicroSim's magnetic core library.
  350. *   You are welcome to make as many copies of it as you find convenient.
  351.  
  352. * The parameters in this model library were derived from the data sheets for
  353. * each core.  The Jiles-Atherton magnetics model is described in:
  354. *
  355. *   Theory of Ferromagnetic Hysteresis, by D C Jiles and D L Atherton,
  356. *   Journal of Magnetism and Magnetic Materials, vol 61 (1986) pp 48-60
  357. *
  358. * Model parameters for ferrite material (Ferroxcube 3C8) were obtained by
  359. * trial simulations, using the B-H curves from the manufacturer's catalog.
  360. * Then, the library was compiled from the data sheets for each core geometry.
  361. * Notice that only the geometric values change once a material is
  362. * characterized.
  363.  
  364. * Example use:  K2 L2 .99 K1409PL_3C8
  365.  
  366. * Notes:
  367. *   1) Using a K device (formerly only for mutual coupling) with a model
  368. *   reference changes the meaning of the L device: the inductance value
  369. *   becomes the number of turns for the winding.
  370. *   2) K devices can "get away" with specifying only one inductor, as in the
  371. *   example above, to simulate power inductors.
  372.  
  373. * Example circuit file:
  374.  
  375. *+-----------------------------------------------------------------------------
  376. *|Demonstration of power inductor B-H curve
  377. *|
  378. *|* To view results with Probe (B-H curve):
  379. *|* 1) Add Trace for B(K1)
  380. *|* 2) set X-axis variable to H(K1)
  381. *|*
  382. *|* Probe x-axis unit is Oersted
  383. *|* Probe y-axis unit is Gauss
  384. *|*
  385. *|.tran .1 4
  386. *|igen0 0 1 sin(0 .1amp 1Hz 0)    ; Generator: starts with 0.1 amp sinewave, then
  387. *|igen1 0 1 sin(0 .1amp 1Hz 1)    ;   +0.1 amps, starting at 1 second
  388. *|igen2 0 1 sin(0 .2amp 1Hz 2)    ;   +0.2 amps, starting at 2 seconds
  389. *|igen3 0 1 sin(0 .8amp 1Hz 3)    ;   +0.4 amps, starting at 3 seconds
  390. *|RL 1 0 1ohm            ; generator source resistance
  391. *|L1 1 0 20            ; inductor with 20 turns
  392. *|K1 L1 .9999 K528T500_3C8    ; Ferroxcube torroid core
  393. *|.model K528T500_3C8    Core(MS=420E3 ALPHA=2E-5 A=26 K=18 C=1.05
  394. *|+            AREA=1.17 PATH=8.49)
  395. *|.options itl5=0
  396. *|.probe
  397. *|.end
  398. *+-----------------------------------------------------------------------------
  399.  
  400. *** Ferroxcube pot cores: 3C8 material
  401.  
  402. .model K3019PL_3C8    Core(Ms=420E3 Alpha=2E-5 A=26 K=18 C=1.05
  403. +            Area=1.38 Path=4.52)
  404.  
  405. *** Ferroxcube square cores: 3C8 material
  406.  
  407. .model KRM8PL_3C8    Core(Ms=420E3 Alpha=2E-5 A=26 K=18 C=1.05
  408. +            Area=.630 Path=3.84)
  409.  
  410. *** Ferroxcube toroid cores: 3C8 material
  411.  
  412. .model K502T300_3C8    Core(Ms=420E3 Alpha=2E-5 A=26 K=18 C=1.05
  413. +            Area=.371 Path=7.32)
  414.  
  415. *-------------------------------------------------------------------------------
  416. * Library of MOSFET model parameters (for "power" MOSFET devices)
  417. *
  418. * This is a reduced version of MicroSim's power MOSFET model library.
  419. *   You are welcome to make as many copies of it as you find convenient.
  420. *
  421. * The parameters in this model library were derived from the data sheets for
  422. * each part.  Each part was characterize using the Parts option.
  423. * Device can also be characterized without Parts as follows:
  424. *    LEVEL        Set to 3 (short-channel device).
  425. *    TOX        Determined from gate ratings.
  426. *    L, LD, W, WD    Assume L=2u.  Calculate from input capacitance.
  427. *    XJ, NSUB    Assume usual technology.
  428. *    IS, RD, RB    Determined from "source-drain diode forward voltage"
  429. *            specification or curve (Idr vs. Vsd).
  430. *    RS        Determine from Rds(on) specification.
  431. *    RDS        Calculated from Idss specification or curves.
  432. *    VTO, UO, THETA    Determined from "output characteristics" curve family
  433. *            (Ids vs. Vds, stepped Vgs).
  434. *    ETA, VMAX, CBS    Set for null effect.
  435. *    CBD, PB, MJ    Determined from "capacitance vs. Vds" curves.
  436. *    RG        Calculate from rise/fall time specification or curves.
  437. *    CGSO, CGDO    Determined from gate-charge, turn-on/off delay and
  438. *            rise time specifications.
  439. *
  440. * NOTE:    when specifying the instance of a device in your circuit file:
  441. *
  442. *    BE SURE to have the source and bulk nodes connected together, as this
  443. *    is the way the real device is constructed.
  444. *
  445. *    DO NOT include values for L, W, AD, AS, PD, PS, NRD, or NDS.
  446. *    The PSpice default values for these parameters are taken into account
  447. *    in the library model statements.  Of course, you should NOT reset
  448. *    the default values using the .OPTIONS statement, either.
  449. *
  450. * Example use:    M17    15 23 7 7    IRF150
  451. *
  452. * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  453. *
  454. * The "power" MOSFET device models benefit from relatively complete specifi-
  455. * cation of static and dynamic characteristics by their manufacturers.  The
  456. * following effects are modeled:
  457. *    - DC transfer curves in forward operation,
  458. *    - gate drive characteristics and switching delay,
  459. *    - "on" resistance,
  460. *    - reverse-mode "body-diode" operation.
  461. *
  462. * The factors not modeled include:
  463. *    - maximum ratings (eg. high-voltage breakdown),
  464. *    - safe operating area (eg. power dissipation),
  465. *    - latch-up,
  466. *    - noise.
  467. *
  468. * For high-current switching applications, we advise that you include
  469. * series inductance elements, for the source and drain, in your circuit file.
  470. * In doing so, voltage spikes due to di/dt will be modeled.  According to the
  471. * 1985 International Rectifier databook, the following case styles have lead
  472. * inductance values of:
  473. *    TO-204 (modified TO-3)    source = 12.5nH        drain = 5.0nH
  474. *    TO-220            source =  7.5nH        drain = 3.5-4.5nH
  475. * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  476. *
  477. .model IRF150    NMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0
  478. +        Tox=100n Uo=600 Phi=.6 Rs=1.624m Kp=20.53u W=.3 L=2u Vto=2.831
  479. +            Rd=1.031m Rds=444.4K Cbd=3.229n Pb=.8 Mj=.5 Fc=.5 Cgso=9.027n
  480. +        Cgdo=1.679n Rg=13.89 Is=194E-18 N=1 Tt=288n)
  481. *        Int'l Rectifier    pid=IRFC150    case=TO3
  482. *        88-08-25 bam    creation
  483.  
  484. .model IRF9140    PMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0
  485. +        Tox=100n Uo=300 Phi=.6 Rs=70.6m Kp=10.15u W=1.9 L=2u Vto=-3.67
  486. +        Rd=60.66m Rds=444.4K Cbd=2.141n Pb=.8 Mj=.5 Fc=.5 Cgso=877.2p
  487. +        Cgdo=369.3p Rg=.811 Is=52.23E-18 N=2 Tt=140n)
  488. *        Int'l Rectifier  pid=IRFC9140    case=TO3
  489. *        88-08-25 bam    creation
  490.  
  491. *-------------------------------------------------------------------------------
  492. * Library of digital logic
  493.  
  494. * Copyright 1989 by MicroSim Corporation
  495. * This is a reduced version of MicroSim's Digital components library.
  496. *   You are welcome to make as many copies of it as you find convenient.
  497. *
  498. * The parameters in this model library were derived from:
  499. *
  500. *   The TTL Data Book, Texas Instruments, 1985
  501. *     vol. 2
  502. *   ALS/AS Logic Data Book, Texas Instruments, 1986
  503. *     
  504. *   High-speed CMOS Logic Data Book, Texas Instruments, 1988
  505. *     
  506. *   F Logic Data Book, Texas Instruments, 1987
  507. *
  508. *   FAST Data Book, Fairchild, 1982
  509. *
  510. * Each device is modeled by a subcircuit.  The interface pins of the 
  511. * subcircuit have the same name as the pin labels in the data book.  The
  512. * general order is inputs followed by outputs, but on the more complex
  513. * devices you will have to look at the subcircuit definition.
  514. * The word "BAR" is appended to inverted inputs or outputs.
  515. *
  516. * The timing charactistics from the data book are included in the models, 
  517. * with all data sheet effects modeled, unless noted in this file.
  518. *
  519. * If a device contains multiple, independant, identical functions, only 
  520. * one is contained in the subcircuit. (e.g. the 7400 contains four two-
  521. * input NAND gates, but there is only one in the 7400 subckt.)
  522. *
  523. * The subcircuit name is the part name.  Only the 74 series (not the 54
  524. * series) is included in the library, except for a few parts which
  525. * are only made in the 54 series. (e.g. 54L00)
  526. *--------------------------------------------------------------------
  527. *
  528. * TYPES-02: QUADRUPLE 2-INPUT POSITIVE-NOR GATES.
  529. *
  530. .SUBCKT 7402 A B Y
  531. U1 NOR(2) A B Y D_02STD IO_STD
  532. .ENDS
  533. .MODEL D_02STD UGATE
  534. +    (tplhty=12ns    tplhmx=22ns    tphlty=8ns    tphlmx=15ns)
  535. .MODEL IO_STD UIO ( 
  536. +       drvh=96.4, drvl=104, AtoD=AtoD_STD,    DtoA=DtoA_STD)
  537. .MODEL IO_DFT UIO ( 
  538. +       drvh=50, drvl=50, AtoD=AtoD_STD,    DtoA=DtoA_STD )
  539. .SUBCKT AtoDDEFAULT A D
  540. O1 A $G_DGND DO74 DGTLNET = D  IO_DFT
  541. .ENDS
  542.  
  543. .SUBCKT DtoADEFAULT D A
  544. N1 A $G_DGND $G_DPWR DIN74 DGTLNET = D  IO_DFT
  545. .ENDS
  546.  
  547. .model DO74 doutput(
  548. +    s0name = 0, s0vlo = -1.5, s0vhi = 0.8,
  549. +       s1name = X, s1vlo =  0.8, s1vhi = 2.0,
  550. +    s2name = 1, s2vlo =  2.0, s2vhi = 7.0)
  551. .model DIN74 dinput(
  552. +    s0name = 0, s0tsw = 3.5ns, s0rlo = 7.13 s0rhi = 389,  ; 7ohm,    0.09v
  553. +    s1name = 1, s1tsw = 5.5ns, s1rlo = 467  s1rhi = 200,  ; 140ohm,  3.5v
  554. +    s2name = X, s2tsw = 3.5ns, s2rlo = 42.9 s2rhi = 116,  ; 31.3ohm, 1.35v
  555. +    s3name = Z, s3tsw = 3.5ns, s3rlo = 200K s3rhi = 200K)
  556. * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  557. * The digital power supply subckt:
  558. *  one instance of this subcircuit is created if any AtoD or DtoA
  559. *  subckts are created.  The one interface pin is always given the 
  560. *  value "0".
  561. *
  562. *  To change the power supply voltage, change the value of VDPWR.
  563. *  To change the digital ground, change the value of VDGND.
  564. *  All interfaces use the global nodes $G_DPWR and $G_DGND as power and 
  565. *  ground.
  566. *
  567. *  The default is that digital ground is 0v, and digital power is 5.0v.
  568.  
  569. .SUBCKT DIGIFPWR GND
  570. VDPWR   $G_DPWR $G_DGND 5v
  571. R1      $G_DPWR GND   1MEG
  572. VDGND   $G_DGND GND   0v
  573. R2      $G_DGND GND   1MEG
  574. .ENDS
  575. * 7400 standard inputs
  576. *
  577. * simple model
  578. *
  579. * connections:       analog input   digital
  580. *                    |              |
  581. .subckt AtoD_STD     a              d
  582. *
  583. O0    a    $G_DGND    DO74  DGTLNET = d  IO_STD
  584. .ends
  585. *
  586. * 7400 standard DtoA model:
  587. *
  588. .SUBCKT DtoA_STD D A
  589. N1 A $G_DGND $G_DPWR DIN74 DGTLNET = D  IO_STD
  590. .ENDS
  591. .MODEL D0_GATE UGATE ()
  592. *
  593. *    Stimulus I/O model
  594.  
  595. .MODEL IO_STM UIO ( 
  596. +       drvh=0, drvl=0, DtoA=DtoA_STM )
  597. *
  598. * Stimulus DtoA model:
  599. *
  600. .SUBCKT DtoA_STM D A
  601. N1 A $G_DGND $G_DPWR DINSTM DGTLNET = D  IO_STM
  602. .ENDS
  603. *----------
  604. *
  605. * TYPES-04: HEX INVERTERS.
  606. *
  607. .SUBCKT 7404 A Y
  608. U1 INV A Y D_04STD IO_STD
  609. .ENDS
  610. .MODEL D_04STD UGATE
  611. +    (tplhty=12ns    tplhmx=22ns    tphlty=8ns    tphlmx=15ns)
  612. *----------
  613. *
  614. * DUAL D-TYPE POSITIVE-EDGE-TRIGGERED FLIP-FLOPS WITH PRESET AND CLEAR
  615. *
  616. .SUBCKT 7474 1CLRBAR 1D 1CLK 1PREBAR 1Q 1QBAR
  617. UFF010 DFF(1) 1PREBAR 1CLRBAR 1CLK 1D 1Q 1QBAR D_74STD_1 IO_STD
  618. .ENDS
  619. .MODEL D_74STD_1 UEFF (TWPCLMN=30NS    TWCLKLMN=37NS    TWCLKHMN=30NS
  620. +    TSUDCLKMN=20NS
  621. +    THDCLKMN=5NS
  622. +    TPPCQLHMX=25NS
  623. +    TPPCQHLMX=40NS
  624. +    TPCLKQLHTY=14NS    TPCLKQLHMX=25NS
  625. +    TPCLKQHLTY=20NS    TPCLKQHLMX=40NS)
  626. *------------------------------------------------------------------
  627. *
  628. * TYPES-393: DUAL 4-BIT BINARY COUNTER WITH INDIVIDUAL CLOCKS.
  629. *
  630.  
  631. .SUBCKT 74393 A CLR QA QB QC QD
  632. U1 JKFF (1) $D_HI CLRB A $D_HI $D_HI QA $D_HI D_393STD_1 IO_STD
  633. U2 JKFF (1) $D_HI CLRB QA $D_HI $D_HI QB $D_HI D_393STD_2 IO_STD
  634. U3 JKFF (1) $D_HI CLRB QB $D_HI $D_HI QC $D_HI D_393STD_2 IO_STD
  635. U4 JKFF (1) $D_HI CLRB QC $D_HI $D_HI QD $D_HI D_393STD_3 IO_STD
  636. U5 INV CLR CLRB D0_GATE IO_STD
  637. .ENDS
  638.  
  639. .MODEL D_393STD_1 UEFF
  640. +    (tppcqhlty=24n tppcqhlmx=39n
  641. +     tpclkqlhty=12n tpclkqlhmx=20n
  642. +     tpclkqhlty=13n tpclkqhlmx=20n
  643. +     twclkhmx=20n twclkhty=20n
  644. +     twclklmx=20n twclklty=20n
  645. +     twpclmx=20n twpclty=20n
  646. +     tsudclkmx=25n tsudclkty=25n)
  647. .MODEL D_393STD_2 UEFF
  648. .MODEL D_393STD_3 UEFF
  649. +    (tpclkqlhty=27n tpclkqlhmx=40n
  650. +     tpclkqhlty=27n tpclkqhlmx=40n)
  651.  
  652. *-------------------------------------------------------------------------------
  653. * Library of optocoupler models
  654.  
  655. * Copyright 1989 by MicroSim Corporation
  656. * This is a reduced version of MicroSim's Opto-coupler components library.
  657. *   You are welcome to make as many copies of it as you find convenient.
  658.  
  659. * The parameters in this model library were derived from the data sheets for
  660. * each part.
  661.  
  662. *.model 4N25
  663. * 6-pin DIP: pin #1   #2   #4   #5   #6
  664. *                |    |    |    |    |
  665. .subckt A4N25      pin1 pin2 pin4 pin5 pin6    params: rel_CTR=1
  666. *        Motorola    pid=4N25
  667. *        88-01-04 pwt
  668. *        88-01-18 pwt    rework Cje approximation
  669.  
  670. * The data sheet used for this model is from Motorola: it was the most
  671. * complete for DC and switching parameters, and is was easy to find the
  672. * component IR-LED and phototransistor as separate devices for further
  673. * specifications.
  674.  
  675.   d_MainLED    pin1 pin2    MainLED
  676.   d_PhotoLED    pin1 1        PhotoLED .001
  677.   v_PhotoLED    1 pin2        0
  678.  
  679.   f_TempComp    0 2        v_PhotoLED 1
  680.   r_TempComp    2 0        TempComp {rel_CTR}
  681.  
  682.   g_BaseSrc    5 6 2 0        .9
  683.   q_PhotoBJT    5 6 4        PhotoBJT
  684.   r_C        5 pin5        .1
  685.   r_B        6 pin6        .1
  686.   r_E        4 pin4        .1
  687.  
  688. * Since active devices dominate pin-to-pin capacitance on each "side" of the
  689. * optocoupler, isolation is modeled by identical capacitances and resistances
  690. * linked to a common point; this gives isolation of .5pF and 1E+11 ohms
  691.   c_1        pin1 7        .4p
  692.   r_1        pin1 7        .12T
  693.   c_2        pin2 7        .4p
  694.   r_2        pin2 7        .12T
  695.   c_4        pin4 7        .4p
  696.   r_4        pin4 7        .12T
  697.   c_5        pin5 7        .4p
  698.   r_5        pin5 7        .12T
  699.   c_6        pin6 7        .4p
  700.   r_6        pin6 7        .12T
  701.  
  702. * Similar to Motorola MLED15.
  703. .model MainLED  D(Is=1.1p Rs=.66 Ikf=30m N=1.9 Xti=3 Cjo=40p M=.34 Vj=.75
  704. +        Isr=30n Nr=3.8 Bv=6 Ibv=100u Tt=.5u)
  705.  
  706. * Models photon generation: same as MainLED except no AC effects, no breakdown.
  707. .model PhotoLED D(Is=1.1p Rs=.66 Ikf=30m N=1.9 Xti=3 Cjo=0   M=.34 Vj=.75
  708. +        Isr=30n Nr=3.8 Bv=0 Tt=0)
  709.  
  710. * Temperature compensation for system: 1.38x @ -55'C, .54x @ +100'C, all @ 10mA
  711. * Note: the photo BJT has its own temperature corrections, which must be kept
  712. * as the transistor is electrically available.
  713. .model TempComp    RES(R=1 Tc1=-11.27m Tc2=43.46u)
  714.  
  715. * Similar to Motorola MDR3050; Hfe=325 @ Ic=500uA, Vce=5V
  716. * Use beta variation (w/Parts) to model change in current-transfer ratio (CTR).
  717. * Hand adjust reverse beta (Br) to match saturation characteristics.
  718. * Set Isc to model dark current.
  719. * Hand adjust Cjc to match fall time @ Ic=10mA (which yields rise time, too).
  720. * Hand adjust reverse transit-time (Tr) to match storage time @ Ic=10mA.
  721. * Delay time set by LED I-V and C-V characteristics; set Cje to 25% of Cjc,
  722. * inspection of phototransistor chip layouts show the emitter area is 20%-25%
  723. * that of the collector area.  The same layouts show that base resistance is
  724. * made negligible by design; also, the operating currents are small.
  725. * Hand adjust forward transit-time (Tf) to match MDR3050 pulse data.  Check
  726. * against 4N25 frequency response (Fig 11, 12).
  727. .model PhotoBJT NPN(Is=10f Xti=3 Vaf=60
  728. +        Bf=400 Ne=3.75 Ise=580p Ikf=.26 Xtb=1.5
  729. +        Br=.04 Nc=2    Isc=3.5n
  730. +        Cjc=10p  Mjc=.3333 Vjc=.75 Tr=88u
  731. +        Cje=2.5p Mje=.3333 Vje=.75 Tf=1.5n)
  732. .ends
  733.  
  734. *.model 4N25A
  735. * 6-pin DIP: pin #1   #2   #4   #5   #6
  736. *                |    |    |    |    |
  737. .subckt A4N25A    pin1 pin2 pin4 pin5 pin6
  738. *        88-01-05 pwt
  739. * Same as 4N25 (UL recognized).
  740.   x1 pin1 pin2 pin4 pin5 pin6 A4N25
  741. .ends
  742. *
  743. * End of library file
  744.