home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
OS/2 Shareware BBS: 10 Tools
/
10-Tools.zip
/
lzo100.zip
/
lzo-1.00
/
configure.in
< prev
next >
Wrap
Text File
|
1997-07-13
|
7KB
|
237 lines
dnl Process this file with autoconf to produce a configure script.
#
# configure.in -- autoconf configuration for the LZO library
#
# This file is part of the LZO real-time data compression library.
#
# Copyright (C) 1997 Markus Franz Xaver Johannes Oberhumer
# Copyright (C) 1996 Markus Franz Xaver Johannes Oberhumer
#
# The LZO library is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License as
# published by the Free Software Foundation; either version 2 of
# the License, or (at your option) any later version.
#
# The LZO library is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with the LZO library; see the file COPYING.
# If not, write to the Free Software Foundation, Inc.,
# 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
#
# Markus F.X.J. Oberhumer
# markus.oberhumer@jk.uni-linz.ac.at
#
# /***********************************************************************
# // Initialization
# ************************************************************************/
AC_INIT(src/lzo_util.c)
AC_PREREQ(2.12)
AC_CONFIG_AUX_DIR(acconfig)
AC_PREFIX_DEFAULT(/usr/local)
AM_INIT_AUTOMAKE(lzo,1.00)
AM_CONFIG_HEADER(config.h:config.hin)
AC_CANONICAL_HOST
AM_MAINTAINER_MODE
AM_CONDITIONAL(MAINTAINER, test x$USE_MAINTAINER_MODE = xyes)
# /***********************************************************************
# //
# ************************************************************************/
dnl CC=""
dnl LIBS=""
dnl CFLAGS=""
dnl ASFLAGS=""
CFLAGS="$CFLAGS -DLZO_HAVE_CONFIG_H"
CFLAGS_O=""
CFLAGS_W=""
AC_SUBST(CFLAGS_O)dnl
AC_SUBST(CFLAGS_W)dnl
ASFLAGS="$ASFLAGS -DLZO_HAVE_CONFIG_H"
AC_SUBST(ASFLAGS)dnl
# /***********************************************************************
# // Checks for compiler
# ************************************************************************/
AC_PROG_CC
AC_PROG_CPP
AM_PROG_CC_STDC
AC_PROG_CC_C_O
mfx_PROG_GCC_PIPE
AM_PROG_LIBTOOL
# /***********************************************************************
# // Checks for other programs
# ************************************************************************/
AM_PROG_INSTALL
AC_CHECK_PROG(RM,rm,rm -f)
## AC_CHECK_PROG(CAT,cat,cat)
## AC_CHECK_PROG(CHMOD,chmod,chmod)
## AC_CHECK_PROG(FIND,find,find)
## AC_CHECK_PROG(PERL,perl,perl)
## AC_CHECK_PROG(SORT,sort,sort)
# /***********************************************************************
# // Checks for libraries
# ************************************************************************/
save_LIBS="$LIBS"
AC_CHECK_LIB(z,zlibVersion)
lzo_test_LIBS="$LIBS"
LIBS="$save_LIBS"
AC_SUBST(lzo_test_LIBS)dnl
# /***********************************************************************
# // Checks for system header files
# ************************************************************************/
AC_HEADER_STDC
AC_HEADER_TIME
AC_CHECK_HEADERS(assert.h ctype.h limits.h stddef.h time.h unistd.h)
AC_CHECK_HEADERS(memory.h sys/param.h sys/resource.h sys/time.h sys/times.h)
AC_CHECK_HEADERS(endian.h sys/endian.h unchecked.h)
# /***********************************************************************
# // Checks for library header files
# ************************************************************************/
AC_CHECK_HEADERS(zlib.h)
# /***********************************************************************
# // Checks for typedefs and structures
# ************************************************************************/
AC_CHECK_TYPE(ptrdiff_t,long)
AC_TYPE_SIZE_T
dnl no support for cross-compiling
AC_CHECK_SIZEOF(unsigned short)
AC_CHECK_SIZEOF(unsigned)
AC_CHECK_SIZEOF(unsigned long)
AC_CHECK_SIZEOF(char *)
mfx_CHECK_SIZEOF(ptrdiff_t)
mfx_CHECK_SIZEOF(size_t)
# /***********************************************************************
# // Checks for compiler characteristics
# ************************************************************************/
AC_C_CONST
dnl no support for cross-compiling
mfx_C_BYTE_ORDER
mfx_ASM_ALIGN
mfx_PROG_CC_BUG_SIGNED_TO_UNSIGNED_CASTING
mfx_PROG_GCC_BUG_SCHEDULE_INSNS
mfx_PROG_GCC_BUG_STRENGTH_REDUCE
# /***********************************************************************
# // Checks for library functions
# ************************************************************************/
AC_CHECK_FUNCS(memcmp memcpy memmove memset)
AC_CHECK_FUNCS(getrusage gettimeofday times)
mfx_FUNC_MEMCMP
# /***********************************************************************
# // Checks for system services
# ************************************************************************/
# /***********************************************************************
# // Customize some macros
# ************************************************************************/
MFX_C_CONST_BROKEN="no"
if test $ac_cv_c_const = no ; then
MFX_C_CONST_BROKEN="yes"
fi
AC_SUBST(MFX_C_CONST_BROKEN)dnl
# /***********************************************************************
# // Compiler and architecture specific stuff
# ************************************************************************/
M_CC="unknown"
AC_SUBST(M_CC)dnl
M_ARCH="unknown"
AC_SUBST(M_ARCH)dnl
M_CPU=`echo "$host_cpu" | sed 's/[-+._]//g'`
AC_SUBST(M_CPU)dnl
M_VPATH=""
AC_SUBST(M_VPATH)dnl
if test "$GCC" = "yes" ; then :
M_CC="GCC"
CFLAGS_O="-O2"
CFLAGS_W="-Wall -Wcast-align -Wwrite-strings"
case $host in
changequote(<<, >>)dnl
i[3456]86-*)
changequote([, ])dnl
M_ARCH="i386"
M_VPATH="/${M_ARCH}/src"
AC_DEFINE(LZO_UNALIGNED_OK_2)
AC_DEFINE(LZO_UNALIGNED_OK_4)
CFLAGS_O="$CFLAGS_O -fno-strength-reduce"
;;
*)
if test "$MFX_PROG_GCC_BUG_STRENGTH_REDUCE" = "yes" ; then :
CFLAGS_O="$CFLAGS_O -fno-strength-reduce"
fi
;;
esac
if test "$MFX_PROG_GCC_BUG_SCHEDULE_INSNS" = "yes" ; then :
CFLAGS_O="$CFLAGS_O -fno-schedule-insns -fno-schedule-insns2"
fi
else
CFLAGS_O="-O"
CFLAGS_W=""
fi
AC_DEFINE_UNQUOTED(MFX_ARCH,"$M_ARCH")
AC_DEFINE_UNQUOTED(MFX_CPU,"$host_cpu")
LZO_ASM_OBJECTS="\$(LZO_ASM_OBJECTS_${M_CC}_${M_ARCH})"
AC_SUBST(LZO_ASM_OBJECTS)dnl
dnl never activate this by default
if test "1" = "2" ; then
AC_DEFINE(LZO_ALIGNED_OK_4)
fi
# /***********************************************************************
# // Write output files
# ************************************************************************/
AC_OUTPUT(Makefile examples/Makefile include/Makefile minilzo/Makefile src/Makefile tests/Makefile)