OS/2 Shareware BBS: 10 Tools/10-Tools.zip/fchek284.zip/build.com

Text File | 1994-12-16 | 2KB | 53 lines

$! BUILD.COM
$!    Creates Ftnchek from source code for VMS systems
$!    This script uses CC.COM and LINK.COM to check whether target
$!    is up to date, giving effect of a crude make utility.
$!
$ On Control_Y Then GoTo The_Exit
$ On Error Then GoTo The_Exit
$! DISABLED at ftnchek 2.8: On Warning Then GoTo The_Exit
$!
$!    First, create the right environment for compilation.
$ IF F$SEARCH("vaxc.opt") .EQS. ""
$ THEN!    Create option file for shareable image: makes executable smaller
$ COPY SYS$INPUT vaxc.opt
sys$library:vaxcrtl/share
$ ENDIF
$ DEFINE lnk$library sys$library:vaxcrtl    ! simplest runtime library
$!
$!   Now compile everything and link it all.  The /DEFINE is not actually
$!   needed since VMS is a predefined symbol in VAX C.
$!   If you have xmalloc/xrealloc, remove the /DEFINE from shell_mung
$!   line and add them to the list of objs to link.
$!   The CC.COM script is used in place of CC command so that if something
$!   is changed, BUILD can be re-run and only re-compiles what changed.
$!   Invocation: @CC PROG DEPENDENCIES [/CFLAGS...]
$ @CC ftnchek ftnchek.h /DEFINE=(VMS,LARGE_MACHINE)
$ @CC exprtype ftnchek.h,keywords.h,symtab.h,tokdefs.h /DEFINE=(VMS,LARGE_MACHINE)
$ @CC forlex ftnchek.h,symtab.h,tokdefs.h /DEFINE=(VMS,LARGE_MACHINE)
$ @CC fortran ftnchek.h,symtab.h,tokdefs.h /DEFINE=(VMS,LARGE_MACHINE)
$ @CC pgsymtab ftnchek.h,symtab.h /DEFINE=(VMS,LARGE_MACHINE)
$ @CC plsymtab ftnchek.h,symtab.h /DEFINE=(VMS,LARGE_MACHINE)
$ @CC project ftnchek.h,symtab.h /DEFINE=(VMS,LARGE_MACHINE)
$ @CC symtab ftnchek.h,iokeywds.h,intrins.h,symtab.h,tokdefs.h /DEFINE=(VMS,LARGE_MACHINE)
$ @CC shell_mung "" /DEFINE=("xmalloc=malloc","xrealloc=realloc")
$ @LINK ftnchek,forlex,fortran,pgsymtab,plsymtab,symtab,exprtype,project,-
shell_mung
$ WRITE SYS$OUTPUT "Ftnchek created"
$ WRITE SYS$OUTPUT "To make it runnable as a command"
$ WRITE SYS$OUTPUT "say   $ FTNCHEK :== $diskname:[pathname]FTNCHEK"
$ On Control_Y Then GoTo Help_Exit
$ On Warning Then GoTo Help_Exit
$! Create the help library.
$ LIBR/CREATE/HELP FTNCHEK.HLB FTNCHEK.HLP
$ WRITE SYS$OUTPUT "Help library created -- to access it via HELP"
$ WRITE SYS$OUTPUT "say   $ DEFINE HLP$LIBRARY diskname:[pathname]FTNCHEK.HLB"
$ EXIT
$ Help_Exit:
$ Set NoVerify
$ WRITE SYS$OUTPUT "Error- help library not created"
$ EXIT
$ The_Exit:
$ Set NoVerify
$ WRITE SYS$OUTPUT "Error- BUILD failed."