home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quakeworld_src / client / mathlibppc.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  13.1 KB  |  604 lines
  1. # 
  2. # Copyright (C) 1996-1997 Id Software, Inc. 
  3. # 
  4. # This program is free software; you can redistribute it and/or 
  5. # modify it under the terms of the GNU General Public License 
  6. # as published by the Free Software Foundation; either version 2 
  7. # of the License, or (at your option) any later version. 
  8. # 
  9. # This program is distributed in the hope that it will be useful, 
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. # 
  13. # See the GNU General Public License for more details. 
  14. # 
  15. # You should have received a copy of the GNU General Public License 
  16. # along with this program; if not, write to the Free Software 
  17. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. # 
  19.  
  20. #
  21. # Quake for AMIGA
  22. #
  23. # mathlibPPC.s
  24. #
  25. # Define WOS for PowerOpen ABI, otherwise SVR4-ABI is used.
  26. #
  27.  
  28. .include        "macrosPPC.i"
  29.  
  30. #
  31. # external references
  32. #
  33.  
  34.     xrefv    c0
  35.     xrefv    c0_5
  36.     xrefv    INT2DBL_0
  37.  
  38.     xrefv    sin
  39.     xrefv    cos
  40.  
  41.  
  42. #
  43. # defines
  44. #
  45.  
  46. .set MPLANE_NORMAL,0
  47. .set MPLANE_DIST,12
  48. .set MPLANE_TYPE,16
  49. .set MPLANE_SIGNBITS,17
  50. .set MPLANE_SIZEOF,20
  51.  
  52. .set PITCH,0
  53. .set YAW,1
  54. .set ROLL,2
  55.  
  56.  
  57.  
  58.  
  59.  
  60. ###########################################################################
  61. #
  62. #       float anglemod(float a)
  63. #
  64. ###########################################################################
  65.  
  66.     funcdef    anglemod
  67.  
  68. # a = (360.0/65536) * ((int)(a*(65536/360.0)) & 65535);
  69.     stwu    r1,-32(r1)
  70.     lf    f2,c64kDIV360    # must be a double precision constant!
  71.     fmul    f1,f1,f2
  72.     fctiwz    f0,f1
  73.     stfd    f0,24(r1)
  74.     lhz    r3,30(r1)
  75.     lis    r11,0x43300000@h
  76.     stw    r11,24(r1)
  77.     xoris    r11,r3,0x80000000@h
  78.     stw    r11,28(r1)
  79.     lfd    f1,24(r1)
  80.     lf    f2,INT2DBL_0
  81.     fsub    f1,f1,f2
  82.     ls    f2,c360DIV64k
  83.     fmul    f1,f1,f2
  84.     addi    r1,r1,32
  85.     blr
  86.  
  87.     funcend    anglemod
  88.  
  89.  
  90.  
  91.  
  92. ###########################################################################
  93. #
  94. #       int BoxOnPlaneSide (vec3_t emins, vec3_t emaxs, mplane_t *p)
  95. #
  96. ###########################################################################
  97.  
  98.     funcdef    BoxOnPlaneSide
  99.  
  100.     lbz     r0,MPLANE_SIGNBITS(r5)
  101.     lfs     f1,0(r5)                #f1 = p->normal[0]
  102.     lfs     f2,4(r5)                #f2 = p->normal[1]
  103.     cmplwi  r0,3
  104.     lfs     f3,8(r5)                #f3 = p->normal[2]
  105.     lfs     f4,0(r3)                #f4 = emins[0]
  106.     cmplwi  cr1,r0,5
  107.     lfs     f5,0(r4)                #f5 = emaxs[0]
  108.     lfs     f6,4(r3)                #f6 = emins[1]
  109.     cmplwi  cr2,r0,7
  110.     lfs     f7,4(r4)                #f7 = emaxs[1]
  111.     lfs     f8,8(r3)                #f8 = emins[2]
  112.     cmplwi  cr3,r0,1
  113.     lfs     f9,8(r4)                #f9 = emaxs[2]
  114.     ble     .lower
  115. .upper:
  116.     blt     cr1,.c4
  117.     beq     cr1,.c5
  118.     blt     cr2,.c6
  119.     beq     cr2,.c7
  120.     trap
  121. .lower:
  122.     beq     .c3
  123.     bgt     cr3,.c2
  124.     beq     cr3,.c1
  125. .c0:
  126.     fmuls   f10,f5,f1               #f10 = p->normal[0]*emaxs[0]
  127.     fmuls   f11,f4,f1               #f11 = p->normal[0]*emins[0]
  128.     fmadd   f10,f2,f7,f10           #f10+= p->normal[1]*emaxs[1]
  129.     fmadd   f11,f2,f6,f11           #f11+= p->normal[1]*emins[1]
  130.     fmadd   f10,f3,f9,f10           #f10+= p->normal[2]*emaxs[2]
  131.     fmadd   f11,f3,f8,f11           #f11+= p->normal[2]*emins[2]
  132.     b       .cont
  133. .c1:
  134.     fmuls   f10,f4,f1               #f10 = p->normal[0]*emins[0]
  135.     fmuls   f11,f5,f1               #f11 = p->normal[0]*emaxs[0]
  136.     fmadd   f10,f2,f7,f10           #f10+= p->normal[1]*emaxs[1]
  137.     fmadd   f11,f2,f6,f11           #f11+= p->normal[1]*emins[1]
  138.     fmadd   f10,f3,f9,f10           #f10+= p->normal[2]*emaxs[2]
  139.     fmadd   f11,f3,f8,f11           #f11+= p->normal[2]*emins[2]
  140.     b       .cont
  141. .c2:
  142.     fmuls   f10,f5,f1               #f10 = p->normal[0]*emaxs[0]
  143.     fmuls   f11,f4,f1               #f11 = p->normal[0]*emins[0]
  144.     fmadd   f10,f2,f6,f10           #f10+= p->normal[1]*emins[1]
  145.     fmadd   f11,f2,f7,f11           #f11+= p->normal[1]*emaxs[1]
  146.     fmadd   f10,f3,f9,f10           #f10+= p->normal[2]*emaxs[2]
  147.     fmadd   f11,f3,f8,f11           #f11+= p->normal[2]*emins[2]
  148.     b       .cont
  149. .c3:
  150.     fmuls   f10,f4,f1               #f10 = p->normal[0]*emins[0]
  151.     fmuls   f11,f5,f1               #f11 = p->normal[0]*emaxs[0]
  152.     fmadd   f10,f2,f6,f10           #f10+= p->normal[1]*emins[1]
  153.     fmadd   f11,f2,f7,f11           #f11+= p->normal[1]*emaxs[1]
  154.     fmadd   f10,f3,f9,f10           #f10+= p->normal[2]*emaxs[2]
  155.     fmadd   f11,f3,f8,f11           #f11+= p->normal[2]*emins[2]
  156.     b       .cont
  157. .c4:
  158.     fmuls   f10,f5,f1               #f10 = p->normal[0]*emaxs[0]
  159.     fmuls   f11,f4,f1               #f11 = p->normal[0]*emins[0]
  160.     fmadd   f10,f2,f7,f10           #f10+= p->normal[1]*emaxs[1]
  161.     fmadd   f11,f2,f6,f11           #f11+= p->normal[1]*emins[1]
  162.     fmadd   f10,f3,f8,f10           #f10+= p->normal[2]*emins[2]
  163.     fmadd   f11,f3,f9,f11           #f11+= p->normal[2]*emaxs[2]
  164.     b       .cont
  165. .c5:
  166.     fmuls   f10,f4,f1               #f10 = p->normal[0]*emins[0]
  167.     fmuls   f11,f5,f1               #f11 = p->normal[0]*emaxs[0]
  168.     fmadd   f10,f2,f7,f10           #f10+= p->normal[1]*emaxs[1]
  169.     fmadd   f11,f2,f6,f11           #f11+= p->normal[1]*emins[1]
  170.     fmadd   f10,f3,f8,f10           #f10+= p->normal[2]*emins[2]
  171.     fmadd   f11,f3,f9,f11           #f11+= p->normal[2]*emaxs[2]
  172.     b       .cont
  173. .c6:
  174.     fmuls   f10,f5,f1               #f10 = p->normal[0]*emaxs[0]
  175.     fmuls   f11,f4,f1               #f11 = p->normal[0]*emins[0]
  176.     fmadd   f10,f2,f6,f10           #f10+= p->normal[1]*eminx[1]
  177.     fmadd   f11,f2,f7,f11           #f11+= p->normal[1]*emaxs[1]
  178.     fmadd   f10,f3,f8,f10           #f10+= p->normal[2]*emins[2]
  179.     fmadd   f11,f3,f9,f11           #f11+= p->normal[2]*emaxs[2]
  180.     b       .cont
  181. .c7:
  182.     fmuls   f10,f4,f1               #f10 = p->normal[0]*emins[0]
  183.     fmuls   f11,f5,f1               #f11 = p->normal[0]*emaxs[0]
  184.     fmadd   f10,f2,f6,f10           #f10+= p->normal[1]*eminx[1]
  185.     fmadd   f11,f2,f7,f11           #f11+= p->normal[1]*emaxs[1]
  186.     fmadd   f10,f3,f8,f10           #f10+= p->normal[2]*emins[2]
  187.     fmadd   f11,f3,f9,f11           #f11+= p->normal[2]*emaxs[2]
  188. .cont:
  189.     lfs     f0,MPLANE_DIST(r5)
  190.     fcmpo   cr0,f10,f0
  191.     blt     .cont2
  192.     li      r3,1
  193. .cont2:
  194.     fcmpo   cr0,f11,f0
  195.     bge     .cont3
  196.     ori     r3,r3,2
  197. .cont3:
  198.     blr
  199.  
  200.     funcend    BoxOnPlaneSide
  201.  
  202.  
  203.  
  204.  
  205. ###########################################################################
  206. #
  207. #       void AngleVectors (vec3_t angles, vec3_t forward, vec3_t right,
  208. #                           vec3_t up)
  209. #
  210. ###########################################################################
  211.  
  212.     funcdef    AngleVectors
  213.  
  214.     init    0,128,4,6
  215.     stmw    r28,gb(r1)
  216.     stfd    f14,fb+0*8(r1)
  217.     stfd    f15,fb+1*8(r1)
  218.     stfd    f16,fb+2*8(r1)
  219.     stfd    f17,fb+3*8(r1)
  220.     stfd    f18,fb+4*8(r1)
  221.     stfd    f19,fb+5*8(r1)
  222.  
  223.     mr      r31,r3
  224.     mr      r30,r4
  225.     mr      r29,r5
  226.     mr      r28,r6
  227.     ls    f19,c1DEGREE
  228.     lfs     f14,YAW*4(r31)
  229.     fmuls   f14,f14,f19
  230.     fmr     f1,f14
  231.     call    sin
  232.     fmr     f15,f1                  #f15 = sy
  233.     fmr     f1,f14
  234.     call    cos
  235.     fmr     f16,f1                  #f16 = cy
  236.     lfs     f14,PITCH*4(r31)
  237.     fmuls   f14,f14,f19
  238.     fmr     f1,f14
  239.     call    sin
  240.     fmr     f17,f1                  #f17 = sp
  241.     fmr     f1,f14
  242.     call    cos
  243.     fmr     f18,f1                  #f18 = cp
  244.     lfs     f14,ROLL*4(r31)
  245.     fmuls   f14,f14,f19
  246.     fmr     f1,f14
  247.     call    sin
  248.     fmr     f19,f1                  #f19 = sr
  249.     fmr     f1,f14
  250.     call    cos
  251.     fmr     f14,f1                  #f14 = cr
  252.     fmuls   f0,f18,f16
  253.     stfs    f0,0(r30)
  254.     fmuls   f1,f18,f15
  255.     stfs    f1,4(r30)
  256.     fneg    f2,f17                  #f2 = -sp
  257.     stfs    f2,8(r30)
  258.     fmuls   f3,f19,f16              #f3 = sr * cy
  259.     fmuls   f4,f19,f15              #f4 = sr * sy
  260.     fmuls   f5,f14,f15              #f5 = cr * sy
  261.     fmuls   f6,f14,f16              #f6 = cr * cy
  262.     fmadds  f7,f3,f2,f5
  263.     stfs    f7,0(r29)
  264.     fmsubs  f8,f4,f2,f6
  265.     stfs    f8,4(r29)
  266.     fmuls   f9,f18,f19
  267.     fneg    f9,f9
  268.     stfs    f9,8(r29)
  269.     fmadds  f7,f6,f17,f4
  270.     stfs    f7,0(r28)
  271.     fmsubs  f8,f5,f17,f3
  272.     stfs    f8,4(r28)
  273.     fmuls   f9,f14,f18
  274.     stfs    f9,8(r28)
  275.  
  276.     lfd    f14,fb+0*8(r1)
  277.     lfd    f15,fb+1*8(r1)
  278.     lfd    f16,fb+2*8(r1)
  279.     lfd    f17,fb+3*8(r1)
  280.     lfd    f18,fb+4*8(r1)
  281.     lfd    f19,fb+5*8(r1)
  282.     lmw    r28,gb(r1)
  283.     exit
  284.  
  285.     funcend    AngleVectors
  286.  
  287.  
  288.  
  289.  
  290. ###########################################################################
  291. #
  292. #       void VectorMA (vec3_t veca, float scale, vec3_t vecb, vec3_t vecc)
  293. #
  294. ###########################################################################
  295.  
  296.     funcdef    VectorMA
  297.  
  298.     lfs     f3,0(r3)
  299.     lfs     f2,0(r4)
  300.     fmadds  f0,f1,f2,f3
  301.     stfs    f0,0(r5)
  302.     lfs     f3,4(r3)
  303.     lfs     f2,4(r4)
  304.     fmadds  f0,f1,f2,f3
  305.     stfs    f0,4(r5)
  306.     lfs     f3,8(r3)
  307.     lfs     f2,8(r4)
  308.     fmadds  f0,f1,f2,f3
  309.     stfs    f0,8(r5)
  310.     blr
  311.  
  312.     funcend    VectorMA
  313.  
  314.  
  315.  
  316.  
  317. ###########################################################################
  318. #
  319. #       vec_t _DotProduct (vec3_t v1, vec3_t v2)
  320. #
  321. ###########################################################################
  322.  
  323.     funcdef    DotProduct
  324.  
  325.     lfs     f1,0(r3)
  326.     lfs     f2,0(r4)
  327.     fmuls   f3,f1,f2
  328.     lfs     f4,4(r3)
  329.     lfs     f5,4(r4)
  330.     fmadd   f6,f4,f5,f3
  331.     lfs     f7,8(r3)
  332.     lfs     f8,8(r4)
  333.     fmadd   f1,f7,f8,f6
  334.     blr
  335.  
  336.     funcend    DotProduct
  337.  
  338.  
  339.  
  340.  
  341. ###########################################################################
  342. #
  343. #      void VectorSubtract (vec3_t veca, vec3_t vecb, vec3_t out)
  344. #
  345. ###########################################################################
  346.  
  347.     funcdef    VectorSubtract
  348.  
  349.     lfs     f1,0(r3)
  350.     lfs     f2,0(r4)
  351.     fsubs   f3,f1,f2
  352.     stfs    f3,0(r5)
  353.     lfs     f4,4(r3)
  354.     lfs     f5,4(r4)
  355.     fsubs   f6,f4,f5
  356.     stfs    f6,4(r5)
  357.     lfs     f7,8(r3)
  358.     lfs     f8,8(r4)
  359.     fsubs   f9,f7,f8
  360.     stfs    f9,8(r5)
  361.     blr
  362.  
  363.     funcend    VectorSubtract
  364.  
  365.  
  366.  
  367.  
  368. ###########################################################################
  369. #
  370. #       void VectorAdd (vec3_t veca, vec3_t vecb, vec3_t out)
  371. #
  372. ###########################################################################
  373.  
  374.     funcdef    VectorAdd
  375.  
  376.     lfs     f1,0(r3)
  377.     lfs     f2,0(r4)
  378.     fadds   f3,f1,f2
  379.     stfs    f3,0(r5)
  380.     lfs     f4,4(r3)
  381.     lfs     f5,4(r4)
  382.     fadds   f6,f4,f5
  383.     stfs    f6,4(r5)
  384.     lfs     f7,8(r3)
  385.     lfs     f8,8(r4)
  386.     fadds   f9,f7,f8
  387.     stfs    f9,8(r5)
  388.     blr
  389.  
  390.     funcend    VectorAdd
  391.  
  392.  
  393.  
  394.  
  395. ###########################################################################
  396. #
  397. #       void VectorCopy (vec3_t in, vec3_t out)
  398. #
  399. ###########################################################################
  400.  
  401.     funcdef    VectorCopy
  402.  
  403.     lfs     f1,0(r3)
  404.     lwz     r5,4(r3)
  405.     lfs     f3,8(r3)
  406.     stfs    f1,0(r4)
  407.     stw     r5,4(r4)
  408.     stfs    f3,8(r4)
  409.     blr
  410.  
  411.     funcend    VectorCopy
  412.  
  413.  
  414.  
  415.  
  416. ###########################################################################
  417. #
  418. #       void CrossProduct (vec3_t v1, vec3_t v2, vec3_t cross)
  419. #
  420. ###########################################################################
  421.  
  422.     funcdef    CrossProduct
  423.  
  424.     lfs     f4,8(r3)
  425.     lfs     f5,4(r4)
  426.     fmuls   f6,f4,f5
  427.     lfs     f1,4(r3)
  428.     lfs     f2,8(r4)
  429.     fmsubs  f3,f1,f2,f6
  430.     stfs    f3,0(r5)
  431.     lfs     f7,0(r3)
  432.     fmuls   f8,f7,f2
  433.     lfs     f9,0(r4)
  434.     fmsubs  f10,f4,f9,f8
  435.     stfs    f10,4(r5)
  436.     fmuls   f11,f1,f9
  437.     fmsubs  f12,f7,f5,f11
  438.     stfs    f12,8(r5)
  439.     blr
  440.  
  441.     funcend    CrossProduct
  442.  
  443.  
  444.  
  445.  
  446. ###########################################################################
  447. #
  448. #       vec3_t Length (vec3_t v)
  449. #
  450. ###########################################################################
  451.  
  452.     funcdef    Length
  453.  
  454.     ls    f3,c0
  455.     lfs     f0,0(r3)
  456.     fmuls   f0,f0,f0
  457.     lfs     f1,4(r3)
  458.     fmadds  f0,f1,f1,f0
  459.     lfs     f2,8(r3)
  460.     fmadds  f1,f2,f2,f0
  461.     fcmpo   cr0,f1,f3
  462.     beqlr
  463.     frsqrte f0,f1
  464.     fres    f1,f0
  465.     blr
  466.  
  467.     funcend    Length
  468.  
  469.  
  470.  
  471.  
  472. ###########################################################################
  473. #
  474. #       float VectorNormalize (vec3_t v)
  475. #
  476. ###########################################################################
  477.  
  478.     funcdef    VectorNormalize
  479.  
  480.     ls    f3,c0
  481.     ls    f7,c0_5
  482.     lfs     f0,0(r3)
  483.     fmuls   f4,f0,f0
  484.     lfs     f6,4(r3)
  485.     fmadds  f5,f6,f6,f4
  486.     lfs     f2,8(r3)
  487.     fmadds  f1,f2,f2,f5
  488.     fcmpo   cr0,f1,f3
  489.     beqlr
  490.     frsqrte f10,f1
  491.     fres    f8,f10
  492.     fdivs   f9,f1,f8
  493.     fadd    f8,f9,f8
  494.     fmul    f1,f8,f7
  495.     fres    f3,f1
  496.     fmuls   f0,f0,f3
  497.     stfs    f0,0(r3)
  498.     fmuls   f6,f6,f3
  499.     stfs    f6,4(r3)
  500.     fmuls   f2,f2,f3
  501.     stfs    f2,8(r3)
  502.     blr
  503.  
  504.     funcend    VectorNormalize
  505.  
  506.  
  507.  
  508.  
  509. ###########################################################################
  510. #
  511. #       void VectorInverse (vec3_t v)
  512. #
  513. ###########################################################################
  514.  
  515.     funcdef    VectorInverse
  516.  
  517.     lfs     f1,0(r3)
  518.     fneg    f0,f1
  519.     stfs    f0,0(r3)
  520.     lfs     f3,4(r3)
  521.     fneg    f2,f3
  522.     stfs    f2,4(r3)
  523.     lfs     f5,8(r3)
  524.     fneg    f4,f5
  525.     stfs    f4,8(r3)
  526.     blr
  527.  
  528.     funcend    VectorInverse
  529.  
  530.  
  531.  
  532.  
  533. ###########################################################################
  534. #
  535. #       void VectorScale (vec3_t in, vec3_t scale, vec3_t out)
  536. #
  537. ###########################################################################
  538.  
  539.     funcdef    VectorScale
  540.  
  541.     lfs     f2,0(r3)
  542.     fmuls   f3,f2,f1
  543.     stfs    f3,0(r4)
  544.     lfs     f4,4(r3)
  545.     fmuls   f5,f4,f1
  546.     stfs    f5,4(r4)
  547.     lfs     f6,8(r3)
  548.     fmuls   f7,f6,f1
  549.     stfs    f7,8(r4)
  550.     blr
  551.  
  552.     funcend    VectorScale
  553.  
  554.  
  555.  
  556.  
  557. ###########################################################################
  558. #
  559. #       void FloorDivMod (double numer, double denom, int *quotient,
  560. #                          int *rem)
  561. #
  562. ###########################################################################
  563.  
  564.     funcdef    FloorDivMod
  565.  
  566.     fctiwz  f0,f1
  567.     stfd    f0,-8(r1)
  568.     lwz     r5,-4(r1)
  569.     mr.    r5,r5
  570.     fctiwz  f0,f2
  571.     stfd    f0,-8(r1)
  572.     lwz     r6,-4(r1)
  573.     divw    r7,r5,r6
  574.     mullw   r8,r7,r6
  575.     subf    r8,r8,r5
  576.     bge     .fdm_exit
  577.     subi    r7,r7,1
  578.     add     r8,r8,r6
  579. .fdm_exit:
  580.     stw     r7,0(r3)
  581.     stw     r8,0(r4)
  582.     blr
  583.  
  584.     funcend    FloorDivMod
  585.  
  586.  
  587.  
  588.  
  589. ###########################################################################
  590.  
  591.  
  592. .ifdef WOS
  593.     .tocd
  594. .else
  595.     .data
  596. .endif
  597.  
  598. lab c1DEGREE
  599.     .float  0.01745329252
  600. lab c64kDIV360
  601.     .long    0x4066c16c,0x16c16c17    # (double)182.0444444...
  602. lab c360DIV64k
  603.     .float    0.0054931641
  604.