home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 13 Bitmap / 13-Bitmap.zip / povscn.zip / scenes / level1 / intee1.pov < prev    next >
Text File  |  1993-09-28  |  2KB  |  73 lines
  1. // Persistence of Vision Raytracer
  2. // Intersection of two cylinders,  with holes cut from each one, in pink
  3. // marblized stone.  Image by Dan Farmer.
  4. // Demonstrates CSG intersection,  layered stone texture.
  5. // Time: about 3 hours @640x480+a0.2 on 486/33
  6.  
  7. #include "colors.inc"           // Standard colors library
  8. #include "shapes.inc"           // Commonly used object shapes
  9. #include "textures.inc"         // LOTS of neat textures.  Lots of NEW textures.
  10.  
  11. camera {
  12.    location <0.0, 10, -26>
  13.    direction <0.0, 0.0,  1.0>
  14.    up  <0.0, 1.0, 0.0>
  15.    right <4/3, 0.0, 0.0>
  16.    look_at <0, 0, 0>
  17. }
  18.  
  19. // Light source
  20. light_source { <-10, 20, -25> color White }
  21. light_source { <0, 0, 0> color White }
  22.  
  23. #declare Color1A = color DustyRose
  24. #declare Color1B = color DarkSlateGray
  25.  
  26. intersection {
  27.    object { Cylinder_X }
  28.    object { Cylinder_Y }
  29.    object { Cylinder_X inverse scale <1, 0.5, 0.5> }  // small hole
  30.    object { Cylinder_Y inverse scale <0.5, 1, 0.5> }  // ditto
  31.  
  32.    // A great looking pinkish marble.  Except that it doesn't use marble
  33.    // or agate... it's all done with bozo and granite!
  34.  
  35.    // Underlying surface is very subtly mottled with bozo in pinks and
  36.    // grays.
  37.  
  38.    texture {
  39.       finish {ambient 0.25 }
  40.       pigment {
  41.          bozo
  42.          turbulence 0.25
  43.          color_map {
  44.             [0.0 1.0 color red 0.9 green 0.75 blue 0.75
  45.                      color red 0.6 green 0.6 blue 0.6 ]
  46.          }
  47.          scale 0.4
  48.       }
  49.    }
  50.  
  51.    // Second layer texture has some filter values, yet a fair amount of color
  52.    // Viening is kept quite thin.
  53.    texture {
  54.       finish {
  55.          Glossy
  56.          phong 0.25
  57.          phong_size 75
  58.          brilliance 4
  59.       }
  60.       pigment {
  61.          granite
  62.          color_map {
  63.             [0.0 0.9  color Color1A filter 1 color Color1A filter 0.5 ]
  64.             [0.9 1.0  color Color1B color Color1B ]
  65.          }
  66.          scale 2
  67.       }
  68.    }
  69.  
  70.    scale 10
  71.    rotate y*45
  72. }
  73.