home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quakeworld_src / client / sys_timerppc.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  3.2 KB  |  171 lines
  1. # 
  2. # Copyright (C) 1996-1997 Id Software, Inc. 
  3. # 
  4. # This program is free software; you can redistribute it and/or 
  5. # modify it under the terms of the GNU General Public License 
  6. # as published by the Free Software Foundation; either version 2 
  7. # of the License, or (at your option) any later version. 
  8. # 
  9. # This program is distributed in the hope that it will be useful, 
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. # 
  13. # See the GNU General Public License for more details. 
  14. # 
  15. # You should have received a copy of the GNU General Public License 
  16. # along with this program; if not, write to the Free Software 
  17. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. # 
  19.  
  20.  
  21. # Determine PPC bus clock by using CIA timers.
  22. # Based on powerpc.library source by Sam Jordan. Thanks Sam!
  23. # ** This code is used for the PowerUp port only **
  24.  
  25.  
  26. # CIATIMER structure
  27. .set    CIATIMER_RESOURCE,    0
  28. .set    CIATIMER_INTERRUPT,    4
  29. .set    CIATIMER_CONTROL,    8
  30. .set    CIATIMER_LOW,        12
  31. .set    CIATIMER_HIGH,        16
  32. .set    CIATIMER_STOPMASK,    20
  33. .set    CIATIMER_STARTMASK,    21
  34. .set    CIATIMER_ICRBIT,    22
  35. .set    CIATIMER_ECLOCK,    24
  36. .set    CIATIMER_SIZE,        28
  37.  
  38.  
  39.     .text
  40.  
  41.  
  42.     .align    3
  43.     .globl    MeasureBusClock
  44. MeasureBusClock:
  45. # r3 = ciatimer structure pointer
  46. # -> r3 = bus clock in microseconds
  47.  
  48.     mflr    r0
  49.     stw    r0,4(r1)
  50.     stwu    r1,-16(r1)
  51.     li    r10,-1
  52.     lwz    r4,CIATIMER_CONTROL(r3)
  53.     lwz    r5,CIATIMER_LOW(r3)
  54.     lwz    r6,CIATIMER_HIGH(r3)
  55.     lbz    r7,CIATIMER_STOPMASK(r3)
  56.     lbz    r8,CIATIMER_STARTMASK(r3)
  57.     lbz    r0,0(r4)
  58.     and    r0,r0,r7
  59.     stb    r0,0(r4)        # stop CIA timer
  60.     stb    r10,0(r5)        # set to 0xffff
  61.     stb    r10,0(r6)
  62.     lbz    r0,0(r4)
  63.     or    r0,r0,r8
  64.     mftbl    r9            # PPC start time
  65.     stb    r0,0(r4)        # start CIA timer
  66.     sync
  67. check:
  68.     lbz    r0,0(r6)
  69.     mr.    r0,r0
  70.     bne    check
  71. check2:
  72.     lbz    r0,0(r6)
  73.     mr.    r0,r0
  74.     beq    check2
  75. check3:
  76.     lbz    r0,0(r6)
  77.     mr.    r0,r0
  78.     bne    check3
  79.     mftbl    r8            # PPC stop time
  80.     lbz    r6,0(r5)
  81.     lbz    r0,0(r4)
  82.     and    r0,r0,r7
  83.     stb    r0,0(r4)        # stop CIA timer
  84.     subf    r8,r9,r8        # PPC timer difference
  85.     lis    r7,0x1ffff@h
  86.     ori    r7,r7,0x1ffff@l
  87.     subf    r7,r6,r7
  88.     lwz    r5,CIATIMER_ECLOCK(r3)
  89.     lis    r9,4000000000@h
  90.     ori    r9,r9,4000000000@l
  91.     mullw    r4,r7,r9
  92.     mulhwu    r3,r7,r9
  93.     bl    Div64_32
  94.     mr    r5,r3
  95.     mullw    r4,r8,r9
  96.     mulhwu    r3,r8,r9
  97.     bl    Div64_32
  98.     slwi    r3,r3,2            # PPC timer is busclock/4
  99.     addi    r1,r1,16
  100.     lwz    r0,4(r1)
  101.     mtlr    r0
  102.     blr
  103.  
  104.     .type    MeasureBusClock,@function
  105.     .size    MeasureBusClock,$-MeasureBusClock
  106.  
  107.  
  108.     .align    3
  109.     .globl    CorrectBusClock
  110. CorrectBusClock:
  111. # r3 = bus clock measured
  112. # -> r3 = bus clock corrected
  113.  
  114.     mr    r5,r3
  115.     mulli    r3,r3,3
  116.     lis    r4,5000000@h
  117.     ori    r4,r4,5000000@l
  118.     add    r3,r3,r4
  119.     lis    r4,10000000@h
  120.     ori    r4,r4,10000000@l
  121.     divwu    r3,r3,r4
  122.     mullw    r3,r3,r4
  123.     li    r4,3
  124.     divwu    r3,r3,r4
  125.     blr
  126.  
  127.     .type    CorrectBusClock,@function
  128.     .size    CorrectBusClock,$-CorrectBusClock
  129.  
  130.  
  131.     .align    3
  132. Div64_32:
  133.     mfctr    r0
  134.     stwu    r1,-32(r1)
  135.     stw    r0,8(r1)
  136.     stw    r4,12(r1)
  137.     stw    r5,16(r1)
  138.     stw    r6,20(r1)
  139.     li    r0,32
  140.     mtctr    r0
  141.     li    r6,0
  142. loop:
  143.     mr.    r3,r3
  144.     bge    cont
  145.     addc    r4,r4,r4
  146.     adde    r3,r3,r3
  147.     add    r6,r6,r6
  148.     b    cont1
  149. cont:
  150.     addc    r4,r4,r4
  151.     adde    r3,r3,r3
  152.     add    r6,r6,r6
  153.     cmplw    r5,r3
  154.     bgt    cont2
  155. cont1:
  156.     subf.    r3,r5,r3
  157.     addi    r6,r6,1
  158. cont2:
  159.     bdnz    loop
  160.     lwz    r0,8(r1)
  161.     mr    r3,r6
  162.     mtctr    r0
  163.     lwz    r4,12(r1)
  164.     lwz    r5,16(r1)
  165.     lwz    r6,20(r1)
  166.     addi    r1,r1,32
  167.     blr
  168.  
  169.     .type    Div64_32,@function
  170.     .size    Div64_32,$-Div64_32
  171.