home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
OS/2 Shareware BBS: 2 BBS
/
02-BBS.zip
/
POINTKT3.ZIP
/
POINT.CMD
< prev
next >
Wrap
OS/2 REXX Batch file
|
1990-12-10
|
4KB
|
134 lines
@Echo Off
Set BBS=C:\BINK
Set BINKLEY=C:\BINK\
Set BOSS=109/301
Set MAIL=C:\BINK\MAIL
Set IN=C:\BINK\INBOUND
Set OUT=C:\BINK\OUTBOUND
Set PENGUIN=C:\BINK\POLYXARC.CFG
Set TZ=EST5EDT
Set RBuf=3072
Set TBuf=512
Set MODEMPriority=4
Set JanusPriority=4
Set RegularPriority=2
REM Set SnoopPipe=\pipe\point /* else do it in BINKLEY.CFG */
C:
CD %BBS%
If Exist INBINK EXIT
ANSI ON
MODE CO80,43
MODE COM1:9600,N,8,1,TO=OFF,XON=OFF,IDSR=OFF,ODSR=OFF,OCTS=ON,DTR=ON,RTS=ON,BUFFER=ON
Goto BTTime
:Top
If Not Exist %OUT%\*.?UT Goto BTTime
Call Ommme
:BTTime
Echo INBINK >INBINK
%BINKLEY%BTP Unattended %1
If ERRORLEVEL 221 Goto Top
If ERRORLEVEL 220 Goto Weekly
If ERRORLEVEL 211 Goto Top
If ERRORLEVEL 210 Goto Maint_Time
If ERRORLEVEL 200 Goto Mail_Out
If ERRORLEVEL 130 Goto Mail_In
If ERRORLEVEL 120 Goto Top
If ERRORLEVEL 110 Goto Top
If ERRORLEVEL 100 Goto Mail_In
If ERRORLEVEL 90 Goto Mail_Out
If ERRORLEVEL 80 Goto Mail_Chk
If ERRORLEVEL 70 Goto POLL
If ERRORLEVEL 50 Goto Hatchit
If ERRORLEVEL 40 Goto Editor
If ERRORLEVEL 39 Goto Top
If ERRORLEVEL 30 Goto Off_Bottom
If ERRORLEVEL 29 Goto Top
If ERRORLEVEL 11 Goto Top
If ERRORLEVEL 10 Goto Help
If ERRORLEVEL 9 Goto Top
If ERRORLEVEL 2 Goto Top
Rem If we got here, then it means we should exit and return to OS/2.
Goto Off_Bottom
:Help
CLS
Echo ╔═════════════════════════════════════════════════════════════════════════╗
Echo ║ BinkleyTerm Point Kit Help Screen ║
Echo ║ ║
Echo ║ F1 = This Help F2 = ║
Echo ║ F3 = Quit BinkleyTerm F4 = Invoke MsgEd ║
Echo ║ F5 = Invoke Hatch F6 = ║
Echo ║ F7 = Poll Boss F8 = Check Outbound Mail ║
Echo ║ F9 = Export Mail F10= Import Mail ║
Echo ║ ║
Echo ║ ║
Echo ║ ║
Echo ║ ║
Echo ║ ║
Echo ╚═════════════════════════════════════════════════════════════════════════╝
Echo.
Pause
Goto Top
:Mail_In
Call Import
If Exist %IN%\nodediff.a* Call Listgen.cmd
Goto Top
Rem If we got here, then it is time for Weekly stuff.
:Weekly
Goto BTTime
Rem If we got here, then it is time to renum and compress echomail.
:Maint_Time
If Exist BINK2.LOG Del BINK2.LOG >Nul:
If Exist BINK1.LOG Ren BINK1.LOG BINK2.* >Nul:
If Exist BINK.LOG Ren BINK.LOG BINK1.* >Nul:
Call Compress
REM Group2 In Link Out Ask /C /B >Nul:
Call oMMMe
REM Group2 Kill /C /B >Nul:
Goto POLL
Rem If we got here, then it is time to Edit echomail.
:Editor
C:
CD %BBS%
Call Msgs
Goto BTTime
Rem If we got here, then it is time to Hatch some files.
:Hatchit
C:
CD %BBS%
HatchP
Goto BTTime
Rem If we got here, then it is time to list the contents of Outbound.
:Mail_Chk
Dir %OUT% /p
Goto BTTime
Rem If we got here, then it is time Export the mail.
:Mail_Out
Rem Clean out calling tickies in Outbound.
If Exist %OUT%\*.?$? Del %OUT%\*.?$? >Nul:
Call Export
Rem If we got here, then it is time to schedule a call to the Boss.
:POLL
If Exist %OUT%\*.?$? Del %OUT%\*.?$? >Nul:
Omail Poll -c%BOSS% >Nul:
Goto Top
Rem Time to get out
:Off_Bottom
If Exist INBINK Del INBINK >Nul:
Echo.