home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / perl502b.zip / lib / DynaLoader.pm < prev    next >
Text File  |  1996-02-20  |  21KB  |  593 lines
  1. package DynaLoader;
  2.  
  3. #   And Gandalf said: 'Many folk like to know beforehand what is to
  4. #   be set on the table; but those who have laboured to prepare the
  5. #   feast like to keep their secret; for wonder makes the words of
  6. #   praise louder.'
  7.  
  8. #   (Quote from Tolkien sugested by Anno Siegel.)
  9. #
  10. # See pod text at end of file for documentation.
  11. # See also ext/DynaLoader/README in source tree for other information.
  12. #
  13. # Tim.Bunce@ig.co.uk, August 1994
  14.  
  15. require Carp;
  16. require Config;
  17. require AutoLoader;
  18.  
  19. @ISA=qw(AutoLoader);
  20.  
  21. $VERSION = $VERSION = "1.00" ;
  22.  
  23. sub import { }        # override import inherited from AutoLoader
  24.  
  25. # enable debug/trace messages from DynaLoader perl code
  26. $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  27.  
  28. ($dl_dlext, $dlsrc, $osname)
  29.     = @Config::Config{'dlext', 'dlsrc', 'osname'};
  30.  
  31. # Some systems need special handling to expand file specifications
  32. # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  33. # See dl_expandspec() for more details. Should be harmless but
  34. # inefficient to define on systems that don't need it.
  35. $do_expand = $Is_VMS = $osname eq 'VMS';
  36.  
  37. @dl_require_symbols = ();       # names of symbols we need
  38. @dl_resolve_using   = ();       # names of files to link with
  39. @dl_library_path    = ();       # path to look for files
  40.  
  41. # This is a fix to support DLD's unfortunate desire to relink -lc
  42. @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
  43.  
  44. # Initialise @dl_library_path with the 'standard' library path
  45. # for this platform as determined by Configure
  46. push(@dl_library_path, split(' ',$Config::Config{'libpth'}));
  47.  
  48. # Add to @dl_library_path any extra directories we can gather from
  49. # environment variables. So far LD_LIBRARY_PATH is the only known
  50. # variable used for this purpose. Others may be added later.
  51. push(@dl_library_path, split(/:/, $ENV{LD_LIBRARY_PATH}))
  52.     if $ENV{LD_LIBRARY_PATH};
  53.  
  54.  
  55. # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
  56. boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader);
  57.  
  58.  
  59. if ($dl_debug) {
  60.     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
  61.     print STDERR "DynaLoader not linked into this perl\n"
  62.         unless defined(&boot_DynaLoader);
  63. }
  64.  
  65. 1; # End of main code
  66.  
  67.  
  68. # The bootstrap function cannot be autoloaded (without complications)
  69. # so we define it here:
  70.  
  71. sub bootstrap {
  72.     # use local vars to enable $module.bs script to edit values
  73.     local(@args) = @_;
  74.     local($module) = $args[0];
  75.     local(@dirs, $file);
  76.  
  77.     Carp::confess("Usage: DynaLoader::bootstrap(module)") unless $module;
  78.  
  79.     # A common error on platforms which don't support dynamic loading.
  80.     # Since it's fatal and potentially confusing we give a detailed message.
  81.     Carp::croak("Can't load module $module, dynamic loading not available in this perl.\n".
  82.     "  (You may need to build a new perl executable which either supports\n".
  83.     "  dynamic loading or has the $module module statically linked into it.)\n")
  84.     unless defined(&dl_load_file);
  85.  
  86.     my @modparts = split(/::/,$module);
  87.     my $modfname = $modparts[-1];
  88.  
  89.     # Some systems have restrictions on files names for DLL's etc.
  90.     # mod2fname returns appropriate file base name (typically truncated)
  91.     # It may also edit @modparts if required.
  92.     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
  93.  
  94.     my $modpname = join('/',@modparts);
  95.  
  96.     print STDERR "DynaLoader::bootstrap for $module ",
  97.         "(auto/$modpname/$modfname.$dl_dlext)\n" if $dl_debug;
  98.  
  99.     foreach (@INC) {
  100.     chop($_ = VMS::Filespec::unixpath($_)) if $Is_VMS;
  101.     my $dir = "$_/auto/$modpname";
  102.     next unless -d $dir; # skip over uninteresting directories
  103.  
  104.     # check for common cases to avoid autoload of dl_findfile
  105.     last if ($file=_check_file("$dir/$modfname.$dl_dlext"));
  106.  
  107.     # no luck here, save dir for possible later dl_findfile search
  108.     push(@dirs, "-L$dir");
  109.     }
  110.     # last resort, let dl_findfile have a go in all known locations
  111.     $file = dl_findfile(@dirs, map("-L$_",@INC), $modfname) unless $file;
  112.  
  113.     Carp::croak("Can't find loadable object for module $module in \@INC (@INC)")
  114.     unless $file;
  115.  
  116.     my $bootname = "boot_$module";
  117.     $bootname =~ s/\W/_/g;
  118.     @dl_require_symbols = ($bootname);
  119.  
  120.     # Execute optional '.bootstrap' perl script for this module.
  121.     # The .bs file can be used to configure @dl_resolve_using etc to
  122.     # match the needs of the individual module on this architecture.
  123.     my $bs = $file;
  124.     $bs =~ s/(\.\w+)?$/\.bs/; # look for .bs 'beside' the library
  125.     if (-s $bs) { # only read file if it's not empty
  126.         print STDERR "BS: $bs ($osname, $dlsrc)\n" if $dl_debug;
  127.         eval { do $bs; };
  128.         warn "$bs: $@\n" if $@;
  129.     }
  130.  
  131.     # Many dynamic extension loading problems will appear to come from
  132.     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
  133.     # Often these errors are actually occurring in the initialisation
  134.     # C code of the extension XS file. Perl reports the error as being
  135.     # in this perl code simply because this was the last perl code
  136.     # it executed.
  137.  
  138.     my $libref = dl_load_file($file) or
  139.     Carp::croak("Can't load '$file' for module $module: ".dl_error()."\n");
  140.  
  141.     my @unresolved = dl_undef_symbols();
  142.     Carp::carp("Undefined symbols present after loading $file: @unresolved\n")
  143.         if @unresolved;
  144.  
  145.     my $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
  146.          Carp::croak("Can't find '$bootname' symbol in $file\n");
  147.  
  148.     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
  149.  
  150.     # See comment block above
  151.     &$xs(@args);
  152. }
  153.  
  154.  
  155. sub _check_file {   # private utility to handle dl_expandspec vs -f tests
  156.     my($file) = @_;
  157.     return $file if (!$do_expand && -f $file); # the common case
  158.     return $file if ( $do_expand && ($file=dl_expandspec($file)));
  159.     return undef;
  160. }
  161.  
  162.  
  163. # Let autosplit and the autoloader deal with these functions:
  164. __END__
  165.  
  166.  
  167. sub dl_findfile {
  168.     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
  169.     # This function does not automatically consider the architecture
  170.     # or the perl library auto directories.
  171.     my (@args) = @_;
  172.     my (@dirs,  $dir);   # which directories to search
  173.     my (@found);         # full paths to real files we have found
  174.     my $dl_so = $Config::Config{'so'};    # suffix for shared libraries
  175.  
  176.     print STDERR "dl_findfile(@args)\n" if $dl_debug;
  177.  
  178.     # accumulate directories but process files as they appear
  179.     arg: foreach(@args) {
  180.         #  Special fast case: full filepath requires no search
  181.         if ($Is_VMS && m%[:>/\]]% && -f $_) {
  182.         push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
  183.         last arg unless wantarray;
  184.         next;
  185.         }
  186.         elsif (m:/: && -f $_ && !$do_expand) {
  187.         push(@found,$_);
  188.         last arg unless wantarray;
  189.         next;
  190.     }
  191.  
  192.         # Deal with directories first:
  193.         #  Using a -L prefix is the preferred option (faster and more robust)
  194.         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
  195.  
  196.         #  Otherwise we try to try to spot directories by a heuristic
  197.         #  (this is a more complicated issue than it first appears)
  198.         if (m:/: && -d $_) {   push(@dirs, $_); next; }
  199.  
  200.         # VMS: we may be using native VMS directry syntax instead of
  201.         # Unix emulation, so check this as well
  202.         if ($Is_VMS && /[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
  203.  
  204.         #  Only files should get this far...
  205.         my(@names, $name);    # what filenames to look for
  206.         if (m:-l: ) {          # convert -lname to appropriate library name
  207.             s/-l//;
  208.             push(@names,"lib$_.$dl_so");
  209.             push(@names,"lib$_.a");
  210.         } else {                # Umm, a bare name. Try various alternatives:
  211.             # these should be ordered with the most likely first
  212.             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
  213.             push(@names,"lib$_.$dl_so")  unless m:/:;
  214.             push(@names,"$_.o")          unless m/\.(o|$dl_so)$/o;
  215.             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
  216.             push(@names, $_);
  217.         }
  218.         foreach $dir (@dirs, @dl_library_path) {
  219.             next unless -d $dir;
  220.             chop($dir = VMS::Filespec::unixpath($dir)) if $Is_VMS;
  221.             foreach $name (@names) {
  222.         my($file) = "$dir/$name";
  223.                 print STDERR " checking in $dir for $name\n" if $dl_debug;
  224.         $file = _check_file($file);
  225.         if ($file) {
  226.                     push(@found, $file);
  227.                     next arg; # no need to look any further
  228.                 }
  229.             }
  230.         }
  231.     }
  232.     if ($dl_debug) {
  233.         foreach(@dirs) {
  234.             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
  235.         }
  236.         print STDERR "dl_findfile found: @found\n";
  237.     }
  238.     return $found[0] unless wantarray;
  239.     @found;
  240. }
  241.  
  242.  
  243. sub dl_expandspec {
  244.     my($spec) = @_;
  245.     # Optional function invoked if DynaLoader.pm sets $do_expand.
  246.     # Most systems do not require or use this function.
  247.     # Some systems may implement it in the dl_*.xs file in which case
  248.     # this autoload version will not be called but is harmless.
  249.  
  250.     # This function is designed to deal with systems which treat some
  251.     # 'filenames' in a special way. For example VMS 'Logical Names'
  252.     # (something like unix environment variables - but different).
  253.     # This function should recognise such names and expand them into
  254.     # full file paths.
  255.     # Must return undef if $spec is invalid or file does not exist.
  256.  
  257.     my $file = $spec; # default output to input
  258.  
  259.     if ($osname eq 'VMS') { # dl_expandspec should be defined in dl_vms.xs
  260.     Carp::croak("dl_expandspec: should be defined in XS file!\n");
  261.     } else {
  262.     return undef unless -f $file;
  263.     }
  264.     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
  265.     $file;
  266. }
  267.  
  268.  
  269. =head1 NAME
  270.  
  271. DynaLoader - Dynamically load C libraries into Perl code
  272.  
  273. dl_error(), dl_findfile(), dl_expandspec(), dl_load_file(), dl_find_symbol(), dl_undef_symbols(), dl_install_xsub(), boostrap() - routines used by DynaLoader modules
  274.  
  275. =head1 SYNOPSIS
  276.  
  277.     package YourPackage;
  278.     require DynaLoader;
  279.     @ISA = qw(... DynaLoader ...);
  280.     bootstrap YourPackage;
  281.  
  282.  
  283. =head1 DESCRIPTION
  284.  
  285. This document defines a standard generic interface to the dynamic
  286. linking mechanisms available on many platforms.  Its primary purpose is
  287. to implement automatic dynamic loading of Perl modules.
  288.  
  289. This document serves as both a specification for anyone wishing to
  290. implement the DynaLoader for a new platform and as a guide for
  291. anyone wishing to use the DynaLoader directly in an application.
  292.  
  293. The DynaLoader is designed to be a very simple high-level
  294. interface that is sufficiently general to cover the requirements
  295. of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
  296.  
  297. It is also hoped that the interface will cover the needs of OS/2, NT
  298. etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
  299.  
  300. It must be stressed that the DynaLoader, by itself, is practically
  301. useless for accessing non-Perl libraries because it provides almost no
  302. Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
  303. library function or supplying arguments.  It is anticipated that any
  304. glue that may be developed in the future will be implemented in a
  305. separate dynamically loaded module.
  306.  
  307. DynaLoader Interface Summary
  308.  
  309.   @dl_library_path
  310.   @dl_resolve_using
  311.   @dl_require_symbols
  312.   $dl_debug
  313.                                                   Implemented in:
  314.   bootstrap($modulename)                               Perl
  315.   @filepaths = dl_findfile(@names)                     Perl
  316.  
  317.   $libref  = dl_load_file($filename)                   C
  318.   $symref  = dl_find_symbol($libref, $symbol)          C
  319.   @symbols = dl_undef_symbols()                        C
  320.   dl_install_xsub($name, $symref [, $filename])        C
  321.   $message = dl_error                                  C
  322.  
  323. =over 4
  324.  
  325. =item @dl_library_path
  326.  
  327. The standard/default list of directories in which dl_findfile() will
  328. search for libraries etc.  Directories are searched in order:
  329. $dl_library_path[0], [1], ... etc
  330.  
  331. @dl_library_path is initialised to hold the list of 'normal' directories
  332. (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
  333. ensure portability across a wide range of platforms.
  334.  
  335. @dl_library_path should also be initialised with any other directories
  336. that can be determined from the environment at runtime (such as
  337. LD_LIBRARY_PATH for SunOS).
  338.  
  339. After initialisation @dl_library_path can be manipulated by an
  340. application using push and unshift before calling dl_findfile().
  341. Unshift can be used to add directories to the front of the search order
  342. either to save search time or to override libraries with the same name
  343. in the 'normal' directories.
  344.  
  345. The load function that dl_load_file() calls may require an absolute
  346. pathname.  The dl_findfile() function and @dl_library_path can be
  347. used to search for and return the absolute pathname for the
  348. library/object that you wish to load.
  349.  
  350. =item @dl_resolve_using
  351.  
  352. A list of additional libraries or other shared objects which can be
  353. used to resolve any undefined symbols that might be generated by a
  354. later call to load_file().
  355.  
  356. This is only required on some platforms which do not handle dependent
  357. libraries automatically.  For example the Socket Perl extension library
  358. (F<auto/Socket/Socket.so>) contains references to many socket functions
  359. which need to be resolved when it's loaded.  Most platforms will
  360. automatically know where to find the 'dependent' library (e.g.,
  361. F</usr/lib/libsocket.so>).  A few platforms need to to be told the location
  362. of the dependent library explicitly.  Use @dl_resolve_using for this.
  363.  
  364. Example usage:
  365.  
  366.     @dl_resolve_using = dl_findfile('-lsocket');
  367.  
  368. =item @dl_require_symbols
  369.  
  370. A list of one or more symbol names that are in the library/object file
  371. to be dynamically loaded.  This is only required on some platforms.
  372.  
  373. =item dl_error()
  374.  
  375. Syntax:
  376.  
  377.     $message = dl_error();
  378.  
  379. Error message text from the last failed DynaLoader function.  Note
  380. that, similar to errno in unix, a successful function call does not
  381. reset this message.
  382.  
  383. Implementations should detect the error as soon as it occurs in any of
  384. the other functions and save the corresponding message for later
  385. retrieval.  This will avoid problems on some platforms (such as SunOS)
  386. where the error message is very temporary (e.g., dlerror()).
  387.  
  388. =item $dl_debug
  389.  
  390. Internal debugging messages are enabled when $dl_debug is set true.
  391. Currently setting $dl_debug only affects the Perl side of the
  392. DynaLoader.  These messages should help an application developer to
  393. resolve any DynaLoader usage problems.
  394.  
  395. $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
  396.  
  397. For the DynaLoader developer/porter there is a similar debugging
  398. variable added to the C code (see dlutils.c) and enabled if Perl was
  399. built with the B<-DDEBUGGING> flag.  This can also be set via the
  400. PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
  401. higher for more.
  402.  
  403. =item dl_findfile()
  404.  
  405. Syntax:
  406.  
  407.     @filepaths = dl_findfile(@names)
  408.  
  409. Determine the full paths (including file suffix) of one or more
  410. loadable files given their generic names and optionally one or more
  411. directories.  Searches directories in @dl_library_path by default and
  412. returns an empty list if no files were found.
  413.  
  414. Names can be specified in a variety of platform independent forms.  Any
  415. names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
  416. an appropriate suffix for the platform.
  417.  
  418. If a name does not already have a suitable prefix and/or suffix then
  419. the corresponding file will be searched for by trying combinations of
  420. prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
  421. and "$name".
  422.  
  423. If any directories are included in @names they are searched before
  424. @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
  425. names are treated as filenames to be searched for.
  426.  
  427. Using arguments of the form C<-Ldir> and C<-lname> is recommended.
  428.  
  429. Example: 
  430.  
  431.     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
  432.  
  433.  
  434. =item dl_expandspec()
  435.  
  436. Syntax:
  437.  
  438.     $filepath = dl_expandspec($spec)
  439.  
  440. Some unusual systems, such as VMS, require special filename handling in
  441. order to deal with symbolic names for files (i.e., VMS's Logical Names).
  442.  
  443. To support these systems a dl_expandspec() function can be implemented
  444. either in the F<dl_*.xs> file or code can be added to the autoloadable
  445. dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
  446. more information.
  447.  
  448. =item dl_load_file()
  449.  
  450. Syntax:
  451.  
  452.     $libref = dl_load_file($filename)
  453.  
  454. Dynamically load $filename, which must be the path to a shared object
  455. or library.  An opaque 'library reference' is returned as a handle for
  456. the loaded object.  Returns undef on error.
  457.  
  458. (On systems that provide a handle for the loaded object such as SunOS
  459. and HPUX, $libref will be that handle.  On other systems $libref will
  460. typically be $filename or a pointer to a buffer containing $filename.
  461. The application should not examine or alter $libref in any way.)
  462.  
  463. This is function that does the real work.  It should use the current
  464. values of @dl_require_symbols and @dl_resolve_using if required.
  465.  
  466.     SunOS: dlopen($filename)
  467.     HP-UX: shl_load($filename)
  468.     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
  469.     NeXT:  rld_load($filename, @dl_resolve_using)
  470.     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
  471.     OS/2:  DosLoadModule(,,$filename,)
  472.  
  473.  
  474. =item dl_find_symbol()
  475.  
  476. Syntax:
  477.  
  478.     $symref = dl_find_symbol($libref, $symbol)
  479.  
  480. Return the address of the symbol $symbol or C<undef> if not found.  If the
  481. target system has separate functions to search for symbols of different
  482. types then dl_find_symbol() should search for function symbols first and
  483. then other types.
  484.  
  485. The exact manner in which the address is returned in $symref is not
  486. currently defined.  The only initial requirement is that $symref can
  487. be passed to, and understood by, dl_install_xsub().
  488.  
  489.     SunOS: dlsym($libref, $symbol)
  490.     HP-UX: shl_findsym($libref, $symbol)
  491.     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
  492.     NeXT:  rld_lookup("_$symbol")
  493.     VMS:   lib$find_image_symbol($libref,$symbol)
  494.     OS/2:  DosQueryProcAddr($libref,0,$symbol,)
  495.  
  496.  
  497. =item dl_undef_symbols()
  498.  
  499. Example
  500.  
  501.     @symbols = dl_undef_symbols()
  502.  
  503. Return a list of symbol names which remain undefined after load_file().
  504. Returns C<()> if not known.  Don't worry if your platform does not provide
  505. a mechanism for this.  Most do not need it and hence do not provide it,
  506. they just return an empty list.
  507.  
  508.  
  509. =item dl_install_xsub()
  510.  
  511. Syntax:
  512.  
  513.     dl_install_xsub($perl_name, $symref [, $filename])
  514.  
  515. Create a new Perl external subroutine named $perl_name using $symref as
  516. a pointer to the function which implements the routine.  This is simply
  517. a direct call to newXSUB().  Returns a reference to the installed
  518. function.
  519.  
  520. The $filename parameter is used by Perl to identify the source file for
  521. the function if required by die(), caller() or the debugger.  If
  522. $filename is not defined then "DynaLoader" will be used.
  523.  
  524.  
  525. =item boostrap()
  526.  
  527. Syntax:
  528.  
  529. bootstrap($module)
  530.  
  531. This is the normal entry point for automatic dynamic loading in Perl.
  532.  
  533. It performs the following actions:
  534.  
  535. =over 8
  536.  
  537. =item *
  538.  
  539. locates an auto/$module directory by searching @INC
  540.  
  541. =item *
  542.  
  543. uses dl_findfile() to determine the filename to load
  544.  
  545. =item *
  546.  
  547. sets @dl_require_symbols to C<("boot_$module")>
  548.  
  549. =item *
  550.  
  551. executes an F<auto/$module/$module.bs> file if it exists
  552. (typically used to add to @dl_resolve_using any files which
  553. are required to load the module on the current platform)
  554.  
  555. =item *
  556.  
  557. calls dl_load_file() to load the file
  558.  
  559. =item *
  560.  
  561. calls dl_undef_symbols() and warns if any symbols are undefined
  562.  
  563. =item *
  564.  
  565. calls dl_find_symbol() for "boot_$module"
  566.  
  567. =item *
  568.  
  569. calls dl_install_xsub() to install it as "${module}::bootstrap"
  570.  
  571. =item *
  572.  
  573. calls &{"${module}::bootstrap"} to bootstrap the module (actually
  574. it uses the function reference returned by dl_install_xsub for speed)
  575.  
  576. =back
  577.  
  578. =back
  579.  
  580.  
  581. =head1 AUTHOR
  582.  
  583. Tim Bunce, 11 August 1994.
  584.  
  585. This interface is based on the work and comments of (in no particular
  586. order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
  587. Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
  588.  
  589. Larry Wall designed the elegant inherited bootstrap mechanism and
  590. implemented the first Perl 5 dynamic loader using it.
  591.  
  592. =cut
  593.