home *** CD-ROM | disk | FTP | other *** search
/ Hackers Magazine 57 / CdHackersMagazineNr57.iso / Software / Programming / nsis-2.46-setup.exe / Examples / System / SysFunc.nsh < prev    next >
Encoding:
Text File  |  2007-12-01  |  10.3 KB  |  398 lines
  1. ; Some useful functions based on System plugin
  2. ; 
  3. ; (c) brainsucker, 2002
  4. ; (r) BSForce
  5.  
  6. ; Check for double includes
  7. !ifndef SysFunc.NSH.Included
  8. !define SysFunc.NSH.Included
  9.  
  10. !include "${NSISDIR}\Examples\System\System.nsh"
  11.  
  12. !verbose 3      ; For WinMessages especially
  13.   !include "WinMessages.nsh"
  14. !verbose 4
  15.  
  16. ; ================= GetInstallerExeName implementation =================
  17.  
  18. ; Adopted Get Parameter function -> now it gets full installer.exe path
  19. ; input - nothing, output -> full path at the top of the stack
  20. Function GetInstallerExeName
  21.    Push $R0
  22.    Push $R1
  23.    Push $R2
  24.    StrCpy $R0 $CMDLINE 1
  25.    StrCpy $R1 '"'
  26.    StrCpy $R2 1
  27.    StrCmp $R0 '"' loop
  28.      StrCpy $R1 ' ' ; we're scanning for a space instead of a quote
  29.    loop:
  30.      StrCpy $R0 $CMDLINE 1 $R2
  31.      StrCmp $R0 $R1 loop2
  32.      StrCmp $R0 "" loop2
  33.      IntOp $R2 $R2 + 1
  34.      Goto loop
  35.    loop2:
  36.  
  37.    ; Ok, have we found last exename character or string end?
  38.    StrCmp $R0 "" "" +2
  39.         IntOp $R2 $R2 - 1       ; last exename char
  40.    StrCmp $R1 ' ' +3    ; was first character the '"', or something other?
  41.         StrCpy $R1 1    ; it was quote
  42.         Goto +2
  43.         StrCpy $R1 0    
  44.    IntOp $R2 $R2 - $R1
  45.    StrCpy $R0 $CMDLINE $R2 $R1  
  46.  
  47.    SearchPath $R0 $R0      ; expand file name to full path
  48.  
  49.    Pop $R2
  50.    Pop $R1
  51.    Exch $R0
  52. FunctionEnd
  53.  
  54. ; ================= systemGetFileSysTime implementation =================
  55.  
  56. !macro smGetFileSysTime FILENAME
  57.         Push ${FILENAME}
  58.         Call systemGetFileSysTime
  59.         Pop  $R0
  60. !macroend
  61.  
  62. ; -----------------------------------------------------------------
  63. ; systemGetFileSysTime (params on stack):
  64. ;       FILENAME        -       name of file to get file time
  65. ; returns to stack (SYSTEMTIME struct addr)
  66. ; -----------------------------------------------------------------
  67.  
  68. ; uses original method from NSIS
  69. Function systemGetFileSysTime
  70.     System::Store "s r1"
  71.  
  72.     StrCpy $R0 0     
  73.  
  74.     ; create WIN32_FIND_DATA struct
  75.     System::Call '*${stWIN32_FIND_DATA} .r2'
  76.  
  77.     ; Find file info
  78.     System::Call '${sysFindFirstFile}(r1, r2) .r3'
  79.  
  80.     ; ok?
  81.     IntCmp $3 ${INVALID_HANDLE_VALUE} sgfst_exit
  82.  
  83.     ; close file search
  84.     System::Call '${sysFindClose}(r3)'
  85.  
  86.     ; Create systemtime struct for local time
  87.     System::Call '*${stSYSTEMTIME} .R0'
  88.  
  89.     ; Get File time
  90.     System::Call '*$2${stWIN32_FIND_DATA} (,,, .r3)'
  91.  
  92.     ; Convert file time (UTC) to local file time
  93.     System::Call '${sysFileTimeToLocalFileTime}(r3, .r1)'
  94.  
  95.     ; Convert file time to system time
  96.     System::Call '${sysFileTimeToSystemTime}(r1, R0)'
  97.  
  98. sgfst_exit:
  99.     ; free used memory for WIN32_FIND_DATA struct
  100.     System::Free $2    
  101.  
  102.     System::Store "P0 l"
  103. FunctionEnd
  104.  
  105. ; ================= systemMessageBox implementation =================
  106.  
  107. ; return to $R0
  108. !macro smMessageBox MODULE MSG CAPTION STYLE ICON
  109.      Push "${ICON}"
  110.      Push "${STYLE}"
  111.      Push "${CAPTION}"
  112.      Push "${MSG}"
  113.      Push "${MODULE}"
  114.      Call systemMessageBox
  115.      Pop $R0
  116. !macroend
  117.  
  118. ; -----------------------------------------------------------------
  119. ; systemMessageBox (params on stack):
  120. ;       Module: either handle ("i HANDLE", HANDLE could be 0) or "modulename" 
  121. ;       Msg: text of message
  122. ;       Caption: caption of message box window
  123. ;       Style: style, buttons etc
  124. ;       Icon: either icon handle ("i HANDLE") or resource name 
  125. ; returns to stack
  126. ; -----------------------------------------------------------------
  127. Function systemMessageBox
  128.      System::Store "s r2r3r4r5r6"
  129.  
  130.      ; may be Module is module handle?
  131.      StrCpy $1 $2
  132.      IntCmp $1 0 0 smbnext smbnext
  133.  
  134.      ; Get module handle
  135.      System::Call '${sysGetModuleHandle}($2) .r1'
  136.      IntCmp $1 0 loadlib libnotloaded libnotloaded
  137.  
  138. loadlib:
  139.      ; Load module and get handle
  140.      System::Call '${sysLoadLibrary}($2) .r1'
  141.      IntCmp $1 0 0 smbnext smbnext
  142.  
  143. libnotloaded:
  144.      ; Indicate that LoadLibrary wasn't used
  145.      StrCpy $2 1
  146.  
  147. smbnext:
  148.      ; Create MSGBOXPARAMS structure
  149.      System::Call '*${stMSGBOXPARAMS}(, $HWNDPARENT, r1, r3, r4, "$5|${MB_USERICON}", $6, _) .r0'
  150.      ; call MessageBoxIndirect
  151.      System::Call '${sysMessageBoxIndirect}(r0) .R0'
  152.      ; free MSGBOXPARAMS structure
  153.  
  154.      System::Free $0
  155.  
  156.      ; have we used load library at start?
  157.      IntCmp $2 0 0 smbskipfree smbskipfree
  158.      ; No, then free the module
  159.      System::Call '${sysFreeLibrary}(r1)'
  160.  
  161. smbskipfree:
  162.      System::Store "P0 l"   
  163. FunctionEnd
  164.  
  165. ; ================= systemSplash implementation =================
  166.  
  167. ; returns to $R0
  168. !macro smSystemSplash DELAY FILE
  169.     Push ${FILE}
  170.     Push ${DELAY}
  171.     call systemSplash
  172.     Pop $R0    
  173. !macroend
  174.  
  175. ; -----------------------------------------------------------------
  176. ; systemSplash (params on stack):
  177. ;       Delay - time in ms to show the splash
  178. ;       File - bitmap (& audio) file name (without extension)
  179. ; returns to stack
  180. ; -----------------------------------------------------------------
  181.  
  182. Function _systemSplashWndCB
  183.    ; Callback receives 4 values
  184.    System::Store "s r2r5r7r9"
  185.  
  186.    ; Message branching
  187.    IntCmp $5 ${WM_CLOSE} m_Close
  188.    IntCmp $5 ${WM_TIMER} m_Timer
  189.    IntCmp $5 ${WM_LBUTTONDOWN} m_Lbtn
  190.    IntCmp $5 ${WM_CREATE} m_Create
  191.    IntCmp $5 ${WM_PAINT} m_Paint
  192.    goto default
  193.  
  194. m_Create:
  195.    ; Create structures
  196.    System::Call "*${stRECT} (_) .R8"
  197.    System::Call "*${stBITMAP} (_, &l0 .R7) .R9"
  198.  
  199.    ; Get bitmap info
  200.    System::Call "${sysGetObject} (r6, R7, R9)" 
  201.    
  202.    ; Get desktop info
  203.    System::Call "${sysSystemParametersInfo} (${SPI_GETWORKAREA}, 0, R8, 0)" 
  204.  
  205.    ; Style (callbacked)
  206.    System::Call "${sysSetWindowLong} (r2, ${GWL_STYLE}, 0) .s" 
  207.    !insertmacro SINGLE_CALLBACK 5 $R7 1 _systemSplashWndCB
  208.  
  209.    ; Calculate and set window pos
  210.  
  211.    ; Get bmWidth(R2) and bmHeight(R3)
  212.    System::Call "*$R9${stBITMAP} (,.R2,.R3)"
  213.    ; Get left(R4), top(R5), right(R6), bottom(R7)
  214.    System::Call "*$R8${stRECT} (.R4,.R5,.R6,.R7)"
  215.  
  216.    ; Left pos
  217.    IntOp $R0 $R6 - $R4
  218.    IntOp $R0 $R0 - $R2
  219.    IntOp $R0 $R0 / 2
  220.    IntOp $R0 $R0 + $R4
  221.  
  222.    ; Top pos
  223.    IntOp $R1 $R7 - $R5
  224.    IntOp $R1 $R1 - $R3
  225.    IntOp $R1 $R1 / 2
  226.    IntOp $R1 $R1 + $R5
  227.  
  228.    System::Call "${sysSetWindowPos} (r2, 0, R0, R1, R2, R3, ${SWP_NOZORDER}) .s" 
  229.    !insertmacro SINGLE_CALLBACK 6 $R7 1 _systemSplashWndCB
  230.  
  231.    ; Show window
  232.    System::Call "${sysShowWindow} (r2, ${SW_SHOW}) .s" 
  233.    !insertmacro SINGLE_CALLBACK 7 $R7 1 _systemSplashWndCB
  234.  
  235.    ; Set Timer
  236.    System::Call "${sysSetTimer} (r2, 1, r8,)"
  237.  
  238.    ; Free used memory
  239.    System::Free $R8
  240.    System::Free $R9
  241.  
  242.    StrCpy $R0 0
  243.    goto exit
  244.  
  245. m_Paint:
  246.    ; Create structures
  247.    System::Call "*${stRECT} (_) .R8"
  248.    System::Call "*${stPAINTSTRUCT} (_) .R9"
  249.  
  250.    ; Begin Paint
  251.    System::Call "${sysBeginPaint} (r2, R9) .R7"
  252.  
  253.    ; CreateCompatibleDC
  254.    System::Call "${sysCreateCompatibleDC} (R7) .R6"
  255.  
  256.    ; GetClientRect
  257.    System::Call "${sysGetClientRect} (r2, R8)"
  258.   
  259.    ; Select new bitmap
  260.    System::Call "${sysSelectObject} (R6, r6) .R5"
  261.  
  262.    ; Get left(R0), top(R1), right(R2), bottom(R3)
  263.    System::Call "*$R8${stRECT} (.R0,.R1,.R2,.R3)"
  264.      
  265.    ; width=right-left  
  266.    IntOp $R2 $R2 - $R0
  267.    ; height=bottom-top
  268.    IntOp $R3 $R3 - $R1
  269.  
  270.    System::Call "${sysBitBlt} (R7, R0, R1, R2, R3, R6, 0, 0, ${SRCCOPY})" 
  271.  
  272.    ; Select old bitmap
  273.    System::Call "${sysSelectObject} (R6, R5)"
  274.    
  275.    ; Delete compatible DC
  276.    System::Call "${sysDeleteDC} (R6)"
  277.  
  278.    ; End Paint
  279.    System::Call "${sysEndPaint} (r2, R9)"
  280.  
  281.    ; Free used memory
  282.    System::Free $R8
  283.    System::Free $R9
  284.  
  285.    StrCpy $R0 0
  286.    goto exit
  287.  
  288. m_Timer:
  289. m_Lbtn:
  290.    StrCpy $4 0
  291.    IntCmp $5 ${WM_TIMER} destroy
  292.         StrCpy $4 1
  293.  
  294. destroy:
  295.    System::Call "${sysDestroyWindow} (r2) .s"
  296.    !insertmacro SINGLE_CALLBACK 12 $R4 1 _systemSplashWndCB
  297.  
  298. default:
  299.    ; Default
  300.    System::Call "${sysDefWindowProc} (r2, r5, r7, r9) .s"
  301.    !insertmacro SINGLE_CALLBACK 14 $R0 1 _systemSplashWndCB
  302.    goto exit
  303.  
  304. m_Close:
  305.    StrCpy $R0 0
  306.    goto exit
  307.  
  308. exit:
  309.    ; Restore
  310.    System::Store "p4P0 l R0r4"
  311.  
  312.    ; Return from callback
  313.    System::Call "$3" $R0
  314. FunctionEnd
  315.  
  316. Function systemSplash
  317.  
  318.    ; Save registers and get input 
  319.    System::Store "s r8r9"
  320.  
  321.    ; Get module instance
  322.    System::Call "${sysGetModuleHandle} (i) .r7"
  323.  
  324.    ; Get arrow cursor
  325.    System::Call "${sysLoadCursor} (0, i ${IDC_ARROW}) .R9" 
  326.  
  327.    ; Get callback
  328.    System::Get "${sysWNDPROC}"
  329.    Pop $3
  330.  
  331.    ; Create window class
  332.    System::Call "*${stWNDCLASS} (0,r3,0,0,r7,0,R9,0,i 0,'_sp') .R9"
  333.  
  334.    ; Register window class
  335.    System::Call "${sysRegisterClass} (R9) .R9"
  336.    IntCmp $R9 0 errorexit ; Class registered ok?
  337.  
  338.    ; Load Image (LR_CREATEDIBSECTION|LR_LOADFROMFILE = 0x2010)
  339.    System::Call '${sysLoadImage} (, s, ${IMAGE_BITMAP}, 0, 0, ${LR_CREATEDIBSECTION}|${LR_LOADFROMFILE}) .r6' "$9.bmp"
  340.    IntCmp $6 0 errorexit        ; Image loaded ok?
  341.  
  342.    ; Start the sound (SND_ASYNC|SND_FILENAME|SND_NODEFAULT = 0x20003)
  343.    System::Call "${sysPlaySound} (s,,${SND_ASYNC}|${SND_FILENAME}|${SND_NODEFAULT})" "$9.wav" 
  344.  
  345.    ; Create window
  346.    System::Call "${sysCreateWindowEx} (${WS_EX_TOOLWINDOW}, s, s,,,,,, $HWNDPARENT,,r7,) .s" "_sp" "_sp" 
  347.    !insertmacro SINGLE_CALLBACK 1 $5 1 _systemSplashWndCB
  348.  
  349.    ; Create MSG struct
  350.    System::Call "*${stMSG} (_) i.R9"
  351.  
  352.    ; -------------------------
  353. repeat:
  354.         ; Check for window
  355.         System::Call "${sysIsWindow} (r5) .s"
  356.         !insertmacro SINGLE_CALLBACK 2 $R8 1 _systemSplashWndCB
  357.         IntCmp $R8 0 finish
  358.  
  359.         ; Get message
  360.         System::Call "${sysGetMessage} (R9, r5,_) .s"
  361.         !insertmacro SINGLE_CALLBACK 3 $R8 1 _systemSplashWndCB
  362.         IntCmp $R8 0 finish
  363.  
  364.         ; Dispatch message
  365.         System::Call "${sysDispatchMessage} (R9) .s"
  366.         !insertmacro SINGLE_CALLBACK 4 $R8 1 _systemSplashWndCB
  367.  
  368.         ; Repeat dispatch cycle
  369.         goto repeat
  370.    ; -------------------------
  371.  
  372. finish:
  373.    ; Stop the sound
  374.    System::Call "${sysPlaySound} (i 0, i 0, i 0)"
  375.  
  376.    ; Delete bitmap object
  377.    System::Call "${sysDeleteObject} (r6)"
  378.  
  379.    ; Delete the callback queue
  380.    System::Free $3
  381.  
  382.    ; Dialog return
  383.    StrCpy $R0 $4
  384.    goto exit
  385.  
  386. ; Exit in case of error
  387. errorexit:
  388.    StrCpy $R0 -1
  389.    goto exit
  390.  
  391. exit:
  392.    ; Restore register and put output
  393.    System::Store "P0 l"
  394. FunctionEnd
  395.  
  396. !verbose 4
  397.  
  398. !endif