home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / xfd_developer / sources / asm / szdd.a < prev    next >
Encoding:
Text File  |  2000-06-27  |  3.8 KB  |  152 lines
  1. ; SZDD decruncher by Kyzer/CSG <kyzer@4u.net>
  2. ; $VER: SZDD.c 1.1 (19.06.2000)
  3. ; v1.1: better xfd name, eliminated 4k buffer
  4. ;
  5. ; based on "ms-expand" by Daniel Risacher <magnus@mit.edu> and someone else
  6. ; http://www.im.lcs.mit.edu/~magnus/ms-expand.c
  7. ;
  8. ; Header:
  9. ; 4 bytes : "SZDD"
  10. ; 4 bytes : $88,$F0,$27,$33
  11. ; 2 bytes : random value? (seen $41,$00 and $41,$39)
  12. ; 4 bytes : A,B,C,D. unpacked size of file is (D<<24)|(C<<16)|(B<<8)|(A)
  13. ; 
  14. ; Compressed data format:
  15. ; - one header byte, whose bits from LSB (0) to MSB (7) dictate the format
  16. ;   of the next 8 elements
  17. ; - if a bit is set, the next element is a single byte literal
  18. ; - otherwise, the next element is a repeat: two bytes, %AAAAAAAA, %BBBBCCCC
  19. ;   where offset = %BBBBAAAAAAAA and length is %CCCC + 3
  20. ;
  21. ; A virtual 4096 byte wraparound window must be kept by the decruncher.
  22. ; A wraparound pointer starts at 4096-16 and each outputted byte must be
  23. ; written at that position and the pointer advanced by one. The buffer
  24. ; starts off filled with zeroes. The offsets of the compressed data refer
  25. ; to an absolute position in this buffer, which may be before the pointer,
  26. ; or after it.
  27. ;
  28. ; It seems that there can often be superfluous data at the end of a file -
  29. ; I can only go by the uncompressed size, so I can only really test running
  30. ; out of source data. Some files end in the middle of a run, so I can't
  31. ; test if they exactly reach the endpoint and no more.
  32.  
  33. SZDD_WNDSIZE=4096
  34. SZDD_WNDMASK=4095
  35. SZDD_MINLEN=14
  36. SZDD_OVERRUN=144
  37.  
  38.     include    exec/memory.i
  39.     include    libraries/xfdmaster.i
  40.     include    lvo/exec_lib.i
  41.  
  42.     IFD    TEST
  43.     include    xfdExeHead.a
  44.     ENDC
  45.  
  46. ForeMan    dc.l    $70FF4E75,XFDF_ID    ; id
  47.     dc.w    XFDF_VERSION        ; foreman version
  48.     dcb.w    5,0            ; reserved stuff
  49.     dc.l    SZDDslv            ; first slave
  50. SZDDslv    dc.l    0
  51.     dc.w    XFDS_VERSION,39
  52.     dc.l    SZDDnam
  53.     dc.w    XFDPFF_DATA!XFDPFF_RECOGLEN!XFDPFF_USERTARGET,0
  54.     dc.l    SZDD_recog,SZDD_decrunch,0,0
  55.     dc.l    0,SZDD_MINLEN
  56.  
  57. SZDD_recog
  58.     cmp.l    #"SZDD",(a0)
  59.     bne.s    .fail
  60.     move.l    10(a0),d0
  61.     rol.w    #8,d0
  62.     swap    d0
  63.     rol.w    #8,d0
  64.     move.l    d0,xfdrr_FinalTargetLen(a1)
  65.     add.l    #SZDD_OVERRUN,d0
  66.     move.l    d0,xfdrr_MinTargetLen(a1)
  67.     moveq    #1,d0            ; return success
  68.     rts
  69. .fail    moveq    #0,d0
  70.     rts
  71.  
  72. SZDD_decrunch
  73.     movem.l    d2-d7/a2-a6,-(sp)
  74.     move.l    a0,a4                ; a4 = BufferInfo
  75.  
  76.     move.l    xfdbi_SourceBuffer(a4),a0    ; a0 = src
  77.     move.l    a0,a2
  78.     adda.l    xfdbi_SourceBufLen(a4),a2    ; a2 = ends
  79.     adda.w    #14,a0
  80.     move.l    xfdbi_UserTargetBuf(a4),a1    ; a1 = dest
  81.     move.l    a1,a3
  82.     adda.l    xfdbi_TargetBufSaveLen(a4),a3    ; a3 = endd
  83.     move.l    a1,d3                ; d3 = start
  84.  
  85.     move.w    #SZDD_WNDSIZE-16,d7        ; d7 = posn
  86.     move.w    #SZDD_WNDMASK,d6        ; d6 = bufmask
  87.  
  88. .mainlp    move.b    (a0)+,d5            ; d5 = bits
  89.     moveq    #0,d4                ; d4 = mask
  90. .bitlp    btst.b    d4,d5
  91.     beq.s    .rep
  92.  
  93.     ; literal
  94.     move.b    (a0)+,(a1)+
  95.     addq.w    #1,d7
  96.     bra.s    .nxtbit
  97.  
  98. .rep    ; repeat
  99.     moveq    #0,d0
  100.     move.b    (a0)+,d0    ; d0 = offset
  101.     move.b    (a0)+,d1    ; d1 = length
  102.  
  103.     moveq    #0,d2
  104.     move.b    d1,d2
  105.     asl.w    #4,d2
  106.     move.b    #0,d2
  107.     or.w    d2,d0
  108.  
  109.     andi.w    #$f,d1
  110.     addq.b    #3,d1
  111.  
  112.     and.w    d6,d7
  113.     cmp.w    d0,d7
  114.     bhi.s    .noadd        ; if (offset <= posn) don't add WNDSIZE
  115.     add.w    #SZDD_WNDSIZE,d7; [or bset #12,d7 - but that's no shorter]
  116. .noadd    lea    (a1,d0.w),a5    ; a5 = rep, = dest+offset-posn
  117.     suba.w    d7,a5
  118.     add.w    d1,d7        ; posn += length
  119.  
  120. .clr    cmp.l    a5,d3        ; if rep >= base, don't do clearing
  121.     bcs.s    .noclr
  122.     clr.b    (a1)+        ; clear one byte
  123.     addq.l    #1,a5        ; rep++
  124.     subq.w    #1,d1        ; length--
  125.     beq.s    .nxtbit
  126.     bra.s    .clr
  127. .noclr    move.b    (a5)+,(a1)+    ; *dest++=*rep++
  128.     subq.w    #1,d1        ; while (length--)
  129.     bne.s    .noclr
  130.  
  131. .nxtbit    cmp.l    a1,a3        ; if dest >= endd, stop now
  132.     bcs.s    .done
  133.  
  134.     addq.l    #1,d4        ; next bit, from 0-7
  135.     cmp.b    #8,d4
  136.     bcs.s    .bitlp        ; if d4<8, goto .bitlp
  137.  
  138.     cmp.l    a0,a2
  139.     bcc.s    .mainlp        ; if src < ends, go back to main loop
  140.  
  141. .corupt    move.w    #XFDERR_CORRUPTEDDATA,xfdbi_Error(a4)
  142.     moveq    #0,d0
  143.     bra.s    .exit
  144. .done    clr.w    xfdbi_Error(a4)
  145.     moveq    #1,d0
  146. .exit    movem.l    (sp)+,d2-d7/a2-a6
  147.     rts
  148.  
  149.  
  150. SZDDnam    dc.b    '(SZDD) Microsoft Data Cruncher',0
  151.     dc.b    '$VER: SZDD 1.1 (19.06.2000) by <kyzer@4u.net>',0
  152.