home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / perl_ste.zip / Data / Dumper.pm next >
Text File  |  1996-12-07  |  26KB  |  905 lines
  1. #
  2. # Data/Dumper.pm
  3. #
  4. # convert perl data structures into perl syntax suitable for both printing
  5. # and eval
  6. #
  7. # Documentation at the __END__
  8. #
  9.  
  10. package Data::Dumper;
  11.  
  12. $VERSION = $VERSION = '2.07';
  13.  
  14. #$| = 1;
  15.  
  16. require 5.002;
  17. require Exporter;
  18. require DynaLoader;
  19.  
  20. use Carp;
  21.  
  22. @ISA = qw(Exporter DynaLoader);
  23. @EXPORT = qw(Dumper);
  24. @EXPORT_OK = qw(DumperX);
  25.  
  26. bootstrap Data::Dumper;
  27.  
  28. # module vars and their defaults
  29. $Indent = 2 unless defined $Indent;
  30. $Purity = 0 unless defined $Purity;
  31. $Pad = "" unless defined $Pad;
  32. $Varname = "VAR" unless defined $Varname;
  33. $Useqq = 0 unless defined $Useqq;
  34. $Terse = 0 unless defined $Terse;
  35. $Freezer = "" unless defined $Freezer;
  36. $Toaster = "" unless defined $Toaster;
  37. $Deepcopy = 0 unless defined $Deepcopy;
  38. #$Expdepth = 0 unless defined $Expdepth;
  39. #$Maxdepth = 0 unless defined $Maxdepth;
  40.  
  41. #
  42. # expects an arrayref of values to be dumped.
  43. # can optionally pass an arrayref of names for the values.
  44. # names must have leading $ sign stripped. begin the name with *
  45. # to cause output of arrays and hashes rather than refs.
  46. #
  47. sub new {
  48.   my($c, $v, $n) = @_;
  49.  
  50.   croak "Usage:  PACKAGE->new(ARRAYREF, [ARRAYREF])" 
  51.     unless (defined($v) && (ref($v) eq 'ARRAY'));
  52.   $n = [] unless (defined($n) && (ref($v) eq 'ARRAY'));
  53.  
  54.   my($s) = { 
  55.              level      => 0,           # current recursive depth
  56.          indent     => $Indent,     # various styles of indenting
  57.          pad    => $Pad,        # all lines prefixed by this string
  58.          xpad       => "",          # padding-per-level
  59.          apad       => "",          # added padding for hash keys n such
  60.          sep        => "",          # list separator
  61.          seen       => {},          # local (nested) refs (id => [name, val])
  62.          todump     => $v,          # values to dump []
  63.          names      => $n,          # optional names for values []
  64.          varname    => $Varname,    # prefix to use for tagging nameless ones
  65.              purity     => $Purity,     # degree to which output is evalable
  66.              useqq     => $Useqq,      # use "" for strings (backslashitis ensues)
  67.              terse     => $Terse,      # avoid name output (where feasible)
  68.              freezer    => $Freezer,    # name of Freezer method for objects
  69.              toaster    => $Toaster,    # name of method to revive objects
  70.              deepcopy    => $Deepcopy,   # dont cross-ref, except to stop recursion
  71. #         expdepth   => $Expdepth,   # cutoff depth for explicit dumping
  72. #         maxdepth    => $Maxdepth,   # depth beyond which we give up
  73.        };
  74.  
  75.   if ($Indent > 0) {
  76.     $s->{xpad} = "  ";
  77.     $s->{sep} = "\n";
  78.   }
  79.   return bless($s, $c);
  80. }
  81.  
  82. #
  83. # add-to or query the table of already seen references
  84. #
  85. sub Seen {
  86.   my($s, $g) = @_;
  87.   if (defined($g) && (ref($g) eq 'HASH'))  {
  88.     my($k, $v, $id);
  89.     while (($k, $v) = each %$g) {
  90.       if (defined $v and ref $v) {
  91.     ($id) = ("$v" =~ /\((.*)\)$/);
  92.     if ($k =~ /^[*](.*)$/) {
  93.       $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
  94.         (ref $v eq 'HASH') ? ( "\\\%" . $1 ) :
  95.           ("\$" . $1 );
  96.     }
  97.     elsif ($k !~ /^\$/) {
  98.       $k = "\$" . $k;
  99.     }
  100.     $s->{seen}{$id} = [$k, $v];
  101.       }
  102.       else {
  103.     carp "Only refs supported, ignoring non-ref item \$$k";
  104.       }
  105.     }
  106.   }
  107.   else {
  108.     return map { @$_ } values %{$s->{seen}};
  109.   }
  110. }
  111.  
  112. #
  113. # set or query the values to be dumped
  114. #
  115. sub Values {
  116.   my($s, $v) = @_;
  117.   if (defined($v) && (ref($v) eq 'ARRAY'))  {
  118.     $s->{todump} = [@$v];        # make a copy
  119.   }
  120.   else {
  121.     return @{$s->{todump}};
  122.   }
  123. }
  124.  
  125. #
  126. # set or query the names of the values to be dumped
  127. #
  128. sub Names {
  129.   my($s, $n) = @_;
  130.   if (defined($n) && (ref($n) eq 'ARRAY'))  {
  131.     $s->{names} = [@$n];         # make a copy
  132.   }
  133.   else {
  134.     return @{$s->{names}};
  135.   }
  136. }
  137.  
  138. sub DESTROY {}
  139.  
  140. #
  141. # dump the refs in the current dumper object.
  142. # expects same args as new() if called via package name.
  143. #
  144. sub Dump {
  145.   my($s) = shift;
  146.   my(@out, $val, $name);
  147.   my($i) = 0;
  148.   local(@post);
  149.  
  150.   $s = $s->new(@_) unless ref $s;
  151.  
  152.   for $val (@{$s->{todump}}) {
  153.     my $out = "";
  154.     @post = ();
  155.     $name = $s->{names}[$i++];
  156.     if (defined $name) {
  157.       if ($name =~ /^[*](.*)$/) {
  158.     if (defined $val) {
  159.       $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
  160.         (ref $val eq 'HASH') ? ( "\%" . $1 ) :
  161.           ("\$" . $1 );
  162.     }
  163.     else {
  164.       $name = "\$" . $1;
  165.     }
  166.       }
  167.       elsif ($name !~ /^\$/) {
  168.     $name = "\$" . $name;
  169.       }
  170.     }
  171.     else {
  172.       $name = "\$" . $s->{varname} . $i;
  173.     }
  174.  
  175.     my $valstr;
  176.     {
  177.       local($s->{apad}) = $s->{apad};
  178.       $s->{apad} .= ' ' x (length($name) + 3) if $s->{indent} >= 2;
  179.       $valstr = $s->_dump($val, $name);
  180.     }
  181.  
  182.     $valstr = "$name = " . $valstr . ';' if @post or !$s->{terse};
  183.     $out .= $s->{pad} . $valstr . $s->{sep};
  184.     $out .= $s->{pad} . join(';' . $s->{sep} . $s->{pad}, @post) 
  185.       . ';' . $s->{sep} if @post;
  186.  
  187.     push @out, $out;
  188.   }
  189.   return wantarray ? @out : join('', @out);
  190. }
  191.  
  192. #
  193. # twist, toil and turn;
  194. # and recurse, of course.
  195. #
  196. sub _dump {
  197.   my($s, $val, $name) = @_;
  198.   my($sname);
  199.   my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);
  200.  
  201.   return "undef" unless defined $val;
  202.  
  203.   $type = ref $val;
  204.   $out = "";
  205.  
  206.   if ($type) {
  207.  
  208.     # prep it, if it looks like an object
  209.     if ($type =~ /[a-z_:]/) {
  210.       my $freezer = $s->{freezer};
  211.       # UNIVERSAL::can should be used here, when we can require 5.004
  212.       if ($freezer) {
  213.     eval { $val->$freezer() };
  214.     carp "WARNING(Freezer method call failed): $@" if $@;
  215.       }
  216.     }
  217.  
  218.     if (exists $ {$type . "::OVERLOAD"}{'""'}) {
  219.       # let's hope this is harmless
  220.       bless $val, "Dumper::FAKE";
  221.       ($realpack, $realtype, $id) = ("$val" =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);
  222.       bless $val, $type;
  223.       $realpack = $type;
  224.     }
  225.     else {
  226.       ($realpack, $realtype, $id) = ("$val" =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);
  227.     }
  228.     
  229.     # keep a tab on it so that we dont fall into recursive pit
  230.     if (exists $s->{seen}{$id}) {
  231. #     if ($s->{expdepth} < $s->{level}) {
  232.       if ($s->{purity} and $s->{level} > 0) {
  233.     $out = ($realtype eq 'HASH') ? '{}' :
  234.       ($realtype eq 'ARRAY') ? '[]' : "''";
  235.       push @post, $name . " = " . $s->{seen}{$id}[0];
  236.       }
  237.       else {
  238.     $out = $s->{seen}{$id}[0];
  239.     if ($name =~ /^([\@\%])/) {
  240.       my $start = $1;
  241.       if ($out =~ /^\\$start/) {
  242.         $out = substr($out, 1);
  243.       }
  244.       else {
  245.         $out = $start . '{' . $out . '}';
  246.       }
  247.     }
  248.       }
  249.       return $out;
  250. #     }
  251.     }
  252.     else {
  253.       # store our name
  254.       $s->{seen}{$id} = [ ($name =~ /^[@%].*$/) ? ('\\' . $name ) : $name, $val ];
  255.     }
  256.  
  257.     $s->{level}++;
  258.     $ipad = $s->{xpad} x $s->{level};
  259.  
  260.     if ($realpack) {          # we have a blessed ref
  261.       $out = 'bless( ';
  262.       $blesspad = $s->{apad};
  263.       $s->{apad} .= '       ' if ($s->{indent} >= 2);
  264.     }
  265.     
  266.     if ($realtype eq 'SCALAR') {
  267.       if ($realpack) {
  268.     $out .= '\\' . '($_ = ' . $s->_dump($$val, "") . ')';
  269.       }
  270.       else {
  271.     $out .= '\\' . $s->_dump($$val, "");
  272.       }
  273.     }
  274.     elsif ($realtype eq 'GLOB') {
  275.     $out .= '\\' . $s->_dump($$val, "");
  276.     }
  277.     elsif ($realtype eq 'ARRAY') {
  278.       my($v, $pad, $mname);
  279.       my($i) = 0;
  280.       $out .= ($name =~ /^\@/) ? '(' : '[';
  281.       $pad = $s->{sep} . $s->{pad} . $s->{apad};
  282.       ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) : 
  283.     ($name =~ /[]}]$/) ? ($mname = $name) : ($mname = $name . '->');
  284.       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
  285.       for $v (@$val) {
  286.     $sname = $mname . '[' . $i . ']';
  287.     $out .= $pad . $ipad . '#' . $i if $s->{indent} >= 3;
  288.     $out .= $pad . $ipad . $s->_dump($v, $sname);
  289.     $out .= "," if $i++ < $#$val;
  290.       }
  291.       $out .= $pad . ($s->{xpad} x ($s->{level} - 1)) if $i;
  292.       $out .= ($name =~ /^\@/) ? ')' : ']';
  293.     }
  294.     elsif ($realtype eq 'HASH') {
  295.       my($k, $v, $pad, $lpad, $mname);
  296.       $out .= ($name =~ /^\%/) ? '(' : '{';
  297.       $pad = $s->{sep} . $s->{pad} . $s->{apad};
  298.       $lpad = $s->{apad};
  299.       ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) : 
  300.     ($name =~ /[]}]$/) ? ($mname = $name) : ($mname = $name . '->');
  301.       $mname .= '->' if $mname =~ /^\*.+\{[A-Z]+\}$/;
  302.       while (($k, $v) = each %$val) {
  303.     my $nk = $s->_dump($k, "");
  304.     $nk = $1 if !$s->{purity} and $nk =~ /^[\"\']([A-Za-z_][\w:]*)[\"\']$/;
  305.     $sname = $mname . '{' . $nk . '}';
  306.     $out .= $pad . $ipad . $nk . " => ";
  307.  
  308.     # temporarily alter apad
  309.     $s->{apad} .= (" " x (length($nk) + 4)) if $s->{indent} >= 2;
  310.     $out .= $s->_dump($val->{$k}, $sname) . ",";
  311.     $s->{apad} = $lpad if $s->{indent} >= 2;
  312.       }
  313.       if (substr($out, -1) eq ',') {
  314.     chop $out;
  315.     $out .= $pad . ($s->{xpad} x ($s->{level} - 1));
  316.       }
  317.       $out .= ($name =~ /^\%/) ? ')' : '}';
  318.     }
  319.     elsif ($realtype eq 'CODE') {
  320.       $out .= '"DUMMY"';
  321.       $out = 'sub { ' . $out . ' }';
  322.       carp "Encountered CODE ref, using dummy placeholder" if $s->{purity};
  323.     }
  324.     else {
  325.       croak "Can\'t handle $realtype type.";
  326.     }
  327.     
  328.     if ($realpack) { # we have a blessed ref
  329.       $out .= ', \'' . $realpack . '\'' . ' )';
  330.       $out .= '->' . $s->{toaster} . '()'  if $s->{toaster} ne '';
  331.       $s->{apad} = $blesspad;
  332.     }
  333.     $s->{level}--;
  334.  
  335.   }
  336.   else {                                 # simple scalar
  337.  
  338.     my $ref = \$_[1];
  339.     # first, catalog the scalar
  340.     if ($name ne '') {
  341.       ($id) = ("$ref" =~ /\(([^\(]*)\)$/);
  342.       if (exists $s->{seen}{$id}) {
  343.     $out = $s->{seen}{$id}[0];
  344.     return $out;
  345.       }
  346.       else {
  347.     $s->{seen}{$id} = ["\\$name", $val];
  348.       }
  349.     }
  350.     if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
  351.       my $name = substr($val, 1);
  352.       if ($name =~ /^[A-Za-z_][\w:]*$/) {
  353.     $name =~ s/^main::/::/;
  354.     $sname = $name;
  355.       }
  356.       else {
  357.     $sname = $s->_dump($name, "");
  358.     $sname = '{' . $sname . '}';
  359.       }
  360.       if ($s->{purity}) {
  361.     my $k;
  362.     local ($s->{level}) = 0;
  363.     for $k (qw(SCALAR ARRAY HASH)) {
  364.       # _dump can push into @post, so we hold our place using $postlen
  365.       my $postlen = scalar @post;
  366.       $post[$postlen] = "\*$sname = ";
  367.       local ($s->{apad}) = " " x length($post[$postlen]) if $s->{indent} >= 2;
  368.       $post[$postlen] .= $s->_dump(*{$name}{$k}, "\*$sname\{$k\}");
  369.     }
  370.       }
  371.       $out .= '*' . $sname;
  372.     }
  373.     elsif ($val =~ /^-?[1-9]\d{0,8}$/) { # safe decimal number
  374.       $out .= $val;
  375.     }
  376.     else {                 # string
  377.       if ($s->{useqq}) {
  378.     $out .= qquote($val);
  379.       }
  380.       else {
  381.     $val =~ s/([\\\'])/\\$1/g;
  382.     $out .= '\'' . $val .  '\'';
  383.       }
  384.     }
  385.   }
  386.  
  387.   # if we made it this far, $id was added to seen list at current
  388.   # level, so remove it to get deep copies
  389.   delete($s->{seen}{$id}) if $id and $s->{deepcopy};
  390.   return $out;
  391. }
  392.   
  393. #
  394. # non-OO style of earlier version
  395. #
  396. sub Dumper {
  397.   return Data::Dumper->Dump([@_]);
  398. }
  399.  
  400. #
  401. # same, only calls the XS version
  402. #
  403. sub DumperX {
  404.   return Data::Dumper->Dumpxs([@_], []);
  405. }
  406.  
  407. sub Dumpf { return Data::Dumper->Dump(@_) }
  408.  
  409. sub Dumpp { print Data::Dumper->Dump(@_) }
  410.  
  411. #
  412. # reset the "seen" cache 
  413. #
  414. sub Reset {
  415.   my($s) = shift;
  416.   $s->{seen} = {};
  417. }
  418.  
  419. sub Indent {
  420.   my($s, $v) = @_;
  421.   if (defined($v)) {
  422.     if ($v == 0) {
  423.       $s->{xpad} = "";
  424.       $s->{sep} = "";
  425.     }
  426.     else {
  427.       $s->{xpad} = "  ";
  428.       $s->{sep} = "\n";
  429.     }
  430.     $s->{indent} = $v;
  431.   }
  432.   return $s->{indent};
  433. }
  434.  
  435. sub Pad {
  436.   my($s, $v) = @_;
  437.   defined($v) ? ($s->{pad} = $v) : $s->{pad};
  438. }
  439.  
  440. sub Varname {
  441.   my($s, $v) = @_;
  442.   defined($v) ? ($s->{varname} = $v) : $s->{varname};
  443. }
  444.  
  445. sub Purity {
  446.   my($s, $v) = @_;
  447.   defined($v) ? ($s->{purity} = $v) : $s->{purity};
  448. }
  449.  
  450. sub Useqq {
  451.   my($s, $v) = @_;
  452.   defined($v) ? ($s->{useqq} = $v) : $s->{useqq};
  453. }
  454.  
  455. sub Terse {
  456.   my($s, $v) = @_;
  457.   defined($v) ? ($s->{terse} = $v) : $s->{terse};
  458. }
  459.  
  460. sub Freezer {
  461.   my($s, $v) = @_;
  462.   defined($v) ? ($s->{freezer} = $v) : $s->{freezer};
  463. }
  464.  
  465. sub Toaster {
  466.   my($s, $v) = @_;
  467.   defined($v) ? ($s->{toaster} = $v) : $s->{toaster};
  468. }
  469.  
  470. sub Deepcopy {
  471.   my($s, $v) = @_;
  472.   defined($v) ? ($s->{deepcopy} = $v) : $s->{deepcopy};
  473. }
  474.  
  475. # put a string value in double quotes
  476. sub qquote {
  477.   local($_) = shift;
  478.   s/([\\\"\@\$\%])/\\$1/g;    
  479.   s/\a/\\a/g;
  480.   s/[\b]/\\b/g;
  481.   s/\t/\\t/g;
  482.   s/\n/\\n/g;
  483.   s/\f/\\f/g;
  484.   s/\r/\\r/g;
  485.   s/\e/\\e/g;
  486.  
  487. # this won't work!
  488. #  s/([^\a\b\t\n\f\r\e\038-\176])/'\\'.sprintf('%03o',ord($1))/eg;
  489.   s/([\000-\006\013\016-\032\034-\037\177\200-\377])/'\\'.sprintf('%03o',ord($1))/eg;
  490.   return "\"$_\"";
  491. }
  492.  
  493. 1;
  494. __END__
  495.  
  496. =head1 NAME
  497.  
  498. Data::Dumper - stringified perl data structures, suitable for both printing and C<eval>
  499.  
  500.  
  501. =head1 SYNOPSIS
  502.  
  503.     use Data::Dumper;
  504.  
  505.     # simple procedural interface
  506.     print Dumper($foo, $bar);
  507.  
  508.     # extended usage with names
  509.     print Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
  510.  
  511.     # configuration variables
  512.     {
  513.       local $Data::Dump::Purity = 1;
  514.       eval Data::Dumper->Dump([$foo, $bar], [qw(foo *ary)]);
  515.     }
  516.  
  517.     # OO usage
  518.     $d = Data::Dumper->new([$foo, $bar], [qw(foo *ary)]);
  519.        ...
  520.     print $d->Dump;
  521.        ...
  522.     $d->Purity(1);
  523.     $d->Terse(1);
  524.     $d->Deepcopy(1);
  525.     eval $d->Dump;
  526.  
  527.  
  528. =head1 DESCRIPTION
  529.  
  530. Given a list of scalars or reference variables, writes out their contents in
  531. perl syntax. The references can also be objects.  The contents of each
  532. variable is output in a single Perl statement.
  533.  
  534. The return value can be C<eval>ed to get back the original reference
  535. structure. Bear in mind that a reference so created will not preserve
  536. pointer equalities with the original reference.
  537.  
  538. Handles self-referential structures correctly.  Any references that are the
  539. same as one of those passed in will be marked C<$VAR>I<n> (where I<n> is a
  540. numeric suffix), and other duplicate references to substructures within 
  541. C<$VAR>I<n> will be appropriately labeled using arrow notation.  You can
  542. specify names for individual values to be dumped if you use the C<Dump()>
  543. method, or you can change the default C<$VAR> prefix to something else.  See
  544. L<$Data::Dumper::Varname> and L<$Data::Dumper::Terse> below.
  545.  
  546. The default output of self-referential structures can be C<eval>ed, but the
  547. nested references to C<$VAR>I<n> will be undefined, since a recursive
  548. structure cannot be constructed using one Perl statement.  You can set the
  549. C<Purity> flag to 1 to get additional statements that will correctly fill in
  550. these references.
  551.  
  552. In the extended usage form, the references to be dumped can be given
  553. user-specified names.  If a name begins with a C<*>, the output will 
  554. describe the dereferenced type of the supplied reference for hashes and
  555. arrays.  Output of names will be avoided where possible if the C<Terse>
  556. flag is set.
  557.  
  558. Several styles of output are possible, all controlled by setting
  559. the C<Indent> flag.  See L<Configuration Variables or Methods> below 
  560. for details.
  561.  
  562.  
  563. =head2 Methods
  564.  
  565. =over 4
  566.  
  567. =item I<PACKAGE>->new(I<ARRAYREF [>, I<ARRAYREF]>)
  568.  
  569. Returns a newly created C<Data::Dumper> object.  The first argument is an
  570. anonymous array of values to be dumped.  The optional second argument is an
  571. anonymous array of names for the values.  The names need not have a leading
  572. C<$> sign, and must be comprised of alphanumeric characters.  You can begin
  573. a name with a C<*> to specify that the dereferenced type must be dumped
  574. instead of the reference itself, for ARRAY and HASH references.
  575.  
  576. The prefix specified by C<$Data::Dumper::Varname> will be used with a
  577. numeric suffix if the name for a value is undefined.
  578.  
  579. Data::Dumper will catalog all references encountered while dumping the
  580. values. Cross-references (in the form of names of substructures in perl
  581. syntax) will be inserted at all possible points, preserving any structural
  582. interdependencies in the original set of values.  Structure traversal is
  583. depth-first,  and proceeds in order from the first supplied value to
  584. the last.
  585.  
  586. =item I<$OBJ>->Dump  I<or>  I<PACKAGE>->Dump(I<ARRAYREF [>, I<ARRAYREF]>)
  587.  
  588. Returns the stringified form of the values stored in the object (preserving
  589. the order in which they were supplied to C<new>), subject to the
  590. configuration options below.  In an array context, it returns a list
  591. of strings corresponding to the supplied values.
  592.  
  593. The second form, for convenience, simply calls the C<new> method on its
  594. arguments before dumping the object immediately.
  595.  
  596. =item I<$OBJ>->Dumpxs  I<or>  I<PACKAGE>->Dumpxs(I<ARRAYREF [>, I<ARRAYREF]>)
  597.  
  598. This method is available if you were able to compile and install the XSUB
  599. extension to C<Data::Dumper>. It is exactly identical to the C<Dump> method 
  600. above, only about 4 to 5 times faster, since it is written entirely in C.
  601.  
  602. =item I<$OBJ>->Seen(I<[HASHREF]>)
  603.  
  604. Queries or adds to the internal table of already encountered references.
  605. You must use C<Reset> to explicitly clear the table if needed.  Such
  606. references are not dumped; instead, their names are inserted wherever they
  607. are encountered subsequently.
  608.  
  609. Expects a anonymous hash of name => value pairs.  Same rules apply for names
  610. as in C<new>.  If no argument is supplied, will return the "seen" list of
  611. name => value pairs, in an array context.
  612.  
  613. =item I<$OBJ>->Values(I<[ARRAYREF]>)
  614.  
  615. Queries or replaces the internal array of values that will be dumped.
  616.  
  617. =item I<$OBJ>->Names(I<[ARRAYREF]>)
  618.  
  619. Queries or replaces the internal array of user supplied names for the values
  620. that will be dumped.
  621.  
  622. =item I<$OBJ>->Reset
  623.  
  624. Clears the internal table of "seen" references.
  625.  
  626. =back
  627.  
  628. =head2 Functions
  629.  
  630. =over 4
  631.  
  632. =item Dumper(I<LIST>)
  633.  
  634. Returns the stringified form of the values in the list, subject to the
  635. configuration options below.  The values will be named C<$VAR>I<n> in the
  636. output, where I<n> is a numeric suffix.  Will return a list of strings
  637. in an array context.
  638.  
  639. =item DumperX(I<LIST>)
  640.  
  641. Identical to the C<Dumper()> function above, but this calls the XSUB 
  642. implementation.  Only available if you were able to compile and install
  643. the XSUB extensions in C<Data::Dumper>.
  644.  
  645. =back
  646.  
  647. =head2 Configuration Variables or Methods
  648.  
  649. Several configuration variables can be used to control the kind of output
  650. generated when using the procedural interface.  These variables are usually
  651. C<local>ized in a block so that other parts of the code are not affected by
  652. the change.  
  653.  
  654. These variables determine the default state of the object created by calling
  655. the C<new> method, but cannot be used to alter the state of the object
  656. thereafter.  The equivalent method names should be used instead to query
  657. or set the internal state of the object.
  658.  
  659. =over 4
  660.  
  661. =item $Data::Dumper::Indent  I<or>  I<$OBJ>->Indent(I<[NEWVAL]>)
  662.  
  663. Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
  664. spews output without any newlines, indentation, or spaces between list
  665. items.  It is the most compact format possible that can still be called
  666. valid perl.  Style 1 outputs a readable form with newlines but no fancy
  667. indentation (each level in the structure is simply indented by a fixed
  668. amount of whitespace).  Style 2 (the default) outputs a very readable form
  669. which takes into account the length of hash keys (so the hash value lines
  670. up).  Style 3 is like style 2, but also annotates the elements of arrays
  671. with their index (but the comment is on its own line, so array output
  672. consumes twice the number of lines).  Style 2 is the default.
  673.  
  674. =item $Data::Dumper::Purity  I<or>  I<$OBJ>->Purity(I<[NEWVAL]>)
  675.  
  676. Controls the degree to which the output can be C<eval>ed to recreate the
  677. supplied reference structures.  Setting it to 1 will output additional perl
  678. statements that will correctly recreate nested references.  The default is
  679. 0.
  680.  
  681. =item $Data::Dumper::Pad  I<or>  I<$OBJ>->Pad(I<[NEWVAL]>)
  682.  
  683. Specifies the string that will be prefixed to every line of the output.
  684. Empty string by default.
  685.  
  686. =item $Data::Dumper::Varname  I<or>  I<$OBJ>->Varname(I<[NEWVAL]>)
  687.  
  688. Contains the prefix to use for tagging variable names in the output. The
  689. default is "VAR".
  690.  
  691. =item $Data::Dumper::Useqq  I<or>  I<$OBJ>->Useqq(I<[NEWVAL]>)
  692.  
  693. When set, enables the use of double quotes for representing string values.
  694. Whitespace other than space will be represented as C<[\n\t\r]>, "unsafe"
  695. characters will be backslashed, and unprintable characters will be output as
  696. quoted octal integers.  Since setting this variable imposes a performance
  697. penalty, the default is 0.  The C<Dumpxs()> method does not honor this
  698. flag yet.
  699.  
  700. =item $Data::Dumper::Terse  I<or>  I<$OBJ>->Terse(I<[NEWVAL]>)
  701.  
  702. When set, Data::Dumper will emit single, non-self-referential values as
  703. atoms/terms rather than statements.  This means that the C<$VAR>I<n> names
  704. will be avoided where possible, but be advised that such output may not
  705. always be parseable by C<eval>.
  706.  
  707. =item $Data::Dumper::Freezer  I<or>  $I<OBJ>->Freezer(I<[NEWVAL]>)
  708.  
  709. Can be set to a method name, or to an empty string to disable the feature.
  710. Data::Dumper will invoke that method via the object before attempting to
  711. stringify it.  This method can alter the contents of the object (if, for
  712. instance, it contains data allocated from C), and even rebless it in a
  713. different package.  The client is responsible for making sure the specified
  714. method can be called via the object, and that the object ends up containing
  715. only perl data types after the method has been called.  Defaults to an empty
  716. string.
  717.  
  718. =item $Data::Dumper::Toaster  I<or>  $I<OBJ>->Toaster(I<[NEWVAL]>)
  719.  
  720. Can be set to a method name, or to an empty string to disable the feature.
  721. Data::Dumper will emit a method call for any objects that are to be dumped
  722. using the syntax C<bless(DATA, CLASS)->METHOD()>.  Note that this means that
  723. the method specified will have to perform any modifications required on the
  724. object (like creating new state within it, and/or reblessing it in a
  725. different package) and then return it.  The client is responsible for making
  726. sure the method can be called via the object, and that it returns a valid
  727. object.  Defaults to an empty string.
  728.  
  729. =item $Data::Dumper::Deepcopy  I<or>  $I<OBJ>->Deepcopy(I<[NEWVAL]>)
  730.  
  731. Can be set to a boolean value to enable deep copies of structures.
  732. Cross-referencing will then only be done when absolutely essential
  733. (i.e., to break reference cycles).  Default is 0.
  734.  
  735. =back
  736.  
  737. =head2 Exports
  738.  
  739. =item Dumper
  740.  
  741.  
  742. =head1 EXAMPLE
  743.  
  744. Run these code snippets to get a quick feel for the behavior of this
  745. module.  When you are through with these examples, you may want to
  746. add or change the various configuration variables described above,
  747. to see their behavior.  (See the testsuite in the Data::Dumper
  748. distribution for more examples.)
  749.  
  750.  
  751.     use Data::Dumper;
  752.  
  753.     package Foo;
  754.     sub new {bless {'a' => 1, 'b' => sub { return "foo" }}, $_[0]};
  755.  
  756.     package Fuz;                       # a weird REF-REF-SCALAR object
  757.     sub new {bless \($_ = \ 'fu\'z'), $_[0]};
  758.  
  759.     package main;
  760.     $foo = Foo->new;
  761.     $fuz = Fuz->new;
  762.     $boo = [ 1, [], "abcd", \*foo,
  763.              {1 => 'a', 023 => 'b', 0x45 => 'c'}, 
  764.              \\"p\q\'r", $foo, $fuz];
  765.     
  766.     ########
  767.     # simple usage
  768.     ########
  769.  
  770.     $bar = eval(Dumper($boo));
  771.     print($@) if $@;
  772.     print Dumper($boo), Dumper($bar);  # pretty print (no array indices)
  773.  
  774.     $Data::Dumper::Terse = 1;          # don't output names where feasible
  775.     $Data::Dumper::Indent = 0;         # turn off all pretty print
  776.     print Dumper($boo), "\n";
  777.  
  778.     $Data::Dumper::Indent = 1;         # mild pretty print
  779.     print Dumper($boo);
  780.  
  781.     $Data::Dumper::Indent = 3;         # pretty print with array indices
  782.     print Dumper($boo);
  783.  
  784.     $Data::Dumper::Useqq = 1;          # print strings in double quotes
  785.     print Dumper($boo);
  786.     
  787.     
  788.     ########
  789.     # recursive structures
  790.     ########
  791.     
  792.     
  793.     @c = ('c');
  794.     $c = \@c;
  795.     $b = {};
  796.     $a = [1, $b, $c];
  797.     $b->{a} = $a;
  798.     $b->{b} = $a->[1];
  799.     $b->{c} = $a->[2];
  800.     print Data::Dumper->Dump([$a,$b,$c], [qw(a b c)]);
  801.     
  802.     
  803.     $Data::Dumper::Purity = 1;         # fill in the holes for eval
  804.     print Data::Dumper->Dump([$a, $b], [qw(*a b)]); # print as @a
  805.     print Data::Dumper->Dump([$b, $a], [qw(*b a)]); # print as %b
  806.     
  807.     
  808.     $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
  809.     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
  810.     
  811.     
  812.     $Data::Dumper::Purity = 0;         # avoid cross-refs
  813.     print Data::Dumper->Dump([$b, $a], [qw(*b a)]);
  814.     
  815.     
  816.     ########
  817.     # object-oriented usage
  818.     ########
  819.     
  820.     
  821.     $d = Data::Dumper->new([$a,$b], [qw(a b)]);
  822.     $d->Seen({'*c' => $c});            # stash a ref without printing it
  823.     $d->Indent(3);
  824.     print $d->Dump;
  825.     $d->Reset;                         # empty the seen cache
  826.     $d->Purity(0);
  827.     print join "----\n", $d->Dump;
  828.     
  829.     
  830.     ########
  831.     # persistence
  832.     ########
  833.     
  834.     
  835.     package Foo;
  836.     sub new { bless { state => 'awake' }, shift }
  837.     sub Freeze {
  838.         my $s = shift;
  839.     print STDERR "preparing to sleep\n";
  840.     $s->{state} = 'asleep';
  841.     return bless $s, 'Foo::ZZZ';
  842.     }
  843.     
  844.     package Foo::ZZZ;
  845.     sub Thaw {
  846.         my $s = shift;
  847.     print STDERR "waking up\n";
  848.     $s->{state} = 'awake';
  849.     return bless $s, 'Foo';
  850.     }
  851.     
  852.     package Foo;
  853.     use Data::Dumper;
  854.     my $a = Foo->new;
  855.     my $b = Data::Dumper->new([$a], ['c']);
  856.     $b->Freezer('Freeze');
  857.     $b->Toaster('Thaw');
  858.     my $c = $b->Dump;
  859.     print $c;
  860.     my $d = eval $c;
  861.     print Data::Dumper->Dump([$d], ['d']);
  862.  
  863.  
  864. =head1 BUGS
  865.  
  866. Due to limitations of Perl subroutine call semantics, you cannot pass an
  867. array or hash.  Prepend it with a C<\> to pass its reference instead.  This
  868. will be remedied in time, with the arrival of prototypes in later versions
  869. of Perl.  For now, you need to use the extended usage form, and prepend the
  870. name with a C<*> to output it as a hash or array.
  871.  
  872. C<Data::Dumper> cheats with CODE references.  If a code reference is
  873. encountered in the structure being processed, an anonymous subroutine that
  874. contains the string '"DUMMY"' will be inserted in its place, and a warning
  875. will be printed if C<Purity> is set.  You can C<eval> the result, but bear
  876. in mind that the anonymous sub that gets created is just a placeholder.
  877. Someday, perl will have a switch to cache-on-demand the string
  878. representation of a compiled piece of code, I hope.
  879.  
  880. The C<Useqq> flag is not honored by C<Dumpxs()> (it always outputs
  881. strings in single quotes).
  882.  
  883. SCALAR objects have the weirdest looking C<bless> workaround.
  884.  
  885.  
  886. =head1 AUTHOR
  887.  
  888. Gurusamy Sarathy        gsar@umich.edu
  889.  
  890. Copyright (c) 1996 Gurusamy Sarathy. All rights reserved.
  891. This program is free software; you can redistribute it and/or
  892. modify it under the same terms as Perl itself.
  893.  
  894.  
  895. =head1 VERSION
  896.  
  897. Version 2.07    (7 December 1996)
  898.  
  899.  
  900. =head1 SEE ALSO
  901.  
  902. perl(1)
  903.  
  904. =cut
  905.