home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / netdor3.zip / VNDINST / FRNTENDS / WPWIN51 / PACKINST.CMD next >
OS/2 REXX Batch file  |  1996-04-04  |  6KB  |  153 lines
  1. /**********************************************************************
  2. Description:    WordPerfect for Windows 5.1 Installation exec
  3.  
  4. Details:        This exec creates a local directory where work
  5.                 files can be saved.  It adds this information to
  6.                 OS2.INI.  It copies DDEML.DLL to the user's 
  7.                 \OS2\MDOS\WINOS2\SYSTEM subdirectory.  This file
  8.                 is required for WP to run.  When WP is installed
  9.                 on the server the \OS2... directory is created there.
  10.                 The file should then be copied to the \WPWIN51
  11.                 directory on the server.
  12.  
  13. Dependencies:
  14.    Externals:   RXUTILS.DLL - Part of VENDOR package.
  15.    Drive(s):    None
  16.    Directories: \WPWIN51-----+--\WPWIN\--+--WPWIN.EXE
  17.                              |           +--WPWP_NET.INI
  18.                              |           +--WP{WP}.SET
  19.                              |           +--WP{WP}.ENV
  20.                              |
  21.                              +--\WPC\----+--SPWIN.EXE
  22.                              |           +--THWIN.EXE
  23.                              |           +--FMWIN.EXE
  24.                              |           +--MCWIN.EXE
  25.                              |           +--MXWIN.EXE
  26.                              |           +--MFWIN.EXE
  27.                              |           +--FM{FM}.ENV
  28.                              |           +--SP{SP}.ENV
  29.                              |           +--TH{TH}.ENV
  30.                              |           +--WPC_NET.INI
  31.                              |           +--WPFM_NET.INI
  32.                              |           +--WPMF_NET.INI
  33.                              |           +--WPMC_NET.INI
  34.                              |           +--WPMX_NET.INI
  35.                              |           +--WPSP_NET.INI
  36.                              |           +--WPTH_NET.INI
  37.                              |
  38.                              +--\WPCINI\ (not used, old INI files)
  39.                                    (moved to \WPC for network use)
  40.                                         (see README.NET on Disk 1)
  41.  
  42.    Window Type: FS/Win
  43.    App Title:   WordPerfect for Windows
  44.  
  45. Last Updated:   10/1/92
  46. **********************************************************************/
  47.  trace 'O'
  48.  '@echo off'
  49.  
  50. call RxFuncAdd 'RXDIREXIST',  'RXUTILS', 'RXDIREXIST'
  51. call RxFuncAdd 'RXPAUSE',     'RXUTILS', 'RXPAUSE'
  52. call RxFuncAdd 'RXMKDIR',     'RXUTILS', 'RXMKDIR'
  53. call RxFuncAdd 'RXOS2INI',    'RXUTILS', 'RXOS2INI'
  54. call RxFuncAdd 'RXBOOTDRIVE', 'RXUTILS', 'RXBOOTDRIVE'
  55. call RxFuncAdd 'RXDRIVEMAP',  'RXUTILS', 'RXDRIVEMAP'
  56. call RxFuncAdd 'RXDRIVEINFO', 'RXUTILS', 'RXDRIVEINFO'
  57. call RxFuncAdd 'RXOS2VER',    'RXUTILS', 'RXOS2VER'
  58.  
  59. /* Give header */
  60. say
  61. say ' WordPerfect for Windows 5.1 Installation exec'
  62. say ' ---------------------------------------------'
  63. say
  64.  
  65. parse source . . exec
  66. path=left(exec, lastpos('\', exec))
  67. drive=left(path,2)
  68. bdr=RxBootDrive()
  69.  
  70. /*****************************************/
  71. /** Determine if OS/2 2.0 is being used **/
  72. /*****************************************/
  73.  
  74. if (RxOS2Ver() < 2.0) then do
  75.   say
  76.   say d2c(7)|| 'Error!'
  77.   say 'You must be using OS/2 2.0 or later in order to'
  78.   say 'run WordPerfect for Windows.  Windows programs'
  79.   say 'cannot be run on versions of OS/2 less than 2.0'
  80.   say
  81.   call RxPause 'Press any key to exit'
  82.   'exit 10'
  83. end /* do */
  84.  
  85. /***********************************************/
  86. /** Check if a Local.Directory already exists **/
  87. /***********************************************/
  88.  
  89. Local.Directory = RxOS2Ini(, 'Directories', 'WPWin')
  90. if RxDirExist(Local.Directory)=1 then do
  91.    say ' Current WordPerfect for Windows local directory = 'Local.Directory
  92.    say
  93. end  /* if RxDirExist... */
  94.  
  95. /***************************************************************/
  96. /** Get the valid local drives, remove the VDISK, prompt user **/
  97. /***************************************************************/
  98.  
  99. DrvMap = RxDriveMap('C:', 'LOCAL' )
  100. parse upper value RxDriveInfo( right(DrvMap,2)) with . 'LABEL='label .
  101. if pos('VDISK', label)<>0 then DrvMap=left(DrvMap, length(DrvMap)-3)
  102.  
  103. /****************************************************************/
  104. /** Prompt user for Local Directory.  Do until a valid local   **/
  105. /** drive is used.  Create the directory and add it to OS2.INI **/
  106. /****************************************************************/
  107.  
  108. say
  109. say ' Enter a local directory for your WordPerfect for Windows'
  110. say ' work files; i.e. D:\WPWIN'
  111. say ' Valid local Drives:' DrvMap
  112. say
  113.  
  114. OK=0
  115. do until OK=1
  116.    Local.Directory = translate( LINEIN('STDIN') )
  117.    if POS( left(Local.Directory,2), DrvMap) <> 0 then
  118.       OK=1
  119.    else do
  120.       say
  121.       say d2c(7)||' Cannot create directory.  Try again...'
  122.       say
  123.       OK=0
  124.    end /* do */
  125.    if OK=1 then do
  126.       if Local.Directory<>'' then do
  127.          call RxMkDir Local.Directory
  128.          if RxDirExist(Local.Directory) then
  129.             call RxOS2Ini , 'Directories', 'WPWin', Local.Directory
  130.          if RxDirExist(Local.Directory)=0 then do
  131.             OK=0
  132.             say
  133.             say d2c(7)||' Cannot create directory.  Try again...'
  134.             say
  135.          end  /* do */
  136.       end /* do */
  137.    end /* do */
  138. end /* do until */
  139.  
  140. /**************************************************/
  141. /** copy DLL file to user's Window's directory,  **/
  142. /** required for WordPerfect for Windows to run. **/
  143. /**************************************************/
  144.  
  145. 'copy DDEML.DLL 'bdr'\OS2\MDOS\WINOS2\SYSTEM >NUL'
  146.  
  147. say
  148. say ' WordPerfect for Windows is now ready to run.'
  149. say ' A reboot is not required'
  150. say
  151. call RxPause
  152. 'exit 0'
  153.