home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 13 Bitmap / 13-Bitmap.zip / povscn.zip / scenes / level2 / soft.pov < prev    next >
Text File  |  1993-09-28  |  3KB  |  136 lines
  1. // POV-Ray 2.0 sample scene file
  2. // Demo of extended light sources by Steve Anger
  3.  
  4. #include "colors.inc"
  5. #include "textures.inc"
  6. #include "shapes.inc"
  7.  
  8.  
  9. // A rather boring texture but it renders quick
  10. #declare Text_Texture = texture {
  11.    pigment { Red }
  12.    finish {
  13.       phong 2.0
  14.       phong_size 80
  15.       ambient 0.1
  16.       diffuse 1.5
  17.    }
  18. }
  19.  
  20. #declare Letter_S = union {
  21.     difference {
  22.        torus { 4.0, 1.5 rotate 90*x }
  23.        box { <0, -5.5, -1.5>, <5.5, 0, 1.5> }
  24.  
  25.        bounded_by { box { <-5.5, -5.5, -1.5>, <5.5, 5.5, 1.5> } }
  26.        translate 4*y
  27.     }
  28.  
  29.     difference {
  30.        torus { 4.0, 1.5 rotate 90*x }
  31.        box { <-5.5, 0, -1.5>, <0, 5.5, 1.5> }
  32.  
  33.        bounded_by { box { <-5.5, -5.5, -1.5>, <5.5, 5.5, 1.5> } }
  34.        translate -4*y
  35.     }
  36.  
  37.     sphere { <4, 4, 0>, 1.5 }
  38.     sphere { <-4, -4, 0>, 1.5 }
  39.  
  40.     bounded_by { box { <-5.5, -9.5, -1.5> <5.5, 9.5, 1.5> } }
  41. }
  42.  
  43. #declare Letter_O = union {
  44.     torus { 4.0, 1.5
  45.         rotate 90*x
  46.  
  47.         clipped_by { box { <-5.5, 0, -1.5> <5.5, 5.5, 1.5> } }
  48.         bounded_by { clipped_by }
  49.         translate 4*y
  50.     }
  51.  
  52.     torus { 4.0, 1.5
  53.         rotate 90*x
  54.  
  55.         clipped_by { box { <-5.5, -5.5, -1.5> <5.5, 0, 1.5> } }
  56.         bounded_by { clipped_by }
  57.         translate -4*y
  58.     }
  59.  
  60.     cylinder { <-4, -4, 0>, <-4, +4, 0>, 1.5 }
  61.     cylinder { <+4, -4, 0>, <+4, +4, 0>, 1.5 }
  62.  
  63.     bounded_by { box { <-5.5, -9.5, -1.5>, <5.5, 9.5, 1.5> } }
  64. }
  65.  
  66. #declare Letter_F = union {
  67.     cylinder { <-4, -8, 0>, <-4, 8, 0>, 1.5 }
  68.     cylinder { <-4, 0, 0>, <1.5, 0, 0>, 1.5 }
  69.     cylinder { <-4, 8, 0>, <4, 8, 0>, 1.5 }
  70.  
  71.     sphere { <-4, -8, 0>, 1.5 }
  72.     sphere { <-4, 8, 0>, 1.5 }
  73.     sphere { <4, 8, 0>, 1.5 }
  74.     sphere { <1.5, 0, 0>, 1.5 }
  75.  
  76.     bounded_by { box { <-5.5, -9.5, -1.5>, <5.5, 9.5, 1.5> } }
  77. }
  78.  
  79. #declare Letter_T = union {
  80.     cylinder { <0, -8, 0>, <0, 8, 0>, 1.5 }
  81.     cylinder { <-4, 8, 0>, <4, 8, 0>, 1.5 }
  82.  
  83.     sphere { <-4, 8, 0>, 1.5 }
  84.     sphere { <+4, 8, 0>, 1.5 }
  85.     sphere { <0, -8, 0>, 1.5 }
  86.  
  87.     bounded_by { box { <-5.5, -9.5, -1.5> <5.5, 9.5, 1.5> } }
  88. }
  89.  
  90.  
  91. // Put the letters together
  92. union {
  93.     object { Letter_S  translate -20*x }
  94.     object { Letter_O  translate  -7*x }
  95.     object { Letter_F  translate   7*x }
  96.     object { Letter_T  translate  20*x }
  97.  
  98.     texture { Text_Texture }
  99.  
  100.     translate 9.5*y
  101. }
  102.  
  103. // Floor
  104. plane { y, 0
  105.     pigment { Tan }
  106.     finish {
  107.         ambient 0.0
  108.         diffuse 0.8
  109.     }
  110. }
  111.  
  112. // Something to light the front of the text
  113. light_source { <0, 30, -90> color Gray30 }
  114.  
  115. // An extended area spotlight to backlight the letters
  116. light_source {
  117.    <0, 50, 100> color White
  118.  
  119.    // The spotlight parameters
  120.    spotlight
  121.    point_at <0, 0, -5>
  122.    radius 6
  123.    falloff 22
  124.  
  125.    // The extended area light paramaters
  126.    area_light <6, 0, 0>, <0, 6, 0>, 9, 9
  127.    adaptive 0
  128.    jitter
  129. }
  130.  
  131. camera {
  132.     direction <0, 0, 1.5>
  133.     location <0, 30, -90>
  134.     look_at <0, 0, -2>
  135. }
  136.