home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 10 Tools / 10-Tools.zip / OL.LZH / PROCS.LZH / ANSI.ICN < prev    next >
Text File  |  1991-09-06  |  6KB  |  210 lines
  1. ############################################################################ 
  2. # 
  3. #    Name:     ansi.icn
  4. # 
  5. #    Title:     ANSI-based terminal control library
  6. # 
  7. #    Author:  Richard Goerwitz, based on an earlier version by
  8. #           Ralph E. Griswold
  9. # 
  10. #    Version: 1.1
  11. #
  12. #    Date:     June 28, 1991
  13. # 
  14. ############################################################################ 
  15. # 
  16. #     This package of procedures implements a subset of the ANSI terminal
  17. #  control sequences.  The names of the procedures are taken directly from
  18. #  the ANSI names.  If it is necessary to use these routines with non-ANSI
  19. #  devices, link in iolib.icn, and (optionally) iscreen.icn as well.  Use
  20. #  will be made of whatever routines are made available via either of these
  21. #  libraries.  Be careful of naming conflicts if you link in iscreen.icn.
  22. #  It contains procedures like "clear" and "boldface."
  23. #
  24. #     CUB(i)        Moves the cursor left i columns
  25. #     CUD(i)        Moves the cursor down i rows
  26. #     CUF(i)        Moves the cursor right i columns
  27. #     CUP(i,j)    Moves the cursor to row i, column j
  28. #     CUU(i)        Moves the cursor up i rows
  29. #     ED(i)        Erases screen: i = 0, cursor to end; i = 1,
  30. #               beginning to cursor; i = 2, all (default 2)
  31. #     EL(i)        Erases data in cursor row: i = 0, cursor to
  32. #               end; i = 1, beginning to cursor; i = 2, all
  33. #               (default 0)
  34. #     SGR(i)        Sets video attributes: 0 = off; 1 = bold; 4 =
  35. #               underscore; 5 = blink; 7 = reverse (default
  36. #               0)    
  37. #
  38. #     Note that not all so-called ANSI terminals support every ANSI
  39. #  screen control sequence - not even the limited subset included in
  40. #  this file.
  41. #
  42. #     If you plan on using these routines with non-ANSI magic-cookie
  43. #  terminals (e.g. a Wyse-50) then it is strongly recommended that you
  44. #  link in iolib or itlib *and* iscreen (not just iolib or itlib by
  45. #  itself).  The routines WILL WORK with most magic cookie terminals;
  46. #  they just don't always get all the modes displayed (because they
  47. #  are basically too busy erasing the cookies).
  48. #
  49. ############################################################################ 
  50. #
  51. #  Links: iolib or itlib, iscreen (all optional)
  52. #
  53. ############################################################################ 
  54. #
  55. #  For DOS, or any system using ANSI-conformant output devices, there
  56. #  is no need to link any routines in.
  57. #
  58. #  For Unix systems, you may choose to link in itlib or iolib, and (if
  59. #  desired) iscreen as well.  Some of these may be in the IPL.  You can
  60. #  get any that aren't from Richard Goerwitz (goer@sophist.uchicago.edu).
  61. #
  62. ############################################################################ 
  63.  
  64. procedure _isANSI()
  65.     static isANSI
  66.     initial {
  67.     if find("MS-DOS",&features) then {
  68.         isANSI := 1
  69.     } else {
  70.         if type(getname) == "procedure" then {
  71.         if find("ansi",map(getname())) | getname() == "li"
  72.         then isANSI := 1
  73.         else isANSI := &null
  74.         } else {
  75.         # We'll take a chance on the user knowing what he/she
  76.         # is doing.
  77.         isANSI := 1
  78.         # If you're not so confident, comment out the following
  79.         # line:
  80.         # stop("_isANSI:  you need to link itlib or iolib")
  81.         }
  82.     }
  83.     }
  84.     return \isANSI
  85. end
  86.  
  87. procedure CUD(i)
  88.     if _isANSI()
  89.     then writes("\^[[",i,"B")
  90.     else {
  91.     iputs(igoto(getval("DO"),i)) | {
  92.         every 1 to i do
  93.         iputs(getval("do")) | stop("CUD:  no do capability")
  94.     }
  95.     }
  96.     return
  97. end
  98.  
  99. procedure CUB(i)
  100.     if _isANSI()
  101.     then writes("\^[[",i,"D")
  102.     else {
  103.     iputs(igoto(getval("LE"),i)) | {
  104.         every 1 to i do
  105.         iputs(getval("le")) | stop("CUB:  no le capability")
  106.     }
  107.     }
  108.     return
  109. end
  110.  
  111. procedure CUF(i)
  112.     if _isANSI()
  113.     then writes("\^[[",i,"C")
  114.     else {
  115.     iputs(igoto(getval("RI"),i)) | {
  116.         every 1 to i do
  117.         iputs(getval("nd")) | stop("CUF:  no nd capability")
  118.     }
  119.     }
  120.     return
  121. end
  122.  
  123. procedure CUP(i,j)
  124.     if _isANSI()
  125.     then writes("\^[[",i,";",j,"H")
  126.     else iputs(igoto(getval("cm"), j, i)) | stop("CUP:  no cm capability")
  127.     return
  128. end
  129.  
  130. procedure CUU(i)
  131.     if _isANSI()
  132.     then writes("\^[[",i,"A")
  133.     else {
  134.     iputs(igoto(getval("UP"),i)) | {
  135.         every 1 to i do
  136.         iputs(getval("up")) | stop("CUU:  no up capability")
  137.     }
  138.     }
  139.     return
  140. end
  141.  
  142. procedure ED(i)
  143.     /i := 2
  144.     if _isANSI() then {
  145.     writes("\^[[",i,"J")
  146.     } else {
  147.     case i of {
  148.         0:  iputs(getval("cd")) | stop("ED:  no cd capability")
  149.         1:  stop("ED:  termcap doesn't specify capability")
  150.         2:  {
  151.         if type(emphasize) == "procedure" then clear()
  152.         else iputs(getval("cl")) | stop("ED:  no cl capability")
  153.         }
  154.         default:  stop("ED:  unknown clear code, ",i)
  155.     }
  156.     }
  157.    return
  158. end
  159.  
  160. procedure EL(i)
  161.     /i := 0
  162.     if _isANSI() then {
  163.     if i = 0
  164.     then writes("\^[[K")
  165.     else writes("\^[[",i,"K")
  166.     } else {
  167.     case i of {
  168.         0:  iputs(getval("ce")) | stop("EL:  no ce capability")
  169.         1:  stop("EL:  termcap doesn't specify capability")
  170.         2:  stop("EL:  try using CUP to go to col 1, then EL(0)")
  171.         default:  stop("EL:  unknown line clear code, ",i)
  172.     }
  173.     }
  174.    return
  175. end
  176.  
  177. procedure SGR(i)
  178.  
  179.     static isISCR
  180.     initial {
  181.     if type(emphasize) == "procedure"
  182.     then isISCR := 1
  183.     }
  184.  
  185.     /i := 0
  186.     if _isANSI() then {
  187.     writes("\^[[",i,"m")
  188.     } else {
  189.     case i of {
  190.         0: (\isISCR, normal()) | {
  191.         every iputs(getval("me"|"so"|"ue"))
  192.         }
  193.         1: (\isISCR, boldface()) | {
  194.         iputs(getval("md"|"so"|"us"))
  195.         }
  196.         4: (\isISCR, underline()) | {
  197.         iputs(getval("us"|"md"|"so"))
  198.         }
  199.         5: (\isISCR, blink()) | {
  200.         iputs(getval("mb"|"us"|"me"|"so"))
  201.         }
  202.         7: (\isISCR, emphasize()) | {
  203.         iputs(getval("so"|"me"|"ue"))
  204.         }
  205.         default:  stop("SGR:  unknown mode, ",i)
  206.     }
  207.     }
  208.    return
  209. end
  210.