home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / adav313.zip / gnat-3_13p-os2-bin-20010916.zip / emx / gnatlib / g-hesorg.adb < prev    next >
Text File  |  2000-07-19  |  6KB  |  136 lines
  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT RUNTIME COMPONENTS                          --
  4. --                                                                          --
  5. --                     G N A T . H E A P _ S O R T _ G                      --
  6. --                                                                          --
  7. --                                 B o d y                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.6 $                              --
  10. --                                                                          --
  11. --           Copyright (C) 1995-1999 Ada Core Technologies, Inc.            --
  12. --                                                                          --
  13. -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14. -- terms of the  GNU General Public License as published  by the Free Soft- --
  15. -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16. -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17. -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18. -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19. -- for  more details.  You should have  received  a copy of the GNU General --
  20. -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21. -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22. -- MA 02111-1307, USA.                                                      --
  23. --                                                                          --
  24. -- As a special exception,  if other files  instantiate  generics from this --
  25. -- unit, or you link  this unit with other files  to produce an executable, --
  26. -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27. -- covered  by the  GNU  General  Public  License.  This exception does not --
  28. -- however invalidate  any other reasons why  the executable file  might be --
  29. -- covered by the  GNU Public License.                                      --
  30. --                                                                          --
  31. -- GNAT is maintained by Ada Core Technologies Inc (http://www.gnat.com).   --
  32. --                                                                          --
  33. ------------------------------------------------------------------------------
  34.  
  35. package body GNAT.Heap_Sort_G is
  36.  
  37.    ----------
  38.    -- Sort --
  39.    ----------
  40.  
  41.    --  We are using the classical heapsort algorithm (i.e. Floyd's Treesort3)
  42.    --  as described by Knuth ("The Art of Programming", Volume III, first
  43.    --  edition, section 5.2.3, p. 145-147) with the modification that is
  44.    --  mentioned in exercise 18. For more details on this algorithm, see
  45.    --  Robert B. K. Dewar PhD thesis "The use of Computers in the X-ray
  46.    --  Phase Problem". University of Chicago, 1968, which was the first
  47.    --  publication of the modification, which reduces the number of compares
  48.    --  from 2NlogN to NlogN.
  49.  
  50.    procedure Sort (N : Natural) is
  51.  
  52.       Max : Natural := N;
  53.       --  Current Max index in tree being sifted
  54.  
  55.       procedure Sift (S : Positive);
  56.       --  This procedure sifts up node S, i.e. converts the subtree rooted
  57.       --  at node S into a heap, given the precondition that any sons of
  58.       --  S are already heaps. On entry, the contents of node S is found
  59.       --  in the temporary (index 0), the actual contents of node S on
  60.       --  entry are irrelevant. This is just a minor optimization to avoid
  61.       --  what would otherwise be two junk moves in phase two of the sort.
  62.  
  63.       procedure Sift (S : Positive) is
  64.          C      : Positive := S;
  65.          Son    : Positive;
  66.          Father : Positive;
  67.  
  68.       begin
  69.          --  This is where the optimization is done, normally we would do a
  70.          --  comparison at each stage between the current node and the larger
  71.          --  of the two sons, and continue the sift only if the current node
  72.          --  was less than this maximum. In this modified optimized version,
  73.          --  we assume that the current node will be less than the larger
  74.          --  son, and unconditionally sift up. Then when we get to the bottom
  75.          --  of the tree, we check parents to make sure that we did not make
  76.          --  a mistake. This roughly cuts the number of comparisions in half,
  77.          --  since it is almost always the case that our assumption is correct.
  78.  
  79.          --  Loop to pull up larger sons
  80.  
  81.          loop
  82.             Son := 2 * C;
  83.             exit when Son > Max;
  84.  
  85.             if Son < Max and then Lt (Son, Son + 1) then
  86.                Son := Son + 1;
  87.             end if;
  88.  
  89.             Move (Son, C);
  90.             C := Son;
  91.          end loop;
  92.  
  93.          --  Loop to check fathers
  94.  
  95.          while C /= S loop
  96.             Father := C / 2;
  97.  
  98.             if Lt (Father, 0) then
  99.                Move (Father, C);
  100.                C := Father;
  101.             else
  102.                exit;
  103.             end if;
  104.          end loop;
  105.  
  106.          --  Last step is to pop the sifted node into place
  107.  
  108.          Move (0, C);
  109.       end Sift;
  110.  
  111.    --  Start of processing for Sort
  112.  
  113.    begin
  114.       --  Phase one of heapsort is to build the heap. This is done by
  115.       --  sifting nodes N/2 .. 1 in sequence.
  116.  
  117.       for J in reverse 1 .. N / 2 loop
  118.          Move (J, 0);
  119.          Sift (J);
  120.       end loop;
  121.  
  122.       --  In phase 2, the largest node is moved to end, reducing the size
  123.       --  of the tree by one, and the displaced node is sifted down from
  124.       --  the top, so that the largest node is again at the top.
  125.  
  126.       while Max > 1 loop
  127.          Move (Max, 0);
  128.          Move (1, Max);
  129.          Max := Max - 1;
  130.          Sift (1);
  131.       end loop;
  132.  
  133.    end Sort;
  134.  
  135. end GNAT.Heap_Sort_G;
  136.