home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / perl_pod.zip / perlsyn.pod < prev    next >
Text File  |  1997-11-25  |  19KB  |  559 lines
  1. =head1 NAME
  2.  
  3. perlsyn - Perl syntax
  4.  
  5. =head1 DESCRIPTION
  6.  
  7. A Perl script consists of a sequence of declarations and statements.
  8. The only things that need to be declared in Perl are report formats
  9. and subroutines.  See the sections below for more information on those
  10. declarations.  All uninitialized user-created objects are assumed to
  11. start with a null or 0 value until they are defined by some explicit
  12. operation such as assignment.  (Though you can get warnings about the
  13. use of undefined values if you like.)  The sequence of statements is
  14. executed just once, unlike in B<sed> and B<awk> scripts, where the
  15. sequence of statements is executed for each input line.  While this means
  16. that you must explicitly loop over the lines of your input file (or
  17. files), it also means you have much more control over which files and
  18. which lines you look at.  (Actually, I'm lying--it is possible to do an
  19. implicit loop with either the B<-n> or B<-p> switch.  It's just not the
  20. mandatory default like it is in B<sed> and B<awk>.)
  21.  
  22. =head2 Declarations
  23.  
  24. Perl is, for the most part, a free-form language.  (The only
  25. exception to this is format declarations, for obvious reasons.) Comments
  26. are indicated by the "#" character, and extend to the end of the line.  If
  27. you attempt to use C</* */> C-style comments, it will be interpreted
  28. either as division or pattern matching, depending on the context, and C++
  29. C<//> comments just look like a null regular expression, so don't do
  30. that.
  31.  
  32. A declaration can be put anywhere a statement can, but has no effect on
  33. the execution of the primary sequence of statements--declarations all
  34. take effect at compile time.  Typically all the declarations are put at
  35. the beginning or the end of the script.  However, if you're using
  36. lexically-scoped private variables created with my(), you'll have to make sure
  37. your format or subroutine definition is within the same block scope
  38. as the my if you expect to be able to access those private variables.
  39.  
  40. Declaring a subroutine allows a subroutine name to be used as if it were a
  41. list operator from that point forward in the program.  You can declare a
  42. subroutine without defining it by saying C<sub name>, thus:
  43.  
  44.     sub myname;
  45.     $me = myname $0         or die "can't get myname";
  46.  
  47. Note that it functions as a list operator, not as a unary operator; so
  48. be careful to use C<or> instead of C<||> in this case.  However, if
  49. you were to declare the subroutine as C<sub myname ($)>, then
  50. C<myname> would functonion as a unary operator, so either C<or> or
  51. C<||> would work.
  52.  
  53. Subroutines declarations can also be loaded up with the C<require> statement
  54. or both loaded and imported into your namespace with a C<use> statement.
  55. See L<perlmod> for details on this.
  56.  
  57. A statement sequence may contain declarations of lexically-scoped
  58. variables, but apart from declaring a variable name, the declaration acts
  59. like an ordinary statement, and is elaborated within the sequence of
  60. statements as if it were an ordinary statement.  That means it actually
  61. has both compile-time and run-time effects.
  62.  
  63. =head2 Simple statements
  64.  
  65. The only kind of simple statement is an expression evaluated for its
  66. side effects.  Every simple statement must be terminated with a
  67. semicolon, unless it is the final statement in a block, in which case
  68. the semicolon is optional.  (A semicolon is still encouraged there if the
  69. block takes up more than one line, because you may eventually add another line.)
  70. Note that there are some operators like C<eval {}> and C<do {}> that look
  71. like compound statements, but aren't (they're just TERMs in an expression),
  72. and thus need an explicit termination if used as the last item in a statement.
  73.  
  74. Any simple statement may optionally be followed by a I<SINGLE> modifier,
  75. just before the terminating semicolon (or block ending).  The possible
  76. modifiers are:
  77.  
  78.     if EXPR
  79.     unless EXPR
  80.     while EXPR
  81.     until EXPR
  82.  
  83. The C<if> and C<unless> modifiers have the expected semantics,
  84. presuming you're a speaker of English.  The C<while> and C<until>
  85. modifiers also have the usual "while loop" semantics (conditional
  86. evaluated first), except when applied to a do-BLOCK (or to the
  87. now-deprecated do-SUBROUTINE statement), in which case the block
  88. executes once before the conditional is evaluated.  This is so that you
  89. can write loops like:
  90.  
  91.     do {
  92.     $line = <STDIN>;
  93.     ...
  94.     } until $line  eq ".\n";
  95.  
  96. See L<perlfunc/do>.  Note also that the loop control
  97. statements described later will I<NOT> work in this construct, because
  98. modifiers don't take loop labels.  Sorry.  You can always wrap
  99. another block around it to do that sort of thing.
  100.  
  101. =head2 Compound statements
  102.  
  103. In Perl, a sequence of statements that defines a scope is called a block.
  104. Sometimes a block is delimited by the file containing it (in the case
  105. of a required file, or the program as a whole), and sometimes a block
  106. is delimited by the extent of a string (in the case of an eval).
  107.  
  108. But generally, a block is delimited by curly brackets, also known as braces.
  109. We will call this syntactic construct a BLOCK.
  110.  
  111. The following compound statements may be used to control flow:
  112.  
  113.     if (EXPR) BLOCK
  114.     if (EXPR) BLOCK else BLOCK
  115.     if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
  116.     LABEL while (EXPR) BLOCK
  117.     LABEL while (EXPR) BLOCK continue BLOCK
  118.     LABEL for (EXPR; EXPR; EXPR) BLOCK
  119.     LABEL foreach VAR (LIST) BLOCK
  120.     LABEL BLOCK continue BLOCK
  121.  
  122. Note that, unlike C and Pascal, these are defined in terms of BLOCKs,
  123. not statements.  This means that the curly brackets are I<required>--no
  124. dangling statements allowed.  If you want to write conditionals without
  125. curly brackets there are several other ways to do it.  The following
  126. all do the same thing:
  127.  
  128.     if (!open(FOO)) { die "Can't open $FOO: $!"; }
  129.     die "Can't open $FOO: $!" unless open(FOO);
  130.     open(FOO) or die "Can't open $FOO: $!";    # FOO or bust!
  131.     open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
  132.             # a bit exotic, that last one
  133.  
  134. The C<if> statement is straightforward.  Because BLOCKs are always
  135. bounded by curly brackets, there is never any ambiguity about which
  136. C<if> an C<else> goes with.  If you use C<unless> in place of C<if>,
  137. the sense of the test is reversed.
  138.  
  139. The C<while> statement executes the block as long as the expression is
  140. true (does not evaluate to the null string or 0 or "0").  The LABEL is
  141. optional, and if present, consists of an identifier followed by a colon.
  142. The LABEL identifies the loop for the loop control statements C<next>,
  143. C<last>, and C<redo>.  If the LABEL is omitted, the loop control statement
  144. refers to the innermost enclosing loop.  This may include dynamically
  145. looking back your call-stack at run time to find the LABEL.  Such
  146. desperate behavior triggers a warning if you use the B<-w> flag.
  147.  
  148. If there is a C<continue> BLOCK, it is always executed just before the
  149. conditional is about to be evaluated again, just like the third part of a
  150. C<for> loop in C.  Thus it can be used to increment a loop variable, even
  151. when the loop has been continued via the C<next> statement (which is
  152. similar to the C C<continue> statement).
  153.  
  154. =head2 Loop Control
  155.  
  156. The C<next> command is like the C<continue> statement in C; it starts
  157. the next iteration of the loop:
  158.  
  159.     LINE: while (<STDIN>) {
  160.     next LINE if /^#/;    # discard comments
  161.     ...
  162.     }
  163.  
  164. The C<last> command is like the C<break> statement in C (as used in
  165. loops); it immediately exits the loop in question.  The
  166. C<continue> block, if any, is not executed:
  167.  
  168.     LINE: while (<STDIN>) {
  169.     last LINE if /^$/;    # exit when done with header
  170.     ...
  171.     }
  172.  
  173. The C<redo> command restarts the loop block without evaluating the
  174. conditional again.  The C<continue> block, if any, is I<not> executed.
  175. This command is normally used by programs that want to lie to themselves
  176. about what was just input.
  177.  
  178. For example, when processing a file like F</etc/termcap>.
  179. If your input lines might end in backslashes to indicate continuation, you
  180. want to skip ahead and get the next record.
  181.  
  182.     while (<>) {
  183.     chomp;
  184.     if (s/\\$//) {
  185.         $_ .= <>;
  186.         redo unless eof();
  187.     }
  188.     # now process $_
  189.     }
  190.  
  191. which is Perl short-hand for the more explicitly written version:
  192.  
  193.     LINE: while (defined($line = <ARGV>)) {
  194.     chomp($line);
  195.     if ($line =~ s/\\$//) {
  196.         $line .= <ARGV>;
  197.         redo LINE unless eof(); # not eof(ARGV)!
  198.     }
  199.     # now process $line
  200.     }
  201.  
  202. Or here's a simpleminded Pascal comment stripper (warning: assumes no
  203. { or } in strings).
  204.  
  205.     LINE: while (<STDIN>) {
  206.     while (s|({.*}.*){.*}|$1 |) {}
  207.     s|{.*}| |;
  208.     if (s|{.*| |) {
  209.         $front = $_;
  210.         while (<STDIN>) {
  211.         if (/}/) {    # end of comment?
  212.             s|^|$front{|;
  213.             redo LINE;
  214.         }
  215.         }
  216.     }
  217.     print;
  218.     }
  219.  
  220. Note that if there were a C<continue> block on the above code, it would get
  221. executed even on discarded lines.
  222.  
  223. If the word C<while> is replaced by the word C<until>, the sense of the
  224. test is reversed, but the conditional is still tested before the first
  225. iteration.
  226.  
  227. The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer
  228. available.   Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>.
  229.  
  230. =head2 For Loops
  231.  
  232. Perl's C-style C<for> loop works exactly like the corresponding C<while> loop;
  233. that means that this:
  234.  
  235.     for ($i = 1; $i < 10; $i++) {
  236.     ...
  237.     }
  238.  
  239. is the same as this:
  240.  
  241.     $i = 1;
  242.     while ($i < 10) {
  243.     ...
  244.     } continue {
  245.     $i++;
  246.     }
  247.  
  248. (There is one minor difference: The first form implies a lexical scope
  249. for variables declared with C<my> in the initialization expression.)
  250.  
  251. Besides the normal array index looping, C<for> can lend itself
  252. to many other interesting applications.  Here's one that avoids the
  253. problem you get into if you explicitly test for end-of-file on
  254. an interactive file descriptor causing your program to appear to
  255. hang.
  256.  
  257.     $on_a_tty = -t STDIN && -t STDOUT;
  258.     sub prompt { print "yes? " if $on_a_tty }
  259.     for ( prompt(); <STDIN>; prompt() ) {
  260.     # do something
  261.     }
  262.  
  263. =head2 Foreach Loops
  264.  
  265. The C<foreach> loop iterates over a normal list value and sets the
  266. variable VAR to be each element of the list in turn.  If the variable
  267. is preceded with the keyword C<my>, then it is lexically scoped, and
  268. is therefore visible only within the loop.  Otherwise, the variable is
  269. implicitly local to the loop and regains its former value upon exiting
  270. the loop.  If the variable was previously declared with C<my>, it uses
  271. that variable instead of the global one, but it's still localized to
  272. the loop.  (Note that a lexically scoped variable can cause problems
  273. with you have subroutine or format declarations.)
  274.  
  275. The C<foreach> keyword is actually a synonym for the C<for> keyword, so
  276. you can use C<foreach> for readability or C<for> for brevity.  If VAR is
  277. omitted, $_ is set to each value.  If LIST is an actual array (as opposed
  278. to an expression returning a list value), you can modify each element of
  279. the array by modifying VAR inside the loop.  That's because the C<foreach>
  280. loop index variable is an implicit alias for each item in the list that
  281. you're looping over.
  282.  
  283. Examples:
  284.  
  285.     for (@ary) { s/foo/bar/ }
  286.  
  287.     foreach my $elem (@elements) {
  288.     $elem *= 2;
  289.     }
  290.  
  291.     for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
  292.     print $count, "\n"; sleep(1);
  293.     }
  294.  
  295.     for (1..15) { print "Merry Christmas\n"; }
  296.  
  297.     foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
  298.     print "Item: $item\n";
  299.     }
  300.  
  301. Here's how a C programmer might code up a particular algorithm in Perl:
  302.  
  303.     for (my $i = 0; $i < @ary1; $i++) {
  304.     for (my $j = 0; $j < @ary2; $j++) {
  305.         if ($ary1[$i] > $ary2[$j]) {
  306.         last; # can't go to outer :-(
  307.         }
  308.         $ary1[$i] += $ary2[$j];
  309.     }
  310.     # this is where that last takes me
  311.     }
  312.  
  313. Whereas here's how a Perl programmer more comfortable with the idiom might
  314. do it:
  315.  
  316.     OUTER: foreach my $wid (@ary1) {
  317.     INNER:   foreach my $jet (@ary2) {
  318.         next OUTER if $wid > $jet;
  319.         $wid += $jet;
  320.          }
  321.       }
  322.  
  323. See how much easier this is?  It's cleaner, safer, and faster.  It's
  324. cleaner because it's less noisy.  It's safer because if code gets added
  325. between the inner and outer loops later on, the new code won't be
  326. accidentally executed.  The C<next> explicitly iterates the other loop
  327. rather than merely terminating the inner one.  And it's faster because
  328. Perl executes a C<foreach> statement more rapidly than it would the
  329. equivalent C<for> loop.
  330.  
  331. =head2 Basic BLOCKs and Switch Statements
  332.  
  333. A BLOCK by itself (labeled or not) is semantically equivalent to a
  334. loop that executes once.  Thus you can use any of the loop control
  335. statements in it to leave or restart the block.  (Note that this is
  336. I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief
  337. C<do{}> blocks, which do I<NOT> count as loops.)  The C<continue>
  338. block is optional.
  339.  
  340. The BLOCK construct is particularly nice for doing case
  341. structures.
  342.  
  343.     SWITCH: {
  344.     if (/^abc/) { $abc = 1; last SWITCH; }
  345.     if (/^def/) { $def = 1; last SWITCH; }
  346.     if (/^xyz/) { $xyz = 1; last SWITCH; }
  347.     $nothing = 1;
  348.     }
  349.  
  350. There is no official switch statement in Perl, because there are
  351. already several ways to write the equivalent.  In addition to the
  352. above, you could write
  353.  
  354.     SWITCH: {
  355.     $abc = 1, last SWITCH  if /^abc/;
  356.     $def = 1, last SWITCH  if /^def/;
  357.     $xyz = 1, last SWITCH  if /^xyz/;
  358.     $nothing = 1;
  359.     }
  360.  
  361. (That's actually not as strange as it looks once you realize that you can
  362. use loop control "operators" within an expression,  That's just the normal
  363. C comma operator.)
  364.  
  365. or
  366.  
  367.     SWITCH: {
  368.     /^abc/ && do { $abc = 1; last SWITCH; };
  369.     /^def/ && do { $def = 1; last SWITCH; };
  370.     /^xyz/ && do { $xyz = 1; last SWITCH; };
  371.     $nothing = 1;
  372.     }
  373.  
  374. or formatted so it stands out more as a "proper" switch statement:
  375.  
  376.     SWITCH: {
  377.     /^abc/         && do {
  378.                 $abc = 1;
  379.                 last SWITCH;
  380.                };
  381.  
  382.     /^def/         && do {
  383.                 $def = 1;
  384.                 last SWITCH;
  385.                };
  386.  
  387.     /^xyz/         && do {
  388.                 $xyz = 1;
  389.                 last SWITCH;
  390.                 };
  391.     $nothing = 1;
  392.     }
  393.  
  394. or
  395.  
  396.     SWITCH: {
  397.     /^abc/ and $abc = 1, last SWITCH;
  398.     /^def/ and $def = 1, last SWITCH;
  399.     /^xyz/ and $xyz = 1, last SWITCH;
  400.     $nothing = 1;
  401.     }
  402.  
  403. or even, horrors,
  404.  
  405.     if (/^abc/)
  406.     { $abc = 1 }
  407.     elsif (/^def/)
  408.     { $def = 1 }
  409.     elsif (/^xyz/)
  410.     { $xyz = 1 }
  411.     else
  412.     { $nothing = 1 }
  413.  
  414.  
  415. A common idiom for a switch statement is to use C<foreach>'s aliasing to make
  416. a temporary assignment to $_ for convenient matching:
  417.  
  418.     SWITCH: for ($where) {
  419.         /In Card Names/     && do { push @flags, '-e'; last; };
  420.         /Anywhere/          && do { push @flags, '-h'; last; };
  421.         /In Rulings/        && do {                    last; };
  422.         die "unknown value for form variable where: `$where'";
  423.         }
  424.  
  425. Another interesting approach to a switch statement is arrange
  426. for a C<do> block to return the proper value:
  427.  
  428.     $amode = do {
  429.     if     ($flag & O_RDONLY) { "r" }
  430.     elsif  ($flag & O_WRONLY) { ($flag & O_APPEND) ? "a" : "w" }
  431.     elsif  ($flag & O_RDWR)   {
  432.         if ($flag & O_CREAT)  { "w+" }
  433.         else                  { ($flag & O_APPEND) ? "a+" : "r+" }
  434.     }
  435.     };
  436.  
  437. =head2 Goto
  438.  
  439. Although not for the faint of heart, Perl does support a C<goto> statement.
  440. A loop's LABEL is not actually a valid target for a C<goto>;
  441. it's just the name of the loop.  There are three forms: goto-LABEL,
  442. goto-EXPR, and goto-&NAME.
  443.  
  444. The goto-LABEL form finds the statement labeled with LABEL and resumes
  445. execution there.  It may not be used to go into any construct that
  446. requires initialization, such as a subroutine or a foreach loop.  It
  447. also can't be used to go into a construct that is optimized away.  It
  448. can be used to go almost anywhere else within the dynamic scope,
  449. including out of subroutines, but it's usually better to use some other
  450. construct such as last or die.  The author of Perl has never felt the
  451. need to use this form of goto (in Perl, that is--C is another matter).
  452.  
  453. The goto-EXPR form expects a label name, whose scope will be resolved
  454. dynamically.  This allows for computed gotos per FORTRAN, but isn't
  455. necessarily recommended if you're optimizing for maintainability:
  456.  
  457.     goto ("FOO", "BAR", "GLARCH")[$i];
  458.  
  459. The goto-&NAME form is highly magical, and substitutes a call to the
  460. named subroutine for the currently running subroutine.  This is used by
  461. AUTOLOAD() subroutines that wish to load another subroutine and then
  462. pretend that the other subroutine had been called in the first place
  463. (except that any modifications to @_ in the current subroutine are
  464. propagated to the other subroutine.)  After the C<goto>, not even caller()
  465. will be able to tell that this routine was called first.
  466.  
  467. In almost all cases like this, it's usually a far, far better idea to use the
  468. structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of
  469. resorting to a C<goto>.  For certain applications, the catch and throw pair of
  470. C<eval{}> and die() for exception processing can also be a prudent approach.
  471.  
  472. =head2 PODs: Embedded Documentation
  473.  
  474. Perl has a mechanism for intermixing documentation with source code.
  475. While it's expecting the beginning of a new statement, if the compiler
  476. encounters a line that begins with an equal sign and a word, like this
  477.  
  478.     =head1 Here There Be Pods!
  479.  
  480. Then that text and all remaining text up through and including a line
  481. beginning with C<=cut> will be ignored.  The format of the intervening
  482. text is described in L<perlpod>.
  483.  
  484. This allows you to intermix your source code
  485. and your documentation text freely, as in
  486.  
  487.     =item snazzle($)
  488.  
  489.     The snazzle() function will behave in the most spectacular
  490.     form that you can possibly imagine, not even excepting
  491.     cybernetic pyrotechnics.
  492.  
  493.     =cut back to the compiler, nuff of this pod stuff!
  494.  
  495.     sub snazzle($) {
  496.     my $thingie = shift;
  497.     .........
  498.     }
  499.  
  500. Note that pod translators should look at only paragraphs beginning
  501. with a pod directive (it makes parsing easier), whereas the compiler
  502. actually knows to look for pod escapes even in the middle of a
  503. paragraph.  This means that the following secret stuff will be
  504. ignored by both the compiler and the translators.
  505.  
  506.     $a=3;
  507.     =secret stuff
  508.      warn "Neither POD nor CODE!?"
  509.     =cut back
  510.     print "got $a\n";
  511.  
  512. You probably shouldn't rely upon the warn() being podded out forever.
  513. Not all pod translators are well-behaved in this regard, and perhaps
  514. the compiler will become pickier.
  515.  
  516. One may also use pod directives to quickly comment out a section
  517. of code.
  518.  
  519. =head2 Plain Old Comments (Not!)
  520.  
  521. Much like the C preprocessor, perl can process line directives.  Using
  522. this, one can control perl's idea of filenames and line numbers in
  523. error or warning messages (especially for strings that are processed
  524. with eval()).  The syntax for this mechanism is the same as for most
  525. C preprocessors: it matches the regular expression
  526. C</^#\s*line\s+(\d+)\s*(?:\s"([^"]*)")?/> with C<$1> being the line
  527. number for the next line, and C<$2> being the optional filename
  528. (specified within quotes).
  529.  
  530. Here are some examples that you should be able to type into your command
  531. shell:
  532.  
  533.     % perl
  534.     # line 200 "bzzzt"
  535.     # the `#' on the previous line must be the first char on line
  536.     die 'foo';
  537.     __END__
  538.     foo at bzzzt line 201.
  539.  
  540.     % perl
  541.     # line 200 "bzzzt"
  542.     eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
  543.     __END__
  544.     foo at - line 2001.
  545.  
  546.     % perl
  547.     eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
  548.     __END__
  549.     foo at foo bar line 200.
  550.  
  551.     % perl
  552.     # line 345 "goop"
  553.     eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
  554.     print $@;
  555.     __END__
  556.     foo at goop line 345.
  557.  
  558. =cut
  559.