home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / adav313.zip / gnat-3_13p-os2-bin-20010916.zip / emx / gnatlib / s-imgllw.adb < prev    next >
Text File  |  2000-07-19  |  5KB  |  141 lines
  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT RUNTIME COMPONENTS                          --
  4. --                                                                          --
  5. --                       S Y S T E M . I M G _ L L W                        --
  6. --                                                                          --
  7. --                                 B o d y                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.4 $                              --
  10. --                                                                          --
  11. --     Copyright (C) 1992,1993,1994,1995 Free Software Foundation, Inc.     --
  12. --                                                                          --
  13. -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14. -- terms of the  GNU General Public License as published  by the Free Soft- --
  15. -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16. -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17. -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18. -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19. -- for  more details.  You should have  received  a copy of the GNU General --
  20. -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21. -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22. -- MA 02111-1307, USA.                                                      --
  23. --                                                                          --
  24. -- As a special exception,  if other files  instantiate  generics from this --
  25. -- unit, or you link  this unit with other files  to produce an executable, --
  26. -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27. -- covered  by the  GNU  General  Public  License.  This exception does not --
  28. -- however invalidate  any other reasons why  the executable file  might be --
  29. -- covered by the  GNU Public License.                                      --
  30. --                                                                          --
  31. -- GNAT was originally developed  by the GNAT team at  New York University. --
  32. -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  33. --                                                                          --
  34. ------------------------------------------------------------------------------
  35.  
  36. with System.Unsigned_Types; use System.Unsigned_Types;
  37.  
  38. package body System.Img_LLW is
  39.  
  40.    ---------------------------------------
  41.    -- Set_Image_Width_Long_Long_Integer --
  42.    ---------------------------------------
  43.  
  44.    procedure Set_Image_Width_Long_Long_Integer
  45.      (V : Long_Long_Integer;
  46.       W : Integer;
  47.       S : out String;
  48.       P : in out Natural)
  49.    is
  50.       Start : Natural;
  51.  
  52.    begin
  53.       --  Positive case can just use the unsigned circuit directly
  54.  
  55.       if V >= 0 then
  56.          Set_Image_Width_Long_Long_Unsigned
  57.            (Long_Long_Unsigned (V), W, S, P);
  58.  
  59.       --  Negative case has to set a minus sign. Note also that we have to be
  60.       --  careful not to generate overflow with the largest negative number.
  61.  
  62.       else
  63.          P := P + 1;
  64.          S (P) := ' ';
  65.          Start := P;
  66.  
  67.          declare
  68.             pragma Suppress (Overflow_Check);
  69.             pragma Suppress (Range_Check);
  70.          begin
  71.             Set_Image_Width_Long_Long_Unsigned
  72.               (Long_Long_Unsigned (-V), W - 1, S, P);
  73.          end;
  74.  
  75.          --  Set minus sign in last leading blank location. Because of the
  76.          --  code above, there must be at least one such location.
  77.  
  78.          while S (Start + 1) = ' ' loop
  79.             Start := Start + 1;
  80.          end loop;
  81.  
  82.          S (Start) := '-';
  83.       end if;
  84.  
  85.    end Set_Image_Width_Long_Long_Integer;
  86.  
  87.    ----------------------------------------
  88.    -- Set_Image_Width_Long_Long_Unsigned --
  89.    ----------------------------------------
  90.  
  91.    procedure Set_Image_Width_Long_Long_Unsigned
  92.      (V : Long_Long_Unsigned;
  93.       W : Integer;
  94.       S : out String;
  95.       P : in out Natural)
  96.    is
  97.       Start : constant Natural := P;
  98.       F, T  : Natural;
  99.  
  100.       procedure Set_Digits (T : Long_Long_Unsigned);
  101.       --  Set digits of absolute value of T
  102.  
  103.       procedure Set_Digits (T : Long_Long_Unsigned) is
  104.       begin
  105.          if T >= 10 then
  106.             Set_Digits (T / 10);
  107.             P := P + 1;
  108.             S (P) := Character'Val (T mod 10 + Character'Pos ('0'));
  109.          else
  110.             P := P + 1;
  111.             S (P) := Character'Val (T + Character'Pos ('0'));
  112.          end if;
  113.       end Set_Digits;
  114.  
  115.    --  Start of processing for Set_Image_Width_Long_Long_Unsigned
  116.  
  117.    begin
  118.       Set_Digits (V);
  119.  
  120.       --  Add leading spaces if required by width parameter
  121.  
  122.       if P - Start < W then
  123.          F := P;
  124.          P := P + (W - (P - Start));
  125.          T := P;
  126.  
  127.          while F > Start loop
  128.             S (T) := S (F);
  129.             T := T - 1;
  130.             F := F - 1;
  131.          end loop;
  132.  
  133.          for J in Start + 1 .. T loop
  134.             S (J) := ' ';
  135.          end loop;
  136.       end if;
  137.  
  138.    end Set_Image_Width_Long_Long_Unsigned;
  139.  
  140. end System.Img_LLW;
  141.