home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / OL.LZH / PROCS.LZH / DOSFILES.ICN < prev    next >
Text File  |  1991-07-13  |  2KB  |  65 lines
  1. ############################################################################
  2. #
  3. #   Name:    dosfiles.icn
  4. #
  5. #   Title:   Get MS-DOS file names.
  6. #
  7. #   Author:  Paul Abrahams
  8. #
  9. #   Date:    September 24, 1990
  10. #
  11. ############################################################################
  12. #  dosfiles(pfn) accepts a DOS filename possibly containing wildcards.
  13. #  The filename can also include a drive letter and path.
  14. #  If the filename ends in "\" or ":", "*.*" is appended.
  15. # 
  16. #  The result sequence is a sequence of the filenames corresponding to pfn.
  17. # 
  18. ############################################################################
  19. #
  20. #  Requires: MS-DOS extensions
  21. #
  22. ############################################################################
  23.  
  24. procedure dosfiles(pfn)
  25.    local asciiz, fnr, prefix, k, name
  26.    local ds, dx, result, fnloc, string_block
  27.  
  28. # Get Disk Transfer Address; filename locn is 30 beyond that.
  29.  
  30.    result := Int86([16r21, 16r2f00] ||| list(7,0))
  31.    fnloc := 16 * result[8] + result[3]+ 30
  32.  
  33. # Get the generalized filename.
  34.  
  35.    fnr := reverse(pfn)
  36.    k := upto("\\:", fnr) | *fnr + 1
  37.    prefix := reverse(fnr[k:0])
  38.    name := "" ~== reverse(fnr[1:k]) | "*.*"
  39.  
  40. # Get the first file in the sequence.
  41.  
  42.    asciiz := prefix || name || "\x00"
  43.    Poke(string_block := GetSpace(*asciiz), asciiz)
  44.    ds := string_block / 16
  45.    dx := string_block % 16
  46.    result := Int86([16r21, 16r4e00, 0, 0, dx, 0, 0, 0, ds])
  47.    case result[2] of {
  48.       0 : {}
  49.       18 : fail
  50.       default : stop("i/o error ", result[2])
  51.       }
  52.    suspend prefix || extract_name(fnloc)
  53.  
  54. # Get the remaining files in the sequence.
  55.  
  56.    while Int86([16r21, 16r4f00, 0, 0, 0, 0, 0, 0, 0])[2] = 0 do
  57.       suspend prefix || extract_name(fnloc)
  58. end
  59.  
  60. procedure extract_name(fnloc)
  61.    local asciiz
  62.    asciiz := Peek(fnloc, 13)
  63.    return asciiz[1:upto("\x00", asciiz)]
  64. end
  65.