home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / RCS43X.ZIP / RCSFILE.MAN < prev    next >
Text File  |  1990-11-19  |  5KB  |  135 lines
  1. NAME
  2.      rcsfile - format of RCS file
  3.  
  4. DESCRIPTION
  5.      An RCS file is an ASCII file. Its contents are described by
  6.      the grammar below. The text is free format, i.e., spaces,
  7.      tabs and new lines have no significance except in strings.
  8.      Strings are enclosed by `@'.  If a string contains a `@', it
  9.      must be doubled.
  10.  
  11.      The meta syntax uses the following conventions: `|' (bar)
  12.      separates alternatives; `{' and `}' enclose optional
  13.      phrases; `{' and `}*' enclose phrases that may be repeated
  14.      zero or more times; `{' and '}+' enclose phrases that must
  15.      appear at least once and may be repeated; `<' and `>'
  16.      enclose nonterminals.
  17.  
  18.  
  19.      <rcstext>      ::=  <admin> {<delta>}* <desc> {<deltatext>}*
  20.  
  21.      <admin>        ::=  head      {<num>};
  22.                          branch    {<num>};
  23.                          access    {<id>}*;
  24.                          symbols   {<id> : <num>}*;
  25.                          locks     {<id> : <num>}*;
  26.                          comment   {<string>};
  27.  
  28.      <delta>        ::=  <num>
  29.                          date      <num>;
  30.                          author    <id>;
  31.                          state     {<id>};
  32.                          branches  {<num>}*;
  33.                          next      {<num>};
  34.  
  35.      <desc>         ::=  desc      <string>
  36.  
  37.      <deltatext>    ::=  <num>
  38.                          log       <string>
  39.                          text      <string>
  40.  
  41.  
  42.      <num>          ::=  {<digit>{.}}+
  43.  
  44.      <digit>        ::=  0 | 1 | ... | 9
  45.  
  46.      <id>           ::=  <letter>{<idchar>}*
  47.  
  48.      <letter>       ::=  A | B | ... | Z | a | b | ... | z
  49.  
  50.      <idchar>       ::=  Any printing ASCII character except space,
  51.                          tab, carriage return, new line, and <special>.
  52.  
  53.      <special>      ::=  ; | : | , | @
  54.  
  55.      <string>       ::=  @{any ASCII character, with `@' doubled}*@
  56.  
  57.  
  58.  
  59.      Identifiers are case sensitive. Keywords are in lower case
  60.      only.  The sets of keywords and identifiers may overlap.
  61.  
  62.      The <delta> nodes form a tree. All nodes whose numbers con-
  63.      sist of a single pair (e.g., 2.3, 2.1, 1.3, etc.) are on the
  64.      "trunk", and are linked through the next field in order of
  65.      decreasing numbers. The head field in the <admin> node
  66.      points to the head of that sequence (i.e., contains the
  67.      highest pair). The branch node in the admin node indicates
  68.      the default branch (or revision) for most RCS operations. If
  69.      empty, the default branch is the highest branch on the
  70.      trunk.
  71.  
  72.      All <delta> nodes whose numbers consist of 2n fields (n_2)
  73.      (e.g., 3.1.1.1, 2.1.2.2, etc.) are linked as follows. All
  74.      nodes whose first (2n)-1 number fields are identical are
  75.      linked through the next field in order of increasing
  76.      numbers.  For each such sequence, the <delta> node whose
  77.      number is identical to the first 2(n-1) number fields of the
  78.      deltas on that sequence is called the branchpoint.  The
  79.      branches field of a node contains a list of the numbers of
  80.      the first nodes of all sequences for which it is a bran-
  81.      chpoint.  This list is ordered in increasing numbers.
  82.  
  83.      Example:
  84.                                 Head
  85.                                   |
  86.                                   |
  87.                                   v
  88.                               ---------
  89.         / \          / \      |       |      / \           / \
  90.        /   \        /   \     |  2.1  |     /   \         /   \
  91.       /     \      /     \    |       |    /     \      /       \
  92.      /1.2.1.3\    /1.3.1.1\   |       |   /1.2.2.2\   /1.2.2.1.1.1\
  93.      ---------    ---------   ---------   ---------   -------------
  94.          ^            ^           |           ^             ^
  95.          |            |           |           |             |
  96.          |            |           v           |             |
  97.         / \           |       ---------      / \            |
  98.        /   \          |       \  1.3  /     /   \           |
  99.       /     \         ---------\     /     /     \-----------
  100.      /1.2.1.1\                  \   /     /1.2.2.1\
  101.      ---------                   \ /      ---------
  102.          ^                        |           ^
  103.          |                        |           |
  104.          |                        v           |
  105.          |                    ---------       |
  106.          |                    \  1.2  /       |
  107.          ----------------------\     /---------
  108.                                 \   /
  109.                                  \ /
  110.                                   |
  111.                                   |
  112.                                   v
  113.                               ---------
  114.                               \  1.1  /
  115.                                \     /
  116.                                 \   /
  117.                                  \ /
  118.  
  119.  
  120.                        Fig. 1: A revision tree
  121.  
  122. IDENTIFICATION
  123.      Author: Walter F. Tichy, Purdue University, West Lafayette,
  124.      IN, 47907.
  125.      Revision Number: 1.3 ; Release Date: 89/10/30 .
  126.      Copyright c 1982, 1988, 1989 by Walter F. Tichy.
  127.  
  128. SEE ALSO
  129.      ci(L), co(L), ident(L), rcs(L), rcsdiff(L), rcsmerge(L),
  130.      rlog(L),
  131.      Walter F. Tichy, "Design, Implementation, and Evaluation of
  132.      a Revision Control System," in Proceedings of the 6th Inter-
  133.      national Conference on Software Engineering, IEEE, Tokyo,
  134.      Sept. 1982.
  135.