home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / PPOS2.ZIP / ARGV.ASM < prev    next >
Assembly Source File  |  1988-09-13  |  5KB  |  135 lines
  1.         title   ARGV --- return argument pointer
  2.         page    55,132
  3.         .286
  4.  
  5. ;
  6. ; ARGV.ASM:     Return address and length of specified 
  7. ;               command line argument or fully qualified 
  8. ;               program name.  Treats blanks and tabs 
  9. ;               as whitespace.
  10. ;
  11. ; OS/2 version Copyright (C) 1987 Ray Duncan
  12. ; 
  13. ; Call with:    AX    = argument number (0 based)
  14. ;
  15. ; Returns:      ES:BX = argument address
  16. ;               AX    = argument length (0=no argument)
  17. ;
  18. ; Uses:         nothing (other registers preserved)
  19. ;
  20. ; Note: if called with AX=0 (argv[0]), returns ES:BX 
  21. ; pointing to fully qualified program name in environment 
  22. ; block and AX=length.
  23. ;
  24.  
  25. tab     equ     09h             ; ASCII tab
  26. blank   equ     20h             ; ASCII space character
  27.  
  28.         extrn   DosGetEnv:far
  29.  
  30. _TEXT   segment word public 'CODE'
  31.  
  32.         assume  cs:_TEXT
  33.  
  34.         public  argv            ; make ARGV available to Linker
  35.  
  36.                                 ; local variables...
  37. envseg  equ     [bp-2]          ; environment segment
  38. cmdoffs equ     [bp-4]          ; command line offset   
  39.  
  40. argv    proc    near
  41.  
  42.         enter   4,0             ; make room for local variables
  43.         push    cx              ; save original CX and DI 
  44.         push    di
  45.  
  46.         push    ax              ; save argument number
  47.  
  48.         push    ss              ; get selector for environment 
  49.         lea     ax,envseg       ; and offset of command line 
  50.         push    ax
  51.         push    ss
  52.         lea     ax,cmdoffs
  53.         push    ax
  54.         call    DosGetEnv       ; transfer to OS/2      
  55.         or      ax,ax           ; test operation status
  56.         pop     ax              ; restore argument number
  57.         jnz     argv7           ; jump if DosGetEnv failed
  58.  
  59.         mov     es,envseg       ; set ES:BX = command line
  60.         mov     bx,cmdoffs
  61.  
  62.         or      ax,ax           ; is requested argument=0?
  63.         jz      argv8           ; yes, jump to get program name
  64.  
  65. argv0:  inc     bx              ; scan off first field
  66.         cmp     byte ptr es:[bx],0      
  67.         jne     argv0
  68.  
  69.         xor     ah,ah           ; initialize argument counter
  70.  
  71. argv1:  mov     cx,-1           ; set flag = outside argument
  72.  
  73. argv2:  inc     bx              ; point to next character 
  74.         cmp     byte ptr es:[bx],0
  75.         je      argv7           ; exit if null byte
  76.         cmp     byte ptr es:[bx],blank
  77.         je      argv1           ; outside argument if ASCII blank
  78.         cmp     byte ptr es:[bx],tab    
  79.         je      argv1           ; outside argument if ASCII tab
  80.  
  81.                                 ; if not blank or tab...
  82.         jcxz    argv2           ; jump if already inside argument
  83.  
  84.         inc     ah              ; else count arguments found
  85.         cmp     ah,al           ; is this the one we're looking for?
  86.         je      argv4           ; yes, go find its length
  87.         not     cx              ; no, set flag = inside argument
  88.         jmp     argv2           ; and look at next character
  89.  
  90. argv4:                          ; found desired argument, now
  91.                                 ; determine its length...
  92.         mov     ax,bx           ; save param. starting address 
  93.  
  94. argv5:  inc     bx              ; point to next character
  95.         cmp     byte ptr es:[bx],0
  96.         je      argv6           ; found end if null byte
  97.         cmp     byte ptr es:[bx],blank
  98.         je      argv6           ; found end if ASCII blank
  99.         cmp     byte ptr es:[bx],tab    
  100.         jne     argv5           ; found end if ASCII tab
  101.  
  102. argv6:  xchg    bx,ax           ; set ES:BX = argument address
  103.         sub     ax,bx           ; and AX = argument length
  104.         jmp     argvx           ; return to caller
  105.  
  106. argv7:  xor     ax,ax           ; set AX = 0, argument not found
  107.         jmp     argvx           ; return to caller
  108.  
  109. argv8:                          ; special handling for argv=0
  110.         xor     di,di           ; find the program name by
  111.         xor     al,al           ; first skipping over all the
  112.         mov     cx,-1           ; environment variables...
  113.         cld
  114. argv9:  repne scasb             ; scan for double null (can't use
  115.         scasb                   ; (SCASW since might be odd addr.)
  116.         jne     argv9           ; loop if it was a single null
  117.         mov     bx,di           ; save program name address
  118.         mov     cx,-1           ; now find its length... 
  119.         repne scasb             ; scan for another null byte
  120.         not     cx              ; convert CX to length 
  121.         dec     cx
  122.         mov     ax,cx           ; return length in AX
  123.  
  124. argvx:                          ; common exit point
  125.         pop     di              ; restore original CX and DI
  126.         pop     cx
  127.         leave                   ; discard stack frame
  128.         ret                     ; return to caller
  129.  
  130. argv    endp
  131.  
  132. _TEXT   ends
  133.  
  134.         end     
  135.