OS/2 Shareware BBS: 10 Tools/10-Tools.zip/wsgatsam.zip/install/installDS.bat

DOS Batch File | 2003-02-24 | 3KB | 79 lines

@title Creating Datasource - IBM WebServices Gateway

@rem parameters are 1=Gateway install directory (typically C:\WebSphere\Gateway)
@rem                2=WebShere node name
@rem                3=WebSphere AppServer directory (typically C:\WebSphere\AppServer)
@rem                4=DB2 userid
@rem                5=DB2 password

@if .%1==. goto invalidparams
@if .%2==. goto invalidparams
@if .%3==. goto invalidparams
@if .%4==. goto invalidparams
@if .%5==. goto invalidparams

@rem Check parameter 1 is a valid directory.
@if EXIST %1 goto goodparam1
@echo The directory %1 specified for Gateway install directory does not exist.
@goto invalidparams

@rem Check parameter 3 is a valid directory.
:goodparam1
@if EXIST %3 goto goodparams
@echo The directory %3 specified for WebSphere install directory does not exist.
@goto invalidparams

@rem Parameters are good.
:goodparams
set NODENAME=%2
set WASDIR=%3
set DBUSER=%4
set DBPWD=%5

@echo About to install WebServices Gateway datasource
@echo Using this call to XMLConfig:
@echo call %WASDIR%\bin\XMLConfig -adminNodeName %NODENAME% -import %1\install\wsgw_datasource.xml
@echo      -substitute "NODE_NAME=%NODENAME%;WAS_DIR=%WASDIR%;DB_DEFAULT_USER=%DBUSER%;
@echo                  DB_DEFAULT_PWD=*****;JNDI_NAME=jdbc/WSGWDB"

@call %WASDIR%\bin\XMLConfig -adminNodeName %NODENAME% -import %1\install\wsgw_datasource.xml -substitute "NODE_NAME=%NODENAME%;WAS_DIR=%WASDIR%;DB_DEFAULT_USER=%DBUSER%;DB_DEFAULT_PWD=%DBPWD%;JNDI_NAME=jdbc/WSGWDB"
@if errorlevel 0 goto InstallWorked

@echo.
@echo *** Warning: an error might have occurred during the installation of the WebService Gateway.
@echo Please check the WSGWInstallDS.log file in the \logs subdirectory
@echo of the WebSphere Application Server directory.
@echo.
@echo Please also check WSGWInstallJDBC.log in the \logs subdirectory, as an
@echo earlier failure in the JDBC step of the install could have caused this failure.
@echo.
@echo A problem in the JDBC step could be caused by the fact that you have DB2 installed in
@echo a non-default location (that is, a location other than C:\Program Files\SQLLIB).
@echo In this case you will need to set up the WebServices Gateway JDBC driver and datasource by hand
@echo using the WebSphere Administrative console.   The instructions for
@echo Installing on WebSphere single-server edition for developers (AEd),
@echo in steps 1) and 2) provide details for the set up of the JDBC driver and datasource.
@echo Having done that, you should then follow the instructions on Installing the WebServices Gateway
@echo into WebSphere, to deploy the WebServices Gateway application into WebSphere.
@echo.
@goto InstallFailed

:InstallWorked
@echo About to recycle WebSphere Admin Server
@echo Stopping WebSphere Admin Server
net stop "IBM WS AdminServer 4.0"
@echo Starting WebSphere Admin Server
net start "IBM WS AdminServer 4.0"

:InstallFailed
@goto :eof

:invalidparams
@echo This command file should not be run standalone
@echo Parameters are 1=Gateway install directory (typically C:\WebSphere\Gateway)
@echo                2=WebShere node name
@echo                3=WebSphere AppServer directory (typically C:\WebSphere\AppServer)
@echo                4=DB2 userid
@echo                5=DB2 password