home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / PPOS2.ZIP / QFN.ASM < prev    next >
Assembly Source File  |  1988-10-19  |  10KB  |  266 lines
  1.         title   QFN.ASM --- qualify file name
  2.         page    55,132
  3.         .286
  4.  
  5. ; QFN.ASM -- Qualify File Name, OS/2 Version
  6. ; by Ray Duncan, Copyright (C) 1988 Ziff Davis
  7. ;
  8. ; Call with:    DS:SI = filename address
  9. ;               AX    = length
  10. ;
  11. ; Returns:      Carry = clear if filename OK
  12. ;               DS:SI = qualified filename
  13. ;               AX    = length
  14. ;               or
  15. ;               Carry = set if bad filename
  16. ; 
  17. ;               Registers other than DS:SI
  18. ;               and AX are preserved.
  19.  
  20.         extrn   DosChDir:far    ; OS/2 API functions
  21.         extrn   DosQCurDisk:far
  22.         extrn   DosQCurDir:far
  23.         extrn   DosSelectDisk:far
  24.  
  25. DGROUP  group   _DATA
  26.  
  27. _DATA   segment word public 'DATA'
  28.  
  29. cdrive  dw      0               ; current drive
  30. cpath   db      '\',64 dup (0)  ; current directory
  31. cpsiz   dw      $-cpath-1
  32. drvmap  dd      ?               ; valid drive bitmap
  33. ndrive  dw      0               ; new drive
  34.  
  35. tbuff   db      64 dup (0)      ; target directory
  36.  
  37. qbuff   db      'X:\'           ; qualified pathname
  38.         db      64 dup (0)
  39. qbsiz   dw      $-qbuff-3
  40.  
  41. fname   dw      ?               ; filename address
  42. flen    dw      ?               ; filename length
  43.  
  44. _DATA   ends
  45.  
  46.  
  47. _TEXT   segment word public 'CODE'
  48.  
  49.         assume  cs:_TEXT,ds:DGROUP
  50.  
  51.         public  qfn             ; make visible to Linker
  52.  
  53. qfn     proc    near            ; qualify file name
  54.  
  55.         push    bx              ; save registers        
  56.         push    cx
  57.         push    dx
  58.         push    di
  59.         push    es
  60.  
  61.         mov     flen,ax         ; save length and 
  62.         mov     fname,si        ; address of filename
  63.  
  64.         mov     ax,ds           ; make DGROUP addressable
  65.         mov     es,ax           ; with ES register
  66.  
  67.                                 ; save current drive...
  68.         push    ds              ; receives drive ID
  69.         push    offset DGROUP:cdrive
  70.         push    ds              ; receives valid drive bitmap
  71.         push    offset DGROUP:drvmap
  72.         call    DosQCurDisk     ; transfer to OS/2      
  73.  
  74.                                 ; save current directory...
  75.         push    0               ; drive ID = current
  76.         push    ds              ; receives directory path
  77.         push    offset DGROUP:cpath+1
  78.         push    ds              ; contains buffer length
  79.         push    offset DGROUP:cpsiz
  80.         call    DosQCurDir      ; transfer to OS/2
  81.  
  82.                                 ; did caller specify drive?
  83.         mov     di,fname        ; get address of name
  84.         mov     cx,flen         ; get length of name
  85.  
  86.         cmp     cx,2            ; if drive, length must 
  87.                                 ; be >= 2 chars.
  88.         jl      qfn2            ; too short, no drive
  89.  
  90.                                 ; check for drive delimiter
  91.         cmp     byte ptr [di+1],':'
  92.         jne     qfn2            ; no delimiter, jump
  93.  
  94.         mov     al,[di]         ; get ASCII drive code
  95.         or      al,20h          ; fold to lower case
  96.         sub     al,'a'-1        ; convert it to binary
  97.         xor     ah,ah
  98.  
  99.                                 ; now select new drive
  100.         push    ax              ; binary drive ID
  101.         call    DosSelectDisk   ; transfer to OS/2
  102.         or      ax,ax           ; was drive valid?
  103.         jz      qfn1            ; jump, drive was OK
  104.         jmp     qfn8            ; exit, drive not valid
  105.  
  106. qfn1:   add     di,2            ; bump pointer past drive
  107.         sub     cx,2            ; and decrement length
  108.  
  109. qfn2:                           ; get current directory 
  110.                                 ; again for new drive...
  111.         push    0               ; drive ID = current
  112.         push    ds              ; receives directory path
  113.         push    offset DGROUP:cpath+1
  114.         push    ds              ; contains buffer length
  115.         push    offset DGROUP:cpsiz
  116.         call    DosQCurDir      ; transfer to OS/2
  117.  
  118.                                 ; scan off path if any
  119.         push    di              ; save start of path
  120.         mov     al,'\'          ; path delimiter
  121.  
  122. qfn3:   mov     fname,di        ; save path pointer
  123.         mov     flen,cx         ; save path length
  124.         jcxz    qfn4            ; jump if none left
  125.  
  126.         repne scasb             ; any '\' left in path?
  127.         je      qfn3            ; loop if '\' found
  128.  
  129. qfn4:   pop     si              ; recover starting address
  130.                                 ; of path portion
  131.  
  132.                                 ; copy path to local buffer
  133.                                 ; and make it ASCIIZ...
  134.         mov     di,offset DGROUP:tbuff
  135.         mov     cx,fname        ; calculate path length
  136.         sub     cx,si
  137.         jz      qfn6            ; jump, no path at all
  138.         cmp     cx,1            ; root directory?
  139.         je      qfn5            ; jump if root
  140.         dec     cx              ; else discard last '\'
  141.  
  142. qfn5:   rep movsb               ; transfer path and
  143.         xor     al,al           ; append null byte
  144.         stosb
  145.         
  146.                                 ; select target directory...
  147.         push    ds              ; directory path address
  148.         push    offset DGROUP:tbuff
  149.         push    0               ; DWORD reserved
  150.         push    0
  151.         call    DosChDir        ; transfer to OS/2
  152.         or      ax,ax           ; directory valid?
  153.         jnz     qfn8            ; jump, no such directory
  154.  
  155. qfn6:                           ; build up full pathname...
  156.                                 ; get current drive
  157.         push    ds              ; receives drive ID
  158.         push    offset DGROUP:ndrive
  159.         push    ds              ; receives valid drive bitmap
  160.         push    offset DGROUP:drvmap
  161.         call    DosQCurDisk     ; transfer to OS/2      
  162.         mov     ax,ndrive       ; convert binary drive code
  163.         add     ax,'a'-1        ; to ASCII drive identifier
  164.         mov     qbuff,al
  165.  
  166.                                 ; get current directory
  167.         push    0               ; drive ID = current
  168.         push    ds              ; receives directory path
  169.         push    offset DGROUP:qbuff+3
  170.         push    ds              ; contains buffer length
  171.         push    offset DGROUP:qbsiz
  172.         call    DosQCurDir      ; transfer to OS/2
  173.         or      ax,ax           ; operation successful?
  174.         jnz     qfn8            ; no, return error
  175.  
  176.                                 ; point to path component
  177.         mov     di,offset DGROUP:qbuff+3
  178.         cmp     byte ptr [di],0 ; is current directory
  179.                                 ; the root directory?
  180.         je      qfn7            ; yes, jump
  181.  
  182.         xor     al,al           ; scan for null byte at
  183.         mov     cx,-1           ; end of path name
  184.         repne scasb             ; and append backslash
  185.         mov     byte ptr [di-1],'\'
  186.  
  187. qfn7:                           ; now append filename
  188.                                 ; to drive and path...
  189.         mov     si,fname        ; filename address
  190.         cmp     byte ptr [si],'.'
  191.         je      qfn8            ; exit if directory alias
  192.         mov     cx,flen         ; filename length
  193.         rep movsb               ; copy it
  194.                                         
  195.                                 ; set DS:SI = address 
  196.         mov     si,offset DGROUP:qbuff
  197.         mov     ax,di           ; and AX = length of
  198.         sub     ax,si           ; fully qualified filename
  199.  
  200.         call    makelc          ; fold filename to lower
  201.                                 ; case to make it pretty
  202.  
  203.         clc                     ; set Carry = false to 
  204.                                 ; indicate success and
  205.         jmp     qfn9            ; go to common exit point
  206.  
  207. qfn8:                           ; come here if any 
  208.                                 ; error detected...
  209.         stc                     ; set Carry = true to 
  210.                                 ; indicate error
  211.  
  212. qfn9:   pushf                   ; save Carry flag
  213.         push    ax              ; save final length
  214.  
  215.                                 ; restore original directory
  216.         push    ds              ; address of directory path
  217.         push    offset DGROUP:cpath
  218.         push    0               ; DWORD reserved
  219.         push    0
  220.         call    DosChDir        ; transfer to OS/2
  221.  
  222.                                 ; restore original drive
  223.         push    cdrive          ; binary drive ID
  224.         call    DosSelectDisk
  225.  
  226.         pop     ax              ; restore length
  227.         popf                    ; and Carry flag
  228.  
  229.         pop     es              ; restore other affected
  230.         pop     di              ; registers
  231.         pop     dx
  232.         pop     cx
  233.         pop     bx
  234.         ret                     ; back to caller
  235.  
  236. qfn     endp
  237.  
  238.  
  239. makelc  proc    near            ; string -> lower case
  240.                                 ; DS:SI = address
  241.                                 ; AX = length
  242.  
  243.         push    bx              ; save BX contents
  244.         xor     bx,bx           ; BX will be pointer
  245.  
  246. mlc1:                           ; change A-Z to a-z
  247.         cmp     byte ptr [bx+si],'A'
  248.         jb      mlc2
  249.         cmp     byte ptr [bx+si],'Z'
  250.         ja      mlc2
  251.         or      byte ptr [bx+si],20h
  252.  
  253. mlc2:   inc     bx              ; advance through string
  254.         cmp     bx,ax           ; done with string yet?
  255.         jne     mlc1            ; no, check next char.
  256.  
  257.         pop     bx              ; restore BX and
  258.         ret                     ; return to caller
  259.  
  260. makelc  endp
  261.  
  262. _TEXT   ends
  263.  
  264.         end
  265.  
  266.