home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / perl_ste.zip / Net / FTP.pm < prev    next >
Text File  |  1997-12-02  |  32KB  |  1,393 lines
  1. # Net::FTP.pm
  2. #
  3. # Copyright (c) 1995 Graham Barr <gbarr@pobox.com>. All rights reserved.
  4. # This program is free software; you can redistribute it and/or
  5. # modify it under the same terms as Perl itself.
  6. #
  7. # Documentation (at end) improved 1996 by Nathan Torkington <gnat@frii.com>.
  8.  
  9. package Net::FTP;
  10.  
  11. require 5.001;
  12.  
  13. use strict;
  14. use vars qw(@ISA $VERSION);
  15. use Carp;
  16.  
  17. use Socket 1.3;
  18. use IO::Socket;
  19. use Time::Local;
  20. use Net::Cmd;
  21. use Net::Config;
  22. use AutoLoader qw(AUTOLOAD);
  23.  
  24. $VERSION = "2.28"; # $Id: //depot/libnet/Net/FTP.pm#12$
  25. @ISA     = qw(Exporter Net::Cmd IO::Socket::INET);
  26.  
  27. # Someday I will "use constant", when I am not bothered to much about
  28. # compatability with older releases of perl
  29.  
  30. use vars qw($TELNET_IAC $TELNET_IP $TELNET_DM);
  31. ($TELNET_IAC,$TELNET_IP,$TELNET_DM) = (255,244,242);
  32.  
  33. 1;
  34.  
  35. __END__
  36.  
  37. sub new
  38. {
  39.  my $pkg  = shift;
  40.  my $peer = shift;
  41.  my %arg  = @_; 
  42.  
  43.  my $host = $peer;
  44.  my $fire = undef;
  45.  
  46.  # Should I use Net::Ping here ?? --GMB
  47.  if(exists($arg{Firewall}) || !defined(inet_aton($peer)))
  48.   {
  49.    $fire = $arg{Firewall}
  50.     || $ENV{FTP_FIREWALL}
  51.     || $NetConfig{ftp_firewall}
  52.     || undef;
  53.  
  54.    if(defined $fire)
  55.     {
  56.      $peer = $fire;
  57.      delete $arg{Port};
  58.     }
  59.   }
  60.  
  61.  my $ftp = $pkg->SUPER::new(PeerAddr => $peer, 
  62.                 PeerPort => $arg{Port} || 'ftp(21)',
  63.                 Proto    => 'tcp',
  64.                 Timeout  => defined $arg{Timeout}
  65.                         ? $arg{Timeout}
  66.                         : 120
  67.                ) or return undef;
  68.  
  69.  ${*$ftp}{'net_ftp_host'}     = $host;        # Remote hostname
  70.  ${*$ftp}{'net_ftp_type'}     = 'A';        # ASCII/binary/etc mode
  71.  
  72.  ${*$ftp}{'net_ftp_firewall'} = $fire
  73.     if(defined $fire);
  74.  
  75.  ${*$ftp}{'net_ftp_passive'} = int
  76.     exists $arg{Passive}
  77.         ? $arg{Passive}
  78.         : exists $ENV{FTP_PASSIVE}
  79.         ? $ENV{FTP_PASSIVE}
  80.         : defined $fire
  81.             ? $NetConfig{ftp_ext_passive}
  82.             : $NetConfig{ftp_int_passive};    # Whew! :-)
  83.  
  84.  $ftp->autoflush(1);
  85.  
  86.  $ftp->debug(exists $arg{Debug} ? $arg{Debug} : undef);
  87.  
  88.  unless ($ftp->response() == CMD_OK)
  89.   {
  90.    $ftp->close();
  91.    undef $ftp;
  92.   }
  93.  
  94.  $ftp;
  95. }
  96.  
  97. ##
  98. ## User interface methods
  99. ##
  100.  
  101. sub quit
  102. {
  103.  my $ftp = shift;
  104.  
  105.  $ftp->_QUIT;
  106.  $ftp->close;
  107. }
  108.  
  109. sub DESTROY
  110. {
  111.  my $ftp = shift;
  112.  defined(fileno($ftp)) && $ftp->quit
  113. }
  114.  
  115. sub ascii  { shift->type('A',@_); }
  116. sub binary { shift->type('I',@_); }
  117.  
  118. sub ebcdic
  119. {
  120.  carp "TYPE E is unsupported, shall default to I";
  121.  shift->type('E',@_);
  122. }
  123.  
  124. sub byte
  125. {
  126.  carp "TYPE L is unsupported, shall default to I";
  127.  shift->type('L',@_);
  128. }
  129.  
  130. # Allow the user to send a command directly, BE CAREFUL !!
  131.  
  132. sub quot
  133. { 
  134.  my $ftp = shift;
  135.  my $cmd = shift;
  136.  
  137.  $ftp->command( uc $cmd, @_);
  138.  $ftp->response();
  139. }
  140.  
  141. sub mdtm
  142. {
  143.  my $ftp  = shift;
  144.  my $file = shift;
  145.  
  146.  $ftp->_MDTM($file) && $ftp->message =~ /(\d{4})(\d\d)(\d\d)(\d\d)(\d\d)(\d\d)/
  147.     ? timegm($6,$5,$4,$3,$2-1,$1 - 1900)
  148.     : undef;
  149. }
  150.  
  151. sub size
  152. {
  153.  my $ftp  = shift;
  154.  my $file = shift;
  155.  
  156.  $ftp->_SIZE($file)
  157.     ? ($ftp->message =~ /(\d+)/)[0]
  158.     : undef;
  159. }
  160.  
  161. sub login
  162. {
  163.  my($ftp,$user,$pass,$acct) = @_;
  164.  my($ok,$ruser);
  165.  
  166.  unless (defined $user)
  167.   {
  168.    require Net::Netrc;
  169.  
  170.    my $rc = Net::Netrc->lookup(${*$ftp}{'net_ftp_host'});
  171.  
  172.    ($user,$pass,$acct) = $rc->lpa()
  173.     if ($rc);
  174.   }
  175.  
  176.  $user ||= "anonymous";
  177.  $ruser = $user;
  178.  
  179.  if(defined ${*$ftp}{'net_ftp_firewall'})
  180.   {
  181.    $user .= "@" . ${*$ftp}{'net_ftp_host'};
  182.   }
  183.  
  184.  $ok = $ftp->_USER($user);
  185.  
  186.  # Some dumb firewalls don't prefix the connection messages
  187.  $ok = $ftp->response()
  188.     if($ok == CMD_OK && $ftp->code == 220 && $user =~ /\@/);
  189.  
  190.  if ($ok == CMD_MORE)
  191.   {
  192.    unless(defined $pass)
  193.     {
  194.      require Net::Netrc;
  195.  
  196.      my $rc = Net::Netrc->lookup(${*$ftp}{'net_ftp_host'}, $ruser);
  197.  
  198.      ($ruser,$pass,$acct) = $rc->lpa()
  199.     if ($rc);
  200.  
  201.      $pass = eval {"-" . (getpwuid($>))[0] . "@"}
  202.         if (!defined $pass && (!defined($ruser) || $ruser =~ /^anonymous/o));
  203.     }
  204.  
  205.    $ok = $ftp->_PASS($pass || "");
  206.   }
  207.  
  208.  $ok = $ftp->_ACCT($acct || "")
  209.     if ($ok == CMD_MORE);
  210.  
  211.  $ftp->authorize()
  212.     if($ok == CMD_OK && defined ${*$ftp}{'net_ftp_firewall'});
  213.  
  214.  $ok == CMD_OK;
  215. }
  216.  
  217. sub account
  218. {
  219.  @_ == 2 or croak 'usage: $ftp->account( ACCT )';
  220.  my $ftp = shift;
  221.  my $acct = shift;
  222.  $ftp->_ACCT($acct) == CMD_OK;
  223. }
  224.  
  225. sub authorize
  226. {
  227.  @_ >= 1 || @_ <= 3 or croak 'usage: $ftp->authorize( [AUTH [, RESP]])';
  228.  
  229.  my($ftp,$auth,$resp) = @_;
  230.  
  231.  unless(defined $resp)
  232.   {
  233.    require Net::Netrc;
  234.  
  235.    $auth ||= eval { (getpwuid($>))[0] };
  236.  
  237.    my $rc = Net::Netrc->lookup(${*$ftp}{'net_ftp_firewall'}, $auth)
  238.         || Net::Netrc->lookup(${*$ftp}{'net_ftp_firewall'});
  239.  
  240.    ($auth,$resp) = $rc->lpa()
  241.      if($rc);
  242.   }
  243.  
  244.  my $ok = $ftp->_AUTH($auth || "");
  245.  
  246.  $ok = $ftp->_RESP($resp || "")
  247.     if ($ok == CMD_MORE);
  248.  
  249.  $ok == CMD_OK;
  250. }
  251.  
  252. sub rename
  253. {
  254.  @_ == 3 or croak 'usage: $ftp->rename(FROM, TO)';
  255.  
  256.  my($ftp,$from,$to) = @_;
  257.  
  258.  $ftp->_RNFR($from)
  259.     && $ftp->_RNTO($to);
  260. }
  261.  
  262. sub type
  263. {
  264.  my $ftp = shift;
  265.  my $type = shift;
  266.  my $oldval = ${*$ftp}{'net_ftp_type'};
  267.  
  268.  return $oldval
  269.     unless (defined $type);
  270.  
  271.  return undef
  272.     unless ($ftp->_TYPE($type,@_));
  273.  
  274.  ${*$ftp}{'net_ftp_type'} = join(" ",$type,@_);
  275.  
  276.  $oldval;
  277. }
  278.  
  279. sub abort
  280. {
  281.  my $ftp = shift;
  282.  
  283.  send($ftp,pack("CC",$TELNET_IAC,$TELNET_IP),0);
  284.  send($ftp,pack("CC", $TELNET_IAC, $TELNET_DM),MSG_OOB);
  285.  
  286.  $ftp->command("ABOR");
  287.  
  288. # defined ${*$ftp}{'net_ftp_dataconn'}
  289. #    ? ${*$ftp}{'net_ftp_dataconn'}->close()
  290. #    : $ftp->response();
  291.  
  292.  ${*$ftp}{'net_ftp_dataconn'}->close()
  293.     if defined ${*$ftp}{'net_ftp_dataconn'};
  294.  
  295.  $ftp->response();
  296. #    if $ftp->status == CMD_REJECT;
  297.  
  298.  $ftp->status == CMD_OK;
  299. }
  300.  
  301. sub get
  302. {
  303.  my($ftp,$remote,$local,$where) = @_;
  304.  
  305.  my($loc,$len,$buf,$resp,$localfd,$data);
  306.  local *FD;
  307.  
  308.  $localfd = ref($local) ? fileno($local)
  309.             : undef;
  310.  
  311.  ($local = $remote) =~ s#^.*/##
  312.     unless(defined $local);
  313.  
  314.  ${*$ftp}{'net_ftp_rest'} = $where
  315.     if ($where);
  316.  
  317.  delete ${*$ftp}{'net_ftp_port'};
  318.  delete ${*$ftp}{'net_ftp_pasv'};
  319.  
  320.  $data = $ftp->retr($remote) or
  321.     return undef;
  322.  
  323.  if(defined $localfd)
  324.   {
  325.    $loc = $local;
  326.   }
  327.  else
  328.   {
  329.    $loc = \*FD;
  330.  
  331.    unless(($where) ? open($loc,">>$local") : open($loc,">$local"))
  332.     {
  333.      carp "Cannot open Local file $local: $!\n";
  334.      $data->abort;
  335.      return undef;
  336.     }
  337.   }
  338.  
  339.  if($ftp->type eq 'I' && !binmode($loc))
  340.   {
  341.    carp "Cannot binmode Local file $local: $!\n";
  342.    $data->abort;
  343.    return undef;
  344.   }
  345.  
  346.  $buf = '';
  347.  
  348.  do
  349.   {
  350.    $len = $data->read($buf,1024);
  351.   }
  352.  while($len > 0 && syswrite($loc,$buf,$len) == $len);
  353.  
  354.  close($loc)
  355.     unless defined $localfd;
  356.  
  357.  $data->close(); # implied $ftp->response
  358.  
  359.  return $local;
  360. }
  361.  
  362. sub cwd
  363. {
  364.  @_ == 2 || @_ == 3 or croak 'usage: $ftp->cwd( [ DIR ] )';
  365.  
  366.  my($ftp,$dir) = @_;
  367.  
  368.  $dir ||= "/";
  369.  
  370.  $dir eq ".."
  371.     ? $ftp->_CDUP()
  372.     : $ftp->_CWD($dir);
  373. }
  374.  
  375. sub cdup
  376. {
  377.  @_ == 1 or croak 'usage: $ftp->cdup()';
  378.  $_[0]->_CDUP;
  379. }
  380.  
  381. sub pwd
  382. {
  383.  @_ == 1 || croak 'usage: $ftp->pwd()';
  384.  my $ftp = shift;
  385.  
  386.  $ftp->_PWD();
  387.  $ftp->_extract_path;
  388. }
  389.  
  390. sub rmdir
  391. {
  392.  @_ == 2 || croak 'usage: $ftp->rmdir( DIR )';
  393.  
  394.  $_[0]->_RMD($_[1]);
  395. }
  396.  
  397. sub mkdir
  398. {
  399.  @_ == 2 || @_ == 3 or croak 'usage: $ftp->mkdir( DIR [, RECURSE ] )';
  400.  
  401.  my($ftp,$dir,$recurse) = @_;
  402.  
  403.  $ftp->_MKD($dir) || $recurse or
  404.     return undef;
  405.  
  406.  my $path = $dir;
  407.  
  408.  unless($ftp->ok)
  409.   {
  410.    my @path = split(m#(?=/+)#, $dir);
  411.  
  412.    $path = "";
  413.  
  414.    while(@path)
  415.     {
  416.      $path .= shift @path;
  417.  
  418.      $ftp->_MKD($path);
  419.      $path = $ftp->_extract_path($path);
  420.  
  421.      # 521 means directory already exists
  422.      last
  423.         unless $ftp->ok || $ftp->code == 521 || $ftp->code == 550;
  424.     }
  425.   }
  426.  
  427.  $ftp->_extract_path($path);
  428. }
  429.  
  430. sub delete
  431. {
  432.  @_ == 2 || croak 'usage: $ftp->delete( FILENAME )';
  433.  
  434.  $_[0]->_DELE($_[1]);
  435. }
  436.  
  437. sub put        { shift->_store_cmd("stor",@_) }
  438. sub put_unique { shift->_store_cmd("stou",@_) }
  439. sub append     { shift->_store_cmd("appe",@_) }
  440.  
  441. sub nlst { shift->_data_cmd("NLST",@_) }
  442. sub list { shift->_data_cmd("LIST",@_) }
  443. sub retr { shift->_data_cmd("RETR",@_) }
  444. sub stor { shift->_data_cmd("STOR",@_) }
  445. sub stou { shift->_data_cmd("STOU",@_) }
  446. sub appe { shift->_data_cmd("APPE",@_) }
  447.  
  448. sub _store_cmd 
  449. {
  450.  my($ftp,$cmd,$local,$remote) = @_;
  451.  my($loc,$sock,$len,$buf,$localfd);
  452.  local *FD;
  453.  
  454.  $localfd = ref($local) ? fileno($local)
  455.             : undef;
  456.  
  457.  unless(defined $remote)
  458.   {
  459.    croak 'Must specify remote filename with stream input'
  460.     if defined $localfd;
  461.  
  462.    ($remote = $local) =~ s%.*/%%;
  463.   }
  464.  
  465.  if(defined $localfd)
  466.   {
  467.    $loc = $local;
  468.   }
  469.  else
  470.   {
  471.    $loc = \*FD;
  472.  
  473.    unless(open($loc,"<$local"))
  474.     {
  475.      carp "Cannot open Local file $local: $!\n";
  476.      return undef;
  477.     }
  478.   }
  479.  
  480.  if($ftp->type eq 'I' && !binmode($loc))
  481.   {
  482.    carp "Cannot binmode Local file $local: $!\n";
  483.    return undef;
  484.   }
  485.  
  486.  delete ${*$ftp}{'net_ftp_port'};
  487.  delete ${*$ftp}{'net_ftp_pasv'};
  488.  
  489.  $sock = $ftp->_data_cmd($cmd, $remote) or 
  490.     return undef;
  491.  
  492.  while(1)
  493.   {
  494.    last unless $len = sysread($loc,$buf="",1024);
  495.  
  496.    unless($sock->write($buf,$len) == $len)
  497.     {
  498.      $sock->abort;
  499.      close($loc)
  500.     unless defined $localfd;
  501.      return undef;
  502.     }
  503.   }
  504.  
  505.  $sock->close();
  506.  
  507.  close($loc)
  508.     unless defined $localfd;
  509.  
  510.  ($remote) = $ftp->message =~ /unique file name:\s*(\S*)\s*\)/
  511.     if ('STOU' eq uc $cmd);
  512.  
  513.  return $remote;
  514. }
  515.  
  516. sub port
  517. {
  518.  @_ == 1 || @_ == 2 or croak 'usage: $ftp->port([PORT])';
  519.  
  520.  my($ftp,$port) = @_;
  521.  my $ok;
  522.  
  523.  delete ${*$ftp}{'net_ftp_intern_port'};
  524.  
  525.  unless(defined $port)
  526.   {
  527.    # create a Listen socket at same address as the command socket
  528.  
  529.    ${*$ftp}{'net_ftp_listen'} ||= IO::Socket::INET->new(Listen    => 5,
  530.                                         Proto     => 'tcp',
  531.                                         LocalAddr => $ftp->sockhost, 
  532.                                        );
  533.   
  534.    my $listen = ${*$ftp}{'net_ftp_listen'};
  535.  
  536.    my($myport, @myaddr) = ($listen->sockport, split(/\./,$listen->sockhost));
  537.  
  538.    $port = join(',', @myaddr, $myport >> 8, $myport & 0xff);
  539.  
  540.    ${*$ftp}{'net_ftp_intern_port'} = 1;
  541.   }
  542.  
  543.  $ok = $ftp->_PORT($port);
  544.  
  545.  ${*$ftp}{'net_ftp_port'} = $port;
  546.  
  547.  $ok;
  548. }
  549.  
  550. sub ls  { shift->_list_cmd("NLST",@_); }
  551. sub dir { shift->_list_cmd("LIST",@_); }
  552.  
  553. sub pasv
  554. {
  555.  @_ == 1 or croak 'usage: $ftp->pasv()';
  556.  
  557.  my $ftp = shift;
  558.  
  559.  delete ${*$ftp}{'net_ftp_intern_port'};
  560.  
  561.  $ftp->_PASV && $ftp->message =~ /(\d+(,\d+)+)/
  562.     ? ${*$ftp}{'net_ftp_pasv'} = $1
  563.     : undef;    
  564. }
  565.  
  566. sub unique_name
  567. {
  568.  my $ftp = shift;
  569.  ${*$ftp}{'net_ftp_unique'} || undef;
  570. }
  571.  
  572. sub supported {
  573.     @_ == 2 or croak 'usage: $ftp->supported( CMD )';
  574.     my $ftp = shift;
  575.     my $cmd = uc shift;
  576.     my $hash = ${*$ftp}{'net_ftp_supported'} ||= {};
  577.  
  578.     return $hash->{$cmd}
  579.         if exists $hash->{$cmd};
  580.  
  581.     my $ok = $ftp->_HELP($cmd) &&
  582.         $ftp->message !~ /unimplemented/i;
  583.  
  584.     $hash->{$cmd} = $ok;
  585. }
  586.  
  587. ##
  588. ## Depreciated methods
  589. ##
  590.  
  591. sub lsl
  592. {
  593.  carp "Use of Net::FTP::lsl depreciated, use 'dir'"
  594.     if $^W;
  595.  goto &dir;
  596. }
  597.  
  598. sub authorise
  599. {
  600.  carp "Use of Net::FTP::authorise depreciated, use 'authorize'"
  601.     if $^W;
  602.  goto &authorize;
  603. }
  604.  
  605.  
  606. ##
  607. ## Private methods
  608. ##
  609.  
  610. sub _extract_path
  611. {
  612.  my($ftp, $path) = @_;
  613.  
  614.  # This tries to work both with and without the quote doubling
  615.  # convention (RFC 959 requires it, but the first 3 servers I checked
  616.  # didn't implement it).  It will fail on a server which uses a quote in
  617.  # the message which isn't a part of or surrounding the path.
  618.  $ftp->ok &&
  619.     $ftp->message =~ /(?:^|\s)\"(.*)\"(?:$|\s)/ &&
  620.     ($path = $1) =~ s/\"\"/\"/g;
  621.  
  622.  $path;
  623. }
  624.  
  625. ##
  626. ## Communication methods
  627. ##
  628.  
  629. sub _dataconn
  630. {
  631.  my $ftp = shift;
  632.  my $data = undef;
  633.  my $pkg = "Net::FTP::" . $ftp->type;
  634.  
  635.  eval "require " . $pkg;
  636.  
  637.  $pkg =~ s/ /_/g;
  638.  
  639.  delete ${*$ftp}{'net_ftp_dataconn'};
  640.  
  641.  if(defined ${*$ftp}{'net_ftp_pasv'})
  642.   {
  643.    my @port = split(/,/,${*$ftp}{'net_ftp_pasv'});
  644.  
  645.    $data = $pkg->new(PeerAddr => join(".",@port[0..3]),
  646.                      PeerPort => $port[4] * 256 + $port[5],
  647.                      Proto    => 'tcp'
  648.                     );
  649.   }
  650.  elsif(defined ${*$ftp}{'net_ftp_listen'})
  651.   {
  652.    $data = ${*$ftp}{'net_ftp_listen'}->accept($pkg);
  653.    close(delete ${*$ftp}{'net_ftp_listen'});
  654.   }
  655.  
  656.  if($data)
  657.   {
  658.    ${*$data} = "";
  659.    $data->timeout($ftp->timeout);
  660.    ${*$ftp}{'net_ftp_dataconn'} = $data;
  661.    ${*$data}{'net_ftp_cmd'} = $ftp;
  662.   }
  663.  
  664.  $data;
  665. }
  666.  
  667. sub _list_cmd
  668. {
  669.  my $ftp = shift;
  670.  my $cmd = uc shift;
  671.  
  672.  delete ${*$ftp}{'net_ftp_port'};
  673.  delete ${*$ftp}{'net_ftp_pasv'};
  674.  
  675.  my $data = $ftp->_data_cmd($cmd,@_);
  676.  
  677.  return undef
  678.     unless(defined $data);
  679.  
  680.  require Net::FTP::A;
  681.  bless $data, "Net::FTP::A"; # Force ASCII mode
  682.  
  683.  my $databuf = '';
  684.  my $buf = '';
  685.  
  686.  while($data->read($databuf,1024))
  687.   {
  688.    $buf .= $databuf;
  689.   }
  690.  
  691.  my $list = [ split(/\n/,$buf) ];
  692.  
  693.  $data->close();
  694.  
  695.  wantarray ? @{$list}
  696.            : $list;
  697. }
  698.  
  699. sub _data_cmd
  700. {
  701.  my $ftp = shift;
  702.  my $cmd = uc shift;
  703.  my $ok = 1;
  704.  my $where = delete ${*$ftp}{'net_ftp_rest'} || 0;
  705.  
  706.  if(${*$ftp}{'net_ftp_passive'} &&
  707.      !defined ${*$ftp}{'net_ftp_pasv'} &&
  708.      !defined ${*$ftp}{'net_ftp_port'})
  709.   {
  710.    my $data = undef;
  711.  
  712.    $ok = defined $ftp->pasv;
  713.    $ok = $ftp->_REST($where)
  714.     if $ok && $where;
  715.  
  716.    if($ok)
  717.     {
  718.      $ftp->command($cmd,@_);
  719.      $data = $ftp->_dataconn();
  720.      $ok = CMD_INFO == $ftp->response();
  721.      if($ok) 
  722.       {
  723.        $data->reading
  724.          if $data && $cmd =~ /RETR|LIST|NLST/;
  725.        return $data
  726.       }
  727.      $data->_close
  728.     if $data;
  729.     }
  730.    return undef;
  731.   }
  732.  
  733.  $ok = $ftp->port
  734.     unless (defined ${*$ftp}{'net_ftp_port'} ||
  735.             defined ${*$ftp}{'net_ftp_pasv'});
  736.  
  737.  $ok = $ftp->_REST($where)
  738.     if $ok && $where;
  739.  
  740.  return undef
  741.     unless $ok;
  742.  
  743.  $ftp->command($cmd,@_);
  744.  
  745.  return 1
  746.     if(defined ${*$ftp}{'net_ftp_pasv'});
  747.  
  748.  $ok = CMD_INFO == $ftp->response();
  749.  
  750.  return $ok 
  751.     unless exists ${*$ftp}{'net_ftp_intern_port'};
  752.  
  753.  return $ftp->_dataconn()
  754.     if $ok;
  755.  
  756.  close(delete ${*$ftp}{'net_ftp_listen'});
  757.  
  758.  return undef;
  759. }
  760.  
  761. ##
  762. ## Over-ride methods (Net::Cmd)
  763. ##
  764.  
  765. sub debug_text { $_[2] =~ /^(pass|resp)/i ? "$1 ....\n" : $_[2]; }
  766.  
  767. sub command
  768. {
  769.  my $ftp = shift;
  770.  
  771.  delete ${*$ftp}{'net_ftp_port'};
  772.  $ftp->SUPER::command(@_);
  773. }
  774.  
  775. sub response
  776. {
  777.  my $ftp = shift;
  778.  my $code = $ftp->SUPER::response();
  779.  
  780.  delete ${*$ftp}{'net_ftp_pasv'}
  781.     if ($code != CMD_MORE && $code != CMD_INFO);
  782.  
  783.  $code;
  784. }
  785.  
  786. sub parse_response
  787. {
  788.  return ($1, $2 eq "-")
  789.     if $_[1] =~ s/^(\d\d\d)(.?)//o;
  790.  
  791.  my $ftp = shift;
  792.  
  793.  # Darn MS FTP server is a load of CRAP !!!!
  794.  return ()
  795.     unless ${*$ftp}{'net_cmd_code'} + 0;
  796.  
  797.  (${*$ftp}{'net_cmd_code'},1);
  798. }
  799.  
  800. ##
  801. ## Allow 2 servers to talk directly
  802. ##
  803.  
  804. sub pasv_xfer
  805. {
  806.  my($sftp,$sfile,$dftp,$dfile) = @_;
  807.  
  808.  ($dfile = $sfile) =~ s#.*/##
  809.     unless(defined $dfile);
  810.  
  811.  my $port = $sftp->pasv or
  812.     return undef;
  813.  
  814.  unless($dftp->port($port) && $sftp->retr($sfile) && $dftp->stor($dfile))
  815.   {
  816.    $sftp->abort;
  817.    $dftp->abort;
  818.    return undef;
  819.   }
  820.  
  821.  $dftp->pasv_wait($sftp);
  822. }
  823.  
  824. sub pasv_xfer_unique
  825. {
  826.  my($sftp,$sfile,$dftp,$dfile) = @_;
  827.  
  828.  ($dfile = $sfile) =~ s#.*/##
  829.     unless(defined $dfile);
  830.  
  831.  my $port = $sftp->pasv or
  832.     return undef;
  833.  
  834.  unless($dftp->port($port) && $sftp->retr($sfile) && $dftp->stou($dfile))
  835.   {
  836.    $sftp->abort;
  837.    $dftp->abort;
  838.    return undef;
  839.   }
  840.  
  841.  $dftp->pasv_wait($sftp);
  842. }
  843.  
  844. sub pasv_wait
  845. {
  846.  @_ == 2 or croak 'usage: $ftp->pasv_wait(NON_PASV_FTP)';
  847.  
  848.  my($ftp, $non_pasv) = @_;
  849.  my($file,$rin,$rout);
  850.  
  851.  vec($rin,fileno($ftp),1) = 1;
  852.  select($rout=$rin, undef, undef, undef);
  853.  
  854.  $ftp->response();
  855.  $non_pasv->response();
  856.  
  857.  return undef
  858.     unless $ftp->ok() && $non_pasv->ok();
  859.  
  860.  return $1
  861.     if $ftp->message =~ /unique file name:\s*(\S*)\s*\)/;
  862.  
  863.  return $1
  864.     if $non_pasv->message =~ /unique file name:\s*(\S*)\s*\)/;
  865.  
  866.  return 1;
  867. }
  868.  
  869. sub cmd { shift->command(@_)->response() }
  870.  
  871. ########################################
  872. #
  873. # RFC959 commands
  874. #
  875.  
  876. sub _ABOR { shift->command("ABOR")->response()     == CMD_OK }
  877. sub _CDUP { shift->command("CDUP")->response()     == CMD_OK }
  878. sub _NOOP { shift->command("NOOP")->response()     == CMD_OK }
  879. sub _PASV { shift->command("PASV")->response()     == CMD_OK }
  880. sub _QUIT { shift->command("QUIT")->response()     == CMD_OK }
  881. sub _DELE { shift->command("DELE",@_)->response() == CMD_OK }
  882. sub _CWD  { shift->command("CWD", @_)->response() == CMD_OK }
  883. sub _PORT { shift->command("PORT",@_)->response() == CMD_OK }
  884. sub _RMD  { shift->command("RMD", @_)->response() == CMD_OK }
  885. sub _MKD  { shift->command("MKD", @_)->response() == CMD_OK }
  886. sub _PWD  { shift->command("PWD", @_)->response() == CMD_OK }
  887. sub _TYPE { shift->command("TYPE",@_)->response() == CMD_OK }
  888. sub _RNTO { shift->command("RNTO",@_)->response() == CMD_OK }
  889. sub _ACCT { shift->command("ACCT",@_)->response() == CMD_OK }
  890. sub _RESP { shift->command("RESP",@_)->response() == CMD_OK }
  891. sub _MDTM { shift->command("MDTM",@_)->response() == CMD_OK }
  892. sub _SIZE { shift->command("SIZE",@_)->response() == CMD_OK }
  893. sub _HELP { shift->command("HELP",@_)->response() == CMD_OK }
  894. sub _APPE { shift->command("APPE",@_)->response() == CMD_INFO }
  895. sub _LIST { shift->command("LIST",@_)->response() == CMD_INFO }
  896. sub _NLST { shift->command("NLST",@_)->response() == CMD_INFO }
  897. sub _RETR { shift->command("RETR",@_)->response() == CMD_INFO }
  898. sub _STOR { shift->command("STOR",@_)->response() == CMD_INFO }
  899. sub _STOU { shift->command("STOU",@_)->response() == CMD_INFO }
  900. sub _RNFR { shift->command("RNFR",@_)->response() == CMD_MORE }
  901. sub _REST { shift->command("REST",@_)->response() == CMD_MORE }
  902. sub _USER { shift->command("user",@_)->response() } # A certain brain dead firewall :-)
  903. sub _PASS { shift->command("PASS",@_)->response() }
  904. sub _AUTH { shift->command("AUTH",@_)->response() }
  905.  
  906. sub _ALLO { shift->unsupported(@_) }
  907. sub _SMNT { shift->unsupported(@_) }
  908. sub _MODE { shift->unsupported(@_) }
  909. sub _SITE { shift->unsupported(@_) }
  910. sub _SYST { shift->unsupported(@_) }
  911. sub _STAT { shift->unsupported(@_) }
  912. sub _STRU { shift->unsupported(@_) }
  913. sub _REIN { shift->unsupported(@_) }
  914.  
  915. 1;
  916.  
  917. __END__
  918.  
  919. =head1 NAME
  920.  
  921. Net::FTP - FTP Client class
  922.  
  923. =head1 SYNOPSIS
  924.  
  925.     use Net::FTP;
  926.     
  927.     $ftp = Net::FTP->new("some.host.name");
  928.     $ftp->login("anonymous","me@here.there");
  929.     $ftp->cwd("/pub");
  930.     $ftp->get("that.file");
  931.     $ftp->quit;
  932.  
  933. =head1 DESCRIPTION
  934.  
  935. C<Net::FTP> is a class implementing a simple FTP client in Perl as
  936. described in RFC959.  It provides wrappers for a subset of the RFC959
  937. commands.
  938.  
  939. =head1 OVERVIEW
  940.  
  941. FTP stands for File Transfer Protocol.  It is a way of transferring
  942. files between networked machines.  The protocol defines a client
  943. (whose commands are provided by this module) and a server (not
  944. implemented in this module).  Communication is always initiated by the
  945. client, and the server responds with a message and a status code (and
  946. sometimes with data).
  947.  
  948. The FTP protocol allows files to be sent to or fetched from the
  949. server.  Each transfer involves a B<local file> (on the client) and a
  950. B<remote file> (on the server).  In this module, the same file name
  951. will be used for both local and remote if only one is specified.  This
  952. means that transferring remote file C</path/to/file> will try to put
  953. that file in C</path/to/file> locally, unless you specify a local file
  954. name.
  955.  
  956. The protocol also defines several standard B<translations> which the
  957. file can undergo during transfer.  These are ASCII, EBCDIC, binary,
  958. and byte.  ASCII is the default type, and indicates that the sender of
  959. files will translate the ends of lines to a standard representation
  960. which the receiver will then translate back into their local
  961. representation.  EBCDIC indicates the file being transferred is in
  962. EBCDIC format.  Binary (also known as image) format sends the data as
  963. a contiguous bit stream.  Byte format transfers the data as bytes, the
  964. values of which remain the same regardless of differences in byte size
  965. between the two machines (in theory - in practice you should only use
  966. this if you really know what you're doing).
  967.  
  968. =head1 CONSTRUCTOR
  969.  
  970. =over 4
  971.  
  972. =item new (HOST [,OPTIONS])
  973.  
  974. This is the constructor for a new Net::FTP object. C<HOST> is the
  975. name of the remote host to which a FTP connection is required.
  976.  
  977. C<OPTIONS> are passed in a hash like fashion, using key and value pairs.
  978. Possible options are:
  979.  
  980. B<Firewall> - The name of a machine which acts as a FTP firewall. This can be
  981. overridden by an environment variable C<FTP_FIREWALL>. If specified, and the
  982. given host cannot be directly connected to, then the
  983. connection is made to the firewall machine and the string C<@hostname> is
  984. appended to the login identifier. This kind of setup is also refered to
  985. as a ftp proxy.
  986.  
  987. B<Port> - The port number to connect to on the remote machine for the
  988. FTP connection
  989.  
  990. B<Timeout> - Set a timeout value (defaults to 120)
  991.  
  992. B<Debug> - debug level (see the debug method in L<Net::Cmd>)
  993.  
  994. B<Passive> - If set to I<true> then all data transfers will be done using 
  995. passive mode. This is required for some I<dumb> servers, and some
  996. firewall configurations.  This can also be set by the environment
  997. variable C<FTP_PASSIVE>.
  998.  
  999. =back
  1000.  
  1001. =head1 METHODS
  1002.  
  1003. Unless otherwise stated all methods return either a I<true> or I<false>
  1004. value, with I<true> meaning that the operation was a success. When a method
  1005. states that it returns a value, failure will be returned as I<undef> or an
  1006. empty list.
  1007.  
  1008. =over 4
  1009.  
  1010. =item login ([LOGIN [,PASSWORD [, ACCOUNT] ] ])
  1011.  
  1012. Log into the remote FTP server with the given login information. If
  1013. no arguments are given then the C<Net::FTP> uses the C<Net::Netrc>
  1014. package to lookup the login information for the connected host.
  1015. If no information is found then a login of I<anonymous> is used.
  1016. If no password is given and the login is I<anonymous> then the users
  1017. Email address will be used for a password.
  1018.  
  1019. If the connection is via a firewall then the C<authorize> method will
  1020. be called with no arguments.
  1021.  
  1022. =item authorize ( [AUTH [, RESP]])
  1023.  
  1024. This is a protocol used by some firewall ftp proxies. It is used
  1025. to authorise the user to send data out.  If both arguments are not specified
  1026. then C<authorize> uses C<Net::Netrc> to do a lookup.
  1027.  
  1028. =item type (TYPE [, ARGS])
  1029.  
  1030. This method will send the TYPE command to the remote FTP server
  1031. to change the type of data transfer. The return value is the previous
  1032. value.
  1033.  
  1034. =item ascii ([ARGS]) binary([ARGS]) ebcdic([ARGS]) byte([ARGS])
  1035.  
  1036. Synonyms for C<type> with the first arguments set correctly
  1037.  
  1038. B<NOTE> ebcdic and byte are not fully supported.
  1039.  
  1040. =item rename ( OLDNAME, NEWNAME )
  1041.  
  1042. Rename a file on the remote FTP server from C<OLDNAME> to C<NEWNAME>. This
  1043. is done by sending the RNFR and RNTO commands.
  1044.  
  1045. =item delete ( FILENAME )
  1046.  
  1047. Send a request to the server to delete C<FILENAME>.
  1048.  
  1049. =item cwd ( [ DIR ] )
  1050.  
  1051. Attempt to change directory to the directory given in C<$dir>.  If
  1052. C<$dir> is C<"..">, the FTP C<CDUP> command is used to attempt to
  1053. move up one directory. If no directory is given then an attempt is made
  1054. to change the directory to the root directory.
  1055.  
  1056. =item cdup ()
  1057.  
  1058. Change directory to the parent of the current directory.
  1059.  
  1060. =item pwd ()
  1061.  
  1062. Returns the full pathname of the current directory.
  1063.  
  1064. =item rmdir ( DIR )
  1065.  
  1066. Remove the directory with the name C<DIR>.
  1067.  
  1068. =item mkdir ( DIR [, RECURSE ])
  1069.  
  1070. Create a new directory with the name C<DIR>. If C<RECURSE> is I<true> then
  1071. C<mkdir> will attempt to create all the directories in the given path.
  1072.  
  1073. Returns the full pathname to the new directory.
  1074.  
  1075. =item ls ( [ DIR ] )
  1076.  
  1077. Get a directory listing of C<DIR>, or the current directory.
  1078.  
  1079. In an array context, returns a list of lines returned from the server. In
  1080. a scalar context, returns a reference to a list.
  1081.  
  1082. =item dir ( [ DIR ] )
  1083.  
  1084. Get a directory listing of C<DIR>, or the current directory in long format.
  1085.  
  1086. In an array context, returns a list of lines returned from the server. In
  1087. a scalar context, returns a reference to a list.
  1088.  
  1089. =item get ( REMOTE_FILE [, LOCAL_FILE [, WHERE]] )
  1090.  
  1091. Get C<REMOTE_FILE> from the server and store locally. C<LOCAL_FILE> may be
  1092. a filename or a filehandle. If not specified the the file will be stored in
  1093. the current directory with the same leafname as the remote file.
  1094.  
  1095. If C<WHERE> is given then the first C<WHERE> bytes of the file will
  1096. not be transfered, and the remaining bytes will be appended to
  1097. the local file if it already exists.
  1098.  
  1099. Returns C<LOCAL_FILE>, or the generated local file name if C<LOCAL_FILE>
  1100. is not given.
  1101.  
  1102. =item put ( LOCAL_FILE [, REMOTE_FILE ] )
  1103.  
  1104. Put a file on the remote server. C<LOCAL_FILE> may be a name or a filehandle.
  1105. If C<LOCAL_FILE> is a filehandle then C<REMOTE_FILE> must be specified. If
  1106. C<REMOTE_FILE> is not specified then the file will be stored in the current
  1107. directory with the same leafname as C<LOCAL_FILE>.
  1108.  
  1109. Returns C<REMOTE_FILE>, or the generated remote filename if C<REMOTE_FILE>
  1110. is not given.
  1111.  
  1112. B<NOTE>: If for some reason the transfer does not complete and an error is
  1113. returned then the contents that had been transfered will not be remove
  1114. automatically.
  1115.  
  1116. =item put_unique ( LOCAL_FILE [, REMOTE_FILE ] )
  1117.  
  1118. Same as put but uses the C<STOU> command.
  1119.  
  1120. Returns the name of the file on the server.
  1121.  
  1122. =item append ( LOCAL_FILE [, REMOTE_FILE ] )
  1123.  
  1124. Same as put but appends to the file on the remote server.
  1125.  
  1126. Returns C<REMOTE_FILE>, or the generated remote filename if C<REMOTE_FILE>
  1127. is not given.
  1128.  
  1129. =item unique_name ()
  1130.  
  1131. Returns the name of the last file stored on the server using the
  1132. C<STOU> command.
  1133.  
  1134. =item mdtm ( FILE )
  1135.  
  1136. Returns the I<modification time> of the given file
  1137.  
  1138. =item size ( FILE )
  1139.  
  1140. Returns the size in bytes for the given file as stored on the remote server.
  1141.  
  1142. B<NOTE>: The size reported is the size of the stored file on the remote server.
  1143. If the file is subsequently transfered from the server in ASCII mode
  1144. and the remote server and local machine have different ideas about
  1145. "End Of Line" then the size of file on the local machine after transfer
  1146. may be different.
  1147.  
  1148. =item supported ( CMD )
  1149.  
  1150. Returns TRUE if the remote server supports the given command.
  1151.  
  1152. =back
  1153.  
  1154. The following methods can return different results depending on
  1155. how they are called. If the user explicitly calls either
  1156. of the C<pasv> or C<port> methods then these methods will
  1157. return a I<true> or I<false> value. If the user does not
  1158. call either of these methods then the result will be a
  1159. reference to a C<Net::FTP::dataconn> based object.
  1160.  
  1161. =over 4
  1162.  
  1163. =item nlst ( [ DIR ] )
  1164.  
  1165. Send a C<NLST> command to the server, with an optional parameter.
  1166.  
  1167. =item list ( [ DIR ] )
  1168.  
  1169. Same as C<nlst> but using the C<LIST> command
  1170.  
  1171. =item retr ( FILE )
  1172.  
  1173. Begin the retrieval of a file called C<FILE> from the remote server.
  1174.  
  1175. =item stor ( FILE )
  1176.  
  1177. Tell the server that you wish to store a file. C<FILE> is the
  1178. name of the new file that should be created.
  1179.  
  1180. =item stou ( FILE )
  1181.  
  1182. Same as C<stor> but using the C<STOU> command. The name of the unique
  1183. file which was created on the server will be available via the C<unique_name>
  1184. method after the data connection has been closed.
  1185.  
  1186. =item appe ( FILE )
  1187.  
  1188. Tell the server that we want to append some data to the end of a file
  1189. called C<FILE>. If this file does not exist then create it.
  1190.  
  1191. =back
  1192.  
  1193. If for some reason you want to have complete control over the data connection,
  1194. this includes generating it and calling the C<response> method when required,
  1195. then the user can use these methods to do so.
  1196.  
  1197. However calling these methods only affects the use of the methods above that
  1198. can return a data connection. They have no effect on methods C<get>, C<put>,
  1199. C<put_unique> and those that do not require data connections.
  1200.  
  1201. =over 4
  1202.  
  1203. =item port ( [ PORT ] )
  1204.  
  1205. Send a C<PORT> command to the server. If C<PORT> is specified then it is sent
  1206. to the server. If not the a listen socket is created and the correct information
  1207. sent to the server.
  1208.  
  1209. =item pasv ()
  1210.  
  1211. Tell the server to go into passive mode. Returns the text that represents the
  1212. port on which the server is listening, this text is in a suitable form to
  1213. sent to another ftp server using the C<port> method.
  1214.  
  1215. =back
  1216.  
  1217. The following methods can be used to transfer files between two remote
  1218. servers, providing that these two servers can connect directly to each other.
  1219.  
  1220. =over 4
  1221.  
  1222. =item pasv_xfer ( SRC_FILE, DEST_SERVER [, DEST_FILE ] )
  1223.  
  1224. This method will do a file transfer between two remote ftp servers. If
  1225. C<DEST_FILE> is omitted then the leaf name of C<SRC_FILE> will be used.
  1226.  
  1227. =item pasv_xfer_unique ( SRC_FILE, DEST_SERVER [, DEST_FILE ] )
  1228.  
  1229. Like C<pasv_xfer> but the file is stored on the remote server using
  1230. the STOU command.
  1231.  
  1232. =item pasv_wait ( NON_PASV_SERVER )
  1233.  
  1234. This method can be used to wait for a transfer to complete between a passive
  1235. server and a non-passive server. The method should be called on the passive
  1236. server with the C<Net::FTP> object for the non-passive server passed as an
  1237. argument.
  1238.  
  1239. =item abort ()
  1240.  
  1241. Abort the current data transfer.
  1242.  
  1243. =item quit ()
  1244.  
  1245. Send the QUIT command to the remote FTP server and close the socket connection.
  1246.  
  1247. =back
  1248.  
  1249. =head2 Methods for the adventurous
  1250.  
  1251. C<Net::FTP> inherits from C<Net::Cmd> so methods defined in C<Net::Cmd> may
  1252. be used to send commands to the remote FTP server.
  1253.  
  1254. =over 4
  1255.  
  1256. =item quot (CMD [,ARGS])
  1257.  
  1258. Send a command, that Net::FTP does not directly support, to the remote
  1259. server and wait for a response.
  1260.  
  1261. Returns most significant digit of the response code.
  1262.  
  1263. B<WARNING> This call should only be used on commands that do not require
  1264. data connections. Misuse of this method can hang the connection.
  1265.  
  1266. =back
  1267.  
  1268. =head1 THE dataconn CLASS
  1269.  
  1270. Some of the methods defined in C<Net::FTP> return an object which will
  1271. be derived from this class.The dataconn class itself is derived from
  1272. the C<IO::Socket::INET> class, so any normal IO operations can be performed.
  1273. However the following methods are defined in the dataconn class and IO should
  1274. be performed using these.
  1275.  
  1276. =over 4
  1277.  
  1278. =item read ( BUFFER, SIZE [, TIMEOUT ] )
  1279.  
  1280. Read C<SIZE> bytes of data from the server and place it into C<BUFFER>, also
  1281. performing any <CRLF> translation necessary. C<TIMEOUT> is optional, if not
  1282. given the the timeout value from the command connection will be used.
  1283.  
  1284. Returns the number of bytes read before any <CRLF> translation.
  1285.  
  1286. =item write ( BUFFER, SIZE [, TIMEOUT ] )
  1287.  
  1288. Write C<SIZE> bytes of data from C<BUFFER> to the server, also
  1289. performing any <CRLF> translation necessary. C<TIMEOUT> is optional, if not
  1290. given the the timeout value from the command connection will be used.
  1291.  
  1292. Returns the number of bytes written before any <CRLF> translation.
  1293.  
  1294. =item abort ()
  1295.  
  1296. Abort the current data transfer.
  1297.  
  1298. =item close ()
  1299.  
  1300. Close the data connection and get a response from the FTP server. Returns
  1301. I<true> if the connection was closed successfully and the first digit of
  1302. the response from the server was a '2'.
  1303.  
  1304. =back
  1305.  
  1306. =head1 UNIMPLEMENTED
  1307.  
  1308. The following RFC959 commands have not been implemented:
  1309.  
  1310. =over 4
  1311.  
  1312. =item B<ALLO>
  1313.  
  1314. Allocates storage for the file to be transferred.
  1315.  
  1316. =item B<SMNT>
  1317.  
  1318. Mount a different file system structure without changing login or
  1319. accounting information.
  1320.  
  1321. =item B<HELP>
  1322.  
  1323. Ask the server for "helpful information" (that's what the RFC says) on
  1324. the commands it accepts.
  1325.  
  1326. =item B<MODE>
  1327.  
  1328. Specifies transfer mode (stream, block or compressed) for file to be
  1329. transferred.
  1330.  
  1331. =item B<SITE>
  1332.  
  1333. Request remote server site parameters.
  1334.  
  1335. =item B<SYST>
  1336.  
  1337. Request remote server system identification.
  1338.  
  1339. =item B<STAT>
  1340.  
  1341. Request remote server status.
  1342.  
  1343. =item B<STRU>
  1344.  
  1345. Specifies file structure for file to be transferred.
  1346.  
  1347. =item B<REIN>
  1348.  
  1349. Reinitialize the connection, flushing all I/O and account information.
  1350.  
  1351. =back
  1352.  
  1353. =head1 REPORTING BUGS
  1354.  
  1355. When reporting bugs/problems please include as much information as possible.
  1356. It may be difficult for me to reproduce the problem as almost every setup
  1357. is different.
  1358.  
  1359. A small script which yields the problem will probably be of help. It would
  1360. also be useful if this script was run with the extra options C<Debug => 1>
  1361. passed to the constructor, and the output sent with the bug report. If you
  1362. cannot include a small script then please include a Debug trace from a
  1363. run of your program which does yield the problem.
  1364.  
  1365. =head1 AUTHOR
  1366.  
  1367. Graham Barr <gbarr@pobox.com>
  1368.  
  1369. =head1 SEE ALSO
  1370.  
  1371. L<Net::Netrc>
  1372. L<Net::Cmd>
  1373.  
  1374. ftp(1), ftpd(8), RFC 959
  1375. http://www.cis.ohio-state.edu/htbin/rfc/rfc959.html
  1376.  
  1377. =head1 CREDITS
  1378.  
  1379. Henry Gabryjelski <henryg@WPI.EDU> - for the suggestion of creating directories
  1380. recursively.
  1381.  
  1382. Nathan Torkington <gnat@frii.com> - for some input on the documentation.
  1383.  
  1384. Roderick Schertler <roderick@gate.net> - for various inputs
  1385.  
  1386. =head1 COPYRIGHT
  1387.  
  1388. Copyright (c) 1995-1997 Graham Barr. All rights reserved.
  1389. This program is free software; you can redistribute it and/or modify it
  1390. under the same terms as Perl itself.
  1391.  
  1392. =cut
  1393.