home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quakeworld_src / client / in_amigamouse68k.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  2.6 KB  |  109 lines
  1. * 
  2. * Copyright (C) 1996-1997 Id Software, Inc. 
  3. * 
  4. * This program is free software; you can redistribute it and/or 
  5. * modify it under the terms of the GNU General Public License 
  6. * as published by the Free Software Foundation; either version 2 
  7. * of the License, or (at your option) any later version. 
  8. * 
  9. * This program is distributed in the hope that it will be useful, 
  10. * but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. * 
  13. * See the GNU General Public License for more details. 
  14. * 
  15. * You should have received a copy of the GNU General Public License 
  16. * along with this program; if not, write to the Free Software 
  17. * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. * 
  19.  
  20. **
  21. ** Input interrupt routine for mouse control
  22. **
  23. ** used for M68k as well as for PowerPC
  24. **
  25.  
  26.     include "exec/types.i"
  27.     include "devices/inputevent.i"
  28.  
  29.  
  30.     STRUCTURE       InputIntDat,0
  31. ; must be the same as struct InputIntDat in in_amigamouse.c
  32.     ULONG           iid_LeftButtonDown
  33.     ULONG           iid_MidButtonDown
  34.     ULONG           iid_RightButtonDown
  35.     ULONG           iid_LeftButtonUp
  36.     ULONG           iid_MidButtonUp
  37.     ULONG           iid_RightButtonUp
  38.     ULONG           iid_MouseX
  39.     ULONG           iid_MouseY
  40.     ULONG        iid_MouseSpeed
  41.  
  42.  
  43.     code
  44.  
  45.     xdef    _InputIntCode
  46.     xdef    InputIntCode
  47. _InputIntCode:
  48. InputIntCode:
  49.     move.l  a0,-(sp)
  50.     move.l    iid_MouseSpeed(a1),d1
  51. .loop:
  52.     cmp.b   #IECLASS_RAWMOUSE,ie_Class(a0)
  53.     bne.b   .next
  54.     move.w  ie_Code(a0),d0
  55.     btst    #7,d0
  56.     bne.b   .up
  57.     cmp.w   #IECODE_LBUTTON,d0
  58.     beq.b   .lmb_down
  59.     cmp.w   #IECODE_MBUTTON,d0
  60.     beq.b   .mmb_down
  61.     cmp.w   #IECODE_RBUTTON,d0
  62.     beq.b   .rmb_down
  63.     bra.b   .move
  64. .up:
  65.     and.w   #$007f,d0
  66.     cmp.w   #IECODE_LBUTTON,d0
  67.     beq.b   .lmb_up
  68.     cmp.w   #IECODE_MBUTTON,d0
  69.     beq.b   .mmb_up
  70.     cmp.w   #IECODE_RBUTTON,d0
  71.     beq.b   .rmb_up
  72.     bra.b   .move
  73. .lmb_down:
  74.     move.l  #-1,iid_LeftButtonDown(a1)
  75.     clr.l   iid_LeftButtonUp(a1)
  76.     bra.b   .move
  77. .mmb_down:
  78.     move.l  #-1,iid_MidButtonDown(a1)
  79.     clr.l   iid_MidButtonUp(a1)
  80.     bra.b   .move
  81. .rmb_down:
  82.     move.l  #-1,iid_RightButtonDown(a1)
  83.     clr.l   iid_RightButtonUp(a1)
  84.     bra.b   .move
  85. .lmb_up:
  86.     move.l  #-1,iid_LeftButtonUp(a1)
  87.     clr.l   iid_LeftButtonDown(a1)
  88.     bra.b   .move
  89. .mmb_up:
  90.     move.l  #-1,iid_MidButtonUp(a1)
  91.     clr.l   iid_MidButtonDown(a1)
  92.     bra.b   .move
  93. .rmb_up:
  94.     move.l  #-1,iid_RightButtonUp(a1)
  95.     clr.l   iid_RightButtonDown(a1)
  96. .move:
  97.     move.w  ie_X(a0),d0
  98.     muls    d1,d0
  99.     move.l  d0,iid_MouseX(a1)
  100.     move.w  ie_Y(a0),d0
  101.     muls    d1,d0
  102.     move.l  d0,iid_MouseY(a1)
  103. .next:
  104.     move.l  ie_NextEvent(a0),d0
  105.     move.l  d0,a0
  106.     bne.b   .loop
  107.     move.l  (sp)+,d0
  108.     rts
  109.